Adding metadata

23 files changed, 551 insertions, 14 deletions

diff --git a/dev-python/desktop-notifier/Manifest b/dev-python/desktop-notifier/Manifest
index 7e296cfdd2ab..096ed3cae128 100644
--- a/dev-python/desktop-notifier/Manifest
+++ b/dev-python/desktop-notifier/Manifest
@@ -1,2 +1,4 @@
+DIST desktop-notifier-6.0.0.gh.tar.gz 3873893 BLAKE2B 9005cb839eff75f0038e9d0111ab1cc3c4fdc3a4b20d8df6bbfda6f777b9b8081d54b97c0e3084bd61659042086b79bac79581daea742a9425638749d6d3cd8b SHA512 1a6a4b172e9b0d542008fbfd91989fa0502fcd6e3557d5b59a0f6a90227d84745e1a71c938a7dd2855dc6d61d4b56bdd2f74f70ce9a9b99ae1f4168d5a343399
+DIST desktop-notifier-6.1.0.gh.tar.gz 3876246 BLAKE2B c44833e65f9a7fc1f5965545cad6f7bf68068c41bf1eb6e820f0e2b9403645003eb88745eb344c5b7c70c3335559e125a330ae0bc96f7dcb759a0f8d8b59b89f SHA512 9e7bc21e2814e087e5cd483811272cf573f9a0020dc95cbcb19dc05b53f846526b59ff15025983ffabfdb2e2348312b507e25bf386b04d9c217662712e309cd4
 DIST desktop_notifier-4.0.0.tar.gz 29934 BLAKE2B da9944edd6577f36116a03a6620a5a8ec68071954df4ac31a96af148608a9c6d990805f025b44925a943274bc961d4412690dde7876520f9a42bca0b6b008f9b SHA512 a96f96d6cbf7876bebcc9eb8a33d348eb5ed8f2a86fd5a9761105684e0267d9496904bb38f54caba39d29dfc23e00530655669d8e849607e066c85512f67c045
 DIST desktop_notifier-5.0.1.tar.gz 32731 BLAKE2B 1c1d567badc50b60bac1743cf0ab8e2dbb44d0b4de0fb5f5c82dc958bbd558637953f96a7e5a5920fe80be0007ef814ae2e15d1c3eb19503a2ac784f65813583 SHA512 72b9a928817bb0834801842d9d5f065ec704b3c64c0ca0cd2457f08e8f37902f94a6bb06070eb83bd3414f613c14c11152fed45ff4061ab652c89780aa95046e
