Adding metadata

30 files changed, 525 insertions, 107 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index eac3b5cdedc1..27210848c093 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -3,3 +3,4 @@ DIST boto3-1.37.23.gh.tar.gz 920294 BLAKE2B c1bfcb5dd8c883c122b530ac2756c77884d7
 DIST boto3-1.37.28.gh.tar.gz 922848 BLAKE2B 134a4054d1142de5f63198f6fd97eef3dc5fe38523e688ccda56960200f2b1cd2ee862d95a275a13744844006e78584d1510850b2873da74d3ebdf53ceecd0a1 SHA512 f794769b083f52dd7e546758fec9a42dbf6fa8e09eef82a631b8d3b9dcb3b449aa85b7e72cb9a1f33c6bcaf89ef2bede4f771110e723efd98b47c9ab5c31c51f
 DIST boto3-1.37.29.gh.tar.gz 923479 BLAKE2B ab940851062f611e3a3011e908c28c7cd3129020cec11272b85613b0c135af1a9df6e171b4a1c3ed4f0c4015512da8b00a3f8430bff38ba89c6030dcddd6adff SHA512 d2dbb36e0e375084a1022ae1dc8fb89601c625edd4f780ab01a1d137377752ea28f691a1e774077ad2585b0df119f4e29c9f74ea43c9e63ca4bebc95387f0b7b
 DIST boto3-1.37.30.gh.tar.gz 924249 BLAKE2B 54fa0f7a3f2a926345aaaaf1bdf9610b4ea8b5745eb64adf10b863b00b587e91fb987d7047fe4b62d66815c907ab01198d364506c9c0b72ab097c53c3f4053af SHA512 d50188a48f0257f89a2884b3f4f5e2d6b06a9af692119e09b0846b9b3d53d40cf11a15045edf267d1faed3cf59a5cb5274f7e253451ce129b64562fd89bba0f6
+DIST boto3-1.37.31.gh.tar.gz 925896 BLAKE2B 999eb64d1910092cad350e95cc6ffc3da971794c6acd4ed093142a64a6aa66a98de4a3bfa63810479948990dc9c3ff90c91f88df215897be62e492f2daeb47db SHA512 69471906f22b5fd760a9c6c96a508b06620ffb3fdeb0b4a7d5ea952f3e835dcfba6fa5ce697b9756a8202ceeb6ec52f5f4c74a2f3d1d43ab5ba4c2da5c76ebfb
diff --git a/dev-python/boto3/boto3-1.37.31.ebuild b/dev-python/boto3/boto3-1.37.31.ebuild
new file mode 100644
index 000000000000..dfe05b3d9a81
--- /dev/null
+++ b/dev-python/boto3/boto3-1.37.31.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+SRC_URI="
+	https://github.com/boto/boto3/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.11.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 064ab0f59462..80b951033ea3 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -3,3 +3,4 @@ DIST botocore-1.37.23.gh.tar.gz 14408721 BLAKE2B 6309e847210a3f7f916679078fba54a
 DIST botocore-1.37.28.gh.tar.gz 14529730 BLAKE2B aa04a445d45d24ff7dad8553ce19676fc73e6cd852b5ee41c3cc29039aa6b353399ce9e17b8081e21652fd2bb06b1f58822cf1143a0305256c78515f21d64fa9 SHA512 ea757146393a94faee45487d3b0b4ba0927f0d3a5a37349788a2e2a4d1b4950d027d47bc92c3eb021d2253ce80fc4399a5dbfca447382d6b68e49786951fa02f
 DIST botocore-1.37.29.gh.tar.gz 14534398 BLAKE2B 22916213e7dcba5c6e17105a6abf2752586d17fc1496c1d09b92584cd2d4c5a341c251253bdbdf0699b8cc7d4a2d190d1855698847adf0352f003a1a667bac25 SHA512 3346fa9013d4b361a9fff66aed238d71ba65ebd63555c50fd443aa07eda7c599e1816c8900320a97799ed3aaedd1fd246a5499627ceb9933204f45b878fece6c
 DIST botocore-1.37.30.gh.tar.gz 14539545 BLAKE2B 73b3c393d5da95b89d798695ba1fb656017c9d3754371d2d6debbcac8e33795d27bad0fd18258b0381148cd2fd45cabadc59a17745bf1908f23342bbfae3b60f SHA512 8f6d8b963e06b94fd373ab54a84c4083c9a55637d88cb75d2844e094dc1a6ca7a954b215f71515841a6a2776526f1807c2a50983f6417b08057bc2ca843ac390
