Adding metadata

34 files changed, 587 insertions, 18 deletions

diff --git a/dev-python/Faker/Faker-8.12.0.ebuild b/dev-python/Faker/Faker-8.12.0.ebuild
new file mode 100644
index 000000000000..1f1f09ada79c
--- /dev/null
+++ b/dev-python/Faker/Faker-8.12.0.ebuild
@@ -0,0 +1,29 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="A Python package that generates fake data for you"
+HOMEPAGE="https://github.com/joke2k/faker"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/python-dateutil-2.4.2[${PYTHON_USEDEP}]
+	>=dev-python/text-unidecode-1.3[${PYTHON_USEDEP}]
+	!dev-ruby/faker"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP},tiff]
+		dev-python/random2[${PYTHON_USEDEP}]
+		dev-python/validators[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
diff --git a/dev-python/Faker/Manifest b/dev-python/Faker/Manifest
index 7b2b83f57a49..67cb86eb3c17 100644
--- a/dev-python/Faker/Manifest
+++ b/dev-python/Faker/Manifest
@@ -3,6 +3,7 @@ DIST Faker-8.10.1.tar.gz 1144158 BLAKE2B 7463566a8bf2f510ab89b7fd67ee3aea80ce657
 DIST Faker-8.10.2.tar.gz 1150102 BLAKE2B 5ca744d201a7822cbe35791757a73628d3c12f6521ca55bc2d340c974cb6e76362f87395cbc858e4681738440cf676e9f9bf7a8002b908ff564dc6703ef794e0 SHA512 5a148327df7c34623c0d8c154e6181a183a0aa484659e5872013f0b9c510418690278550ebbed6eb984c87cef588fd862b213295a379b5be3433afe312181103
 DIST Faker-8.10.3.tar.gz 1149954 BLAKE2B 665ed95be11f734ed2ae9b593a4e287cc53b041521ab223efc045f061133e983de500ef12a858d7420342a500926297565b7c50674fe5533b985a00816251031 SHA512 a5969f04dd96660b3e62ece20ce4d92de9c781faa1742e45404b0a6f04dc7521c9532c519df06c4b3e9a815dde43837b7ab7628ef25ed3b60bda49c927b8ace7
 DIST Faker-8.11.0.tar.gz 1150354 BLAKE2B 9799163239afef521d352dea601a63f2702536380891182c72f856bf442441ed654412ba035dd4964ea9ca3f2c19e0737e0225a58178a2edffcc52b06047e2f1 SHA512 5a42ea5c843272f9f70edc88e405f0b309f6e6ae5c061d1f1ca7ed01f40688539371a1bce5084a0de3e424f3eb50443430ff1fafd1ef0a035d385d80b16cae2c
+DIST Faker-8.12.0.tar.gz 1151218 BLAKE2B b55d1b1bac6a580c51fdd3f87919cbcea107aff309bce4d2092ec77046dc40c67650f3c53d176147b6b433008e7487dae9e096eb9ba6c8722ec54ce5d6d39449 SHA512 5df90c0976cb8b5e96f4c6645a984e813130fd22f25b5fb99b7cd28b6e079eec54b19f8ca643b795be15f41b9f5b677e89db1379615479983f0b5519a6dd56b4
 DIST Faker-8.8.2.tar.gz 1148529 BLAKE2B 279984479ad4f790dc7acd74b5ccd1cf5f32689b8b1ccf2152d7dfaa6fc7b4699d9827c16f83bb86e298723b6906a5cc40c2fa7f75439b5af5fc78c1af99a3f6 SHA512 4273008bf9ab693a40da2f93ff1fe40e9e7b102a2d5439f09096b6754b82dc26310666da65723b363f628365c97d44dd290e1e7065b7a9d862130baa292325b7
 DIST Faker-8.9.0.tar.gz 1148829 BLAKE2B b24a7fa87886cb38850808de2ffe1ceafab3c548c694af30d53b1f415d329264fe7e53f33f46b913d16310dd83d95fe591689a308bb7d4c653254e39defaa24b SHA512 d2e26ae140c30ae8069f8e0fd75bb9bf54aa00a7271b327e37dd248520256e137d192082071bc36a584fc864c54c050107ddecb40624288636c6b41caf1ea574
 DIST Faker-8.9.1.tar.gz 1148890 BLAKE2B 2cab6461bf6067d9dfd8872c19c8c11fa25ffef82b61b7e7676ffc187346d228703424a73278678f19263423716c74ecd47cfc1c17bf54d38bba712e456650b8 SHA512 f7016b320c7394b0eccc06e833a80e227cdbad9c0f34eb9f8f4413f56a4743f58bbd7ec5eac3b8c0642e7764c6c5986707d493f0c84daa75575a12061631c9c5
diff --git a/dev-python/astroid/Manifest b/dev-python/astroid/Manifest
index 05ffb3d99b96..8979c4f9b2b0 100644
--- a/dev-python/astroid/Manifest
+++ b/dev-python/astroid/Manifest
@@ -2,3 +2,4 @@ DIST astroid-2.6.2.tar.gz 360787 BLAKE2B a2744b9ada601b731989f17ec75aa94d8882569
 DIST astroid-2.6.5.tar.gz 364383 BLAKE2B 22da12e30bbb27ad93516ef18ebe64839fc1f7057a46fe82444c189bada942b32e00c314fe47eaecaf7cb2e7e047206152e1df98b4f46a40010bef9392721b9c SHA512 28c6fe2953f10f99c31af611644137d566489188459c9249e5621c4dc1c5fecb59c1ba3cc0bbab95c2609203388d1df299f0cb87a1fc3b3bb8b4ad3ad6b010a4
 DIST astroid-2.6.6.tar.gz 368118 BLAKE2B c5117566579ee6c8ccf973e180b3de3cd3896110221627cfa16d17fbeb049954d4452d3f55ab4161751a9eb7892fbd49090eb8e82c5a90f5985ec13a9f5d1fdd SHA512 a077c291b90f52d353d27b8e6aee2ffca1d69bf0e1e7185c32f3959853d9f2957f411975e5bf66f27d73b66cce6bd1e55529de6b7d0a17dea5399edf3a404825
 DIST astroid-2.7.1.tar.gz 373086 BLAKE2B 85ad87041ccafcc3d008455163d71c8d7b98083a7e86d45722c8d5b9a782721a7e6b5e19b0532a14801ce6ec68da72b448867c80db3bdab07e061748502bee38 SHA512 b37f445c499a2015b201b1676530c06f76b6b3e8829740208c32267aba47d77f0e94484202824f0bfc2d35021ba147d8748de89ced8f09010d08b4ca20a63120
+DIST astroid-2.7.2.tar.gz 374584 BLAKE2B 09f0f70bd0caa8e4971611d2190ccfbc06a8f871abe1e47313ff574bf4680eb26ec67c0a89fc0a434a15535b2c31d005036a0780b62495ac9d6b69e7f04419d3 SHA512 c14841265b2d50a76a5f4ff9c9f19fcdab9e1de8d726e1d40185e517bd3e9c7e1c131e23e0160102f842d7233884eb66d7db7d2443e2609db87d6ec88ed7d5b6
diff --git a/dev-python/astroid/astroid-2.7.2.ebuild b/dev-python/astroid/astroid-2.7.2.ebuild
new file mode 100644
index 000000000000..8ff40315092e
--- /dev/null
+++ b/dev-python/astroid/astroid-2.7.2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="
+	https://github.com/PyCQA/astroid/
+	https://pypi.org/project/astroid/"
+SRC_URI="
+	https://github.com/PyCQA/astroid/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+# Version specified in __pkginfo__.py.
+RDEPEND="
+	>=dev-python/lazy-object-proxy-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/wrapt-1.11.2[${PYTHON_USEDEP}]"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local deselect=(
+		# no clue why it's broken
+		tests/unittest_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
+	)
+
+	# Faker causes sys.path_importer_cache keys to be overwritten
+	# with PosixPaths
+	epytest -p no:faker ${deselect[@]/#/--deselect }
+}
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 28e73224158a..03f758fc6079 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -2,4 +2,5 @@ DIST boto3-1.18.15.tar.gz 400374 BLAKE2B 2170319480578b9ac7b6c0da9e9a2f256ce907b
 DIST boto3-1.18.21.tar.gz 402611 BLAKE2B 39974c66ed5ad0697be6df04dbb141ce28e9a09863349f7adfcf756666d58ed02232453a9d86d46e62380c0b7f197a52b6869469309dff0c532e50a6bfc88403 SHA512 9920891b7be9d98c3a3d2f3065183532624e78fd2ff7a94d26594d2499cd5d17db0ac4ba6adf27f0e0f67fa836020dfac648babc144e4339a3dd717a1bd56ef7
 DIST boto3-1.18.24.tar.gz 404333 BLAKE2B fd0857a3462485a8cb633888ad6cae1578f32f7ef80ca5195e4b4953d2a4767baa41ce824eda5cb71211675529eb54b7d8d3ad42f1ec79a0b2cef847b13cdaee SHA512 c3e67c62bdf24d177c27d187eacb1118a7f221cb0143c72c6307af489bf9fe5358e2bde9f7d5f03ef9782a50faa17f31e57832ebc2f5dc73d1278c3eefc6cc3b
 DIST boto3-1.18.25.tar.gz 404826 BLAKE2B 629a7c76ec4125c93a57f5e103d0b6e5fe360038bfc73a87369a035b321b6b143cc61fb2092f70f2dc6b07f6444180e64cafeb2e31a8f1e73b195abe06979c52 SHA512 a8f2c1a6248a75f67848bf75970535c71c098bb326ab9e344d7ab53e02562383be7acb0b41a18bc031459e0751e62bf29c3db17242ea4ebf0d7f88636251872a