diff --git a/dev-python/desktop-notifier/desktop-notifier-6.0.0.ebuild b/dev-python/desktop-notifier/desktop-notifier-6.0.0.ebuild
new file mode 100644
index 000000000000..3965ed777532
--- /dev/null
+++ b/dev-python/desktop-notifier/desktop-notifier-6.0.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+DESCRIPTION="desktop-notifier is a Python library for cross-platform desktop notifications"
+HOMEPAGE="
+	https://desktop-notifier.readthedocs.io
+	https://pypi.org/project/desktop-notifier/
+	https://github.com/samschott/desktop-notifier
+"
+SRC_URI="https://github.com/samschott/desktop-notifier/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/dbus-fast[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/build[${PYTHON_USEDEP}]
+	test? (
+		dev-python/bidict
+		dev-python/pytest-asyncio
+	)
+"
+
+# Most tests fail, they need some prior setup
+EPYTEST_DESELECT=(
+	tests/test_api.py::test_send
+	tests/test_api.py::test_clear
+	tests/test_api.py::test_clear_all
+	tests/test_callbacks
+	tests/test_sync_api
+)
+distutils_enable_tests pytest
diff --git a/dev-python/desktop-notifier/desktop-notifier-6.1.0.ebuild b/dev-python/desktop-notifier/desktop-notifier-6.1.0.ebuild
new file mode 100644
index 000000000000..e5afa21c02c4
--- /dev/null
+++ b/dev-python/desktop-notifier/desktop-notifier-6.1.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+DESCRIPTION="desktop-notifier is a Python library for cross-platform desktop notifications"
+HOMEPAGE="
+	https://desktop-notifier.readthedocs.io
+	https://pypi.org/project/desktop-notifier/
+	https://github.com/samschott/desktop-notifier
+"
+SRC_URI="https://github.com/samschott/desktop-notifier/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/dbus-fast[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/build[${PYTHON_USEDEP}]
+	test? (
+		dev-python/bidict
+		dev-python/pytest-asyncio
+	)
+"
+
+# Most tests fail, they need some prior setup
+EPYTEST_DESELECT=(
+	tests/test_api.py::test_send
+	tests/test_api.py::test_clear
+	tests/test_api.py::test_clear_all
+	tests/test_callbacks
+	tests/test_sync_api
+)
+distutils_enable_tests pytest
diff --git a/dev-python/fullmoon/Manifest b/dev-python/fullmoon/Manifest
new file mode 100644
index 000000000000..b598dd0391e6
--- /dev/null
+++ b/dev-python/fullmoon/Manifest
@@ -0,0 +1 @@
+DIST fullmoon-1.0.2.tar.gz 6041 BLAKE2B b0ce5f45608a37c703a60ddb037932d21da60684de75c3b071c7c4031c1e83bc83f1542fbbfbcfc1011aabddba80c30195daa7d3d6f93d5f0ab053cb78dc1f78 SHA512 a8ba84ca6990748ca7ee7cced6f277ebd6df862e08039416b89561af9074254c3e0e0b00bc2dbf98d25ed1dee177e5d7667c561c283b19405361f6ea21831fc1
diff --git a/dev-python/fullmoon/files/fullmoon-1.0.2-setuptools.patch b/dev-python/fullmoon/files/fullmoon-1.0.2-setuptools.patch
new file mode 100644
index 000000000000..2485f4f0373c
--- /dev/null
+++ b/dev-python/fullmoon/files/fullmoon-1.0.2-setuptools.patch
@@ -0,0 +1,5 @@
+license classifiers are deprecated and may become an error
+--- a/setup.py
++++ b/setup.py
+@@ -37 +36,0 @@
+-        'License :: OSI Approved :: MIT License',

diff --git a/dev-python/fullmoon/fullmoon-1.0.2.ebuild b/dev-python/fullmoon/fullmoon-1.0.2.ebuild
new file mode 100644
index 000000000000..0f5650468da5
--- /dev/null
+++ b/dev-python/fullmoon/fullmoon-1.0.2.ebuild
@@ -0,0 +1,19 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+inherit distutils-r1 pypi
+
+DESCRIPTION="Determine full moon occurences"
+HOMEPAGE="https://github.com/jr-k/python-fullmoon/"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-setuptools.patch
+)
diff --git a/dev-python/fullmoon/metadata.xml b/dev-python/fullmoon/metadata.xml
new file mode 100644
index 000000000000..786658643d66
--- /dev/null
+++ b/dev-python/fullmoon/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person">
+  <email>ionen@gentoo.org</email>
+  <name>Ionen Wolkens</name>
+ </maintainer>
+ 
+ <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/gfloat/gfloat-0.4.ebuild b/dev-python/gfloat/gfloat-0.4.ebuild
index 053a81a013d7..cf1191c42e16 100644
--- a/dev-python/gfloat/gfloat-0.4.ebuild
+++ b/dev-python/gfloat/gfloat-0.4.ebuild
@@ -16,7 +16,7 @@ HOMEPAGE="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 ~x86"
+KEYWORDS="amd64 ~arm arm64 ~x86"
 IUSE="test-rust"
 
 RDEPEND="
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index 69009f8259b7..a6b5e78f46f7 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -1,2 +1,3 @@
 DIST hypothesis-6.129.4.gh.tar.gz 9528147 BLAKE2B c85806af24ddd934338f99c9d62a577fb35c8809d71ddf23aea0d613f33e690c70662279e88f4680d48c0c3b51fa10ff99c29fde7cf2d3c094cfaa0aa65b7612 SHA512 aec846f34e3a66da8a79929da681bd41ac7deb4a83934a51ee69bf989ddb8f3f7bd8f612571e625d3334cf786e3841b4e4d05fe4368e930e5975077e0f027a7d
 DIST hypothesis-6.130.8.gh.tar.gz 9538996 BLAKE2B 7f2779a69fbb1301cf7cdf0b414aff28e60cb2efb4d2451f2962cda1c048401d1e532e205c993691e1b2aa0f71af1a67274f40dd03a449db4f62de01c22c9dd8 SHA512 85df9ed0477d37b9fb96ada20aa41b8b65b27496fb0a4cfb44ebbab94d6859bc2767e8529f76b53e6f28cc122eea8529784a97b4e4b1803004072e317ecee00f