+DIST botocore-1.37.31.gh.tar.gz 14540600 BLAKE2B 872049187a44ff5d7099902c10cf68a83983421798eecee50b02d8b5bd646a04f22ed2b41ec84374499c9d97ed6a2a4fd4e39b5de77e0c8e56fa94c31c2c94aa SHA512 0fffb63321c4ff58533c121e18a6a3cb4cf1587ce0a6fb8ddacc02d52e50de91f278e928dfaad8801b7f081761e0c7ae311a6acab386bdea6de917ddae13cced
diff --git a/dev-python/botocore/botocore-1.37.31.ebuild b/dev-python/botocore/botocore-1.37.31.ebuild
new file mode 100644
index 000000000000..df85ee0d220c
--- /dev/null
+++ b/dev-python/botocore/botocore-1.37.31.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+SRC_URI="
+	https://github.com/boto/botocore/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+# unbundled packages
+RDEPEND+="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/cfn-lint/Manifest b/dev-python/cfn-lint/Manifest
index 4f9b537f59db..57ad394a3032 100644
--- a/dev-python/cfn-lint/Manifest
+++ b/dev-python/cfn-lint/Manifest
@@ -1,3 +1,4 @@
 DIST cfn_lint-1.31.3.tar.gz 2856311 BLAKE2B 46c7dee3b3a70f59675dd3879604a0860b99b193ce37e11b05f60bb08d1f3e97da7887b8d13be48d5721826ca46f5bdca61945b8d2fc6558d9290eec5257fa64 SHA512 4d63d3d529b292125be9b139ebc73ae75024e61afa0928afd6f73f573aaadd9cb1e359cf4bc61aa245c05de86406b9894bca1519b682248946eff0664bbefeba
 DIST cfn_lint-1.32.4.tar.gz 3090585 BLAKE2B 348c0a4326bcd8a7c0c0230d6090774b300192e4a68086ab4a8350ed0b854b750feae0ad55953c1f3a8ccf32990b58078668b76bfbd41ee59bc736bede87f524 SHA512 81545db95bca2f31a41f327e4303e4ec5d398b7b1b25030bb0a8f550ff79591d0e350173234c2a54ae4317180442943bd0c0e4d8327e3163c1f5ff9b92dc5fac
 DIST cfn_lint-1.33.0.tar.gz 3162568 BLAKE2B e2056dc29c6df1b8da62b1ac715ab7360c152ab7287e972f7b65cb2b936332dc07f42dc752089c6e43086fb73ab4ecf9bb2d5706adc4c03dacc84715edbf3ecf SHA512 bf856045ae3a5ce61bb59f50b0d3f445f3ee8e7afef94cc51db807fe02a55e141b83c37750038eb75cc7a9255b2f35c23c57059a8fd955065db4d0a1d52d8379
