Adding metadata

21 files changed, 466 insertions, 4 deletions

diff --git a/dev-python/PySocks/metadata.xml b/dev-python/PySocks/metadata.xml
index c4fa42768771..fb4e107f8c15 100644
--- a/dev-python/PySocks/metadata.xml
+++ b/dev-python/PySocks/metadata.xml
@@ -10,4 +10,5 @@
   <remote-id type="github">Anorov/PySocks</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/aesara/Manifest b/dev-python/aesara/Manifest
index 1f56d826c5b5..f0a6ed0e34a3 100644
--- a/dev-python/aesara/Manifest
+++ b/dev-python/aesara/Manifest
@@ -1,3 +1,4 @@
 DIST aesara-rel-2.0.1.tar.gz 7975083 BLAKE2B 6dfeffb5abbd2a9b8097b9f91b537f215b1d2ee8ec9d2ad2abcb823761b722c2e4de75843c74584445c96add175366ac4e2a62eced88ad75c58d0c31f2b4df87 SHA512 8dad298ada2d4a20151cf86c08424b02e1c0afc5060915844ba06a492866b04225e6cb0407bf1de8d651c0e7ed8bca34e184f2f9a2778a66ed41f08d4b51bfd2
 DIST aesara-rel-2.0.2.tar.gz 7974102 BLAKE2B 53ddfada4304776694553d491e80a8b20cec5b5b46819adcc099a7b4cf32dfc68b46d83ba7b769f22f0d088a42e8de269c3385aed4e185920a37c4a349b4a1d5 SHA512 f8f34a1750b5ad250e9243fc0d47f19cd0f8847650e98ea3cef6da03d5a50b884d03e7b6f5cab36d65948a6dd904742a851ac8ea475a0113eb9cbe230a5c834d
 DIST aesara-rel-2.0.3.tar.gz 8019978 BLAKE2B 5e3a7cdca08569a06b7731ff55894c618599c1ebfbaa168cae2d5b8d5b29c5a638b96daa934e663b7cdca6a10ca4b32562c26ab5d240d741ba869863b1701ef4 SHA512 a72c142f9eb1dae34eb0ea172dad7758771e9e8da471a2563798b33fc622e26210f0081013b9a6fb61a927e9ca07e53399ced1fcedc4648f6d76384a3c5c386e