+DIST boto3-1.18.26.tar.gz 405107 BLAKE2B b851a4358fb2b7cc6a6468f09690ebf91e0348e7bbc878fbe403d8eadf023601673673aa62841a94045e55fac353bc632e419afd2483e124798477e0325a86a6 SHA512 941f41639c551b9ea140a003d215c87e209e0933031cdef717bba406a6957266447e8532aef00069c3e5e482b999c094eb89c9f2df084ad7154724b6d3ab3158
 DIST boto3-1.18.7.tar.gz 395640 BLAKE2B 6a9fa1dd55644806fe93271805f35fbe0c4cb65d1de08dded2d2f57fcefa96e32c4ebe7b60743c52c0898222bc06d33dbd03d304bbef327b88022450a7943e2c SHA512 20e7fedab7d061ab02f391e9baf36cb554e7f194f38d24d5a75f76715b2acf1b51b6adce5d8cf5a2a0d29df73566db00b8813a219d45a194d9a8eb93d0dab570
diff --git a/dev-python/boto3/boto3-1.18.26.ebuild b/dev-python/boto3/boto3-1.18.26.ebuild
new file mode 100644
index 000000000000..bee358e1c595
--- /dev/null
+++ b/dev-python/boto3/boto3-1.18.26.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# prevent an infinite loop
+	rm tests/functional/docs/test_smoke.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests -v tests/unit/ tests/functional/ ||
+		die "test failed under ${EPYTHON}"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index dc4e28aacb30..449b0865b82e 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -2,4 +2,5 @@ DIST botocore-1.21.15.tar.gz 8012673 BLAKE2B cdd2b4128e67c85879e85f61265b10c1e57
 DIST botocore-1.21.21.tar.gz 8042971 BLAKE2B 888abb929e1d66c293bff9d3d25682590e0fce3173ca6e121b969d1ef92dd4bb3fd010f72ab4bed664ed6e2df94fd61a9211a3aad72742eb1d4ee2b192cb4f7d SHA512 f8f47c2a2ed07f90263fd5eefe593bf14e8bb2a8df599660f2c84c504a16eb1c370ff8edea0b809be34f1fe9c7e8a3d604b74689b9e16c0686e6ff7c640534a4
 DIST botocore-1.21.24.tar.gz 8048949 BLAKE2B 2948da75d445114d5489d3f7cef1d8bef9324da8699f69092eeb4c65a9be0fd82aae4ee97498f09d7cac05e33bc53fbd6720849a309c5edad96eba5450b45cd0 SHA512 6c205a0c27f9602580de7fbacee476b2855599bdd017f3c010f07b8f48a2ffd6acbce48f661d22ef0ebe30baba9db1ae65b1bea6afa3ae1a1c3add92abbd1478
 DIST botocore-1.21.25.tar.gz 8063998 BLAKE2B b3e4563cd36825468b6c7755fa101d13260519240b856fa26166d5bb034352431a29e816dc9e7d60f4c10e9d3b5fd152342749cc19a75a9c35ba228023da3f48 SHA512 cf91fc16047d0168d743db5bd95003a2ae06dc72ca586c622690e8c7be546bca050ba81eaf49fd860eb42e3a0046ef99e3927772b6893ddfdaf57a1071489714