+DIST cfn_lint-1.33.1.tar.gz 3162624 BLAKE2B 24fb34624a6570a04bcb963061784934215194bf87943572218501b1613ae7b68f3e44a604020ba3f610e99e05f2671ef255e915f59d04cacae198a15d320820 SHA512 7bf79c9c5ceadddbadcb8cdc5b72289fc97ef67629def53f09eaffa4fba42f3c5adf69aa6b8b9844bf0dd6ae6e112226ef649adbdd0c38b6ca2fbd1c7b267743
diff --git a/dev-python/cfn-lint/cfn-lint-1.33.1.ebuild b/dev-python/cfn-lint/cfn-lint-1.33.1.ebuild
new file mode 100644
index 000000000000..253fbf6c8232
--- /dev/null
+++ b/dev-python/cfn-lint/cfn-lint-1.33.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="CloudFormation Linter"
+HOMEPAGE="
+	https://github.com/aws-cloudformation/cfn-lint/
+	https://pypi.org/project/cfn-lint/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/aws-sam-translator-1.96.0[${PYTHON_USEDEP}]
+	dev-python/jsonpatch[${PYTHON_USEDEP}]
+	>=dev-python/jschema-to-python-1.2.3[${PYTHON_USEDEP}]
+	<dev-python/jsonschema-5[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]
+	dev-python/junit-xml[${PYTHON_USEDEP}]
+	<dev-python/networkx-4[${PYTHON_USEDEP}]
+	>dev-python/pyyaml-5.4[${PYTHON_USEDEP}]
+	>=dev-python/regex-2021.7.1[${PYTHON_USEDEP}]
+	>=dev-python/sarif-om-1.0.4[${PYTHON_USEDEP}]
+	>=dev-python/sympy-1.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools-77.0.3[${PYTHON_USEDEP}]
+	test? (
+		dev-python/defusedxml[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin the deps
+	sed -e 's:~=[0-9.]*::' -i pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# different line wrapping somehow
+		test/unit/module/template/test_template.py::TestTemplate::test_build_graph
+		# requires git repo
+		test/unit/module/maintenance/test_update_documentation.py::TestUpdateDocumentation::test_update_docs
+	)
+
+	# from tox.ini
+	local -x AWS_DEFAULT_REGION=us-east-1
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
diff --git a/dev-python/configshell-fb/Manifest b/dev-python/configshell-fb/Manifest
index 3adf62e57242..b59823660b3f 100644
--- a/dev-python/configshell-fb/Manifest
+++ b/dev-python/configshell-fb/Manifest
@@ -1 +1,2 @@
 DIST configshell_fb-2.0.0.tar.gz 33794 BLAKE2B 7bb46a19b58107c7e4d0f7a4dde9520cdd31b85238ad7579f85c30f855c7fb90736470419e7f6882bbeed89d9d55091b92f7a3f1e4bbff5e5a9eae813c148756 SHA512 3e0c0c3fda661cd09d80cd07e32cc942aa804fde49c00cfed5234671b1005f8126264c39a72aec466b3b9324366faa83828eee74f8b541d6f8bc628548d31a9e
+DIST configshell_fb-2.0.1.tar.gz 34046 BLAKE2B b9337ab17d1a3486e7a762669b4f3a37ef40bdbe26da8f35757b2ef839a3e8e1b5fa778d722f9afdcbc7dbd26cd48c82609cfad8dbced083da0d260436c42189 SHA512 77006982cd213ee5c30091232146787b8387b5366452d24ce6c931096b6048f503a4c87d7aefd4b5dafda475d69f5782b7a4f1efb5cd0e376f1ab336f749c15b
diff --git a/dev-python/configshell-fb/configshell-fb-2.0.1.ebuild b/dev-python/configshell-fb/configshell-fb-2.0.1.ebuild
new file mode 100644
index 000000000000..f78790722e58
--- /dev/null
+++ b/dev-python/configshell-fb/configshell-fb-2.0.1.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A Python library for building configuration shells"
+HOMEPAGE="
+	https://github.com/open-iscsi/configshell-fb/
+	https://pypi.org/project/configshell-fb/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/pyparsing-2.4.7[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+"
+
+python_test() {
+	"${EPYTHON}" examples/myshell || die "Test failed with ${EPYTHON}"
+}
diff --git a/dev-python/emcee/Manifest b/dev-python/emcee/Manifest
index 9bed9eb8fc10..f3d7ab936c41 100644
--- a/dev-python/emcee/Manifest
+++ b/dev-python/emcee/Manifest
@@ -1,3 +1 @@
-DIST emcee-3.1.4.tar.gz 2869179 BLAKE2B 19e93a154a7c9f8c43389681b7318ff6e79aea8588af10bf86d63bdee51551c538ad8850b82c1233f656a45bbbd344655aad01ed93ddb30337ad49b6bfed8b46 SHA512 23f3945571bc4346c90026f9c675cb72a5cf173294eafd5bf02dc8572cfea63de3260ade91cb9360e420969f2a939fa8ac55961e808c55900fef903be357facf
-DIST emcee-3.1.5.tar.gz 2870972 BLAKE2B 49ddd0a41a61f33573f1b1e0b198306567e097b86153392fc0f874b3c7e728611fdfb2d45b8427c85208beb3c819ec174bdf5481005a3b17a4f5ea196a54ff3e SHA512 7cc6fe30ad472d4823b12c8bab50fa7d3aea49ca22d38479d77d90d357e715c0dadda7f96575291fbe05ff27962f8a180c49b6629ddb891b044db2719bd88610
 DIST emcee-3.1.6.tar.gz 2871117 BLAKE2B 07f1ff1af716f6ef3f3fe9091ec70f700bc9798da1609c13aa5718a4efb9d0e1e5e8c7e45d86fc3cd91b6faef348cfaa3ee402a1df825eb8ac3fdb6ab9a33bfa SHA512 4ea0a57c3c5e7a3c5976016c89ebddbe9a3e149615e48b39caed45d1b671e704ea0d3a765337c0b98a99fe4e74683c55b9ad5861bee59a09a6f0c756fcadfe51
diff --git a/dev-python/emcee/emcee-3.1.4.ebuild b/dev-python/emcee/emcee-3.1.4.ebuild
deleted file mode 100644
index f4498754c347..000000000000
--- a/dev-python/emcee/emcee-3.1.4.ebuild
+++ /dev/null
@@ -1,50 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9,10,11,12,13} )
-
-inherit distutils-r1 multiprocessing pypi
-
-DESCRIPTION="Python ensemble sampling toolkit for affine-invariant MCMC"
-HOMEPAGE="
-	https://emcee.readthedocs.io/en/stable/
-	https://github.com/dfm/emcee/
-	https://pypi.org/project/emcee/
-"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
-
-DEPEND="
-	dev-python/h5py[${PYTHON_USEDEP}]
-	dev-python/numpy[${PYTHON_USEDEP}]
-"
-RDEPEND="
-	${DEPEND}
-"
-BDEPEND="
-	dev-python/setuptools-scm[${PYTHON_USEDEP}]
-	test? (
-		dev-python/pytest-xdist[${PYTHON_USEDEP}]
-		dev-python/scipy[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-
-DOCS=( AUTHORS.rst README.rst )
-
-src_prepare() {
-	# unnecessary dep
-	sed -i -e '/wheel/d' setup.py || die
-	distutils-r1_src_prepare
-}
-
-python_test() {
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest -p xdist -n "$(makeopts_jobs)" --dist=worksteal
-}
diff --git a/dev-python/emcee/emcee-3.1.5.ebuild b/dev-python/emcee/emcee-3.1.5.ebuild
deleted file mode 100644
index 00782da6aaa2..000000000000
--- a/dev-python/emcee/emcee-3.1.5.ebuild
+++ /dev/null
@@ -1,50 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9,10,11,12,13} )
-
-inherit distutils-r1 multiprocessing pypi
-
-DESCRIPTION="Python ensemble sampling toolkit for affine-invariant MCMC"
-HOMEPAGE="
-	https://emcee.readthedocs.io/en/stable/
-	https://github.com/dfm/emcee/
-	https://pypi.org/project/emcee/
-"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
-
-DEPEND="
-	dev-python/h5py[${PYTHON_USEDEP}]
-	dev-python/numpy[${PYTHON_USEDEP}]
-"
-RDEPEND="
-	${DEPEND}
-"
-BDEPEND="
-	dev-python/setuptools-scm[${PYTHON_USEDEP}]
-	test? (
-		dev-python/pytest-xdist[${PYTHON_USEDEP}]
-		dev-python/scipy[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-
-DOCS=( AUTHORS.rst README.rst )
-
-src_prepare() {
-	# unnecessary dep
-	sed -i -e '/wheel/d' setup.py || die
-	distutils-r1_src_prepare
-}
-
-python_test() {
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest -p xdist -n "$(makeopts_jobs)" --dist=worksteal
-}
diff --git a/dev-python/emcee/emcee-3.1.6.ebuild b/dev-python/emcee/emcee-3.1.6.ebuild
index 00782da6aaa2..f105574a98e3 100644
--- a/dev-python/emcee/emcee-3.1.6.ebuild
+++ b/dev-python/emcee/emcee-3.1.6.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index 91e6034cc940..8ec5e199f8da 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -1,5 +1,6 @@
 DIST hypothesis-6.129.4.gh.tar.gz 9528147 BLAKE2B c85806af24ddd934338f99c9d62a577fb35c8809d71ddf23aea0d613f33e690c70662279e88f4680d48c0c3b51fa10ff99c29fde7cf2d3c094cfaa0aa65b7612 SHA512 aec846f34e3a66da8a79929da681bd41ac7deb4a83934a51ee69bf989ddb8f3f7bd8f612571e625d3334cf786e3841b4e4d05fe4368e930e5975077e0f027a7d
 DIST hypothesis-6.130.10.gh.tar.gz 9540669 BLAKE2B 778cbdefdb84c8e86598926aca720efebfab5cafd08a421e1cde40341002088191e450f33c62e73a32eea47fe26791e96586416620592d2ee5cd359f478e92c9 SHA512 0534355ffdb03b8efaaf196dd3fc909cb6df113b0170710aa1e441bedcd772ae55b1e3d60596b45edc2f150871e54494fbbeccbd21e9c2416bdcb39c4fea2162
 DIST hypothesis-6.130.12.gh.tar.gz 9543942 BLAKE2B 27c4bef0f68ee434ce81582b86441138be1cc7b7c39e56bbd64914a3bc2754a9f997e7d3a86b6187e2d46defa7dd4de21f7eb7a0ea8a5a0f1a71338a4e73ba0e SHA512 ee766ab5d3864384ae8d31a835f3eb742f2573031246791d9260a49d6fa6c27be247bdef4595b6f9f5561c4e5e057f097bfaae8d301c2267b53302e0df0a3433
+DIST hypothesis-6.130.13.gh.tar.gz 9544282 BLAKE2B 9a74af5cab1562b5eb2fc00fe1ea67471171ac1ecf71ef01e51082b6e3469c7a9b1de7e56119a4517b8f6c45be5efbc5461dcd258ab80c246e07df7c58dbf9c2 SHA512 25dbde677bf8b2e727999c39083f6746c9431e22326034c50ed723b51a3d7678a62dce648fcfd16802808f2034ad7cb74fe0b98fe50519b505a5b05412afa17a
 DIST hypothesis-6.130.8.gh.tar.gz 9538996 BLAKE2B 7f2779a69fbb1301cf7cdf0b414aff28e60cb2efb4d2451f2962cda1c048401d1e532e205c993691e1b2aa0f71af1a67274f40dd03a449db4f62de01c22c9dd8 SHA512 85df9ed0477d37b9fb96ada20aa41b8b65b27496fb0a4cfb44ebbab94d6859bc2767e8529f76b53e6f28cc122eea8529784a97b4e4b1803004072e317ecee00f
 DIST hypothesis-6.130.9.gh.tar.gz 9540297 BLAKE2B f1739aa493baf7c908064b6450f601576b5e71ad254bf3b45cb2cdcf6b34f98f647beef5ed939e099c33e60cfe5ffc8b1b13b85ac115361e3a19c34ca30fef04 SHA512 11ac4ae33a53d622eaebdf6106b13d51141a57140c268d465d202650ae79925777fbebde828188b2ba1ba87f6e062f8d014131eef5b0d2315a327a9dcea7d30c
diff --git a/dev-python/hypothesis/hypothesis-6.130.13.ebuild b/dev-python/hypothesis/hypothesis-6.130.13.ebuild
new file mode 100644
index 000000000000..ba7cfa420917
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.130.13.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( pypy3 python3_{10..13} )
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/pytest-8[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,_hypothesis_pytestplugin
+	local -x HYPOTHESIS_NO_PLUGINS=1
+
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# failing due to warnings from numpy/cython
+				hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+			)
+			;;
+		python3.1[23]*)
+			EPYTEST_DESELECT+=(
+				# TODO
+				'hypothesis-python/tests/cover/test_reflection.py::test_clean_source[case-5]'
+			)
+			;;
+	esac
+
+	epytest -o filterwarnings= -p rerunfailures --reruns=5 \
+		tests/cover tests/pytest tests/quality
+}
+
+src_install() {
+	local HAD_CLI=
+
+	distutils-r1_src_install
+
+	if [[ ! ${HAD_CLI} ]]; then
+		rm -r "${ED}/usr/bin" || die
+	fi
+}
+
+python_install() {
+	distutils-r1_python_install
+	if use cli && has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		HAD_CLI=1
+	else
+		rm -r "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/lxml-html-clean/Manifest b/dev-python/lxml-html-clean/Manifest
index 5c8640819113..2cd77d984a0d 100644
--- a/dev-python/lxml-html-clean/Manifest
+++ b/dev-python/lxml-html-clean/Manifest
@@ -1 +1,2 @@
 DIST lxml_html_clean-0.4.1.tar.gz 21378 BLAKE2B 607c2a5b3b35b0cc89729f4114af7a358fa03e386ea3099369d3b10b083ad092ee7b83ea44f6afc1b9be85457737f22df0db458065eb4910388c142c3c335772 SHA512 87e7835f77da6c20a3581edf86fa42df600e1012b2802686e341f525fd4b78211369282bfd873cb07626cb6f1cc0c898d36ab24ec44700f0b9947d1dbee9f6d6
+DIST lxml_html_clean-0.4.2.tar.gz 21622 BLAKE2B 796db28e480e88baffc6f57bc9d1c9c47b898afa28349a65456c46cef61a3ba73d88c8c241857e134da9eee1854877df32d69b795186b30d6806b866d11823e2 SHA512 6d4e55e17dfb174694dc0ba9159a8d59581b8cc374546ed286a4c5fb8f46f06169959a0dca43406126d486ccdfbe079aba18ab4975b04682f76eb95554090c52
diff --git a/dev-python/lxml-html-clean/lxml-html-clean-0.4.2.ebuild b/dev-python/lxml-html-clean/lxml-html-clean-0.4.2.ebuild
new file mode 100644
index 000000000000..5fc803c9a927
--- /dev/null
+++ b/dev-python/lxml-html-clean/lxml-html-clean-0.4.2.ebuild
@@ -0,0 +1,31 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Separate project for HTML cleaning functionalities copied from lxml.html.clean"
+HOMEPAGE="
+	https://github.com/fedora-python/lxml_html_clean/
+	https://pypi.org/project/lxml-html-clean/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/lxml-5.2.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+
+python_test() {
+	eunittest
+	"${EPYTHON}" -m doctest -v tests/*.txt ||
+		die "Doctests failed on ${EPYTHON}"
+}
diff --git a/dev-python/narwhals/Manifest b/dev-python/narwhals/Manifest
index a645e024f087..25d784721131 100644
--- a/dev-python/narwhals/Manifest
+++ b/dev-python/narwhals/Manifest
@@ -1,3 +1,4 @@
 DIST narwhals-1.32.0.gh.tar.gz 683557 BLAKE2B 830ff49ba0c3dd41b9b35d78a29693b8d79a35e5be8a77a9cc4980f7e853fb60ae2221b486df8d17499608c97bf92aa74b199b048eb0b3ab8249c5e4906864e4 SHA512 cdae2b4b579bd011d57fd6f0b6e9fbff7150f97f03f94044c3ba31ca95a782bded605607d7281fe717d765adbb1e7409f16c4031c0df51b20ffa99fb10479889
 DIST narwhals-1.33.0.gh.tar.gz 689586 BLAKE2B e3e3b8540caf66e599dab3df78860eff10ab2b502a0c1d51054aff2cd573a0f2f11d1a8f95a67273311ea00b8469b33e1e43189abff33b0160f45bb1a324b78d SHA512 03ee9992e7dcbf70a24bed784b890344831116891109001032ffadda24234c6c62a6a975e9765989789dc05ea93396b7fc8b2ab8f0aac40d0cc162de7c388843
 DIST narwhals-1.34.0.gh.tar.gz 692545 BLAKE2B 9463525dc1e1e8601abd071d76a1acd603b5d1d8a5ad872434fe33d498844a99d5d3f67f074ff00272e8bc671a064aeed406a912f1a955ad4a760431b8e5aff5 SHA512 4ed6ef2d896bb94cb75cb2584eeef669a14808b223a984cd89d7b648274d50cb85c1dc516e103a6c19dcf1ce56081b159ebf2503ed8d53088a8d7c78abfb0dc2
+DIST narwhals-1.34.1.gh.tar.gz 692736 BLAKE2B cdde47102f74ab7cb3917943997f003020d58c4470e2be0ce512683fe45334e85fe5614b7984e1a1ca1c200576bdcc194ed537e3f0a2b8b99c712af2c61a650e SHA512 83aa76aa208f7faff0bb9a24ce31fb8e1d91aed9edc1376790d61c561f580b441f4016b1bb9cdb0ca849d432c09392bd9fd697da7631a7ac2af2779314fe6ba9
diff --git a/dev-python/narwhals/narwhals-1.34.1.ebuild b/dev-python/narwhals/narwhals-1.34.1.ebuild
new file mode 100644
index 000000000000..7059c1a7ca16
--- /dev/null
+++ b/dev-python/narwhals/narwhals-1.34.1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Extremely lightweight compatibility layer between dataframe libraries"
+HOMEPAGE="
+	https://github.com/narwhals-dev/narwhals/
+	https://pypi.org/project/narwhals/
+"
+# https://github.com/narwhals-dev/narwhals/issues/2284
+SRC_URI="
+	https://github.com/narwhals-dev/narwhals/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pyarrow[${PYTHON_USEDEP}]
+		dev-python/pytest-env[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest --runslow --constructors="pandas,pandas[pyarrow],pyarrow"
+}
diff --git a/dev-python/orderly-set/Manifest b/dev-python/orderly-set/Manifest
index 94b58a986681..7829db59fc27 100644
--- a/dev-python/orderly-set/Manifest
+++ b/dev-python/orderly-set/Manifest
@@ -1,2 +1,3 @@
 DIST orderly_set-5.3.0.tar.gz 20026 BLAKE2B fa5f2e190d9f2ed079e16c45cf60044ba57ddaca875ae70f71a98055bf36053410985db762fbdafb94d7d9faeff906a3e240462267363f15f2f334d96ff852a8 SHA512 b7520653bf23c99ab124bde8b9e34f0c9eb14192eb09b2bfc9736b281f1c5d511964849496fe74c8f35d1000ba5857578906dbf47b581007bdfb81c9bd88c81a
 DIST orderly_set-5.3.1.tar.gz 20826 BLAKE2B e515531887b285f74c8a21f49c52063f120a60c91c1f7de9bf30479a0acf3d0a3322fbd2db0f353ced7d1c7c26f76c564074b73a942cc577321b3a1d36af05ec SHA512 1dceadbdb5471111f2c91e319861490768d9bbe22350463a819c799950d8c29753df8e67916a7662edb4c3fb6f8eca9da1bbd6f01f63132b5d68e33ee23cd6ae
+DIST orderly_set-5.3.2.tar.gz 20937 BLAKE2B 7c5a6193d02cd802300e03c2a96abff85312b8ff11aacb4fce338f9c4e4a8fd63f411570bbfef709af29a381d4823ed805c5e7c496be708adab2254cf2708ba8 SHA512 f7803f001f5510d060f1a1264104bfa652bc498da9d8db5526d2796fdc17c72a1d780374b2bb934be38a970b02468bb3764ab48880f4839dd2d83173266d65f6
diff --git a/dev-python/orderly-set/orderly-set-5.3.2.ebuild b/dev-python/orderly-set/orderly-set-5.3.2.ebuild
new file mode 100644
index 000000000000..2124383bce7a
--- /dev/null
+++ b/dev-python/orderly-set/orderly-set-5.3.2.ebuild
@@ -0,0 +1,29 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A package containing multiple implementations of Ordered Set"
+HOMEPAGE="
+	https://github.com/seperman/orderly-set/
+	https://pypi.org/project/orderly-set/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unconditional mypy dep for a test that is not even run
+	# https://github.com/seperman/orderly-set/pull/5
+	sed -i -e '/mypy\.api/d' tests/*.py || die
+}
diff --git a/dev-python/pbs-installer/Manifest b/dev-python/pbs-installer/Manifest
index a1900c109a2b..353f44df2bee 100644
--- a/dev-python/pbs-installer/Manifest
+++ b/dev-python/pbs-installer/Manifest
@@ -1,2 +1,3 @@
 DIST pbs-installer-2025.03.11.gh.tar.gz 84837 BLAKE2B 32860346f216907a320881e9107a194870a460f39c51d6a4f4f366119de0717b36a7dbf6a98be99a6aef30212eb48e9e949c1d9ae95642ea7bda34264549cd55 SHA512 5b323d6b1a116516a03843ffcea2e0217c53b7726089ba57f1633dd0072c4217d3d229b32f8a5746f034b54f84be1a0a12bfe3ea6d73ab3fff45c76205230e9f
 DIST pbs-installer-2025.03.17.gh.tar.gz 84857 BLAKE2B 84a53ba5257817ae877dc2e65ddeb0cdcc10b88ed72888a773986d66bc349fcfb8892bb8974cc5b81fdf8d5e295771da0fcb21822537bd6ede14f669ad883535 SHA512 8ab4f418c9415ce6395334147a982fe6d04bd0952f33a859a67346c6666c00fdae92d200849fbeb13c7e03fba1c088b04d31a6dbbee5adf44b812a32659624c0
+DIST pbs-installer-2025.04.09.gh.tar.gz 88038 BLAKE2B cdd7abd128d369b85041e27c1b0c728af0e64f1efc7b879b682abea1df6f5a2e124fa2f22e697624b3d8a604956fccd594394d426e262c4e7c2c30918bd85a1f SHA512 089aae49a2eb1c9e46f0c47f84497068e6f47bff85840991c6b4cafbda60f6ddddd6e91ea9decedbf93afdbf55499e7fd01dbf04908e42cda634a29654bc7d4b
diff --git a/dev-python/pbs-installer/pbs-installer-2025.04.09.ebuild b/dev-python/pbs-installer/pbs-installer-2025.04.09.ebuild
new file mode 100644
index 000000000000..3844530d8280
--- /dev/null
+++ b/dev-python/pbs-installer/pbs-installer-2025.04.09.ebuild
@@ -0,0 +1,35 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Installer for Python Build Standalone"
+HOMEPAGE="
+	https://pypi.org/project/pbs-installer/
+	https://github.com/frostming/pbs-installer/
+
+"
+SRC_URI="
+	https://github.com/frostming/pbs-installer/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+BDEPEND="
+	dev-python/zstandard[${PYTHON_USEDEP}]
+"
+
+# upstream does not provide any tests
+RESTRICT=test
+
+python_configure_all() {
+	export PDM_BUILD_SCM_VERSION=${PV}
+}
diff --git a/dev-python/python-tests/python-tests-3.10.17.ebuild b/dev-python/python-tests/python-tests-3.10.17.ebuild
index c423a21e03ab..c86a67e43b3a 100644
--- a/dev-python/python-tests/python-tests-3.10.17.ebuild
+++ b/dev-python/python-tests/python-tests-3.10.17.ebuild
@@ -28,7 +28,7 @@ S="${WORKDIR}/${MY_P}/Lib"
 
 LICENSE="PSF-2"
 SLOT="${PYVER}"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
 RDEPEND="
diff --git a/dev-python/python-tests/python-tests-3.11.12.ebuild b/dev-python/python-tests/python-tests-3.11.12.ebuild
index d3487fcbbcbf..1dc242d81559 100644
--- a/dev-python/python-tests/python-tests-3.11.12.ebuild
+++ b/dev-python/python-tests/python-tests-3.11.12.ebuild
@@ -28,7 +28,7 @@ S="${WORKDIR}/${MY_P}/Lib"
 
 LICENSE="PSF-2"
 SLOT="${PYVER}"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~alpha ~amd64 ~arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc ~x86"
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
 RDEPEND="
diff --git a/dev-python/python-tests/python-tests-3.12.10.ebuild b/dev-python/python-tests/python-tests-3.12.10.ebuild
index 943b544daf16..1c35cd1ee4cd 100644
--- a/dev-python/python-tests/python-tests-3.12.10.ebuild
+++ b/dev-python/python-tests/python-tests-3.12.10.ebuild
@@ -28,7 +28,7 @@ S="${WORKDIR}/${MY_P}/Lib"
 
 LICENSE="PSF-2"
 SLOT="${PYVER}"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
 RDEPEND="
diff --git a/dev-python/python-tests/python-tests-3.13.3.ebuild b/dev-python/python-tests/python-tests-3.13.3.ebuild
index db959e992087..f771b1aadb9a 100644
--- a/dev-python/python-tests/python-tests-3.13.3.ebuild
+++ b/dev-python/python-tests/python-tests-3.13.3.ebuild
@@ -28,7 +28,7 @@ S="${WORKDIR}/${MY_P}/Lib"
 
 LICENSE="PSF-2"
 SLOT="${PYVER}"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
 RDEPEND="
diff --git a/dev-python/rtslib-fb/Manifest b/dev-python/rtslib-fb/Manifest
index 7b339f433b05..b3a4b736b870 100644
--- a/dev-python/rtslib-fb/Manifest
+++ b/dev-python/rtslib-fb/Manifest
@@ -1,2 +1,3 @@
 DIST rtslib-fb-2.1.76.tar.gz 78055 BLAKE2B df22093072a7e7b12a080db8253eff9e6aff1efb44a8bdb6c37a21601fd10beea03b665d1e1621904a9a0c1d1299e7f9e5f61682669f75a06f4e050c503da9a7 SHA512 fee3087702e44ede59b9635d7cbe7af06da104d6aeffc3fbb584ce6e8170b7856650a006ee574940448801a67e9f7d9610ccb9ad632dd6d0c378fe7c6cd1c159
 DIST rtslib_fb-2.2.2.tar.gz 45508 BLAKE2B e233bd7b346e7da98d8d6237f1cfc976a4963a13802c06175612c9c5497b20fb708228561b8a7a03dfd31e24359c1c339bae9c09228d2c3df5f1a5d9fbad6b08 SHA512 e64b0cc32520c19747c4e752a33aef9e27557f34a695d321b699bfd12feaba9749b32b5e292c96258bf0e6bf87fc4bb56287257691a7dccd786d12c9bec72964
+DIST rtslib_fb-2.2.3.tar.gz 45629 BLAKE2B fe7514b09a386a8c6e6f5023dd5e04094551bd636f5a60b5d12006b1958336410532549fa9e7684c5a4fcc2890325057435e1287484c45ecc83992c33d10f62a SHA512 c02e635aaa6d62620ab5c252cd5a1231dc835dc3a385b914439d20eba7d41dacd9d6060c0bb68655c69f198e7f6b6c4806e6a1fb0d83c9905672361e3235c322
diff --git a/dev-python/rtslib-fb/rtslib-fb-2.2.3.ebuild b/dev-python/rtslib-fb/rtslib-fb-2.2.3.ebuild
new file mode 100644
index 000000000000..98700b7b9191
--- /dev/null
+++ b/dev-python/rtslib-fb/rtslib-fb-2.2.3.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1 systemd pypi
+
+DESCRIPTION="A Python object API for managing the Linux LIO kernel target"
+HOMEPAGE="
+	https://github.com/open-iscsi/rtslib-fb/
+	https://pypi.org/project/rtslib-fb/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/pyudev[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests import-check
+
+src_install() {
+	distutils-r1_src_install
+	systemd_dounit "${FILESDIR}/target.service"
+}
diff --git a/dev-python/scripttest/Manifest b/dev-python/scripttest/Manifest
index cb1557a003cf..31bc7a2861ef 100644
--- a/dev-python/scripttest/Manifest
+++ b/dev-python/scripttest/Manifest
@@ -1 +1,2 @@
 DIST scripttest-2.0.gh.tar.gz 14676 BLAKE2B 12515127e02d2ad8d4a60517571066ed3f381e21d7c64424f436a97d331e1a0d1b7ab7f6898b1a97dc2d379a59184a409b1ad35c472d7bf794953fbd5eeed150 SHA512 c3a2ccb1856c11a377287829683e63f3c8b4653ee778596a606195712bb8c01dcfb6e98408ac1012bfb3d0b45853f3076301f6a42e1f03bebf1df8a06e9d15f9
+DIST scripttest-2.0.post1.tar.gz 16203 BLAKE2B b2d84351ff6cb9de087e846157b0d5589735dace47b21087d6f9f1fd5b3e93a0351d6b5bc63224dd88de1ebb8d824866ed594344b4b93a024026a180dfd6ce24 SHA512 0d0c6248c29bd735c4c1832faca16d6f7d42fd9bb432700a0dcc56ff08d6a77ec9add99914006a1b7a9b57c1fa5f252195f419ad952ccc0fcb2a7267fdf10954
diff --git a/dev-python/scripttest/scripttest-2.0_p1.ebuild b/dev-python/scripttest/scripttest-2.0_p1.ebuild
new file mode 100644
index 000000000000..15269e52efd1
--- /dev/null
+++ b/dev-python/scripttest/scripttest-2.0_p1.ebuild
@@ -0,0 +1,21 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Helper to test command-line scripts"
+HOMEPAGE="
+	https://pypi.org/project/scripttest/
+	https://github.com/pypa/scripttest/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+distutils_enable_tests pytest