+DIST aesara-rel-2.0.4.tar.gz 8020138 BLAKE2B 4fa1d0d1979eaac1635cd09d9af61ae4be0cbac3722c37cba54a81a93f358f72a7b6c543e2f8c4b120262469e27f96273bffb9222a2c36f58284bc5b7c148d89 SHA512 8205cbbdfb2ce901ea4991a2dc82a8809d1151b2a8da9382cb5306ecb916793c927f8e7c057cc32145802625883476d6a69b5e19b69a69bc843b0114775918ae
diff --git a/dev-python/aesara/aesara-2.0.4.ebuild b/dev-python/aesara/aesara-2.0.4.ebuild
new file mode 100644
index 000000000000..f23baa5bc574
--- /dev/null
+++ b/dev-python/aesara/aesara-2.0.4.ebuild
@@ -0,0 +1,65 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1 optfeature
+
+MY_P=aesara-rel-${PV}
+DESCRIPTION="Library for operating on mathematical expressions with multi-dimensional arrays"
+HOMEPAGE="https://github.com/pymc-devs/aesara"
+SRC_URI="https://github.com/pymc-devs/aesara/archive/rel-${PV}.tar.gz -> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_sphinx doc 'dev-python/sphinx_rtd_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -i -e "s/tests.\*/tests\*/" setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local exclude=(
+		# speed tests are unreliable
+		tests/scan/test_basic.py::test_speed
+		tests/scan/test_basic.py::test_speed_rnn
+		tests/scan/test_basic.py::test_speed_batchrnn
+		tests/link/test_vm.py::test_speed
+		tests/link/test_vm.py::test_speed_lazy
+		tests/tensor/test_gc.py::test_merge_opt_runtime
+	)
+
+	distutils_install_for_testing --via-root
+	pytest -vv ${exclude[@]/#/--deselect } \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+# https://dev.gentoo.org/~mgorny/python-guide/concept.html#packaging-pkgutil-style-namespaces-in-gentoo
+python_install() {
+	rm "${BUILD_DIR}"/lib/bin/__init__.py || die
+	distutils-r1_python_install
+}
+
+pkg_postinst() {
+	optfeature "GPU code generation/execution on NVIDIA gpus" dev-util/nvidia-cuda-toolkit dev-util/nvidia-cuda-sdk
+	optfeature "GPU/CPU code generation on CUDA and OpenCL devices" dev-libs/libgpuarray dev-python/pycuda
+}
diff --git a/dev-python/importlib_metadata/Manifest b/dev-python/importlib_metadata/Manifest
index 6bfd72dca741..ffe2a0af41fd 100644
--- a/dev-python/importlib_metadata/Manifest
+++ b/dev-python/importlib_metadata/Manifest
@@ -3,3 +3,4 @@ DIST importlib_metadata-3.7.0.tar.gz 36517 BLAKE2B b96ac99bbc9ed7c961635a598d46b
 DIST importlib_metadata-3.7.1.tar.gz 36595 BLAKE2B c4eaf3671ec48610ce310a2609625ab77496252953c2d0567cc4824c39a8601ef99fb3ffd5d7968eb7aa358aaedf0ab81d87271afdddac68d7bd3a70971b153a SHA512 b301c6c72b185d893e5e400dbd9417b2ba94122073d6cb163c9e9949fb13762ddc57b34dbba1330b55bef47073fc72a6a4b5689adf9af819a68be603c9d64c9e
 DIST importlib_metadata-3.7.2.tar.gz 36644 BLAKE2B 11e8f0c012d405a7059842fbc0aa1edfd8313a01b12b36e40c5a542b17f6ebe5284e945967f080c5934758820354f131df81e84d1fa4d5e6ac1660dac055a914 SHA512 ecf630c83c08895d566fbf3f435d4bfc5c0336dff1c682e6413598749c13720211aad4085dd7b9a88ca4218ef5514cd730a6f13c2c53be6cc349edd142106204
 DIST importlib_metadata-3.7.3.tar.gz 37193 BLAKE2B 0de5f4ece99db9ec4f86e9b967c8583d06a5bda939a7bdb137dba3c6a9d7fd034802d9fa0eb5bf209ae5ada89ebd0f3120557d3fa2b300739ebff2ff1bb6edb8 SHA512 1d6ee80edb3e5efb56deb0676ef42ba72fdaf124504023954cb3b1192e5378c3370a35b5e77708f3d9a19c02f0d89a1ba08a919a7aaec5e284f54c2eb3c61fc1
+DIST importlib_metadata-3.8.0.tar.gz 38515 BLAKE2B ba5e06f8a43632dedcb1cb10007dbc7978b33c9a264e3ddc743855f44c932a00b05bae810a1d6621742a75161ef828bd9523045a023f657a24dab6d7e36bc1bf SHA512 2c336457accf8b33426e73632c90ea46720230822826b683365e5a32fe89c2fccfd45843613d9631cbbe926c03418ba107609ea85fead88ab2f9b9b18c67ddb5
diff --git a/dev-python/importlib_metadata/importlib_metadata-3.8.0.ebuild b/dev-python/importlib_metadata/importlib_metadata-3.8.0.ebuild
new file mode 100644
index 000000000000..eb45b99adc44
--- /dev/null
+++ b/dev-python/importlib_metadata/importlib_metadata-3.8.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# NB: this package extends beyond built-in importlib stuff in py3.8+
+# new entry_point API not yet included in cpython release
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Read metadata from Python packages"
+HOMEPAGE="https://github.com/python/importlib_metadata"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	$(python_gen_cond_dep 'dev-python/typing-extensions[${PYTHON_USEDEP}]' python3_{6,7})
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pyfakefs[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/importlib_resources[${PYTHON_USEDEP}]
+		' pypy3 python3_{7,8})
+	)
+"
+
+distutils_enable_sphinx docs dev-python/jaraco-packaging dev-python/rst-linker
+distutils_enable_tests unittest
+
+python_prepare_all() {
+	# Skip a test that requires pep517 which is not in the tree
+	sed -e 's:test_find_local:_&:' -i tests/test_integration.py || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index 6dba11f5a5e4..0cbf326fbe7b 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -1,2 +1,3 @@
 DIST ipython-7.20.0.tar.gz 5140776 BLAKE2B ec01caf874ab9c331eb1f074f9e70acb521fe6d4abe3e8f086d9e9e77cd710c3b0d88c6d7b071abc6962eee8141b65a012ec772cbec3450db25f086fc66cf1c6 SHA512 2fff1a64c3d83e794e76bcbdf54e105f499321d9a7e5d3221cdc3e15a96e90543fd465b8dbee4836965286e7c1f1ea6d13e4d3d88c095164858bf71c161111fe
 DIST ipython-7.21.0.tar.gz 5141725 BLAKE2B dae44d481e959ef7d002bdb51d0ab1e2f3eca3449071a2e4161aa735c06fef8a948d80bafd3f2bdd066208437b5ed36615cad5885af453771a32a313fba907eb SHA512 200e41d4e06343b6320f3d106925f6c995f39cf88d01250f53885d4e94d0fd9454a6be4cd7c69410f7dced94b05634f6d2269f9737cc563accf85206d4d7fff8
+DIST ipython-7.22.0.tar.gz 5143229 BLAKE2B be78fc7089d620cb9ad437ed8154b37ac8c7cd68ca18a2569cfcf7ea9af968c58eeee18c8d18a1f26459ccef73e59083ac27055c19e4df254836e484ce0a9908 SHA512 2647dcd5e0d9b6afc8d990d2c099ad7ed581b5eff6d657630929e0d0d9f8965e7c7924c51a10a797e7d7406212d7a06c941c163e6f6046aa62130049a9bbc0d0
diff --git a/dev-python/ipython/ipython-7.22.0.ebuild b/dev-python/ipython/ipython-7.22.0.ebuild
new file mode 100644
index 000000000000..50a76524044f
--- /dev/null
+++ b/dev-python/ipython/ipython-7.22.0.ebuild
@@ -0,0 +1,137 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+CDEPEND="
+	dev-python/backcall[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
+	<dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	matplotlib? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
+"
+
+RDEPEND="${CDEPEND}
+	nbconvert? ( dev-python/nbconvert[${PYTHON_USEDEP}] )"
+
+BDEPEND="
+	test? (
+		${CDEPEND}
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.16[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)"
+
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Remove out of date insource files
+	rm IPython/extensions/cythonmagic.py || die
+	rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	distutils_install_for_testing
+	pushd "${TEST_DIR}" >/dev/null || die
+	"${TEST_DIR}"/scripts/iptest || die
+	popd >/dev/null || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}
diff --git a/dev-python/jaraco-functools/Manifest b/dev-python/jaraco-functools/Manifest
index 4db40eb4f11b..d3c83688b3ac 100644
--- a/dev-python/jaraco-functools/Manifest
+++ b/dev-python/jaraco-functools/Manifest
@@ -1 +1,2 @@
 DIST jaraco.functools-3.2.1.tar.gz 16888 BLAKE2B 87dbc4a68f508a3c3169496c3f57d9844e90a6523b5526e486bbdcb1de996fb31025100e25929c0527ed27dd57ff67c90020d7cddfd70ead2a78e69ec8f65f8b SHA512 279dbb9307f864e3616f9b91ce5d55068df166a30695c0f81bcfae0bc2a1e0df5fdccd157210df3dd73ad73a6a955c1344ec441f925a651cd13a7f460e7a88e1
+DIST jaraco.functools-3.3.0.tar.gz 17116 BLAKE2B 3e1bf63f72d67e55fdf5cfd8d2e12899b7862ebe6cf426be94154f479cf01a69f01b1af152a574c4fb93766b324b6050748464a17a26a27591396d59ed79cb38 SHA512 fc7c5a11a3411692066f4437d76ace7e8a00af2152256ea9f730254b577e74163342298d5b33d472c744cbad5dd316b56345d05aa93ef6f82bc92d6aadb2f2ec
diff --git a/dev-python/jaraco-functools/jaraco-functools-3.3.0.ebuild b/dev-python/jaraco-functools/jaraco-functools-3.3.0.ebuild
new file mode 100644
index 000000000000..8712374a1b9b
--- /dev/null
+++ b/dev-python/jaraco-functools/jaraco-functools-3.3.0.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Additional functions used by other projects by developer jaraco"
+HOMEPAGE="https://github.com/jaraco/jaraco.functools"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/toml[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/jaraco-classes[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	">=dev-python/jaraco-packaging-3.2" \
+	">=dev-python/rst-linker-1.9"
+distutils_enable_tests pytest
diff --git a/dev-python/mypy/metadata.xml b/dev-python/mypy/metadata.xml
index 6927756f75bb..6268f080b402 100644
--- a/dev-python/mypy/metadata.xml
+++ b/dev-python/mypy/metadata.xml
@@ -16,5 +16,4 @@
   <doc>https://mypy.readthedocs.io/</doc>
  </upstream>
  <origin>gentoo-staging</origin>
- <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/mypy/mypy-0.812-r2.ebuild b/dev-python/mypy/mypy-0.812-r2.ebuild
new file mode 100644
index 000000000000..54ca9f962095
--- /dev/null
+++ b/dev-python/mypy/mypy-0.812-r2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Optional static typing for Python"
+HOMEPAGE="http://www.mypy-lang.org/"
+TYPESHED_COMMIT="add4d92f050fb11d3901c6f0ee579a122d4a7a98"
+SRC_URI="
+	https://github.com/python/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/python/typeshed/archive/${TYPESHED_COMMIT}.tar.gz
+		-> typeshed-${TYPESHED_COMMIT}.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# stubgen collides with this package: https://bugs.gentoo.org/585594
+RDEPEND="
+	!dev-util/stubgen
+	>=dev-python/psutil-4[${PYTHON_USEDEP}]
+	>=dev-python/typed-ast-1.4.0[${PYTHON_USEDEP}]
+	<dev-python/typed-ast-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-3.7.4[${PYTHON_USEDEP}]
+	>=dev-python/mypy_extensions-0.4.3[${PYTHON_USEDEP}]
+	<dev-python/mypy_extensions-0.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/attrs-18.0[${PYTHON_USEDEP}]
+		>=dev-python/lxml-4.4.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-6.1.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-1.18[${PYTHON_USEDEP}]
+		>=dev-python/py-1.5.2[${PYTHON_USEDEP}]
+		>=dev-python/virtualenv-16.0.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source dev-python/sphinx_rtd_theme
+distutils_enable_tests pytest
+
+src_unpack() {
+	default
+	rmdir "${S}/mypy/typeshed" || die
+	mv "${WORKDIR}/typeshed-${TYPESHED_COMMIT}" "${S}/mypy/typeshed" || die
+
+	export MYPY_USE_MYPYC=1
+}
+
+python_test() {
+	# Some mypy/test/testcmdline.py::PythonCmdlineSuite tests
+	# fail with high COLUMNS values
+	local -x COLUMNS=80
+	epytest -n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
diff --git a/dev-python/polib/Manifest b/dev-python/polib/Manifest
index 275b9a16cbf0..a651ba65cdfa 100644
--- a/dev-python/polib/Manifest
+++ b/dev-python/polib/Manifest
@@ -1 +1,2 @@
 DIST polib-1.1.0.tar.gz 158484 BLAKE2B 41766f00e3928eacf3c98406b6acce224f0d0cb44d79326c834db900ed8b91181911ab7e26845a737057dd07c067a784d0b06278952708c17888db42d8c1e303 SHA512 74681585b4d7252e107acd7d73f49f7e91c90adcd180722d39d35c40ec158434798af0124a16788cf564c73b84f52a040aefeb58355a1a3cd85848c3f6a5e67f
+DIST polib-1.1.1.tar.gz 154644 BLAKE2B 3dfbaf2fa73d286a60a1fff3e50d8703cf62917b7da0c8b783aaec49b8dcfb927b03b0fe0b411b5f90c2ac89298ea027beb2f0d00ad582a65628d8351397ddab SHA512 38de5fbdbc9ef879a4d55b9fe4f86a3aca3fb90dbb671745bd2b126be443598b8b18fe53afd116c3a4d3efc7a42b5ed05d75569bb5b2ef0bd2ced6e13eda95ad
diff --git a/dev-python/polib/metadata.xml b/dev-python/polib/metadata.xml
index 8903971199e6..a7a6e8539815 100644
--- a/dev-python/polib/metadata.xml
+++ b/dev-python/polib/metadata.xml
@@ -1,6 +1,10 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
+ <maintainer type="project">
+  <email>python@gentoo.org</email>
+  <name>Python</name>
+ </maintainer>
  <upstream>
   <remote-id type="github">izimobil/polib</remote-id>
   <remote-id type="pypi">polib</remote-id>
diff --git a/dev-python/polib/polib-1.1.1.ebuild b/dev-python/polib/polib-1.1.1.ebuild
new file mode 100644
index 000000000000..84de463c33c8
--- /dev/null
+++ b/dev-python/polib/polib-1.1.1.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A library to manipulate gettext files (.po and .mo files)"
+HOMEPAGE="https://github.com/izimobil/polib https://polib.readthedocs.io/en/latest/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+
+distutils_enable_sphinx docs
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.0.7-BE-test.patch
+)
+
+python_test() {
+	"${EPYTHON}" tests/tests.py -v || die "Tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/python-bugzilla/python-bugzilla-3.0.2.ebuild b/dev-python/python-bugzilla/python-bugzilla-3.0.2.ebuild
index 24a2f63cd4a4..03099384dde0 100644
--- a/dev-python/python-bugzilla/python-bugzilla-3.0.2.ebuild
+++ b/dev-python/python-bugzilla/python-bugzilla-3.0.2.ebuild
@@ -12,7 +12,7 @@ DESCRIPTION="A python module for interacting with Bugzilla over XMLRPC"
 HOMEPAGE="https://github.com/python-bugzilla/python-bugzilla"
 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
-KEYWORDS="amd64 arm arm64 ~ppc ~ppc64 ~sparc x86"
+KEYWORDS="amd64 arm arm64 ppc ppc64 ~s390 sparc x86"
 LICENSE="GPL-2+"
 SLOT="0"
 
diff --git a/dev-python/redis-py/redis-py-3.5.3.ebuild b/dev-python/redis-py/redis-py-3.5.3.ebuild
index c1bf8741e2aa..e8d6a93b79d3 100644
--- a/dev-python/redis-py/redis-py-3.5.3.ebuild
+++ b/dev-python/redis-py/redis-py-3.5.3.ebuild
@@ -17,7 +17,7 @@ S="${WORKDIR}/${MY_P}"
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 arm arm64 ~hppa ppc ppc64 ~sparc x86 ~amd64-linux ~x86-linux"
+KEYWORDS="amd64 arm arm64 ~hppa ppc ppc64 sparc x86 ~amd64-linux ~x86-linux"
 IUSE="test"
 RESTRICT="!test? ( test )"
 
diff --git a/dev-python/snakeoil/Manifest b/dev-python/snakeoil/Manifest
index 67bf6e6582e0..d48567c63632 100644
--- a/dev-python/snakeoil/Manifest
+++ b/dev-python/snakeoil/Manifest
@@ -6,3 +6,4 @@ DIST snakeoil-0.9.2.tar.gz 271441 BLAKE2B 754030285f03c83979c74da6cf8ee585486631
 DIST snakeoil-0.9.3.tar.gz 270471 BLAKE2B 2f8c3737c560a756e6fd5450c900d1fbe49b0200e1c4427a312f90d14da22e2e403a710bdc768446b3b03166853d6a0965507550ee837556d273817a7f634282 SHA512 18aa892fe6d225823593f8199f029a1a866052b1cebdf4f77dc57916e6a2b15982b6729d3004a8616eedddee5e3bc260d2c5b2f78170c4d008d1f2e46cc26ce1
 DIST snakeoil-0.9.4.tar.gz 271395 BLAKE2B 6aeaf03e2c2f48a85ce926f1b8e0b86271c608695694358cb6eea56b962c0731b909c16bf37844031e986fc7ebca3a7c4cae5cb94ee55122584bf83981d8c4b6 SHA512 853c3fef517e7161a61ae0622fed82ceffdc110cad4ef7d5e2166728f506228d0802018dd351956f1525f0d27a4150e9885b2cc7c71788950261f72d8d7c4cc9
 DIST snakeoil-0.9.5.tar.gz 266086 BLAKE2B 635d2d821e47a92a668b2e95364d6587f0f74c21438356e708d6b16ed6c027df39a28f73d261d8ae06eb32de471124cd5ba5df0fc899f59dad5f7d2363391e00 SHA512 0762d90932bdf995160b3410e224660dae2cce327cdc30d5093ca9e3d16d3e910f88e409a87d2d7da211b850f7d0b7d9c70f053462dd9a651e4202b8ca018105
+DIST snakeoil-0.9.6.tar.gz 261998 BLAKE2B 1f81e633321b7b1988865092ec2778feb35338edec0eb00c9a5be505a9cf7d4cf27b140c9bc56fc42156dc33a7990e8a269d1a69df7cac92a71b56ce612b65ae SHA512 a900c76ecd5a3519bf5236567e5f9d59bca7c5f7588bdcfbf1bec0d912352486c86dfd4677b0aea19170bc9170109ca782dd60232e365008ae016cdf9ade7217
diff --git a/dev-python/snakeoil/snakeoil-0.9.6.ebuild b/dev-python/snakeoil/snakeoil-0.9.6.ebuild
new file mode 100644
index 000000000000..7e7cd9b00bad
--- /dev/null
+++ b/dev-python/snakeoil/snakeoil-0.9.6.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="threads(+)"
+inherit distutils-r1
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/pkgcore/snakeoil.git"
+	inherit git-r3
+else
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-macos"
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+fi
+
+DESCRIPTION="misc common functionality and useful optimizations"
+HOMEPAGE="https://github.com/pkgcore/snakeoil"
+
+LICENSE="BSD BSD-2 MIT"
+SLOT="0"
+
+RDEPEND="
+	dev-python/lazy-object-proxy[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? ( >=dev-python/pytest-6 )"
+
+[[ ${PV} == 9999 ]] && BDEPEND+=" dev-python/cython[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
diff --git a/dev-python/snakeoil/snakeoil-9999.ebuild b/dev-python/snakeoil/snakeoil-9999.ebuild
index c7f1e36b6691..7e7cd9b00bad 100644
--- a/dev-python/snakeoil/snakeoil-9999.ebuild
+++ b/dev-python/snakeoil/snakeoil-9999.ebuild
@@ -10,7 +10,7 @@ if [[ ${PV} == *9999 ]] ; then
 	EGIT_REPO_URI="https://github.com/pkgcore/snakeoil.git"
 	inherit git-r3
 else
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-macos"
 	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 fi
 
@@ -22,6 +22,8 @@ SLOT="0"
 
 RDEPEND="
 	dev-python/lazy-object-proxy[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? ( >=dev-python/pytest-6 )"
 
 [[ ${PV} == 9999 ]] && BDEPEND+=" dev-python/cython[${PYTHON_USEDEP}]"
 
diff --git a/dev-python/symengine/Manifest b/dev-python/symengine/Manifest
index 9386cd322277..31665474f7d8 100644
--- a/dev-python/symengine/Manifest
+++ b/dev-python/symengine/Manifest
@@ -1,2 +1,3 @@
 DIST symengine.py-0.6.1.tar.gz 112123 BLAKE2B 3b55ddd834c7401a5a211e5e20bafbea68b172738c6388e72b1e6a6e62719e19f28356fb6156caa6cfbad59d051de45c0e103a89d675e3453136cc85e638f327 SHA512 09f452757e3c99dc9d896a322a07d58f57af6d57a9eaa615b9f4f3d834cfc91f6a79de955a36ad94bc30c962365272ef0afe401570583af49c015295ccd7c4ed
 DIST symengine.py-0.7.0.tar.gz 107575 BLAKE2B f3651d8ee0dee83184871a25fa8535802efead1912684d309e6ab6b63ada53af94146ddcee3df8f87530063991a1d6463d2b14799bb9622606ae5eb37792938f SHA512 73df1c9c678127d3a17e2434ad326793ea00f6c6774301d1da372a8a33f733593e873d98866d31315f22430b427fa76d5f1270b6b308a7473d9877a75db3aca4
+DIST symengine.py-0.7.2.tar.gz 107747 BLAKE2B cacd11f316df5132b6bbee356fd7a4c2d3fa30e80b144c5d8982fec1b6856ca3c839ef7a6f8daf4e70a27462fc43870d05fa76ece085e5577a1672b8e9910127 SHA512 afde47e5f6274a02c6ca138a6316bf0f7ec1c7585acaf4ab19ba849280dfee9ba937c3f8f5117e70f2a6377224f6dab9757958272f4facbafdc11d7965ee7a84
diff --git a/dev-python/symengine/symengine-0.7.2.ebuild b/dev-python/symengine/symengine-0.7.2.ebuild
new file mode 100644
index 000000000000..c3d591bf887c
--- /dev/null
+++ b/dev-python/symengine/symengine-0.7.2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+MY_P=${PN}.py-${PV}
+DESCRIPTION="Python wrappers to the symengine C++ library"
+HOMEPAGE="https://github.com/symengine/symengine.py/"
+SRC_URI="
+	https://github.com/symengine/symengine.py/archive/v${PV}.tar.gz
+		-> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+BDEPEND="
+	dev-util/cmake
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/sympy[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=sci-libs/symengine-0.6
+"
+
+distutils_enable_tests pytest
+
+# the C library installs the same docs
+DOCS=()
+
+src_prepare() {
+	default
+
+	# Don't install tests
+	> "${S}/symengine/tests/CMakeLists.txt" || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}" || die
+	epytest
+}
+
+python_install() {
+	distutils-r1_python_install
+	python_optimize
+}