+DIST botocore-1.21.26.tar.gz 8065456 BLAKE2B d6cd96e35ae31e6c440abad2a76f23d2ce6e2e0d5ecbe275fc0404cebaaf0a14245735adc39cc6d7fe5feb9530120cfa403f061af3c188623f6ba1ad01cd8d12 SHA512 3b57a6bcbdb018f0bc20afec8844f07f7135658b29329d0ed4d5579db1a8cc05e5725335560f5786b77c2f7590879ed7dcf6c043e0efd3f16960689c64f1b061
 DIST botocore-1.21.7.tar.gz 7977343 BLAKE2B 19c5bf5de40ab131585e30bb85486fcffc3428808811b312b33578174ce31a691f4f4d955462120f05d2aad2cd5e5772789704eee641760fb67099aa3cddc9b5 SHA512 db1bb36faa6857a1cc717e5d591954415bb948178ee2be90ab9c32c11b1fb45c5b5aff87dfacd907c2f11bc7cdd2cd4de2ee9c847fa8cda4e5f0814a828b1019
diff --git a/dev-python/botocore/botocore-1.21.26.ebuild b/dev-python/botocore/botocore-1.21.26.ebuild
new file mode 100644
index 000000000000..5684261bd4b3
--- /dev/null
+++ b/dev-python/botocore/botocore-1.21.26.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+	# very unstable
+	sed -i -e 's:test_stress_test_token_bucket:_&:' \
+		tests/functional/retries/test_bucket.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# note: suites need to be run separately as one of the unit tests
+	# seems to be leaking mocks and breaking a few functional tests
+	nosetests -v tests/unit ||
+		die "unit tests failed under ${EPYTHON}"
+	nosetests -v tests/functional ||
+		die "functional tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/dask/Manifest b/dev-python/dask/Manifest
index c81af47fe058..acf111d0e35f 100644
--- a/dev-python/dask/Manifest
+++ b/dev-python/dask/Manifest
@@ -1,2 +1,3 @@
 DIST dask-2021.7.2.tar.gz 3739041 BLAKE2B e32389a5d6a47a9c0f741a33d2f9aeb8887c951d4a53ad7e2bdc5d7007e2e7b8db9b639b95725bb70cfdf1f3568aa2541c7f46c5c87cbb50b5433866b7f0e870 SHA512 029832ea2db342cc63dcfc4e5a563e6e92f5d26298ca19d7815548acceb8098e94b53acb5df1a6923172e7014b6235ddb34921f2855701921556db83a9411afa
 DIST dask-2021.8.0.tar.gz 3742254 BLAKE2B a4f086181dc5dd36561d365ac929c0399d05fbb9d39e025ad06a609477cd4e257abb93760244032285812409c413a110f213ad2918ec1042e1526f847da1056f SHA512 b205c05965aec419650b9125193d96383ad9ffa96e8aef92ac15da339e0ba9d1c40ba6bc176e56aca0ef6f84d7a523d7157aba90e146317aef58fe34dc07e2bc