+DIST hypothesis-6.130.9.gh.tar.gz 9540297 BLAKE2B f1739aa493baf7c908064b6450f601576b5e71ad254bf3b45cb2cdcf6b34f98f647beef5ed939e099c33e60cfe5ffc8b1b13b85ac115361e3a19c34ca30fef04 SHA512 11ac4ae33a53d622eaebdf6106b13d51141a57140c268d465d202650ae79925777fbebde828188b2ba1ba87f6e062f8d014131eef5b0d2315a327a9dcea7d30c
diff --git a/dev-python/hypothesis/hypothesis-6.130.9.ebuild b/dev-python/hypothesis/hypothesis-6.130.9.ebuild
new file mode 100644
index 000000000000..08befcf116e3
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.130.9.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( pypy3 python3_{10..13} )
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/pytest-8[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,_hypothesis_pytestplugin
+	local -x HYPOTHESIS_NO_PLUGINS=1
+
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# failing due to warnings from numpy/cython
+				hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+			)
+			;;
+		python3.13)
+			EPYTEST_DESELECT+=(
+				# TODO
+				'hypothesis-python/tests/cover/test_reflection.py::test_clean_source[case-5]'
+			)
+			;;
+	esac
+
+	epytest -o filterwarnings= -p rerunfailures --reruns=5 \
+		tests/cover tests/pytest tests/quality
+}
+
+src_install() {
+	local HAD_CLI=
+
+	distutils-r1_src_install
+
+	if [[ ! ${HAD_CLI} ]]; then
+		rm -r "${ED}/usr/bin" || die
+	fi
+}
+
+python_install() {
+	distutils-r1_python_install
+	if use cli && has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		HAD_CLI=1
+	else
+		rm -r "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/jaraco-itertools/Manifest b/dev-python/jaraco-itertools/Manifest
index 9dd39379f378..a500cb2a9982 100644
--- a/dev-python/jaraco-itertools/Manifest
+++ b/dev-python/jaraco-itertools/Manifest
@@ -1 +1,2 @@
 DIST jaraco.itertools-6.4.1.tar.gz 18202 BLAKE2B f384e7bdbe6068ed85a19e12aeae2ac0ca4bea52a4c3f4840a7ce258440c0a73c0f9f6928be59a1db2f2bef887710a95c423cbf1854bd0e58f068bd4fd833d08 SHA512 57c3ce37d1fb39c7140fc0581bbeacd75479ae1c375af4041144d41bf184299898069418e046f21872c290708ccb44728d1111cb3cfffac4a1d703f1cb86a70a
+DIST jaraco_itertools-6.4.2.tar.gz 19524 BLAKE2B 59e6deb02aeb03072fe0265ff4a418dc0a94f0dbe0874804cefdd6298e4b91d8b3171c355b95c657d4fc80fd53aa36b17ed419c779cab14e83f428d4d6944f8b SHA512 b98e53e9e8ef3d0c8fde73084cfeceee073d266b1060370ddb380c392073b5d4e88adb3207635ce453767dd8c39a4970283d599b61871085e4cf8972d9313aa1
diff --git a/dev-python/jaraco-itertools/jaraco-itertools-6.4.2.ebuild b/dev-python/jaraco-itertools/jaraco-itertools-6.4.2.ebuild
new file mode 100644
index 000000000000..e0ebccfd8969
--- /dev/null
+++ b/dev-python/jaraco-itertools/jaraco-itertools-6.4.2.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Tools for working with iterables. Complements itertools and more_itertools"
+HOMEPAGE="
+	https://github.com/jaraco/jaraco.itertools/
+	https://pypi.org/project/jaraco.itertools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	dev-python/inflect[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-4.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools-scm-1.15.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/libvirt-python/libvirt-python-11.1.0.ebuild b/dev-python/libvirt-python/libvirt-python-11.1.0.ebuild
index 6e495af2f7df..bb2fedc01bd0 100644
--- a/dev-python/libvirt-python/libvirt-python-11.1.0.ebuild
+++ b/dev-python/libvirt-python/libvirt-python-11.1.0.ebuild
@@ -23,7 +23,7 @@ else
 	MY_P="${P/_rc/-rc}"
 	SRC_URI="https://download.libvirt.org/python/${MY_P}.tar.gz
 		verify-sig? ( https://download.libvirt.org/python/${MY_P}.tar.gz.asc )"
-	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 x86"
+	KEYWORDS="amd64 ~arm ~arm64 ppc64 x86"
 	RDEPEND="app-emulation/libvirt:0/${PV}"
 fi
 
diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index 7c2cdc6db6a1..d6280a36725a 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -1,3 +1,4 @@
 DIST moto-4.2.14.tar.gz 4933741 BLAKE2B 4c50a808dc8f27cfbcd0ba234d268084ee9a32f36cb5d6af61aacc4ee79f7bf5cf1045147c4642472129eee37bef8bc2c1953d140260d39d7f333ae0f5e5cf95 SHA512 d4079118ed1d2eef9134575e33dc0ed749bff0293d753baa63a630dbb987914b9933445027abdc344bb93fa1d6e483baf8a337a444c9dd055dda50b095ff9937
 DIST moto-5.1.1.tar.gz 6647375 BLAKE2B 6b12e46010798d776f148b8a8e99c7f65ce9c98cc086698be8335308952049f073eef99f8f41dd7868dd02816d3f1e12c9d8a5e8216644d7e9166f894aec44c6 SHA512 cabb57321dda5670ab81c01d5defe435939949ec77de4ec0ab14a72d18a180e10c67e78c2859b528c2eb6039b018a9be4d4909c9b5b3d73fad45a82be8240312
 DIST moto-5.1.2.tar.gz 6689364 BLAKE2B ed34b8f299924140196b200393dd554808d6b71fabbe671832b7655a3a4fa4f553ff3c11770b118fa3e04d7e957707fdc47e1027265529b0b25936d1590191fb SHA512 6ff45b287987df1c2573c9557b5c7c444f50bf13ed5b7aa458273cbd0e99d8c893b0517089d72520ae3566a3c65ca4aae20fcc0f1d404f5c30bf58b2f84e638f
+DIST moto-5.1.3.tar.gz 6765413 BLAKE2B 3a56d683b0818d09f98509afb94d4b6fb975f563d7f08ba225cac9f447b710c19a3af66c4c602369392190e2bde5b6970e0b64fd684bf361b7fc6a41b79da6ff SHA512 23e1abe55f9686b2b928886a7d31024fc98b70ffff1680611b3794027e568c1e3349857e1ea42891f3649cb87bf2a2376765ac10e480e29ec6fcf3c4e26f628b
diff --git a/dev-python/moto/moto-5.1.3.ebuild b/dev-python/moto/moto-5.1.3.ebuild
new file mode 100644
index 000000000000..fa22c67103ee
--- /dev/null
+++ b/dev-python/moto/moto-5.1.3.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1 pypi toolchain-funcs
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="
+	https://github.com/getmoto/moto/
+	https://pypi.org/project/moto/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-0.93[${PYTHON_USEDEP}]
+	dev-python/boto3[${PYTHON_USEDEP}]
+	>=dev-python/botocore-1.35.47[${PYTHON_USEDEP}]
+	>=dev-python/cfn-lint-0.40.0[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-35.0.0[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	>=dev-python/docker-3.0.0[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja2-2.10.1[${PYTHON_USEDEP}]
+	dev-python/jsonpath-ng[${PYTHON_USEDEP}]
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3.0.7[${PYTHON_USEDEP}]
+	>=dev-python/openapi-spec-validator-0.5.0[${PYTHON_USEDEP}]
+	dev-python/pyaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.25.6[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/sshpubkeys[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/antlr4-python3-runtime[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+	)
+"
+
+: "${EPYTEST_TIMEOUT:=180}"
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_dynamodb/test_dynamodb_import_table.py
+		# require joserfc
+		tests/test_apigateway/test_apigateway.py::test_create_authorizer
+		tests/test_apigateway/test_apigateway.py::test_delete_authorizer
+		tests/test_apigateway/test_apigateway.py::test_update_authorizer_configuration
+		tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserDeleter::test_authenticate_with_signed_out_user
+		tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserPoolDuplidateEmails::test_use_existing_email__when_email_is_
+		tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserPoolDuplidateEmails::test_use_existing_email__when_username_
+		tests/test_cognitoidp/test_cognitoidp_replay.py::TestCreateUserPoolWithPredeterminedID::test_different_seed
+		tests/test_cognitoidp/test_cognitoidp_replay.py::TestCreateUserPoolWithPredeterminedID::test_same_seed
+		tests/test_cognitoidp/test_server.py::test_admin_create_user_without_authentication
+		tests/test_cognitoidp/test_server.py::test_associate_software_token
+		tests/test_cognitoidp/test_server.py::test_sign_up_user_without_authentication
+		# require py_partiql_parser
+		tests/test_dynamodb/test_dynamodb_statements.py
+		tests/test_s3/test_s3_select.py
+		# require graphql
+		tests/test_appsync/test_appsync_schema.py
+		# Internet
+		tests/test_core/test_request_passthrough.py::test_passthrough_calls_for_entire_service
+		tests/test_core/test_request_passthrough.py::test_passthrough_calls_for_specific_url
+		tests/test_core/test_request_passthrough.py::test_passthrough_calls_for_wildcard_urls
+		tests/test_firehose/test_firehose_put.py::test_put_record_http_destination
+		tests/test_firehose/test_firehose_put.py::test_put_record_batch_http_destination
+	)
+	local EPYTEST_IGNORE=(
+		# require joserfc
+		tests/test_cognitoidp/test_cognitoidp.py
+	)
+
+	if ! tc-has-64bit-time_t; then
+		einfo "time_t is smaller than 64 bits, will skip broken tests"
+		EPYTEST_DESELECT+=(
+			tests/test_acm/test_acm.py::test_request_certificate_with_optional_arguments
+			tests/test_s3/test_multiple_accounts_server.py::TestAccountIdResolution::test_with_custom_request_header
+			tests/test_s3/test_server.py::test_s3_server_post_cors_multiple_origins
+		)
+		EPYTEST_IGNORE+=(
+			tests/test_route53domains/test_route53domains_domain.py
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x TZ=UTC
+	local -x AWS_DEFAULT_REGION=us-east-1
+
+	rm -rf moto || die
+	epytest -m 'not network and not requires_docker' \
+		-p rerunfailures --reruns=5
+}
diff --git a/dev-python/mwclient/Manifest b/dev-python/mwclient/Manifest
index ea6e5701ee4c..918cf917d1df 100644
--- a/dev-python/mwclient/Manifest
+++ b/dev-python/mwclient/Manifest
@@ -1 +1 @@
-DIST mwclient-0.10.1.gh.tar.gz 59780 BLAKE2B 1e7f4bc95c4acbe8e08191dd5dda40d7c120303187ebde5c94841364e06d6011c91eb69af122cb64ad5d5529d5decf5fe8a1cbc2cb85809d0da1bf75a3622115 SHA512 80d341863d4c3ba64d56bd978ae85ec1c163dd480eef9a87b8364981a292dd233bb24bd44fa4276043ef9478f5316622efe7cdad178a66574b1f85d34fa61f61
+DIST mwclient-0.11.0.tar.gz 71978 BLAKE2B 9351c185689b3f371b15438fef75cc02ba6c9b29dd01dbba3d08a24a0e46307076fda5d63540e69109c2fc7aa07fa604934dc3be6ed6f9c146943bb0efd82c80 SHA512 8df0e24bca4ebc4b60c9a2da891b4bdfa108e2fbd782d5eb8f9a858c8e573a97ba9f06ded9cfa6693986fde46ee888c95a76fe6beff3d8576c0efb7bdd2007c2
diff --git a/dev-python/mwclient/mwclient-0.10.1.ebuild b/dev-python/mwclient/mwclient-0.11.0.ebuild
index a201f78ec87b..ed20fea39849 100644
--- a/dev-python/mwclient/mwclient-0.10.1.ebuild
+++ b/dev-python/mwclient/mwclient-0.11.0.ebuild
@@ -1,35 +1,35 @@
-# Copyright 2024 Gentoo Authors
+# Copyright 2024-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
 PYTHON_COMPAT=( python3_{9,10,11,12,13} )
-
-inherit distutils-r1
+inherit distutils-r1 pypi
 
 DESCRIPTION="Unofficial lib for MediaWiki API"
 HOMEPAGE="
 	https://github.com/mwclient/mwclient
-	https://pypi.python.org/pypi/mwclient
+	https://pypi.org/project/mwclient/
 "
-SRC_URI="https://github.com/$PN/$PN/archive/refs/tags/v$PV.tar.gz -> $P.gh.tar.gz"
 
 LICENSE="MIT"
-
 SLOT="0"
 KEYWORDS="~amd64"
 
+RDEPEND="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/requests-oauthlib[${PYTHON_USEDEP}]
+"
 BDEPEND="
 	test? (
-		dev-python/pytest[${PYTHON_USEDEP}]
-		dev-python/pytest-cov[${PYTHON_USEDEP}]
 		dev-python/responses[${PYTHON_USEDEP}]
 	)
 "
 
 distutils_enable_tests pytest
 
-RDEPEND="
-	dev-python/requests-oauthlib[${PYTHON_USEDEP}]
-"
+python_test() {
+	# Disable pytest-cov
+	epytest -o addopts=
+}
diff --git a/dev-python/pdm-backend/Manifest b/dev-python/pdm-backend/Manifest
index a4bdb8da6c95..3d9b6e37a32e 100644
--- a/dev-python/pdm-backend/Manifest
+++ b/dev-python/pdm-backend/Manifest
@@ -1 +1,2 @@
 DIST pdm-backend-2.4.3.gh.tar.gz 146089 BLAKE2B 36f65db90de5b507348a2a8407ae0eec8e1939c6b0fea1181548de910fad2497594e17aee7d478572a32e28260ef15660bddfaec4d921b2975b5a51da031dc1e SHA512 378bc4360140f18dd7f66701da77f4b98ef4bad39c86055f11f4e508b16ebbbbce2188f47dedc05cd43525baf7873fc4565ee98d00d9e65efd9d8fc1820ddc15
+DIST pdm-backend-2.4.4.gh.tar.gz 157998 BLAKE2B 936289f56709633eb4d78b851b903e0f436f01d9949f96463fbad4448cb1688d8bad61a8a00e63524abf74f696830bb8227b428f78a050a2e3396545611119d3 SHA512 b8d6983d2df1028d30c046c9952e6182aed0b099e6d0d0b4cc784179cb3e4c9f518b58a6fe5c7a2d15b150dc134b7dc8c427ea142620e8bb29dd05be1a7efe1a
diff --git a/dev-python/pdm-backend/pdm-backend-2.4.4.ebuild b/dev-python/pdm-backend/pdm-backend-2.4.4.ebuild
new file mode 100644
index 000000000000..b1695a5e5757
--- /dev/null
+++ b/dev-python/pdm-backend/pdm-backend-2.4.4.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+	https://pypi.org/project/pdm-backend/
+	https://github.com/pdm-project/pdm-backend/
+"
+SRC_URI="
+	https://github.com/pdm-project/pdm-backend/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# see src/pdm/backend/_vendor/vendor.txt
+RDEPEND="
+	>=dev-python/editables-0.5[${PYTHON_USEDEP}]
+	>=dev-python/packaging-24.0[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-metadata-0.9.0_beta7[${PYTHON_USEDEP}]
+	>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	rm -r src/pdm/backend/_vendor || die
+	find -name '*.py' -exec sed \
+		-e 's:from pdm\.backend\._vendor\.:from :' \
+		-e 's:from pdm\.backend\._vendor ::' \
+		-e 's:import pdm\.backend\._vendor\.:import :' \
+		-i {} + || die
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	# this must not be set during src_test()
+	local -x PDM_BUILD_SCM_VERSION=${PV}
+	distutils-r1_src_compile
+}
+
+src_test() {
+	git config --global user.email "test@example.com" || die
+	git config --global user.name "Test User" || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -k "not [hg"
+}
diff --git a/dev-python/pylsqpack/Manifest b/dev-python/pylsqpack/Manifest
index 8805dd5b505a..25577cb2adc8 100644
--- a/dev-python/pylsqpack/Manifest
+++ b/dev-python/pylsqpack/Manifest
@@ -1 +1,2 @@
 DIST pylsqpack-0.3.19.tar.gz 660771 BLAKE2B b4b8ded7022eadf581270465446a6e0df2d241d18cacdc4fcfd725c865c02f17b5af5cbfd8eba65217ef9db1f24babe06faebc16c6cce68042d452dce03ffb1f SHA512 7ed2c24dcacb099d00100c33ae4ede3bf19488d17920267cfe934eb069f3fc3d3a62b275c2a9d3a23ece42f1c09df6cf736cea47b798959a2a09d27dd8eda97d
+DIST pylsqpack-0.3.20.tar.gz 676273 BLAKE2B ee031fdc56f8193b9f0b13c806f88d76d1e1bc2c8d6b1a5530a9630c07912251e9f9010d958c1f7a5c86aca895533768ead907573723544d0a662482051d131a SHA512 42cb9276ba4a2ffdbd1dd96813c4ab27881c2fe35616fa32e760d2341c71f1065db4959bde1a444df61ca85399870b9a736ed16e8a2768c96edee2df11bdb063
diff --git a/dev-python/pylsqpack/files/pylsqpack-0.3.20-unbundle.patch b/dev-python/pylsqpack/files/pylsqpack-0.3.20-unbundle.patch
new file mode 100644
index 000000000000..6a383511c91d
--- /dev/null
+++ b/dev-python/pylsqpack/files/pylsqpack-0.3.20-unbundle.patch
@@ -0,0 +1,15 @@
+diff --git a/setup.py b/setup.py
+index 03fc754..286eab7 100644
+--- a/setup.py
++++ b/setup.py
+@@ -35,9 +35,8 @@ setuptools.setup(
+             py_limited_api=True,
+             sources=[
+                 "src/pylsqpack/binding.c",
+-                "vendor/ls-qpack/lsqpack.c",
+-                "vendor/ls-qpack/deps/xxhash/xxhash.c",
+             ],
++            libraries=["ls-qpack"],
+         ),
+     ],
+     cmdclass={"bdist_wheel": bdist_wheel_abi3},
diff --git a/dev-python/pylsqpack/pylsqpack-0.3.20-r1.ebuild b/dev-python/pylsqpack/pylsqpack-0.3.20-r1.ebuild
new file mode 100644
index 000000000000..02069025a2bb
--- /dev/null
+++ b/dev-python/pylsqpack/pylsqpack-0.3.20-r1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python wrapper for the ls-qpack QPACK library"
+HOMEPAGE="
+	https://github.com/aiortc/pylsqpack/
+	https://pypi.org/project/pylsqpack/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+distutils_enable_tests pytest
+
+DEPEND="
+	dev-libs/ls-qpack:=
+"
+RDEPEND="
+	${DEPEND}
+"
+
+src_prepare() {
+	local PATCHES=(
+		"${FILESDIR}/${P}-unbundle.patch"
+	)
+
+	distutils-r1_src_prepare
+	rm -r vendor || die
+}
diff --git a/dev-python/pylsqpack/pylsqpack-0.3.20.ebuild b/dev-python/pylsqpack/pylsqpack-0.3.20.ebuild
new file mode 100644
index 000000000000..3093efde158c
--- /dev/null
+++ b/dev-python/pylsqpack/pylsqpack-0.3.20.ebuild
@@ -0,0 +1,24 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python wrapper for the ls-qpack QPACK library"
+HOMEPAGE="
+	https://github.com/aiortc/pylsqpack/
+	https://pypi.org/project/pylsqpack/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+distutils_enable_tests pytest
+
+# TODO: package ls-qpack and unbundle it