+DIST dask-2021.8.1.tar.gz 3786161 BLAKE2B cb47b900e4769113e28e1cea70cb65008debb25431c05792666ca1d9aef9143061d1b0c2ce825ff1a22312c4cc615a2878591fc93236521811c19a35e70446b1 SHA512 aff7b92b66ab5d8858eb28d416c3661e64400a8ddcc9135b74b1bf3cad195a4fc55a00365c5602cb0b66ef8506e73c0f6bd2d3972ce8744d2e77095cdf040d11
diff --git a/dev-python/dask/dask-2021.8.1.ebuild b/dev-python/dask/dask-2021.8.1.ebuild
new file mode 100644
index 000000000000..56fed399ca27
--- /dev/null
+++ b/dev-python/dask/dask-2021.8.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Task scheduling and blocked algorithms for parallel processing"
+HOMEPAGE="https://dask.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/cloudpickle-0.2.2[${PYTHON_USEDEP}]
+	>=dev-python/fsspec-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.15.1[${PYTHON_USEDEP}]
+	>=dev-python/pandas-0.25.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+	>=dev-python/partd-0.3.10[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	>=dev-python/toolz-0.8.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/toolz[${PYTHON_USEDEP}]
+	test? (
+		dev-python/moto[${PYTHON_USEDEP}]
+		dev-python/numexpr[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local deselect=(
+		# require old sqlalchemy
+		dask/dataframe/io/tests/test_sql.py
+	)
+
+	epytest -p no:flaky -m "not network" ${deselect[@]/#/--deselect }
+}
diff --git a/dev-python/django-mptt/Manifest b/dev-python/django-mptt/Manifest
index 3aa926d0a79a..9f942579e7d4 100644
--- a/dev-python/django-mptt/Manifest
+++ b/dev-python/django-mptt/Manifest
@@ -1 +1,2 @@
 DIST django-mptt-0.11.0.tar.gz 98300 BLAKE2B cbae24143007dfe8913aacf4cbe22bbccdf929617adc31640c2d429d6ea8be727a937be0aa8353e82862b9fe8c571397db4dd3877015eb17c2c5a56172cc66a5 SHA512 21af30007661db1474628b6f8af86a3f6de52494efe1aaf9235f8b1660ba153f0de3ad91ff979588e4b681b00b44652a05146df7d3951d6ee62da38a1900fd89
+DIST django-mptt-0.13.gh.tar.gz 302525 BLAKE2B 21b2fde5c81d83321bf7569d2064db87aec3c184f27cf3fc3bd34421be04212188e15f79a575b08aabb3a7b95d116bf3e5f0fb57c56cadf9ad2ac166e8e77845 SHA512 63dbb61dab59d42b5e747f35370a0840d40ed465979d1f93e66561cf4c0726635cae774f87e39cc1ac480847f3ccf0eb65dc8593759a0860d586e334fdd37256
diff --git a/dev-python/django-mptt/django-mptt-0.13.ebuild b/dev-python/django-mptt/django-mptt-0.13.ebuild
new file mode 100644
index 000000000000..65e94e9aa5e6
--- /dev/null
+++ b/dev-python/django-mptt/django-mptt-0.13.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="utilities for modified preorder tree traversal and trees of model instances"
+HOMEPAGE="https://github.com/django-mptt/django-mptt"
+SRC_URI="
+	https://github.com/django-mptt/django-mptt/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/django-1.11[${PYTHON_USEDEP}]
+	dev-python/django-js-asset[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-test-install.patch
+)
+
+python_test() {
+	"${EPYTHON}" tests/manage.py test -v2 myapp ||
+		die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/django-mptt/files/django-mptt-0.13-test-install.patch b/dev-python/django-mptt/files/django-mptt-0.13-test-install.patch
new file mode 100644
index 000000000000..886d5c6e4ebd
--- /dev/null
+++ b/dev-python/django-mptt/files/django-mptt-0.13-test-install.patch
@@ -0,0 +1,26 @@
+From 6bc5860575d491e8cf1edbabee7b07f1c072bdba Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
+Date: Sat, 21 Aug 2021 09:45:45 +0200
+Subject: [PATCH] Do not install tests.myapp
+
+Fix options.packages.find.exclude to cover subpackages of "tests"
+recursively.  Otherwise, tests.myapp is installed.
+---
+ setup.cfg | 1 +
+ 1 file changed, 1 insertion(+)
+
+diff --git a/setup.cfg b/setup.cfg
+index b4094dc..b8ebee3 100644
+--- a/setup.cfg
++++ b/setup.cfg
+@@ -44,6 +44,7 @@ tests =
+ [options.packages.find]
+ exclude =
+     tests
++    tests.*
+     myapp
+ 
+ [flake8]
+-- 
+2.33.0
+
diff --git a/dev-python/django-picklefield/Manifest b/dev-python/django-picklefield/Manifest
index c4f77ddc10da..eb2e7905e5e5 100644
--- a/dev-python/django-picklefield/Manifest
+++ b/dev-python/django-picklefield/Manifest
@@ -1 +1,2 @@
+DIST django-picklefield-3.0.1.gh.tar.gz 12168 BLAKE2B 44af271ce471b5a327d02312c2717c72dcdba8b2e959ada0793bab0962aa02e29d4eeb58857cf3495d7f161abe13595f0027b7624244b070d9978ab51a434d20 SHA512 0b8fe6cd0851d59b3997f328b977430985c0acf5728ff8cc1d0e2e41f145b7c6ce77de02a2d06b4545b43cd4c02e6277206660b8301eb744b8e3b8ea0aed90e5
 DIST django-picklefield-3.0.1.tar.gz 9506 BLAKE2B 6eda8dca31454a5f8cc8a670a19e25ac0b641bf6b7d31d695e617653cd88c1d84b88c39632f1d915ce8e0fe0dd8432d687559f2037d94ab50758f71a8b4f087f SHA512 7f14b4803dc8bdb1d62fec4063bf6eb7714445f85a13a4fe098154fa2d7f6a4e54308bf2324bc4921eaabf1023bb06b89a4bf52bb0ff89594075e02672d217ba
diff --git a/dev-python/django-picklefield/django-picklefield-3.0.1-r1.ebuild b/dev-python/django-picklefield/django-picklefield-3.0.1-r1.ebuild
new file mode 100644
index 000000000000..0e294293f954
--- /dev/null
+++ b/dev-python/django-picklefield/django-picklefield-3.0.1-r1.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Pickled object field for Django."
+HOMEPAGE="https://github.com/gintas/django-picklefield"
+SRC_URI="
+	https://github.com/gintas/django-picklefield/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="dev-python/django[${PYTHON_USEDEP}]"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Fix for >=django-3.2
+	echo "DEFAULT_AUTO_FIELD = 'django.db.models.AutoField'" >> tests/settings.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	"${EPYTHON}" -m django test -v2 --settings=tests.settings || die "Tests fail with ${EPYTHON}"
+}
diff --git a/dev-python/django-picklefield/metadata.xml b/dev-python/django-picklefield/metadata.xml
index 4e8ef052c728..dc1c6478b2a6 100644
--- a/dev-python/django-picklefield/metadata.xml
+++ b/dev-python/django-picklefield/metadata.xml
@@ -8,4 +8,5 @@
   <remote-id type="pypi">django-picklefield</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/llvmlite/Manifest b/dev-python/llvmlite/Manifest
index 6ad265106326..aa5002c97c68 100644
--- a/dev-python/llvmlite/Manifest
+++ b/dev-python/llvmlite/Manifest
@@ -1 +1,2 @@
 DIST llvmlite-0.36.0.gh.tar.gz 232059 BLAKE2B 2d1ace28003d52271fb20f086ba37bec1f2f72c0092ea7a8fa2a1ee8d30c319f9625938a8ebdb69dec5dec63d5a67b598a071401e5e1db9de973d55fd889dc8a SHA512 a769255f276e429def4d6f8d35d516df3ae3e026fb8b4af33c1695a9ea24c64a84c38943b530756c4ffc5c619611158e947de391bba501223dbf2a4cd21d53c0
+DIST llvmlite-0.37.0.gh.tar.gz 223602 BLAKE2B 74f975d5ac1782528f60f1c0d5c6230a02953e0d494d8323e4caa6651f642ad791ad51df44f6593da41edc5c34bd883f144e95b16f9b8962393d16de013fdbc5 SHA512 665f486fd38c9cc4ee91b15fc75f33451ada6391fc9f1b371091ece844693e0cd8e23766400bf76d9879e8f10f53f4e21f8bb19f3ff1e01c4a95ce9004b0884a
diff --git a/dev-python/llvmlite/llvmlite-0.37.0.ebuild b/dev-python/llvmlite/llvmlite-0.37.0.ebuild
new file mode 100644
index 000000000000..bffe170cf4bf
--- /dev/null
+++ b/dev-python/llvmlite/llvmlite-0.37.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1 llvm
+
+DESCRIPTION="Python wrapper around the llvm C++ library"
+HOMEPAGE="https://llvmlite.pydata.org/"
+SRC_URI="https://github.com/numba/llvmlite/archive/v${PV/_/}.tar.gz -> ${P/_/}.gh.tar.gz"
+S=${WORKDIR}/${P/_/}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples"
+
+LLVM_MAX_SLOT=11
+
+RDEPEND="
+	sys-devel/llvm:${LLVM_MAX_SLOT}
+	sys-libs/zlib:0=
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	sed -i -e '/max_python/s:3\.10:3.11:' setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_configure_all() {
+	# upstream's build system is just horrible, and they ignored the PR
+	# fixing it, so let's build the shared lib properly using implicit
+	# make rules
+
+	export LDLIBS=$(llvm-config --libs all)
+	export CXXFLAGS="$(llvm-config --cxxflags) -fPIC ${CXXFLAGS}"
+	export LDFLAGS="$(llvm-config --ldflags) ${LDFLAGS}"
+
+	local files=( ffi/*.cpp )
+	emake -f - <<EOF
+ffi/libllvmlite.so: ${files[*]/.cpp/.o}
+	\$(CXX) -shared \$(CXXFLAGS) \$(LDFLAGS) -o \$@ \$^ \$(LDLIBS)
+EOF
+
+	export LLVMLITE_SKIP_LLVM_VERSION_CHECK=1
+}
+
+python_test() {
+	"${EPYTHON}" runtests.py -v || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
diff --git a/dev-python/mako/Manifest b/dev-python/mako/Manifest
index 62710803df28..071734bd891e 100644
--- a/dev-python/mako/Manifest
+++ b/dev-python/mako/Manifest
@@ -1 +1,2 @@
 DIST Mako-1.1.4.tar.gz 479823 BLAKE2B 048c63c6caf493b9809dbcda8d1d697a7a25c8d22e97f439facae64b26d5b8f5f3002ff65529e9599e6069482fa25d6db95d810175f7f674f5af02cbd3f9f5e3 SHA512 4844c1d6c8d0d474b4ca4e1b31d3557747fc7e30f70a1976163a26b46b1b45c4c96ca6101fbef252b4e3bb4a61635d2a2c6d1c2933fde5b82bb1a1306f31ff84
+DIST Mako-1.1.5.tar.gz 494647 BLAKE2B 5e4f3e111137820997eb39bbaa1af35ac97de101757b66b6efd097e0d35f6d020bfc8b5b98da8c03fc81a907f228526543f5bdaaf161c4f850418cbcaaf81770 SHA512 3eff75f1a94f8e01131ce118df73be1ade79306562ae2ca68079eb2b64ef82c48c09cfd7ed6eda42819bf50c70941cf4115f8918b4d8187f7489717c7d4a423b
diff --git a/dev-python/mako/mako-1.1.5.ebuild b/dev-python/mako/mako-1.1.5.ebuild
new file mode 100644
index 000000000000..29084017b981
--- /dev/null
+++ b/dev-python/mako/mako-1.1.5.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1 optfeature
+
+MY_P=${P^}
+DESCRIPTION="A Python templating language"
+HOMEPAGE="https://www.makotemplates.org/ https://pypi.org/project/Mako/"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${PN^}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="doc"
+
+RDEPEND=">=dev-python/markupsafe-0.9.2[${PYTHON_USEDEP}]"
+
+PATCHES=(
+	"${FILESDIR}"/mako-1.1.1-pypy3-test.patch
+)
+
+distutils_enable_tests pytest
+
+python_install_all() {
+	rm -r doc/build || die
+
+	use doc && local HTML_DOCS=( doc/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "caching support" dev-python/beaker
+}
diff --git a/dev-python/pid/metadata.xml b/dev-python/pid/metadata.xml
index 092b25e403e5..0fe2a0281fa1 100644
--- a/dev-python/pid/metadata.xml
+++ b/dev-python/pid/metadata.xml
@@ -14,4 +14,5 @@
   <remote-id type="pypi">pid</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/pid/pid-3.0.4.ebuild b/dev-python/pid/pid-3.0.4.ebuild
index 798a219568be..68dd038242c4 100644
--- a/dev-python/pid/pid-3.0.4.ebuild
+++ b/dev-python/pid/pid-3.0.4.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
diff --git a/dev-python/prompt_toolkit/Manifest b/dev-python/prompt_toolkit/Manifest
index f90ea75eb192..dad46cd26535 100644
--- a/dev-python/prompt_toolkit/Manifest
+++ b/dev-python/prompt_toolkit/Manifest
@@ -1 +1,2 @@
 DIST prompt_toolkit-3.0.19.tar.gz 3034818 BLAKE2B d1f0741931d4711952cfaabd992e64aa3fd252627c50f2a0ad8ad1aef5882bd4ae054c0d281b141595488fda6328c102f900445a42bc32cf018d37663deb2cb5 SHA512 0f3f7c5a2d12e03e06e900a4239f86f27d959fa7337d072dae8c79bbcd2ffd4c1026d1531210e34a4f4669d483b20b9d2f49c7625d0d7aa1fcb1e3f9f3894349
+DIST prompt_toolkit-3.0.20.tar.gz 3037349 BLAKE2B 52773f9c277d1a16adca007c19d087e46a0dd4ec154076525ea7bb59523762513bb137534bc18f17aa249fdc7ad07327e400b3bb730b32a614929f0a48d9cdfb SHA512 3f2a0edb4c7756cdcfd0ddf19f6016910aaa5de3ca8ee0dac11bd0fdece301b4d562681294b7cf9e6d5eb20937106f771ffaf312961cda4477ce534cce8d8db4
diff --git a/dev-python/prompt_toolkit/prompt_toolkit-3.0.20.ebuild b/dev-python/prompt_toolkit/prompt_toolkit-3.0.20.ebuild
new file mode 100644
index 000000000000..aeb7bc0a3d1f
--- /dev/null
+++ b/dev-python/prompt_toolkit/prompt_toolkit-3.0.20.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Building powerful interactive command lines in Python"
+HOMEPAGE="
+	https://pypi.org/project/prompt-toolkit/
+	https://github.com/prompt-toolkit/python-prompt-toolkit"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE=""
+
+RDEPEND="
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	dev-python/wcwidth[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/pylint/Manifest b/dev-python/pylint/Manifest
index 1907c6eaca4f..e3baffb24693 100644
--- a/dev-python/pylint/Manifest
+++ b/dev-python/pylint/Manifest
@@ -1,2 +1,3 @@
+DIST pylint-2.10.1.gh.tar.gz 813052 BLAKE2B 487c95851c6aa68ae6fa81a345959fa6b7c1ffe9f7c4c1d722f6ceb4c50671870f16c2a24392cc374cdaffa279028d38a23b9cb94376f58f4ff0e448da49d83b SHA512 c32948ef2eceab8857fcd789690c4766a606b053c1f931da13acdc0265f76fe96622439da12661e8ab899cdeccd93427a4561181670f14dfbb36e4e9c720ea07
 DIST pylint-2.9.3.gh.tar.gz 770364 BLAKE2B 3892286ffbd79b417c6decba44bce97f45192299ac8e2ec0e24770b2dd6cf1c28bac790626a478d47a6124ec0470ea9fc0d4230c5a1e807532852844445bb95a SHA512 45c037b970b66254b54a4810a5609dc098b5493d409826333e6a75f9ff0fc02921162711d88c45fd2f437e6521f639c33b25b714830a977c501612ee497501bb
 DIST pylint-2.9.6.gh.tar.gz 779390 BLAKE2B b1d8794e1e7ccdde87919eb943f83287c0a7b85b67f3722cbbe68887f2c61ab30b354548e25b70c661234647e35f79beb6aaad5f6be6bfde8c2475cf03676922 SHA512 a23ff089853398df2e4232767ca87c21e4ab4fc6805de80db796c78c56e0da1ade9b0586f5c14a98524bf607e0d240c354cf63287eec7dfdce263188eb19ddce
diff --git a/dev-python/pylint/pylint-2.10.1.ebuild b/dev-python/pylint/pylint-2.10.1.ebuild
new file mode 100644
index 000000000000..423778586319
--- /dev/null
+++ b/dev-python/pylint/pylint-2.10.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python code static checker"
+HOMEPAGE="https://www.logilab.org/project/pylint
+	https://pypi.org/project/pylint/
+	https://github.com/pycqa/pylint/"
+SRC_URI="
+	https://github.com/pycqa/pylint/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+	<dev-python/astroid-2.8[${PYTHON_USEDEP}]
+	>=dev-python/astroid-2.7.2[${PYTHON_USEDEP}]
+	>=dev-python/isort-4.2.5[${PYTHON_USEDEP}]
+	<dev-python/isort-6[${PYTHON_USEDEP}]
+	>=dev-python/mccabe-0.6[${PYTHON_USEDEP}]
+	<dev-python/mccabe-0.7[${PYTHON_USEDEP}]
+	>=dev-python/toml-0.7.1[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.4.4-sphinx-theme.patch"
+)
+
+distutils_enable_sphinx doc --no-autodoc
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# No need to run the benchmarks
+		tests/benchmark/test_baseline_benchmarks.py
+	)
+	# Specify the test directory explicitly to avoid import file mismatches
+	epytest tests
+}
+
+python_install_all() {
+	if use examples ; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/python-netlink/metadata.xml b/dev-python/python-netlink/metadata.xml
index 2dccc7e1802e..173077e2b3d6 100644
--- a/dev-python/python-netlink/metadata.xml
+++ b/dev-python/python-netlink/metadata.xml
@@ -3,10 +3,12 @@
 <pkgmetadata>
  <maintainer type="person">
   <email>zmedico@gentoo.org</email>
+  <name>Zac Medico</name>
  </maintainer>
  <upstream>
   <remote-id type="pypi">NetLink</remote-id>
   <doc>https://xmine128.tk/Software/Python/netlink/docs/</doc>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/python-netlink/python-netlink-0.1.ebuild b/dev-python/python-netlink/python-netlink-0.1.ebuild
index 74957d374235..618d95bbe2b6 100644
--- a/dev-python/python-netlink/python-netlink-0.1.ebuild
+++ b/dev-python/python-netlink/python-netlink-0.1.ebuild
@@ -1,23 +1,23 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=8
 
 PYTHON_COMPAT=( python3_{6,7,8,9,10} )
-
 inherit distutils-r1
 
-MY_PN="NetLink"
-MY_P="${MY_PN}-${PV}"
+MY_P="NetLink-${PV}"
+
 DESCRIPTION="Pure-Python client for the Linux NetLink interface"
 HOMEPAGE="https://pypi.org/project/NetLink/ https://xmine128.tk/Software/Python/netlink/docs/"
-SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz -> ${P}.tar.gz"
+SRC_URI="mirror://pypi/${MY_P:0:1}/NetLink/${MY_P}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
 LICENSE="LGPL-3+"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
-DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
-RDEPEND="!dev-libs/libnl[python]"
-S=${WORKDIR}/${MY_P}
+
+RDEPEND="!dev-libs/libnl[python(-)]"
 
 python_prepare_all() {
 	distutils-r1_python_prepare_all
diff --git a/dev-python/ratelimit/Manifest b/dev-python/ratelimit/Manifest
index 773574177c96..cc1a11905663 100644
--- a/dev-python/ratelimit/Manifest
+++ b/dev-python/ratelimit/Manifest
@@ -1 +1 @@
-DIST ratelimit-1.4.1.tar.gz 10700 BLAKE2B d2fc1b0695c6bdc7653862ca790e9f5ec87b25513a93ec058384f334b47d5080570e3511eb6680b934b345ef5562771a078fc4ced3ceed263a7aafd26af3bfdd SHA512 ab8a2cc95b852f91c614ba5a5a677d2b4b99d5f810ec8a11e69d97af58cef1f67457e1cf686a286073c85b39c2ebbeca0a459382e410c9e8eda12cecdda57f02
+DIST ratelimit-2.2.1.gh.tar.gz 12366 BLAKE2B 7c810bd111202ef6cd86a789627367665457eb2fd88f13d91b18c934210b72f8f4b0ca1ae0e26b502234c4bf3e74d1c6608260d51a022f9f733d10eb061de023 SHA512 a9a2347e9f9e152e5b1ffcf346cf750c5c52471aa2216b485d989edfc55686077990676a35e0125277313ad50a656a14ab72b7aac61b661e2fc4ec74611b5990
diff --git a/dev-python/ratelimit/metadata.xml b/dev-python/ratelimit/metadata.xml
index f8a9cd4b2d6d..f6c244f68693 100644
--- a/dev-python/ratelimit/metadata.xml
+++ b/dev-python/ratelimit/metadata.xml
@@ -18,4 +18,5 @@
   <remote-id type="pypi">ratelimit</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/ratelimit/ratelimit-1.4.1.ebuild b/dev-python/ratelimit/ratelimit-2.2.1.ebuild
index 5c82747887bd..4a16a6bee352 100644
--- a/dev-python/ratelimit/ratelimit-1.4.1.ebuild
+++ b/dev-python/ratelimit/ratelimit-2.2.1.ebuild
@@ -1,14 +1,17 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
-PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+EAPI=8
 
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
 inherit distutils-r1
 
 DESCRIPTION="An API rate limit decorator for Python"
-SRC_URI="https://github.com/tomasbasham/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 HOMEPAGE="https://github.com/tomasbasham/ratelimit"
+SRC_URI="
+	https://github.com/tomasbasham/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
 
 LICENSE="MIT"
 SLOT="0"
@@ -17,7 +20,7 @@ KEYWORDS="~amd64 ~x86"
 distutils_enable_tests pytest
 
 src_prepare() {
-	default
-	# remove --cov args injection
+	# remove --cov args injection 
 	rm pytest.ini || die
+	distutils-r1_src_prepare
 }
diff --git a/dev-python/testfixtures/Manifest b/dev-python/testfixtures/Manifest
index 55cee461e183..6e96254c9407 100644
--- a/dev-python/testfixtures/Manifest
+++ b/dev-python/testfixtures/Manifest
@@ -1 +1,2 @@
 DIST testfixtures-6.18.0.tar.gz 121584 BLAKE2B abf90012fe79d148c44d72a8aaa5277c95a33933c7b753eecdcaeb11279b4439ad9ea394270e440d9681c22789a17738d367b66adf3d04cf6e6289713c1ead59 SHA512 e6552e6b1837ae4ee4754ce3675bdbf2a68d8e46b892382bd8320290050f2c296348ef6310ce3ff46962bf1978c351fe2cdb853a73c9f800f68818f81d5caec9
+DIST testfixtures-6.18.1.tar.gz 121731 BLAKE2B c31873d3ebbe47d5d3035d6aaaf674472efb32b061080df711ee558bf91d1b01d417ded4eaebf7436132fd7b9233437e735fa60dee47777d032fc1b610fd1de3 SHA512 088c6480eecc9862e91a0188ab45620be3d8f8898ebb284dc932155fffbd9f75ebbab9425fe4db8dee75ee8fcf82d8c27b950a3f9298e9f7ca420744c65edd91
diff --git a/dev-python/testfixtures/testfixtures-6.18.1.ebuild b/dev-python/testfixtures/testfixtures-6.18.1.ebuild
new file mode 100644
index 000000000000..c9348e82a032
--- /dev/null
+++ b/dev-python/testfixtures/testfixtures-6.18.1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="A collection of helpers and mock objects for unit tests and doc tests"
+HOMEPAGE="https://pypi.org/project/testfixtures/ https://github.com/Simplistix/testfixtures"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/pytest-django[${PYTHON_USEDEP}]
+		dev-python/sybil[${PYTHON_USEDEP}]
+		>=dev-python/twisted-18[${PYTHON_USEDEP}]
+		dev-python/zope-component[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# kill weird way of declaring build deps
+	sed -e '/build=/d' -i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTHONPATH="."
+	local -x DJANGO_SETTINGS_MODULE=testfixtures.tests.test_django.settings
+	epytest -Wignore::DeprecationWarning
+}
diff --git a/dev-python/werkzeug/werkzeug-2.0.1-r1.ebuild b/dev-python/werkzeug/werkzeug-2.0.1-r1.ebuild
index fff0abc973ba..36f07349c467 100644
--- a/dev-python/werkzeug/werkzeug-2.0.1-r1.ebuild
+++ b/dev-python/werkzeug/werkzeug-2.0.1-r1.ebuild
@@ -18,7 +18,7 @@ SRC_URI="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv sparc x86"
+KEYWORDS="amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv sparc x86"
 
 BDEPEND="
 	test? (