Adding metadata

author: Liguros - Gitlab CI/CD [develop] <gitlab@liguros.net> 2026-05-11 16:19:27 +0000
committer: Liguros - Gitlab CI/CD [develop] <gitlab@liguros.net> 2026-05-11 16:19:27 +0000
commit: 4912a64be738d6ead0cc7a8288de50714c68c0bf (patch)
tree: fbce5346cff87cfba39f064f7422328ef4ccae74 /dev-python
parent: 448fc515bcf8058695b0a67d165cfc29f80cc36b (diff)
download: baldeagleos-repo-4912a64be738d6ead0cc7a8288de50714c68c0bf.tar.gz
baldeagleos-repo-4912a64be738d6ead0cc7a8288de50714c68c0bf.tar.xz
baldeagleos-repo-4912a64be738d6ead0cc7a8288de50714c68c0bf.zip
53 files changed, 1427 insertions, 472 deletions
diff --git a/dev-python/billiard/Manifest b/dev-python/billiard/Manifest
index 9318a0077575..5c6b11253b3d 100644
--- a/dev-python/billiard/Manifest
+++ b/dev-python/billiard/Manifest
@@ -1 +1,5 @@
-DIST billiard-4.0.2.gh.tar.gz 154301 BLAKE2B 5a4d1e185219886a419c82acb18e8f4adcba980d7732c7909a34f9e81af9936280ff1817ba92bef92333e7b57a4385339503e158d8766b8a8a9a1acd9de3202b SHA512 499ef834b98b2ce4a1afc4e069f43a96b9db8d7f52607fa5fe12298fc06faf25307a0208ac6df7643c0fff87deb5014d9bd1e375ab19731e98ac65ba3199fd4e
+DIST billiard-3.6.4.0.tar.gz 155303 BLAKE2B 93288ab56fedb9b86373318b339afc8c690ba5996d52b2e95197ffd8eda5bc86e9bb52c6364ade5dcda9e8afd52da0efebbc306facacb7c5383223bf2515e24e SHA512 9f2a44024e45c4e7667472a0a3ade7caae755ec7c163929433f818e4b87165218b9cc9545bdee2254e7159c206e525306e383d38906b00fd5428bd1616c39b8f
+DIST billiard-4.2.4.tar.gz 156537 BLAKE2B 62e7da57ed6ea27a6f89902e4f125c0c9288724703ea36654709cbf4cca875ff723edb2faca85f10e0f3f02fc2e55d609f3588f0908cef11c356faa6b9f587f5 SHA512 f05041661da59603da5bdcb3b696d75742d4cb7998f5bbf22474e001641f5be6cf693c3b329cda3e8983cc3fe56e5cc96a1d7880eefa5b2d68cd0d4ffe231626
+EBUILD billiard-3.6.4.0.ebuild 714 BLAKE2B e9f4ffbbb6e29bc07f04ff0cf7580832993530ff722d0a80063114eaea57df13ab225fca8a9c11a05bfeb35e2b338891b1fd62751d447fda9224e6cbe99fc43c SHA512 d64678a017351af1bd05e1d2d2979832e671b6dd90febb8bf85014631b521e25bd5003b0f3d340389b85abba8e22aa1827f23184ef1e20425af64a2474b80238
+EBUILD billiard-4.2.4.ebuild 475 BLAKE2B ee8b3702829fc279d8c82d1a6c0f5b4b1853b5dd2cef8a09c04316fcddbb9fd0c6cd5441e3583b3f9c834b9b2ce05111ded14243bb7a2f5daa7eaaba06a40acb SHA512 0f75807d2a219ff88525af4352293cf2307f528a87dc57b82fa7ab4b0955f6c15d45f6c8402bfc9c44b0aadc33320650f578363b15ff1ae2f8c4e255be45b55e
+MISC metadata.xml 445 BLAKE2B 6fd4606975ee6326c8b9f345dba131cfeda0dbfcb907818e5252378aa30fcf03eac31138c6fbc8b9de9d3e6ec3295c0950c97308801d0300d0371847d975be06 SHA512 8acd7e27fa3170c0af4b63e98642a4dbc445edcaa082b99745f6d251f8de3abf2ade36a36cb36c71f790a9fc85edf30118a5198717f3f3e44b1cc24b9f38caea
diff --git a/dev-python/billiard/billiard-3.6.4.0.ebuild b/dev-python/billiard/billiard-3.6.4.0.ebuild
new file mode 100644
index 000000000000..9387362274ae
--- /dev/null
+++ b/dev-python/billiard/billiard-3.6.4.0.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python multiprocessing fork"
+HOMEPAGE="https://github.com/celery/billiard"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 x86"
+
+BDEPEND="
+	test? (
+		>=dev-python/psutil-5.9.0[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Remove Win32 test
+	rm t/unit/test_win32.py || die
+
+	# Get rid of dev-python/case dependency
+	sed \
+		-e 's/^from case \(.*\), skip$/from unittest.mock \1/' \
+		-e '/^@skip/d' \
+		-i t/unit/test_common.py
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/billiard/billiard-4.0.2.ebuild b/dev-python/billiard/billiard-4.0.2.ebuild
deleted file mode 100644
index 744e1acb595e..000000000000
--- a/dev-python/billiard/billiard-4.0.2.ebuild
+++ /dev/null
@@ -1,25 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{10..14} )
-DISTUTILS_USE_PEP517=setuptools
-inherit distutils-r1
-
-DESCRIPTION="Python multiprocessing fork"
-HOMEPAGE="
-	https://pypi.org/project/billiard/
-	https://github.com/celery/billiard
-"
-SRC_URI="https://github.com/celery/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-BDEPEND="test? ( dev-python/psutil[${PYTHON_USEDEP}] )"
-
-distutils_enable_tests pytest
-
-distutils_enable_sphinx Doc
diff --git a/dev-python/billiard/billiard-4.2.4.ebuild b/dev-python/billiard/billiard-4.2.4.ebuild
new file mode 100644
index 000000000000..80c144ff8051
--- /dev/null
+++ b/dev-python/billiard/billiard-4.2.4.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python multiprocessing fork"
+HOMEPAGE="https://github.com/celery/billiard"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 x86"
+
+BDEPEND="
+	test? (
+		>=dev-python/psutil-5.9.0[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx Doc
diff --git a/dev-python/billiard/metadata.xml b/dev-python/billiard/metadata.xml
index 736a1167c898..08db6659365d 100644
--- a/dev-python/billiard/metadata.xml
+++ b/dev-python/billiard/metadata.xml
@@ -1,6 +1,12 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- 
- <origin>gentoo-guru-overlay</origin>
+ <maintainer type="person">
+  <email>marcin.deranek@slonko.net</email>
+  <name>Marcin Deranek</name>
+ </maintainer>
+ <upstream>
+  <bugs-to>https://github.com/celery/billiard/issues</bugs-to>
+ </upstream>
+ <origin>slonko-overlay</origin>
 </pkgmetadata>
 \ No newline at end of file
diff --git a/dev-python/bluelet/bluelet-0.2.0-r1.ebuild b/dev-python/bluelet/bluelet-0.2.0-r1.ebuild
index 0086007b3f89..9fe743304343 100644
--- a/dev-python/bluelet/bluelet-0.2.0-r1.ebuild
+++ b/dev-python/bluelet/bluelet-0.2.0-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2025 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
diff --git a/dev-python/btrfsutil/Manifest b/dev-python/btrfsutil/Manifest
index 4ca540d633f0..643d96ea2d2b 100644
--- a/dev-python/btrfsutil/Manifest
+++ b/dev-python/btrfsutil/Manifest
@@ -1,2 +1,4 @@
 DIST btrfs-progs-v6.19.1.tar.sign 566 BLAKE2B f743d46a80b03ae63dfe0eea262577228db56b305fc105ac9b24d5672dc60dac59e35673ee96a3f5cc72e4d048fdf7b92c8ea1e96f089bc96bb0d36628af1c97 SHA512 364b858320aa976807d58532b96fb4baaf814e9c6ed54b675275f101d7fb3b9f9187a6e07b0a85e53bae831f7217107c0e838436fda9b6788c3dbf2cd807ae5b
 DIST btrfs-progs-v6.19.1.tar.xz 4977432 BLAKE2B 555bf1c0625afd30dae3cc38f293de195450133cea701096010cadde3d8be405681ed2c4b5e43db777df146e1d2d90697746bc9eea253211df216bd4456e04a1 SHA512 ece500bf512a7970bd6a611c4f74aa3f7285eb55b86987fb8a21bc82cb7d0b1e6b683d02efc34ec8c4ff7f6d620b5ec12ef277af0d6d831586f9f70087355ca9
+DIST btrfs-progs-v7.0.tar.sign 594 BLAKE2B 3b31dc3b529600d65721994742786a65ebec3e296a26f1510c34ceac9f5309ca72068af6322a46925d9b80b0f0492e0624ebb7ddd3904c610a161bb28ad45834 SHA512 78a358f5ba7b4e8ee3477bbcd8eab623c05dd8d157ac3858a7ea7e0ceda8c296363b6bf50a8bdf3f3a590580e4ea8e885d596f0fc3e2d6263337f9847b014813
+DIST btrfs-progs-v7.0.tar.xz 4989268 BLAKE2B a0e8ef7a5bca5c4f4deb5487215a3543ae99759ffec191cd23b776d21621fb9aba173115a47ae34ebd0e6e38d720d430e5092151e938b0b65cff4aabffd9c607 SHA512 f6fc13f16a1f170eacbcb53efb2e5a86e89c73fd797fc8d9a419b7024f5a13a788cd92e0caa41964e7716d8bccc24ce4b8a5e3b3861d85c793642021c5b03791
diff --git a/dev-python/btrfsutil/btrfsutil-7.0.ebuild b/dev-python/btrfsutil/btrfsutil-7.0.ebuild
new file mode 100644
index 000000000000..c71cb042ea88
--- /dev/null
+++ b/dev-python/btrfsutil/btrfsutil-7.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 2024-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dsterba.asc
+
+inherit distutils-r1 verify-sig
+
+DESCRIPTION="Library for managing Btrfs filesystems"
+HOMEPAGE="https://github.com/kdave/btrfs-progs"
+
+MY_PN="btrfs-progs"
+MY_PV="v${PV/_/-}"
+MY_P="${MY_PN}-${MY_PV}"
+SRC_URI="
+	https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.xz
+	verify-sig? ( https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.sign )
+"
+S="${WORKDIR}/${MY_P}/libbtrfsutil/python"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DEPEND="~sys-fs/btrfs-progs-${PV}"
+RDEPEND="${DEPEND}"
+
+distutils_enable_tests unittest
+
+RDEPEND+=" !sys-fs/btrfs-progs[python(-)]"
+
+src_unpack() {
+	if use verify-sig; then
+		verify-sig_uncompress_verify_unpack "${DISTDIR}"/${MY_P}.tar.xz \
+			"${DISTDIR}"/${MY_P}.tar.sign
+	else
+		default
+	fi
+}
+
+src_prepare() {
+	cat <<-EOF > version.py || die
+	#!/usr/bin/env python3
+	btrfs_util_py_version = '${PV}'
+	EOF
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	rm "${ED}"/usr/share/doc/${PF}/README.md || die
+	dodoc "${S}"/../README.md
+}
diff --git a/dev-python/channels/Manifest b/dev-python/channels/Manifest
index 93bbf2713782..b58c0c2009cc 100644
--- a/dev-python/channels/Manifest
+++ b/dev-python/channels/Manifest
@@ -1 +1,5 @@
-DIST channels-4.3.2.gh.tar.gz 206077 BLAKE2B c0913d67dc74bc728dd828584cf803b4ad175bab717de71ccf1e1c5b6aaca296fd15d011deb07b2876e63b7daaefab5e5ee24c323e907b3c563f5358759f14b8 SHA512 29d9c91aca721fad44143978863c45812bf596bb65cf99084803f78d85c664d5cc7ca1015df151cdc27754b822c9cfd18102989b6e5f59bc50257f6c9d8b8b3e
+DIST channels-3.0.5.gh.tar.gz 200118 BLAKE2B 7a7653f986face1e87369917317db013e5c9fc912c6e2d7c737054ffef167bd01feb48f7e2d00d0d331e7a16093478e5416645717aed59e46dfec8f9b3641a2e SHA512 b12d1aec9602b702b5a097e9ca52dccad49940f82fcbe5594890c9bd1f1879a2fcf0f29630ca53e4972a26853df8f71d07d7b2cccd876abbf2417a76dee281bf
+DIST channels-4.2.2.gh.tar.gz 197010 BLAKE2B 321bf62c68038ce511145acd43c036dd298d58056f20ab2d676c3e3a8d6360a86a4f07c8f9ed6c123f888c012d69da22cfae4fb477dd5422cf326bf2de6a4c8f SHA512 8f7c8f27981988fed8ec254db91ce0a130b24842949ef94cc9ae21b4a259a7003654ec86c4e18aa81924e26d9b81b6a2aafaac404e490cbdda6b4a100476917a
+EBUILD channels-3.0.5.ebuild 936 BLAKE2B 788d0e9a2822dd9d0ed2d1d1a62135aeb5f244710b66f7591962518a5204cde5b8e779280783dd1d1a1b1a3fa9b272a0eb457f1d88d62c8ecefc8f67384929ef SHA512 89003fa68c7ab1cdd1a329f4389ba6fe28f491217a70c03b2979a992b450d8aa1a02f024f073ad5fc0aa1d093d81c6c8b1adaa45bdc9a179f5bd1607d85c13ef
+EBUILD channels-4.2.2.ebuild 829 BLAKE2B e5946c4a0eaf9fb3ffa2092a3d5d49d3d6ee16f151483fa2b716c8bab3350eca5e330a22822f881421d8882ffb970f4c56154c613477d094319e46addf1a5537 SHA512 84ce30d87a654c1a89ac299fb0f6447ca9c736e4b63497d83fc2687384e9cbe8094ba8f5021a19f726f9bae97c6b6d11eddef6a9ee5c275efe827bf95d3848ec
+MISC metadata.xml 445 BLAKE2B b4c0a41d6caadfbc53cbba3c41f8b7689a286b3f8d285c37a88a1f79d8dc350b82fea255048c022b92091a1e0cc67bf19645d6c32183b82a6dd49cccadf5078f SHA512 380c8b98efe8d9a2513c51899b7de90b115d4a51f104f46b552ff8929c322850e511e245a2ba0e976213416ae7241a17292ca98248caacfc891fcdcf5cea5d44
diff --git a/dev-python/channels/channels-3.0.5.ebuild b/dev-python/channels/channels-3.0.5.ebuild
new file mode 100644
index 000000000000..03a4923889fe
--- /dev/null
+++ b/dev-python/channels/channels-3.0.5.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Extends Django abilities beyond HTTP protocol"
+HOMEPAGE="https://github.com/django/channels"
+SRC_URI="https://github.com/django/${PN}/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	>=dev-python/django-2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/async-timeout[${PYTHON_USEDEP}]
+		>=dev-python/daphne-3.0[${PYTHON_USEDEP}]
+		<dev-python/daphne-4.0[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-django[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( README.rst )
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# https://github.com/django/channels/issues/1915
+	echo 'asyncio_mode = auto' >> setup.cfg
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/channels/channels-4.2.2.ebuild b/dev-python/channels/channels-4.2.2.ebuild
new file mode 100644
index 000000000000..710613a7cbd1
--- /dev/null
+++ b/dev-python/channels/channels-4.2.2.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Extends Django abilities beyond HTTP protocol"
+HOMEPAGE="https://github.com/django/channels"
+SRC_URI="https://github.com/django/${PN}/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	>=dev-python/asgiref-3.5.0[${PYTHON_USEDEP}]
+	>=dev-python/django-4.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/async-timeout[${PYTHON_USEDEP}]
+		>=dev-python/daphne-4.0.0[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-django[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme
diff --git a/dev-python/channels/channels-4.3.2.ebuild b/dev-python/channels/channels-4.3.2.ebuild
deleted file mode 100644
index ffafd1ece52b..000000000000
--- a/dev-python/channels/channels-4.3.2.ebuild
+++ /dev/null
@@ -1,62 +0,0 @@
-# Copyright 2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..14} )
-
-inherit distutils-r1 #pypi
-
-DESCRIPTION="Brings async, event-driven capabilities to Django"
-HOMEPAGE="
-	https://channels.readthedocs.io/
-	https://github.com/django/channels/
-	https://pypi.org/project/channels/
-"
-# no tests in sdist
-SRC_URI="
-	https://github.com/django/channels/archive/refs/tags/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64"
-
-RDEPEND="
-	<dev-python/asgiref-4[${PYTHON_USEDEP}]
-	>=dev-python/asgiref-3.9.0[${PYTHON_USEDEP}]
-	>=dev-python/django-4.2[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		dev-python/async-timeout[${PYTHON_USEDEP}]
-		dev-python/selenium[${PYTHON_USEDEP}]
-	)
-"
-
-EPYTEST_IGNORE=(
-	# avoid daphne as it requires autobahn
-	tests/sample_project/tests/test_selenium.py
-	tests/security/test_websocket.py
-	tests/test_database.py
-	tests/test_generic_http.py
-	tests/test_generic_websocket.py
-	tests/test_http.py
-	tests/test_testing.py
-)
-
-EPYTEST_PLUGINS=( pytest-django pytest-asyncio )
-distutils_enable_tests pytest
-
-PATCHES=(
-	"${FILESDIR}"/channels-4.3.2-fix-install.patch
-)
-
-python_prepare_all() {
-	# avoid daphne as it requires autobahn
-	sed -e '/"daphne"/d' -i tests/sample_project/config/settings.py || die
-
-	distutils-r1_python_prepare_all
-}
diff --git a/dev-python/channels/files/channels-4.3.2-fix-install.patch b/dev-python/channels/files/channels-4.3.2-fix-install.patch
deleted file mode 100644
index 18eca8f75445..000000000000
--- a/dev-python/channels/files/channels-4.3.2-fix-install.patch
+++ /dev/null
@@ -1,14 +0,0 @@
-diff --git a/setup.cfg b/setup.cfg
-index 742e1f6..43d8c0d 100644
---- a/setup.cfg
-+++ b/setup.cfg
-@@ -52,7 +52,7 @@ types =
- 
- [options.packages.find]
- exclude =
--    tests
-+    tests*
- 
- [flake8]
- exclude = venv/*,tox/*,docs/*,testproject/*,build/*
-
diff --git a/dev-python/channels/metadata.xml b/dev-python/channels/metadata.xml
index 0dec5a678a5f..7093cae71294 100644
--- a/dev-python/channels/metadata.xml
+++ b/dev-python/channels/metadata.xml
@@ -2,10 +2,11 @@
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
  <maintainer type="person">
-  <email>negril.nx+gentoo@gmail.com</email>
-  <name>Paul Zander</name>
+  <email>marcin.deranek@slonko.net</email>
+  <name>Marcin Deranek</name>
  </maintainer>
- 
- <origin>gentoo-guru-overlay</origin>
- <stabilize-allarches/>
+ <upstream>
+  <bugs-to>https://github.com/django/channels/issues</bugs-to>
+ </upstream>
+ <origin>slonko-overlay</origin>
 </pkgmetadata>
 \ No newline at end of file
diff --git a/dev-python/coverage/Manifest b/dev-python/coverage/Manifest
index acd907bd4a67..e11c864035b8 100644
--- a/dev-python/coverage/Manifest
+++ b/dev-python/coverage/Manifest
@@ -1,2 +1,4 @@
 DIST coverage-7.13.5.tar.gz 915967 BLAKE2B e31e8855746c255db960c20b8cef10c3ef9e8f7e90d7003e59de4a4de066092b4951c74681049a34ee8d320504904376503acab046398c98788fd38ad255bf79 SHA512 6210bbd9ed0c044d07630f4303ae97e3c9f84e3bb288d748e7c7598da2206303454fa1827116defc60b557b8dd6c2aca887003634008fc425e45ba4e0cba0097
 DIST coverage-7.13.5.tar.gz.provenance 9680 BLAKE2B 2d4f7742ba5dcaed044b75fde5951d0dd27898c3279f3484edca7b336b9b1cb8c1270acaff8101e0d1a8c3fad75e3b545bb4d9448629dffee7bc516251710ea2 SHA512 538158dac92b66c524d60c76939052b71cd347716e55658638eaaf7d4630b86a0bb5e12f198187700dc72c6e5d4cf41b44b4f293a2091ededa39352d8ceb8bf8
+DIST coverage-7.14.0.tar.gz 919489 BLAKE2B a1fe1a1cc1fac2d3bf0a16b7ec1cd4a2ebfed67186c3c3e27fb2de3adfb34262a8409f3c6ae976d20419735e2ac679dfc7f849828224ed0ca50fa1be6a8d47c3 SHA512 1679a464806b87d513a3636c47f1feee09064186b29c32fb5b8abc33f184cc52c9f8532c2cbde834ac121d9e2e6cb5bc499cd6b73f1bda3de230b7c76caa1ebe
+DIST coverage-7.14.0.tar.gz.provenance 9679 BLAKE2B 1e2e0b897ec7e44b7b920d9a1cb48e0870fee9675707659e88f18b909d51db2a2365d778d8cb5c4a5c48fe293a2ea7dad006db43a3a04a8640695694ca56a678 SHA512 5254b710838b56cccb384c5d0a02da2309f6086b27902c1cc480471dee42854ecb22b9e210f9cade22120c000968d17e7824f3314ec52b75622ffdd33fab4385
diff --git a/dev-python/coverage/coverage-7.14.0.ebuild b/dev-python/coverage/coverage-7.14.0.ebuild
new file mode 100644
index 000000000000..b3a677b0deba
--- /dev/null
+++ b/dev-python/coverage/coverage-7.14.0.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYPI_VERIFY_REPO=https://github.com/coveragepy/coveragepy
+PYTHON_COMPAT=( python3_{10..14} )
+PYTHON_REQ_USE="threads(+),sqlite(+)"
+
+inherit distutils-r1 multiprocessing pypi
+
+DESCRIPTION="Code coverage measurement for Python"
+HOMEPAGE="
+	https://coverage.readthedocs.io/en/latest/
+	https://github.com/coveragepy/coveragepy/
+	https://pypi.org/project/coverage/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="+native-extensions"
+
+BDEPEND="
+	test? (
+		>=dev-python/unittest-mixins-1.4[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( hypothesis pytest-{rerunfailures,xdist} )
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_compile() {
+	if ! use native-extensions; then
+		local -x COVERAGE_DISABLE_EXTENSION=1
+	fi
+
+	distutils-r1_python_compile
+}
+
+test_tracer() {
+	local -x COVERAGE_CORE=${1}
+	einfo "  Testing with the ${COVERAGE_CORE} core ..."
+	epytest -o addopts= "${@:2}" tests
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# broken because of pytest plugins explicity loaded
+		tests/test_debug.py::ShortStackTest::test_short_stack{,_skip}
+		# these expect specific availability of C extension matching
+		# COVERAGE_CORE (which breaks testing pytracer on CPython)
+		tests/test_cmdline.py::CmdLineStdoutTest::test_version
+		tests/test_debug.py::DebugTraceTest::test_debug_sys_ctracer
+		# mismatch of expected concurrency in error message
+		# TODO: report upstream?
+		tests/test_concurrency.py::ConcurrencyTest::test_greenlet
+		tests/test_concurrency.py::ConcurrencyTest::test_greenlet_simple_code
+		# packaging tests, fragile to setuptools version
+		tests/test_setup.py
+		# looks like a difference in exit status reporting?
+		# https://github.com/nedbat/coveragepy/issues/2008
+		tests/test_process.py::ProcessTest::test_save_signal_usr1
+	)
+	local EPYTEST_IGNORE=(
+		# pip these days insists on fetching build deps from Internet
+		tests/test_venv.py
+	)
+
+	"${EPYTHON}" igor.py zip_mods || die
+
+	local -x COVERAGE_TESTING=True
+	# TODO: figure out why they can't be imported inside test env
+	local -x COVERAGE_NO_CONTRACTS=1
+
+	local jobs=${EPYTEST_JOBS:-$(makeopts_jobs)}
+	local xdist_args=()
+	if [[ ${jobs} -gt 1 ]]; then
+		# required upstream to avoid cross-test conflicts
+		xdist_args+=( --dist=loadgroup )
+	fi
+
+	local prev_opt=$(shopt -p nullglob)
+	shopt -s nullglob
+	local c_ext=( "${BUILD_DIR}/install$(python_get_sitedir)"/coverage/*.so )
+	${prev_opt}
+
+	if [[ -n ${c_ext} ]]; then
+		cp "${c_ext}" coverage/ || die
+		test_tracer ctrace "${xdist_args[@]}"
+	fi
+
+	test_tracer pytrace "${xdist_args[@]}"
+
+	case ${EPYTHON} in
+		*3.11)
+			;;
+		*)
+			# available since Python 3.12
+			test_tracer sysmon "${xdist_args[@]}"
+			;;
+	esac
+
+	if [[ -n ${c_ext} ]]; then
+		rm coverage/*.so || die
+	fi
+}
diff --git a/dev-python/dns-lexicon/Manifest b/dev-python/dns-lexicon/Manifest
index 58ea44573397..65efe553326e 100644
--- a/dev-python/dns-lexicon/Manifest
+++ b/dev-python/dns-lexicon/Manifest
@@ -1,2 +1,3 @@
 DIST dns-lexicon-3.23.2.gh.tar.gz 5826336 BLAKE2B b4ec01ac220a4174753e35791eb7b46589e9f5bc866c51cf8473533ffdb929afa02ac9dffcd5d47fe82fa70133ff16a587098ccf7ee633187a79368ed96199f2 SHA512 9b9a3a4dc6811282c1016f38df2238e768887389ea1acc57b89374fe4d59456adddd1ae2ed772d9a519d87e3f27affddef95bf3cd8ed2e175da6e843f6d40453
 DIST dns-lexicon-3.25.1.gh.tar.gz 5897936 BLAKE2B 6ac1441199992e996dcf1454d0ceefdbfd1ceec8271f3398dcdd7d491bb8e77deb36ee39a5229e8a6c244af6bcd6774383c06112ca7850eef1afeb03eaf7b707 SHA512 bc19b64f2e1268993dff0755c29f026b76e660e06dbd15eea445911ad816cd671efb308a79d49e0d309c0d45e4f15d229a9759ec25c13b79e3288932da6a93a0
+DIST dns-lexicon-3.25.2.gh.tar.gz 5897582 BLAKE2B 453b81924ced8d82e2d489eb58386402e7292dec37fca15ba3412ae43bd299453cad118c3cd1defee47849ae9d0789f196e0a33e062a9a8afdf15f5639b2c8ce SHA512 79357a25420cfe9f3d8430a91371e1c6a742c962c09df0d280833e3cc1d11aaed883eb04e723d82ed17fbf955e166c93c1647d7bc78f47d47d1799b0bb462628
diff --git a/dev-python/dns-lexicon/dns-lexicon-3.25.2.ebuild b/dev-python/dns-lexicon/dns-lexicon-3.25.2.ebuild
new file mode 100644
index 000000000000..aa8b875a60fa
--- /dev/null
+++ b/dev-python/dns-lexicon/dns-lexicon-3.25.2.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Manipulate DNS records on various DNS providers in a standardized/agnostic way"
+HOMEPAGE="
+	https://github.com/dns-lexicon/dns-lexicon/
+	https://pypi.org/project/dns-lexicon/
+"
+SRC_URI="
+	https://github.com/dns-lexicon/dns-lexicon/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/beautifulsoup4-4[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2[${PYTHON_USEDEP}]
+	>=dev-python/dnspython-2[${PYTHON_USEDEP}]
+	>=dev-python/pyotp-2[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3[${PYTHON_USEDEP}]
+	>=dev-python/requests-2[${PYTHON_USEDEP}]
+	>=dev-python/requests-unixsocket-0.4[${PYTHON_USEDEP}]
+	>=dev-python/tldextract-2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/boto3-1.28[${PYTHON_USEDEP}]
+		>=dev-python/zeep-3[${PYTHON_USEDEP}]
+		dev-python/vcrpy[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# TODO
+	tests/test_client.py::test_client_init_when_missing_action_should_fail
+)
+
+EPYTEST_IGNORE=(
+	# Requires the "localzone" module
+	tests/providers/test_localzone.py
+	# Requires the "softlayer" module
+	tests/providers/test_softlayer.py
+	# Requires the "transip" module
+	tests/providers/test_transip.py
+	# Requires the "oci" module
+	tests/providers/test_oci.py
+	# Uses tldextract which needs Internet access to download its database
+	tests/providers/test_auto.py
+	# Same (https://github.com/dns-lexicon/dns-lexicon/issues/61)
+	tests/providers/test_godaddy.py
+)
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		optfeature_header \
+			"Install the following packages to enable support for additional DNS providers:"
+		optfeature Gransy dev-python/zeep
+		optfeature Route53 dev-python/boto3
+		optfeature DDNS dev-python/dnspython
+	fi
+}
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index 741075108b00..e471e31662bd 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -1,3 +1,4 @@
 DIST hypothesis-6.151.14.gh.tar.gz 9871044 BLAKE2B bed431dcd481f5af11043fd0beca9caf207c918052dd054ef0e758d07646b1870417d868179bb251c6f6463fe73d10a8adabce5f0b0cfa9858be77e876575a46 SHA512 c1e3e3b03d3ed3ac50c7e83b236b8eda65ab6694adde07c88e5096df7361242d194b7624743656e8f30d885e554428d1af3cb9cbfd20514dca1e50bf3d29b4e5
 DIST hypothesis-6.151.9.gh.tar.gz 9864451 BLAKE2B 9d9c2800cf1212e743a599c261c78c0a7d349e58075a443e0d10e6373b1582e059abde416cec4f3a8185ae424725f93da8ab4e43dd70bd0f86071d69aca94def SHA512 3e41bdd077a18fe72360547bc03f2c3d7218e8cd6cb563fffd6024427bfa5ce0764ca9c7ef0dafdded896625128fc14b9d3f8c4564aa8a509545abf0ad24adbf
 DIST hypothesis-6.152.4.gh.tar.gz 9602982 BLAKE2B 7eb3bf424f35707fa323affc9e5e00c35716c32ac69acfdbc7981634f30abf20dee20a8271c21e561b868e24f175a12f484d0e436132ac8194ad48dc361c1ebe SHA512 8f7490051c49f1a3d7b91b00a63527600ff8aba03456bcb2360a9c6a004eea67995354cadf40eabcdaec0d7cd53ecac013963e2c6e19be3e348e79f9e40d9e8e
+DIST hypothesis-6.152.5.gh.tar.gz 9603889 BLAKE2B cc892069eb1b9d28073974cd5f5d23b7c32f3679ebe127acae9783b71d5a2d9dbfb5b1390f102447f62a5c557e34717911d46de4020e9cef6f93a85a24080848 SHA512 ff36abf597a43bf527dafc85e3bce84d352419650cd6a3854bcaee5bb91443ad8651cce9b2e9a7cb2f69f076e98531e323a14fb65ae05a202142a1856dbd5756
diff --git a/dev-python/hypothesis/hypothesis-6.152.5.ebuild b/dev-python/hypothesis/hypothesis-6.152.5.ebuild
new file mode 100644
index 000000000000..2c65b19aa496
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.152.5.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{11..13} )
+PYTHON_COMPAT=( "${CLI_COMPAT[@]}" pypy3_11 python3_{14..15} python3_{13..15}t )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/pytest-8[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	dev-python/hypothesis-gentoo[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGIN_LOAD_VIA_ENV=1
+EPYTEST_PLUGINS=( "${PN}" pytest-xdist )
+EPYTEST_RERUNS=5
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=(
+		# broken somehow (xdist?)
+		'hypothesis-python/tests/pytest/test_constant_collection_timing.py::test_constant_collection_timing[True]'
+		# used to fail for a few impls, now fails everywhere
+		'hypothesis-python/tests/cover/test_lambda_formatting.py::test_modifying_lambda_source_code_returns_unknown[False]'
+	)
+	local EPYTEST_IGNORE=(
+		# require syrupy
+		tests/cover/test_custom_reprs.py
+	)
+
+	case ${EPYTHON} in
+		python3.15*)
+			EPYTEST_DESELECT+=(
+				'hypothesis-python/tests/cover/test_lookup.py::test_resolves_forwardrefs_to_builtin_types[sentinel]'
+				'hypothesis-python/tests/cover/test_lookup.py::test_resolves_builtin_types[sentinel]'
+			)
+			;;
+	esac
+
+	local -x HYPOTHESIS_NO_PLUGINS=1
+	epytest -o filterwarnings= tests/{cover,pytest,quality}
+}
+
+src_install() {
+	local HAD_CLI=
+
+	distutils-r1_src_install
+
+	if [[ ! ${HAD_CLI} ]]; then
+		rm -r "${ED}/usr/bin" || die
+	fi
+}
+
+python_install() {
+	distutils-r1_python_install
+	if use cli && has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		HAD_CLI=1
+	else
+		rm -r "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/idna/Manifest b/dev-python/idna/Manifest
index a04aa79a9cc7..861e3b326673 100644
--- a/dev-python/idna/Manifest
+++ b/dev-python/idna/Manifest
@@ -4,3 +4,5 @@ DIST idna-3.12.tar.gz 194350 BLAKE2B d7a91d278d32bed5f8813df4b26e2387040e471a341
 DIST idna-3.12.tar.gz.provenance 9315 BLAKE2B 86ef43281fbbd9be9b32c1c85eb3b6bc1939c0d0b1e00c5f616780156e9c5edf1f6f8aa87b0a46c730cd59e3b439781e89c3c37c23f3bc23f1f9a549167acd0f SHA512 fd36a8fa287df7c120d53fd527aa0a1b3485be4ec1d4843ff9eeb11f6275517ee75dc03c5a3e42a657bf291211798cd3265d0b0926236e60683e56c4d6f7d94a
 DIST idna-3.13.tar.gz 194210 BLAKE2B 6c98376ee4fc8320a0cce81230e6475dabc788017cd72eef059aea17a78cdc12189b51e3eaf41aa49035274bdd5bbc7827864315dce950724e4d40702c43512f SHA512 831ed3e23808dd85285973e9ac7717dad0dd4dbb5aeef6a0532fbc04b41c0714ce83cdc1a8efb6c8311a0160ce00abcbb8ff7064633e2a2bde32c0c2017e39b5
 DIST idna-3.13.tar.gz.provenance 8998 BLAKE2B 52b74df186a75decb7cc1438339bbf4fc57cce92ef292c0fb9db38abf35b061440b0a6984730499b940c69d4cbb185a5b50d529ea5a3b725b74b06826b93603d SHA512 fca4396722f497e4a13f744b95742857ef177713299678bfe496c0a47660afb02b5736eaa9abf059eebf525b5bbcce5fc239554ff0c3b6a574589b26d6c961a6
+DIST idna-3.14.tar.gz 198272 BLAKE2B e7c7084109b82c797a9d04074e77533eedd1b339e334a9f48beee4405c1f62b9bcad02ec726445c71b96354088cedc23ee3b9cd3772a77b004f06a2f66382e76 SHA512 be45700d70b8527445c00c9f760311a448d1a38116883e69549405ebc89b78dded0a939625564841c44c51efaad03e2054ba883f284b152552b9fe84ffdb229b
+DIST idna-3.14.tar.gz.provenance 8986 BLAKE2B a9cbeae466fc385c997838513fe35efc862741be2f6b80f0c1151272b0bb473d6ed7efaa8584be1d647d8ed76127a524c7aaa102b248d16c1f9d51baf71af0a6 SHA512 e982ee5071a6a3ba7760c9e622419e47fce5fd210583ba78e70c5ac07a78adb3b2d6479020a7f2c8988b4a45b50b3968412a86d054e57df176c8817d1b54338b
diff --git a/dev-python/idna/idna-3.14.ebuild b/dev-python/idna/idna-3.14.ebuild
new file mode 100644
index 000000000000..32ad58c4395a
--- /dev/null
+++ b/dev-python/idna/idna-3.14.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYPI_VERIFY_REPO=https://github.com/kjd/idna
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Internationalized Domain Names in Applications (IDNA)"
+HOMEPAGE="
+	https://github.com/kjd/idna/
+	https://pypi.org/project/idna/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos ~x64-solaris"
+
+distutils_enable_tests unittest
diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index a11d7c268c91..d12ab8aeaca8 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1 +1,3 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
+EBUILD langdetect-1.0.9.ebuild 494 BLAKE2B 9cd8a2a93a8d45bf51fe2324402b175d641762ea591fcb99459427f977a95eccffa6ca4777ca4df39814eea6eac62711567faa654456d32f79023a4685804504 SHA512 d973b85ba1a44389a4275f02a779a93a005f7c2e096467b94b072862e4984d5b42cf33f9821ac68aa5b85b12c98983a90b96049989d8c84497969174b6bb838e
+MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch b/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
deleted file mode 100644
index 637368d2f237..000000000000
--- a/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
+++ /dev/null
@@ -1,13 +0,0 @@
-Fix "Package 'langdetect.profiles' is absent from the `packages` configuration."
-
---- a/setup.py
-+++ b/setup.py
-@@ -18,7 +18,7 @@ setup(
-     author_email='michal.danilak@gmail.com',
-     url='https://github.com/Mimino666/langdetect',
-     keywords='language detection library',
--    packages=['langdetect', 'langdetect.utils', 'langdetect.tests'],
-+    packages=['langdetect', 'langdetect.utils', 'langdetect.tests', 'langdetect.profiles'],
-     include_package_data=True,
-     install_requires=['six'],
-     license='MIT',
diff --git a/dev-python/langdetect/langdetect-1.0.9.ebuild b/dev-python/langdetect/langdetect-1.0.9.ebuild
index 7100f5f39dd8..271137de443d 100644
--- a/dev-python/langdetect/langdetect-1.0.9.ebuild
+++ b/dev-python/langdetect/langdetect-1.0.9.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2022-2025 Gentoo Authors
+# Copyright 2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -19,6 +19,4 @@ KEYWORDS="~amd64"
 
 RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
 
-PATCHES=( "${FILESDIR}/${P}-explicit-config.patch" )
-
 distutils_enable_tests unittest
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index c0f74ac187e2..020e07f2a3dd 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -2,9 +2,11 @@
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
  <maintainer type="person">
-  <email>pastalian46@gmail.com</email>
-  <name>Takuya Wakazono</name>
+  <email>marcin.deranek@slonko.net</email>
+  <name>Marcin Deranek</name>
  </maintainer>
- 
- <origin>gentoo-guru-overlay</origin>
+ <upstream>
+  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
+ </upstream>
+ <origin>slonko-overlay</origin>
 </pkgmetadata>
 \ No newline at end of file
diff --git a/dev-python/librt/Manifest b/dev-python/librt/Manifest
index 606260dba726..37286c30292f 100644
--- a/dev-python/librt/Manifest
+++ b/dev-python/librt/Manifest
@@ -1,4 +1,6 @@
 DIST librt-0.10.0.tar.gz 191799 BLAKE2B 27dfdbfd999a6ebb2a390dba65ab3356fe155773f8d0d526721a27720a4ee1410db5d04ce8fece6d5aee647d52b4263526ed446bdb6f511f8b41f6b9b5d79d0d SHA512 0cb251c8595d711b90434b7f6bb95b577cf3231bf72d7de75c98db47326dbbdb193cdf69c5bcd165282483c211738ad982bdda2538b62e7ed2eb1de8025f413d
 DIST librt-0.10.0.tar.gz.provenance 9278 BLAKE2B 1bb6485bfff8cde221fbb6851b500d3f912706d5101b7efc7d78d7239ff6e41fdcf57928c52ca62585217b7fe293f578fb8e4dc300b8b4fa32c4805c45438ef0 SHA512 bde45f77e5fb079d123def44620e83b3596a5f93240502050808ec82b5b3ff32d2682b32cbeb68fa41dc50a36a53004ede90bd7f052a6ca3ef333e75f031ddce
+DIST librt-0.11.0.tar.gz 200139 BLAKE2B b7e80bfddad285f75337341bb39b3efedc2904a7ded1d178fb9e18d2787d0447c4f42fc416696141cce2a0fdc7d9b2488c829109e749f14a3d12c02c2b66dfe3 SHA512 5575adcdbe88da23eebb771a33597948cc8dd6f7fc36016daf87f89186bdc02cae572f9e46d3fbdba15d77fb2ee4e130ea06d2ff643227dafcacf77184cb7755
+DIST librt-0.11.0.tar.gz.provenance 9607 BLAKE2B 1f7f54262eed9212b80eed64ff8b412cc5aead788c8c0745ba375b050f50062ca6f7305298e040b1b0f0d09b56e57d6dd209e1b1468b7c3a0ef5a90fa8cde335 SHA512 3c5d9d0edfadb06db252d313e793d41026c2c0982af34038cea647a4e7bce9ff2fc31857982811d46d191149b97d1d1fe39909573567033b7ed85fdad612d236
 DIST librt-0.9.0.tar.gz 184368 BLAKE2B 03e1b1628c902eeab9d97610ec4a4e764767a4ba7a60cf5c9b52d2c8f7486a8b960baed1e75d895d4f5d9e2d2bc9725ec80e4269352b9e602833c4aa92c6bc5e SHA512 0877b217af0898b20623290aa5aeaabc224342d19bf2e6142d7ba7afd1d9d5ab19266e79e09b31a4b6cdd02ebeebc38561fc8876ff13026df1745e35ddd7d7a6
 DIST librt-0.9.0.tar.gz.provenance 9176 BLAKE2B af4aacde70c07d9458714711402f508197fd232abe624dfce92a2a68f32d25c0b99bb15ce09dfc0b7975aa60119146062c722436ded816396eca667d9bf36ca9 SHA512 c568c933cbb8b1016c7b64308001a3d205120afa0f8a7845613ea8907eaffecc796ac5668db002260b30974f4839e17b88d5eb231eb6124263194e9270c78e18
diff --git a/dev-python/librt/librt-0.11.0.ebuild b/dev-python/librt/librt-0.11.0.ebuild
new file mode 100644
index 000000000000..961df9196779
--- /dev/null
+++ b/dev-python/librt/librt-0.11.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2025-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYPI_VERIFY_REPO=https://github.com/mypyc/librt
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Mypyc runtime library"
+HOMEPAGE="
+	https://github.com/mypyc/librt/
+	https://pypi.org/project/librt/
+"
+
+LICENSE="MIT PSF-2.4"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/mypy-extensions[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_compile() {
+	# setuptools is broken for C extensions, bug #907718, bug #967476 etc.
+	distutils-r1_python_compile -j1
+}
+
+python_test() {
+	rm -rf librt || die
+	epytest smoke_tests.py
+}
diff --git a/dev-python/libtmux/Manifest b/dev-python/libtmux/Manifest
index 5802be78b60b..aff359026fba 100644
--- a/dev-python/libtmux/Manifest
+++ b/dev-python/libtmux/Manifest
@@ -9,3 +9,5 @@ DIST libtmux-0.55.0.tar.gz 420859 BLAKE2B f28b33cf3d19772e584dbb6f49ca59ba2c5f6d
 DIST libtmux-0.55.0.tar.gz.provenance 9391 BLAKE2B d32cf5d14af776edb90d1af3acf154208fa54d7696383abc7bc25f115043c6f85609fb52bb6addabd32f92f40e96a52189ae8c3b93df452d7f9960c34d63fdb8 SHA512 bec7e9679b59e000b46ee23e2d4c6ebd2d1039b708cc063250739c93f523178abaca925ced8e4ef5798b02de3a9bf5d91f8cd47a3f02ccd92fb8fc1e4eb81500
 DIST libtmux-0.55.1.tar.gz 439372 BLAKE2B 918d545f0165edaf541d6156b18c9d441eab66bcb429a1ceb33de09813ca2665cde5dfc3a8cd9a016c53304d83f13f847d9715d3342113988f31143f5f14d54b SHA512 9ce3acc77ca6ed964a34dd818f3f6838ca21463240c0b405900955f2b6c7b16cffa06d00007be519ae8315712a200e2b9bf0ed9b217316cd2058b35ff5f016e8
 DIST libtmux-0.55.1.tar.gz.provenance 9253 BLAKE2B fb744d311b3ad21c11a1cb950f2e3b9036627b4378e98f368a0104ce5f07af46f08cf23b738f1b30d9e201b985785477de02adc5add336e696771b1302c87dba SHA512 79ba74ec6221a9adb88e2647f6db03e3786e1a9b489a13ced8b6228ed0d3a925eabbb42ba674ddf0a156d8111e9bc5839245cdaefad7abbdba154794cace8243
+DIST libtmux-0.56.0.tar.gz 476168 BLAKE2B 55fc82e3a8028b82a4a6a112162275d27b77b2d8c67ce6697688a7fbe41e958ed7a9ad644b115d425609340977475a1884c75bdb4502fde391618a29cbc87f50 SHA512 8ff93b87eb1aa3663edc228bd818a0e5a5be4472cd193ee5f1c02195a3f02a0f661a3652602895e0a79fd4e1e80a7d122abf8d96b6cf069a5a147e3fa346421f
+DIST libtmux-0.56.0.tar.gz.provenance 9476 BLAKE2B 6447d0565068024f2f5497153252fcc4fbef60929ab3c24bd744a4a30bab34740c0d30ceea149dcbb958d7b7b6b91d4f3b6f105352067bedd5d227212533a5a9 SHA512 4f6c47fbb885e9a369a55a5cec5fcea227e2f820a987f9dadac4aa74ee4e5902992efb356a4ef5c3f62c2a75b92c3bb4d0a51582a1b1bef1f49aa29a3355da74
diff --git a/dev-python/libtmux/libtmux-0.56.0.ebuild b/dev-python/libtmux/libtmux-0.56.0.ebuild
new file mode 100644
index 000000000000..c88569e4d14c
--- /dev/null
+++ b/dev-python/libtmux/libtmux-0.56.0.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/tmux-python/libtmux
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Typed library that provides an ORM wrapper for tmux, a terminal multiplexer"
+HOMEPAGE="
+	https://libtmux.git-pull.com/
+	https://github.com/tmux-python/libtmux/
+	https://pypi.org/project/libtmux/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	>=app-misc/tmux-3.0a
+"
+
+EPYTEST_PLUGIN_LOAD_VIA_ENV=1
+EPYTEST_PLUGINS=( "${PN}" pytest-mock )
+EPYTEST_RERUNS=5
+distutils_enable_tests pytest
+
+python_test() {
+	# tests/test_window.py::test_fresh_window_data fails if TMUX_PANE is set
+	# https://bugs.gentoo.org/927158
+	local -x TMUX_PANE=
+
+	epytest -o addopts= tests
+}
diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index b146dbac3116..b8c69e56933d 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -3,3 +3,5 @@ DIST moto-5.1.22.tar.gz 8547792 BLAKE2B fda4ea90318a1eb8501ed29b2c6cc23c0779c9cc
 DIST moto-5.1.22.tar.gz.provenance 9052 BLAKE2B 50c2c73d5a6afac0c84c333ddbc00370e83d5dd713af7ee1c412c8f11a50922b1ace8ec79aee35465a840a7754b313c61d9baf47c44933e99cc95f3bf2172fdd SHA512 a9800117bf73b7d51d795732f0589c2e217187465322a20614fcc3fdfbdbcf0d682613dcae3d826c01e2beb672af43f62458d36f0c2d155e87ab8d5a259458c4
 DIST moto-5.2.0.tar.gz 8632930 BLAKE2B 396a09231ba80d0c621711b106c4e394be80f1165bcf12fbea44131d6df01effd45327f053924e54e06ffe4d95f77f99fb00c43d6d7f5613bdd1f265899e3fb9 SHA512 23ac55057ba9acca67ced50fab7eb6b529bcd3f2ce5baf96790a81ca381794af704a9cb34640cd6f1c79e63ba91229a2529728d38ead006544e9d47bbe7c84bf
 DIST moto-5.2.0.tar.gz.provenance 9372 BLAKE2B 5b984d0190d20ca075542ec337bf6e21a0346832f586ec990f6ea624a2b2b9ca27fa4d84e1aa7718419b1dd5dff43fbea8331a3eeb77d703f8f69fe8cc6491c8 SHA512 a5c4261ed91f54ab8e5dafacc8ab0c799eea74a09afc644a52f5fa8ecd810625c6764e07e35f61f02f5ea3c976947b466bc83443fdffe0abb860b4590fbfd48d
+DIST moto-5.2.1.tar.gz 8634437 BLAKE2B bcf2a13d611a3ab8c25b071f8b2655db4abecce75e1b7386828104673a83ad4d138bc629b379d03fe20a0ab450e4675cd2415c46a6813a06cf0368119197c4cb SHA512 eb723316f996becdbe73a89bf01dd1aee9faec7bbace1c0a1c9455a623c8c0e3214d076686306f12b214422ce7bf28528dec46dc0c357bba6a84d9f2b04f7ab8
+DIST moto-5.2.1.tar.gz.provenance 9290 BLAKE2B b5c6c010a9265b12d6a6e2fda6b63f3debffd6c9f006c844f54be3880827691ff6cd1df143e6745561efd373e4893b83f0d4ad49704c9a01b34fa5617ed72b61 SHA512 24cb296cdeabb350200572a5e10f4cdafb16ce20fe1dfc6a0162f16aacbfbe484e200278e12e6ff01d9eb40273474b551ed1384aaf2b88c3aa1e543144c17438
diff --git a/dev-python/moto/moto-5.2.1.ebuild b/dev-python/moto/moto-5.2.1.ebuild
new file mode 100644
index 000000000000..19872f254f7a
--- /dev/null
+++ b/dev-python/moto/moto-5.2.1.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_VERIFY_REPO=https://github.com/getmoto/moto
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi toolchain-funcs
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="
+	https://github.com/getmoto/moto/
+	https://pypi.org/project/moto/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-0.93[${PYTHON_USEDEP}]
+	dev-python/boto3[${PYTHON_USEDEP}]
+	>=dev-python/botocore-1.35.47[${PYTHON_USEDEP}]
+	>=dev-python/cfn-lint-0.40.0[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-35.0.0[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	>=dev-python/docker-3.0.0[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	dev-python/jsonpath-ng[${PYTHON_USEDEP}]
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3.0.7[${PYTHON_USEDEP}]
+	>=dev-python/openapi-spec-validator-0.5.0[${PYTHON_USEDEP}]
+	dev-python/pyaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.25.6[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/sshpubkeys[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/antlr4-python3-runtime[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/joserfc[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_RERUNS=5
+: "${EPYTEST_TIMEOUT:=180}"
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_dynamodb/test_dynamodb_import_table.py
+		# require py_partiql_parser
+		tests/test_dynamodb/test_dynamodb_statements.py
+		tests/test_s3/test_s3_select.py
+		# require graphql
+		tests/test_appsync/test_appsync_schema.py
+		# Internet
+		tests/test_core/test_request_passthrough.py::test_passthrough_calls_for_entire_service
+		tests/test_core/test_request_passthrough.py::test_passthrough_calls_for_specific_url
+		tests/test_core/test_request_passthrough.py::test_passthrough_calls_for_wildcard_urls
+		tests/test_firehose/test_firehose_put.py::test_put_record_http_destination
+		tests/test_firehose/test_firehose_put.py::test_put_record_batch_http_destination
+		# Appears to be internet issues with timing out
+		tests/test_s3/test_multiple_accounts_server.py::TestAccountIdResolution::test_with_custom_request_header
+		tests/test_s3/test_server.py::test_s3_server_post_cors_multiple_origins
+	)
+	local EPYTEST_IGNORE=(
+		# require joserfc
+		tests/test_cognitoidp/test_cognitoidp.py
+	)
+
+	if ! tc-has-64bit-time_t; then
+		einfo "time_t is smaller than 64 bits, will skip broken tests"
+		EPYTEST_DESELECT+=(
+			tests/test_acm/test_acm.py::test_request_certificate_with_optional_arguments
+			tests/test_s3/test_multiple_accounts_server.py::TestAccountIdResolution::test_with_custom_request_header
+			tests/test_s3/test_server.py::test_s3_server_post_cors_multiple_origins
+		)
+		EPYTEST_IGNORE+=(
+			tests/test_route53domains/test_route53domains_domain.py
+		)
+	fi
+
+	local -x TZ=UTC
+	local -x AWS_DEFAULT_REGION=us-east-1
+
+	# -o timeout_func_only=true: bad interaction with pytest-rerunfailures and pytest-timeout leads to a permanent hang otherwise
+	epytest -m 'not network and not requires_docker' -o timeout_func_only=true
+}
diff --git a/dev-python/pdm/Manifest b/dev-python/pdm/Manifest
index 2077d43be7d6..596bc0de6e54 100644
--- a/dev-python/pdm/Manifest
+++ b/dev-python/pdm/Manifest
@@ -1,2 +1,3 @@
 DIST pdm-2.26.7.tar.gz 2679303 BLAKE2B 34f540a63bc8949c2e2f310e93b2e97b111e46cca0def8ae2647e2e177f4758615e592f3348964fc98a5b00640ba5d165fd18f452218ac76d4354cd54c40494f SHA512 eb21bfc0982053ec972e8802815ff6a30d27120fc2f4a3f77451c056a5263c10565a704916447b5e24fca322d8936e390d932a49ad1603442095a00eb76f9400
 DIST pdm-2.26.8.tar.gz 2681418 BLAKE2B e4df1b8c436e567aa7dbc0ef7505a2fb04266122fc12b66500f255463f49d0f60a27e1ba65bd6d758c67dddd28c5ac5c22e12febe6da6a4d1d30806506cf214e SHA512 aaee6ae96c678d04b1477c2c0b2b2e2882dabca3c9e04d095c259e732256e2551b317d6dedd49a1bf51d7b9670167be4a31f3f1296a951fc7a636315d09f9d65
+DIST pdm-2.26.9.tar.gz 2682146 BLAKE2B 8bf0a7071501e6fd2ebea650f62cda29352f6801c64ec34cd77ee62e2a74515d9368c0525572611cd13f00f75fc9e088309f984e793729120e5ba6d14340e972 SHA512 def7fb5a8312f597db661f62ed7a3a297075bbd6295e6eccd6e975df242c3f553b835c04ef1b5e2f3bbb49fdf6376b863ab2ae046d7d1bd84fb0830674091994
diff --git a/dev-python/pdm/pdm-2.26.9.ebuild b/dev-python/pdm/pdm-2.26.9.ebuild
new file mode 100644
index 000000000000..5af2a34490f9
--- /dev/null
+++ b/dev-python/pdm/pdm-2.26.9.ebuild
@@ -0,0 +1,84 @@
+# Copyright 2023-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python package and dependency manager supporting the latest PEP standards"
+HOMEPAGE="
+	https://pdm-project.org/
+	https://github.com/pdm-project/pdm/
+	https://pypi.org/project/pdm/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/dep-logic-0.5[${PYTHON_USEDEP}]
+	<dev-python/findpython-1[${PYTHON_USEDEP}]
+	>=dev-python/findpython-0.7.0[${PYTHON_USEDEP}]
+	dev-python/blinker[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	>=dev-python/hishel-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/httpcore-1.0.6[${PYTHON_USEDEP}]
+	dev-python/httpx[${PYTHON_USEDEP}]
+	>=dev-python/id-1.5.0[${PYTHON_USEDEP}]
+	dev-python/installer[${PYTHON_USEDEP}]
+	>=dev-python/packaging-22.1[${PYTHON_USEDEP}]
+	>=dev-python/pbs-installer-2025.10.07[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+	dev-python/python-dotenv[${PYTHON_USEDEP}]
+	>=dev-python/resolvelib-1.2.0[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
+	dev-python/shellingham[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+	>=dev-python/truststore-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/unearth-0.17.5[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/uv
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{httpserver,httpx,mock,rerunfailures} )
+EPYTEST_RERUNS=5
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unpin deps
+	sed -i -e 's:,<[0-9.a]*::' pyproject.toml || die
+	# remove pkgutil namespace magic, as it doesn't work and makes
+	# dev-python/pdm-backend tests test the wrong package
+	rm src/pdm/__init__.py || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		'tests/models/test_candidates.py::test_expand_project_root_in_url[demo @ file:///${PROJECT_ROOT}/tests/fixtures/artifacts/demo-0.0.1.tar.gz]'
+		# unhappy about extra packages being installed?
+		# (also fails randomly in venv)
+		tests/cli/test_build.py::test_build_with_no_isolation
+		# TODO: random regression?
+		tests/cli/test_python.py::test_find_python
+		# TODO
+		tests/test_formats.py::test_export_from_pylock_not_empty
+	)
+
+	epytest -m "not network and not integration and not path"
+}
diff --git a/dev-python/pillow/Manifest b/dev-python/pillow/Manifest
index d0c9ba2f02d8..90b2a9bbd327 100644
--- a/dev-python/pillow/Manifest
+++ b/dev-python/pillow/Manifest
@@ -1,4 +1,2 @@
-DIST pillow-11.3.0.gh.tar.gz 47173056 BLAKE2B 1260c7025e6013c50782024756a0c891d3735bd7d4c1c9d0a89d9eb1c94bd2f762369086f7269d487100e8a0e2678a73012bf29172697c1a1a18e58f9019a9bd SHA512 7d97e623bd41da94dd89a66dc600cea016d0a4f33fbf036175768ea96b2031c1968acf4fc3d9b2835ce93f9533838a9ce68a6579a7397f4aeccafb6032adb3db
-DIST pillow-12.1.1.gh.tar.gz 47047606 BLAKE2B 7e646b2d16bd7653f1579fb2e752c40b2945e3de97d115e5c9769102af6e4030d1903e2bf0d0926b41586d61bb070dd849c67404d164a0ea7c0827bec7ae6b61 SHA512 791c8972d913b616bd903aa4e9a468b1886faf5a477414fdd07cd37a29253f3e158988adf613969ea3f3efcef716d74b8d667efbac0d85ba12c15da2137c32a3
 DIST pillow-12.2.0.gh.tar.gz 47057046 BLAKE2B 448a928cdaef49c21db4b0b61e2045610ff6bf6c9c52c7ab541d531205149b8a60aa02b1e286c7dc15dac98fa23a07a4c685f524df6e7592013b0914e65a8cc8 SHA512 cd66b5b033f82127934624c474aed55c014d10d5e7cc9455ea6a3470d1b7e9f0b94ad2c0a5f1559e01ce003fc179b01fee89aa1b51d78dff3f04927d8252a41e
 DIST pillow-test-images-7077675d2cda485d63de4aefe0fefbf6f655c5a0.gh.tar.gz 57430276 BLAKE2B 6e8dcde60832004f5a0ea0e14024fdcd0b08cf0e225f27e39b7c2058582d6d5efe7fcaccb5bd28754affa6fe4125735fb4beeaa2075e6aceea0a998ebc0747fe SHA512 795f015c9b73a8c941fb5cd880b1ab36b24d38612db53367ab0e6c05dd1cdbfd47034decb7e36d7de940eeea1582d644ca7bee3b131577578692569c2c60c32b
diff --git a/dev-python/pillow/pillow-11.3.0.ebuild b/dev-python/pillow/pillow-11.3.0.ebuild
deleted file mode 100644
index 948757b2ed5a..000000000000
--- a/dev-python/pillow/pillow-11.3.0.ebuild
+++ /dev/null
@@ -1,168 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-# setuptools wrapper
-DISTUTILS_USE_PEP517=standalone
-PYTHON_COMPAT=( python3_{10..14} )
-PYTHON_REQ_USE='tk?,threads(+)'
-
-inherit distutils-r1 toolchain-funcs virtualx
-
-MY_PN=Pillow
-MY_P=${MY_PN}-${PV}
-
-# upstream always fetches from main
-TEST_IMAGE_COMMIT="7077675d2cda485d63de4aefe0fefbf6f655c5a0"
-
-DESCRIPTION="Python Imaging Library (fork)"
-HOMEPAGE="
-	https://python-pillow.github.io/
-	https://github.com/python-pillow/Pillow/
-	https://pypi.org/project/pillow/
-"
-SRC_URI="
-	https://github.com/python-pillow/Pillow/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-	test? (
-		https://github.com/python-pillow/test-images/archive/${TEST_IMAGE_COMMIT}.tar.gz
-			-> pillow-test-images-${TEST_IMAGE_COMMIT}.gh.tar.gz
-	)
-"
-S=${WORKDIR}/${MY_P}
-
-LICENSE="HPND"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos"
-IUSE="avif examples imagequant +jpeg jpeg2k lcms test tiff tk truetype webp xcb zlib"
-REQUIRED_USE="test? ( jpeg jpeg2k lcms tiff truetype )"
-RESTRICT="!test? ( test )"
-
-DEPEND="
-	avif? ( media-libs/libavif:= )
-	imagequant? ( media-gfx/libimagequant:= )
-	jpeg? ( media-libs/libjpeg-turbo:= )
-	jpeg2k? ( media-libs/openjpeg:2= )
-	lcms? ( media-libs/lcms:2= )
-	tiff? ( media-libs/tiff:=[jpeg,zlib] )
-	truetype? (
-		media-libs/freetype:2=
-		media-libs/harfbuzz:=
-	)
-	webp? ( media-libs/libwebp:= )
-	xcb? ( x11-libs/libxcb )
-	zlib? ( virtual/zlib:= )
-"
-RDEPEND="
-	${DEPEND}
-	dev-python/olefile[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	>=dev-python/setuptools-77[${PYTHON_USEDEP}]
-	dev-python/wheel[${PYTHON_USEDEP}]
-	virtual/pkgconfig
-	test? (
-		dev-python/defusedxml[${PYTHON_USEDEP}]
-		dev-python/packaging[${PYTHON_USEDEP}]
-		|| (
-			media-gfx/imagemagick[png]
-			media-gfx/graphicsmagick[png]
-		)
-	)
-"
-
-EPYTEST_PLUGINS=( pytest-timeout )
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-src_prepare() {
-	local PATCHES=(
-		# https://github.com/python-pillow/pillow/pull/7634
-		"${FILESDIR}/${PN}-10.2.0-cross.patch"
-	)
-
-	distutils-r1_src_prepare
-
-	if use test; then
-		mv "${WORKDIR}/test-images-${TEST_IMAGE_COMMIT}"/* \
-			Tests/images || die
-	fi
-}
-
-usepil() {
-	usex "${1}" enable disable
-}
-
-python_configure_all() {
-	cat >> setup.cfg <<-EOF || die
-		[build_ext]
-		debug = True
-		disable_platform_guessing = True
-		$(usepil avif)_avif = True
-		$(usepil truetype)_freetype = True
-		$(usepil jpeg)_jpeg = True
-		$(usepil jpeg2k)_jpeg2000 = True
-		$(usepil lcms)_lcms = True
-		$(usepil tiff)_tiff = True
-		$(usepil imagequant)_imagequant = True
-		$(usepil webp)_webp = True
-		$(usepil xcb)_xcb = True
-		$(usepil zlib)_zlib = True
-	EOF
-	if use truetype; then
-		# these dependencies are implicitly disabled by USE=-truetype
-		# and we can't pass both disable_* and vendor_*
-		# https://bugs.gentoo.org/935124
-		cat >> setup.cfg <<-EOF || die
-			vendor_raqm = False
-			vendor_fribidi = False
-		EOF
-	fi
-
-	tc-export PKG_CONFIG
-}
-
-src_test() {
-	virtx distutils-r1_src_test
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# TODO (is clipboard unreliable in Xvfb?)
-		Tests/test_imagegrab.py::TestImageGrab::test_grabclipboard
-		# requires xz-utils[extra-filters]?
-		Tests/test_file_libtiff.py::TestFileLibTiff::test_lzma
-	)
-
-	case ${ARCH} in
-		ppc)
-			EPYTEST_DESELECT+=(
-				# https://github.com/python-pillow/Pillow/issues/7008
-				# (we've reverted the upstream patch because it was worse
-				# than the original issue)
-				Tests/test_file_libtiff.py::TestFileLibTiff::test_exif_ifd
-			)
-			;;
-	esac
-
-	"${EPYTHON}" selftest.py --installed || die "selftest failed with ${EPYTHON}"
-	# leak tests are fragile and broken under xdist
-	# nonfatal implied by xvfb
-	nonfatal epytest -k "not leak" || die "Tests failed with ${EPYTHON}"
-}
-
-python_install() {
-	python_doheader src/libImaging/*.h
-	distutils-r1_python_install
-}
-
-python_install_all() {
-	if use examples ; then
-		docinto example
-		dodoc docs/example/*
-		docompress -x /usr/share/doc/${PF}/example
-	fi
-	distutils-r1_python_install_all
-}
diff --git a/dev-python/pillow/pillow-12.1.1.ebuild b/dev-python/pillow/pillow-12.1.1.ebuild
deleted file mode 100644
index 888bb1cd382b..000000000000
--- a/dev-python/pillow/pillow-12.1.1.ebuild
+++ /dev/null
@@ -1,170 +0,0 @@
-# Copyright 1999-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-# setuptools wrapper
-DISTUTILS_USE_PEP517=standalone
-PYTHON_COMPAT=( python3_{10..14} )
-PYTHON_REQ_USE='tk?,threads(+)'
-
-inherit distutils-r1 multiprocessing toolchain-funcs virtualx
-
-MY_PN=Pillow
-MY_P=${MY_PN}-${PV}
-
-# upstream always fetches from main
-TEST_IMAGE_COMMIT="7077675d2cda485d63de4aefe0fefbf6f655c5a0"
-
-DESCRIPTION="Python Imaging Library (fork)"
-HOMEPAGE="
-	https://python-pillow.github.io/
-	https://github.com/python-pillow/Pillow/
-	https://pypi.org/project/pillow/
-"
-SRC_URI="
-	https://github.com/python-pillow/Pillow/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-	test? (
-		https://github.com/python-pillow/test-images/archive/${TEST_IMAGE_COMMIT}.tar.gz
-			-> pillow-test-images-${TEST_IMAGE_COMMIT}.gh.tar.gz
-	)
-"
-S=${WORKDIR}/${MY_P}
-
-LICENSE="HPND"
-SLOT="0"
-KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos"
-IUSE="avif examples imagequant +jpeg jpeg2k lcms test tiff tk truetype webp xcb zlib"
-REQUIRED_USE="test? ( jpeg jpeg2k lcms tiff truetype )"
-RESTRICT="!test? ( test )"
-
-DEPEND="
-	avif? ( media-libs/libavif:= )
-	imagequant? ( media-gfx/libimagequant:= )
-	jpeg? ( media-libs/libjpeg-turbo:= )
-	jpeg2k? ( media-libs/openjpeg:2= )
-	lcms? ( media-libs/lcms:2= )
-	tiff? ( media-libs/tiff:=[jpeg,zlib] )
-	truetype? (
-		media-libs/freetype:2=
-		media-libs/harfbuzz:=
-	)
-	webp? ( media-libs/libwebp:= )
-	xcb? ( x11-libs/libxcb )
-	zlib? ( virtual/zlib:= )
-"
-RDEPEND="
-	${DEPEND}
-	dev-python/olefile[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	dev-python/pybind11[${PYTHON_USEDEP}]
-	>=dev-python/setuptools-77[${PYTHON_USEDEP}]
-	dev-python/wheel[${PYTHON_USEDEP}]
-	virtual/pkgconfig
-	test? (
-		dev-python/defusedxml[${PYTHON_USEDEP}]
-		dev-python/packaging[${PYTHON_USEDEP}]
-		|| (
-			media-gfx/imagemagick[png]
-			media-gfx/graphicsmagick[png]
-		)
-	)
-"
-
-EPYTEST_PLUGINS=( pytest-timeout )
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-src_prepare() {
-	local PATCHES=(
-		# https://github.com/python-pillow/pillow/pull/7634
-		"${FILESDIR}/${PN}-10.2.0-cross.patch"
-	)
-
-	distutils-r1_src_prepare
-
-	if use test; then
-		mv "${WORKDIR}/test-images-${TEST_IMAGE_COMMIT}"/* \
-			Tests/images || die
-	fi
-}
-
-usepil() {
-	usex "${1}" enable disable
-}
-
-python_configure_all() {
-	cat >> setup.cfg <<-EOF || die
-		[build_ext]
-		debug = True
-		disable_platform_guessing = True
-		parallel = $(get_makeopts_jobs)
-		$(usepil avif)_avif = True
-		$(usepil truetype)_freetype = True
-		$(usepil jpeg)_jpeg = True
-		$(usepil jpeg2k)_jpeg2000 = True
-		$(usepil lcms)_lcms = True
-		$(usepil tiff)_tiff = True
-		$(usepil imagequant)_imagequant = True
-		$(usepil webp)_webp = True
-		$(usepil xcb)_xcb = True
-		$(usepil zlib)_zlib = True
-	EOF
-	if use truetype; then
-		# these dependencies are implicitly disabled by USE=-truetype
-		# and we can't pass both disable_* and vendor_*
-		# https://bugs.gentoo.org/935124
-		cat >> setup.cfg <<-EOF || die
-			vendor_raqm = False
-			vendor_fribidi = False
-		EOF
-	fi
-
-	tc-export PKG_CONFIG
-}
-
-src_test() {
-	virtx distutils-r1_src_test
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# TODO (is clipboard unreliable in Xvfb?)
-		Tests/test_imagegrab.py::TestImageGrab::test_grabclipboard
-		# requires xz-utils[extra-filters]?
-		Tests/test_file_libtiff.py::TestFileLibTiff::test_lzma
-	)
-
-	case ${ARCH} in
-		ppc)
-			EPYTEST_DESELECT+=(
-				# https://github.com/python-pillow/Pillow/issues/7008
-				# (we've reverted the upstream patch because it was worse
-				# than the original issue)
-				Tests/test_file_libtiff.py::TestFileLibTiff::test_exif_ifd
-			)
-			;;
-	esac
-
-	"${EPYTHON}" selftest.py --installed || die "selftest failed with ${EPYTHON}"
-	# leak tests are fragile and broken under xdist
-	# nonfatal implied by xvfb
-	nonfatal epytest -k "not leak" || die "Tests failed with ${EPYTHON}"
-}
-
-python_install() {
-	python_doheader src/libImaging/*.h
-	distutils-r1_python_install
-}
-
-python_install_all() {
-	if use examples ; then
-		docinto example
-		dodoc docs/example/*
-		docompress -x /usr/share/doc/${PF}/example
-	fi
-	distutils-r1_python_install_all
-}
diff --git a/dev-python/pillow/pillow-12.2.0.ebuild b/dev-python/pillow/pillow-12.2.0.ebuild
index f719348e01f5..3216b0048134 100644
--- a/dev-python/pillow/pillow-12.2.0.ebuild
+++ b/dev-python/pillow/pillow-12.2.0.ebuild
@@ -35,7 +35,7 @@ S=${WORKDIR}/${MY_P}
 
 LICENSE="HPND"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos"
 IUSE="avif examples imagequant +jpeg jpeg2k lcms test tiff tk truetype webp xcb zlib"
 REQUIRED_USE="test? ( jpeg jpeg2k lcms tiff truetype )"
 RESTRICT="!test? ( test )"
diff --git a/dev-python/pytest-subprocess/Manifest b/dev-python/pytest-subprocess/Manifest
index af73e1cf5922..4cf41d008399 100644
--- a/dev-python/pytest-subprocess/Manifest
+++ b/dev-python/pytest-subprocess/Manifest
@@ -1 +1,2 @@
 DIST pytest-subprocess-1.5.4.gh.tar.gz 39954 BLAKE2B 55998187a3492dd418d394ed373b29238ff26a2a82e806cf0833adf5d1ef9a8003f2f1677f916528ff414faba5ef6f739740c999f2784538717aca8563a5ad90 SHA512 c1f4e7ca0c318a47caf74886f7352983e5bc90b8d29d206649beb570e32da1cd48c94f435aee2e802c1b66f79548b1b3846fe573a8b1df28a082b3369b1f664d
+DIST pytest-subprocess-1.6.0.gh.tar.gz 43337 BLAKE2B 445941ff835134076ff937cde38d1c6df61ae74e5671d987db09596cae221d2b8760abeee0b16647ce44fb1613d919c7d077e76caafd4bcd98f1dfe366a76527 SHA512 5da3f4af4b9226d88af22532027b3746e4640583d60f5022a97ae58b69c41831e94518464a77821a9cb4add85b0a29c345bc1089c70452ecf65836c80cd6c809
diff --git a/dev-python/pytest-subprocess/pytest-subprocess-1.6.0.ebuild b/dev-python/pytest-subprocess/pytest-subprocess-1.6.0.ebuild
new file mode 100644
index 000000000000..e9dfe175fd3c
--- /dev/null
+++ b/dev-python/pytest-subprocess/pytest-subprocess-1.6.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2023-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="A plugin to fake subprocess for pytest"
+HOMEPAGE="
+	https://github.com/aklajnert/pytest-subprocess/
+	https://pypi.org/project/pytest-subprocess/
+"
+SRC_URI="
+	https://github.com/aklajnert/pytest-subprocess/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/pytest-4.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/anyio[${PYTHON_USEDEP}]
+		>=dev-python/docutils-0.12[${PYTHON_USEDEP}]
+		>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-asyncio-0.15.1[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGIN_LOAD_VIA_ENV=1
+EPYTEST_PLUGINS=( "${PN}" pytest-{asyncio,rerunfailures} )
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# broken in plain venv
+	# https://github.com/aklajnert/pytest-subprocess/issues/201
+	'tests/test_examples.py::test_documentation[README.rst]'
+)
diff --git a/dev-python/python-multipart/Manifest b/dev-python/python-multipart/Manifest
index f86e4bec4922..1431174764fa 100644
--- a/dev-python/python-multipart/Manifest
+++ b/dev-python/python-multipart/Manifest
@@ -1,2 +1,3 @@
 DIST python-multipart-0.0.25.gh.tar.gz 109366 BLAKE2B 73c80b51c5bb24b30e2afdc3896032b8b6bf58072bd7a7ae002fe068355faaee97db7af3ff28ac5ea238ed18392fb4dbc11bf6566f3a640425cdc0e05018dcc5 SHA512 eab6a101dce9bb374b974b2ce12f6cb5bd6035327d35c66bc7b478ce9d0c9c7dc87e06d52c6ebaebf9171e1e207de1aae7a901f812e7150b70bc3f6b65552bea
 DIST python-multipart-0.0.27.gh.tar.gz 111753 BLAKE2B 4fd4c14cd47d7d492edcb8ee88b78559f61ab109a92c8809430b5ae4c9b291dba48c9c8eb2a6db6deb0562249261cf319d93d4caf3ce2242f8c3eb72d2f6bf03 SHA512 75e85ed0d71ea526369e8010c92f6c0cb02f34df6064de98b2e984ffb927359ca32838eedacd1647bf2cf76a1dadb5b7026f51cacd6d0a561397a1f56d3f9f4f
+DIST python-multipart-0.0.28.gh.tar.gz 123332 BLAKE2B 6351341a5dd0eea431f84759c4fb17a2753ac2bab493ec0b0c9dd4205d99aae8f221cbb0f62aade67a4001a917b3c8032bc977ff4f5d9ad7dc4b57c6f18ac8fe SHA512 6631866906882fff1b44627e28d2d3f178b2bd569e1675b10f50ea673889bd93300958834ed8947092442b622d782754020669ec6ffee981bfedd96d1229428e
diff --git a/dev-python/python-multipart/python-multipart-0.0.28.ebuild b/dev-python/python-multipart/python-multipart-0.0.28.ebuild
new file mode 100644
index 000000000000..440ede195d00
--- /dev/null
+++ b/dev-python/python-multipart/python-multipart-0.0.28.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="A streaming multipart parser for Python"
+HOMEPAGE="
+	https://github.com/Kludex/python-multipart/
+	https://pypi.org/project/python-multipart/
+"
+SRC_URI="
+	https://github.com/Kludex/python-multipart/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# do not install the backwards compatibility package
+	# we're patching revdeps instead
+	rm -r multipart || die
+}
diff --git a/dev-python/python-tests/Manifest b/dev-python/python-tests/Manifest
index 957333288067..4790593b7ccd 100644
--- a/dev-python/python-tests/Manifest
+++ b/dev-python/python-tests/Manifest
@@ -6,6 +6,8 @@ DIST Python-3.13.13.tar.xz 22957612 BLAKE2B ea7761b9c47df08949798fb7b618ecc111f2
 DIST Python-3.13.13.tar.xz.asc 963 BLAKE2B d8f5d8bfc3e0e7140669f5478d846e5d6d2c44a805f6e44fcfa8fa1f72575771695719179a20c6e42994f27b144e9a61ba8d5fa25805f40fbcaf6421c322e81d SHA512 21e5235cd9a9df3546370feb55ac32539e08601b79ee7b1e39006028f192be6be0434f2f8384fdcc993b70bde7471be3b36ce9850abf0473d1fe2c7cdc98304b
 DIST Python-3.14.4.tar.xz 23855332 BLAKE2B cb96ace0b3a0316ffc8f2fca1e9b67dc8df7d9fe81c1daff1d8883634683703a0e458d6eea61f01b3641bb76997b9e39c939a0c8c28ce5edd7b166e41b2cc1f8 SHA512 89a7f8b8a31f48d150badb4751df137d47d9014c9c422649a1a55aef5618aa7f0259dd18c151e6804fa8312c6a21544332a9f630ee81150dc00505637e62bb8c
 DIST Python-3.14.4.tar.xz.sigstore 5219 BLAKE2B 5d4e076139082e525c2758a64ca2cc4c05c69e601ffc9c402d5a041f8b867ee5f37264ded3bfa014cc979ccd3c573c208d2321ac5a3be93b906116bd0d8a5c37 SHA512 ec41d0d25fa3cd87cf62adcbe6b9e575cecc49f947a64ca997aa792ed22d93ef1bbc4dc2848e365dfb43b6c447dcf47417f9c68a5881d0ede8750fece9f97a87
+DIST Python-3.14.5.tar.xz 23903332 BLAKE2B 1b26d61d320ec1b3681d739231bc0e016336ba565063dbf3b270368c08aaa870fb4e2c731c5460e840278293cc72fee5bac003dfc05a8bacb080f684dabcd677 SHA512 efbaf629703cd004f6b7bc75fb16df794185589adaf8807cd45928f212271045a399df3cd9573e47c8708fb5c5002f9d4efe4e41dde4313b81a3e9d73158769f
+DIST Python-3.14.5.tar.xz.sigstore 5411 BLAKE2B e0fb33b98c39b6759f6bfa99ea44dd93cc92dcc8a897a0faef318b1ba4a3b285a7cfe725076cc3f355e1b627c85b41e9e71579fee97b7e61fc6c79780e9d8d10 SHA512 459f6d648fde31e55a4d53d6a9e878e3d2361c33c9ce0d7e2e2b8f8df81325bb7d0764742364745c448a1102f5b3873d9ae3634bf1a8f88bbc8b12fe2ac6acd8
 DIST Python-3.14.5rc1.tar.xz 23894408 BLAKE2B 7b894cc9fbc6df9255ad04aed506cc7751a8f59295a1d491e150731b34b2197802f3d12cc51c6412247c5a23c051f3f90ce69b969e0bc0a74cffb11e62de58e9 SHA512 67ede84d59046e3b413643449a7eced8cefcd908238b8a34d2ac38507d967201695c62c22464f1bfd51669daf306995262279c7bbfc5a25998ed867a3d743b38
 DIST Python-3.14.5rc1.tar.xz.sigstore 5363 BLAKE2B ad8ed1f9076ce67c33b290cdb6e24846de1642ce2deece0ec42d8adca67e7b403a53f7d64064c8c9d6d7ce05f8f1a62f5069a2cc85721160902b98cfebd254f9 SHA512 26a9129b8df1d5b83f6d81bdc49c78a5f45542ff9e56a3ecfc5b9480b5a0e0ee44b2fd3d1dd7775458c9076b4b27d891f149f3b24304f2456b5a0c5615e6ea12
 DIST Python-3.15.0b1.tar.xz 35178032 BLAKE2B 1bbfdeb373fa3a26b9d957084edc9bfb7f81ae579cd9bf9fba1a43a3bf409a2e01512c56c642eb47b6e1a3c0fe44f182d72a15498b90a75d424b6325d0fd97a1 SHA512 ce486f903aa8690f1725565c3fdc0034a983a60952a96a950fa7c89ab899a71cabed4a9252c497e0474f206f83ff02e2793cf975c345825324b85bced750c270
@@ -18,5 +20,6 @@ DIST python-gentoo-patches-3.13.13_p1.tar.xz 9920 BLAKE2B 81ecba755005b288fcbd8f
 DIST python-gentoo-patches-3.13.3.tar.xz 8336 BLAKE2B 66393886fbd034eb14732e4f81f5798e77650ea3fe1c4f8176bd93808b711c8977a53c3f52be6c9b97a368299258b851d9bdb6d4c8e0c75695c6aea784d48b44 SHA512 c1ed31d6aaef81addf786c2ccc1013309b122b791c42fe10e467a677d0db8f149e8b1cc21928c146298918c7ceb851b4b19d1e59f491cb161004e1c9386db289
 DIST python-gentoo-patches-3.14.0b1.tar.xz 5680 BLAKE2B 514b3edc3025e5bf675d371b5ada17dea426856edf1fb6095c2ee400eae95bd4265ef81fe593ae9338e801e7d0a25b1d5ba2d05ca563fd9dd020114b13575746 SHA512 74289e42cf532b54bb1b66a283ec19156f8a36ba38764209c133842314c9efb2ce2ebcba5aa9213bcf7fc0c8a5ca9b6e7adbd5dbfa4397233136d7cd55f53ee7
 DIST python-gentoo-patches-3.14.4_p1.tar.xz 9016 BLAKE2B 39bee4db44684a087b3bf6793a22d1655c2a90fabb56ea0421ded013cf53e66ac83cb3016d469f06c5d7cab7b8d22138bc4c1e01843a174299e1af0f88e5818c SHA512 a299212bd3d4a70c83a1efe1ec155f7b13829aa10aecf638de0889cf7b8ebe5227d3f14a1d51dac18fa4ae19b1060639490e61f2c1f52deadd40065c07b317f2
+DIST python-gentoo-patches-3.14.5.tar.xz 10308 BLAKE2B 1ce7b8f33d15d27805894a6f3614fbcf280639fa84bb3605c1a1ee596282235f79ba2399b5d2385a06b0b36c8a6bf162ae4e1b15a67612bdca67f48e06a2fae2 SHA512 f2a806bf753e696a0b7474fd0f11c0f5d9a8043f72f478a37a79f7a9ec843cb31cc959aa3fc38670c1a8ac012554a7d3d4899d7e615cee70e21a7dd7afc2da9a
 DIST python-gentoo-patches-3.14.5rc1.tar.xz 8436 BLAKE2B 527156383cba6288df15a0bb0718960ba2a30428a2367d014a11b22e598c63d2c912480e37b064233e05590d1112b6c3c4ac1fa9db392ac11a98b8ec54847d30 SHA512 8adb64ca0bc1c653fb04a71bd6b40415ae3ca4761edf578199c5cc1d1da392b239ca07af395114970467c8233027c5eefb4b869bcab4379d5a7310a286aaec53
 DIST python-gentoo-patches-3.15.0b1.tar.xz 3420 BLAKE2B 266ada600b587ff430a21c38d7585fcdb2d320a4160dd8e93dac3a6517faa685eadda9a9b14b271c6380a78112c83f39fc30bbbece10bfc7e6cde2eba61103fa SHA512 9f42700e03051fbadf3b9e6f7163077ab6b8c1f406e5bfc99560b590dbbabe72e5b38cd8c16b21aec75c4e760af549bffef6d76e65f390d61cd8840894949565
diff --git a/dev-python/python-tests/python-tests-0.3.14.5.ebuild b/dev-python/python-tests/python-tests-0.3.14.5.ebuild
new file mode 100644
index 000000000000..c36baf7f1122
--- /dev/null
+++ b/dev-python/python-tests/python-tests-0.3.14.5.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2024-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..14} )
+VERIFY_SIG_METHOD=sigstore
+
+inherit python-r1 verify-sig
+
+REAL_PV=${PV#0.}
+MY_PV=${REAL_PV/_/}
+MY_P="Python-${MY_PV%_p*}"
+PYVER=$(ver_cut 2-3)t
+PATCHSET="python-gentoo-patches-${MY_PV}"
+
+DESCRIPTION="Test modules from dev-lang/python"
+HOMEPAGE="
+	https://www.python.org/
+	https://github.com/python/cpython/
+"
+SRC_URI="
+	https://www.python.org/ftp/python/${REAL_PV%%_*}/${MY_P}.tar.xz
+	https://distfiles.gentoo.org/pub/proj/python/patchsets/${PYVER%t}/${PATCHSET}.tar.xz
+	verify-sig? (
+		https://www.python.org/ftp/python/${REAL_PV%%_*}/${MY_P}.tar.xz.sigstore
+	)
+"
+S="${WORKDIR}/${MY_P}/Lib"
+
+LICENSE="PSF-2"
+SLOT="${PYVER}"
+if [[ ${PV} != *_rc* ]]; then
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+# enable by default to help CI handle it (we have no additional deps)
+IUSE="+python_targets_${PYTHON_COMPAT[0]}"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	~dev-lang/python-${PV}:${PYVER}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+"
+
+# https://www.python.org/downloads/metadata/sigstore/
+VERIFY_SIG_CERT_IDENTITY=hugo@python.org
+VERIFY_SIG_CERT_OIDC_ISSUER=https://github.com/login/oauth
+
+src_unpack() {
+	if use verify-sig; then
+		verify-sig_verify_detached "${DISTDIR}"/${MY_P}.tar.xz{,.sigstore}
+	fi
+	default
+}
+
+src_prepare() {
+	local PATCHES=(
+		"${WORKDIR}/${PATCHSET}"
+	)
+
+	cd .. || die
+	default
+}
+
+src_install() {
+	python_setup
+	# keep in sync with TESTSUBDIRS in Makefile.pre.in
+	python_moduleinto "/usr/lib/python${PYVER}"
+	python_domodule test
+	python_moduleinto "/usr/lib/python${PYVER}/idlelib"
+	python_domodule idlelib/idle_test
+}
diff --git a/dev-python/python-tests/python-tests-3.14.5.ebuild b/dev-python/python-tests/python-tests-3.14.5.ebuild
new file mode 100644
index 000000000000..47d65c6347a8
--- /dev/null
+++ b/dev-python/python-tests/python-tests-3.14.5.ebuild
@@ -0,0 +1,74 @@
+# Copyright 2024-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..14} )
+VERIFY_SIG_METHOD=sigstore
+
+inherit python-r1 verify-sig
+
+MY_PV=${PV/_/}
+MY_P="Python-${MY_PV%_p*}"
+PYVER=$(ver_cut 1-2)
+PATCHSET="python-gentoo-patches-${MY_PV}"
+
+DESCRIPTION="Test modules from dev-lang/python"
+HOMEPAGE="
+	https://www.python.org/
+	https://github.com/python/cpython/
+"
+SRC_URI="
+	https://www.python.org/ftp/python/${PV%%_*}/${MY_P}.tar.xz
+	https://distfiles.gentoo.org/pub/proj/python/patchsets/${PYVER%t}/${PATCHSET}.tar.xz
+	verify-sig? (
+		https://www.python.org/ftp/python/${PV%%_*}/${MY_P}.tar.xz.sigstore
+	)
+"
+S="${WORKDIR}/${MY_P}/Lib"
+
+LICENSE="PSF-2"
+SLOT="${PYVER}"
+if [[ ${PV} != *_rc* ]]; then
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+# enable by default to help CI handle it (we have no additional deps)
+IUSE="+python_targets_${PYTHON_COMPAT[0]}"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	~dev-lang/python-${PV}:${PYVER}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+"
+
+# https://www.python.org/downloads/metadata/sigstore/
+VERIFY_SIG_CERT_IDENTITY=hugo@python.org
+VERIFY_SIG_CERT_OIDC_ISSUER=https://github.com/login/oauth
+
+src_unpack() {
+	if use verify-sig; then
+		verify-sig_verify_detached "${DISTDIR}"/${MY_P}.tar.xz{,.sigstore}
+	fi
+	default
+}
+
+src_prepare() {
+	local PATCHES=(
+		"${WORKDIR}/${PATCHSET}"
+	)
+
+	cd .. || die
+	default
+}
+
+src_install() {
+	python_setup
+	# keep in sync with TESTSUBDIRS in Makefile.pre.in
+	python_moduleinto "/usr/lib/python${PYVER}"
+	python_domodule test
+	python_moduleinto "/usr/lib/python${PYVER}/idlelib"
+	python_domodule idlelib/idle_test
+}
diff --git a/dev-python/textile/Manifest b/dev-python/textile/Manifest
index dc830c17bce3..1493b0a27f8e 100644
--- a/dev-python/textile/Manifest
+++ b/dev-python/textile/Manifest
@@ -1 +1,2 @@
 DIST python-textile-4.0.3.gh.tar.gz 53228 BLAKE2B f72e3aa58afc3509c4e430a54e6099758655d62dd3274af457c45cd752281e1836aded117496ba6b8d154867f4bf30770156110eabd607d6edcec978ded5e0e4 SHA512 796e8bffe0e5d1d477bb7ea9ef48b5ac19f870d63ea8f895973b2d895475317fec8d888557f586807541601bd97550e5bc2297f5cfefa3031a53ffd3e0bade00
+DIST python-textile-4.0.4.gh.tar.gz 53418 BLAKE2B e779b0bf013ab2c2e71c0795dfce0695df6d991545fcc93f0a7b4acdb69ddcb157405e6660748613e890902755dbb6ec4406257c39667d458f7b7c97b0d3bae5 SHA512 7724977343b33b5569feb667977f0e677985c9415cd8defe41103458f33219342b62651b8471a7e20d48498f03063a55e7d212c7a58578356d38553f6f781e9d
diff --git a/dev-python/textile/textile-4.0.4.ebuild b/dev-python/textile/textile-4.0.4.ebuild
new file mode 100644
index 000000000000..f722261a27d7
--- /dev/null
+++ b/dev-python/textile/textile-4.0.4.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1
+
+MY_P="python-textile-${PV}"
+DESCRIPTION="A Python port of Textile, A humane web text generator"
+HOMEPAGE="
+	https://github.com/textile/python-textile/
+	https://pypi.org/project/textile/
+"
+SRC_URI="
+	https://github.com/textile/python-textile/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	dev-python/nh3[${PYTHON_USEDEP}]
+	dev-python/regex[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# tests that need network access
+		tests/test_getimagesize.py
+		tests/test_imagesize.py
+		tests/test_textile.py
+	)
+	epytest -o addopts=
+}
diff --git a/dev-python/tomlkit/Manifest b/dev-python/tomlkit/Manifest
index d47fe946da61..e0bdaff83f44 100644
--- a/dev-python/tomlkit/Manifest
+++ b/dev-python/tomlkit/Manifest
@@ -1 +1,2 @@
 DIST tomlkit-0.14.0.tar.gz 187167 BLAKE2B d416ae531829d6904c6ee463091f4ed38e647f5af27c0a395f151978e2816d0399cd2de2e5fb4972197d4e22a31d460efb3f2ee0a5cb4229d502dfdf8d451995 SHA512 0abdf1a57c90895e1dd3972d18d2b9cd24fac12d7e59b26a8a88784695403b990598ebe806a232fefc0d769a0f606bcdcf78930a19f91935c0c0165512238d8d
+DIST tomlkit-0.15.0.tar.gz 161875 BLAKE2B b3a6086665fd7ba5edc29c910ff762c2bf516a5604ba7efedfff9b886a5122d2dc9bb5c7aa9832f40fa3e98be32ce85d4d92ef2a15f7cc6193ce491286e859b8 SHA512 dfb7dbb44243f13e01c0b66aa9e0a49edba8c4d8cf720bc81b2faa30877599f465ba38e9235a0b4323100c4efd82d78659b25cf15b345ce5fc5376c3695b73e4
diff --git a/dev-python/tomlkit/tomlkit-0.15.0.ebuild b/dev-python/tomlkit/tomlkit-0.15.0.ebuild
new file mode 100644
index 000000000000..21b4eca763bf
--- /dev/null
+++ b/dev-python/tomlkit/tomlkit-0.15.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Style preserving TOML library"
+HOMEPAGE="
+	https://github.com/python-poetry/tomlkit/
+	https://pypi.org/project/tomlkit/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_configure() {
+	grep -q 'build-backend = "poetry' pyproject.toml ||
+		die "Upstream changed build-backend, recheck"
+	# write a custom pyproject.toml to ease setuptools bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "tomlkit"
+		version = "${PV}"
+		description = "Style preserving TOML library"
+	EOF
+
+	# some brilliant idea about forcing 1970 dates in sdist
+	# which are older than what zip can handle...
+	find -exec touch {} + || die
+}
diff --git a/dev-python/uv-build/Manifest b/dev-python/uv-build/Manifest
index c637ae3275a3..bcf5ef967cd5 100644
--- a/dev-python/uv-build/Manifest
+++ b/dev-python/uv-build/Manifest
@@ -1,6 +1,7 @@
 DIST uv_build-0.11.10.tar.gz 376745 BLAKE2B 8447c14db66981f9188336dc1d8b7918784f2cfbdd2ddeed3d66f5cdc7a1d521f49082c68d5c48d5fbee87b8f4bdc39cb259353f99d63f6e77d2eed02c292e7c SHA512 ab1e10e9c23bfd90ef12a274695076a2e9756da3b13b062a9f4ab073fc8789a2faee3a8b87af1abeb071de84f245a26ebf896b31825b753acdd32ba74df6f1d0
 DIST uv_build-0.11.11.tar.gz 376722 BLAKE2B 58e62e3366961b489f1f6e1e8c83d0b770879660d9d3b0c6266dce46c5da8e9887408b09f0f59fd3fecda30adf887012df6390f386fb22843c0bb66e3c813a97 SHA512 ed612caee074c756c8ab242e3e0bf64e76dfddfefa383c3587b675b07e61621504ccaea653733c27ef2dd9b8bef1aa6d21ba1b9b39102d49c9ec3e9d7d13e758
 DIST uv_build-0.11.12.tar.gz 377487 BLAKE2B f9d4c1b53f9c4ff2209f2b96a581f01f0a363fa02c6724e3d4f1d10ac3dd8447eb15d2aaac2a2fafe3d8a3fe20bf37a0b65c2e24f771d7f163a09f34a0151d51 SHA512 99747e605f984fb8b9b8d9b68a987cf20f49cec24cb57f795ef393268246366befb390398ca8d447f1178b8ad307376a2dbb62d083b8e987c0d2d5ab8116a6b3
+DIST uv_build-0.11.13.tar.gz 377955 BLAKE2B 01f93cb472a2841dd2c516b9a02137fafcf081a3102a45a2ff03b92d4dde9c7a3fc0bc012ca1871a51ac9832f2ba9c9d7f51f0705eec2d239d50cd3c8948dca1 SHA512 d6e2986b16d0dc78a9e03261d70a847186672fbc737be54d6263c2b7992d39561817c2e97e2cd82d64349ed402bbc8b907bd9782ff104988fba9f32504dc9d51
 DIST uv_build-0.11.6.tar.gz 361928 BLAKE2B 800f59a32bab5b850fb30627b6e47c4a2e7bd8d1a292584e2c3b33e2c3aee81907b8e6ebe95298bac607df161e29437cc8a84bb8a44e32435028ab5fd3bf22af SHA512 8a9fc7cca9e42f42db888b6a9f3888393feae79d0ce8ca56568c83cbee977675d8a39a38b820606d1ac685ef99b92a182795c2521f4796865acd774fd73c6bac
 DIST uv_build-0.11.7.tar.gz 365752 BLAKE2B 2de7a3656ea9960d2959a6bde66b85979b56e1cedce5ccc38759dae6a165d1d79998bcab3f43e472d91281fe320aadbb00f765776da3f06902b6a81b37d8b0aa SHA512 5ef23796480d36b20d1ca1b5c22eeb86c6634acbe9eb62642044d6c34a8dc45ca59727a77793fa324dbc3656a3659521544387d8afa346879675ff09fef1ca62
 DIST uv_build-0.11.8.tar.gz 367238 BLAKE2B 04dfc0cec62b53554b5041f77f0c34794ed2b9890449406af7011182acc23aab77bc087cdfcaf3d360a85169a51c998b4e7c0ddbdda1bdad4f487078226c6890 SHA512 67a5931ba6557c12e1fc668b061c5cfaefea7275fbeac4e658b6e37a748fb67b452b694960cec9bea97bcc4da43e24566a6adfec001057be478d8056894f54a5
diff --git a/dev-python/uv-build/uv-build-0.11.13.ebuild b/dev-python/uv-build/uv-build-0.11.13.ebuild
new file mode 100644
index 000000000000..2ab229426f84
--- /dev/null
+++ b/dev-python/uv-build/uv-build-0.11.13.ebuild
@@ -0,0 +1,99 @@
+# Copyright 2025-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Maturin compiles uv-build executable for every impl, we do not want
+# that, so we use another backend.  And since we use another backend,
+# why not dogfood it in the first place?
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="PEP517 uv build backend"
+HOMEPAGE="
+	https://github.com/astral-sh/uv/
+	https://pypi.org/project/uv-build/
+"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/uv-${PV}
+"
+BDEPEND="
+	test? (
+		app-arch/unzip
+		dev-python/build[${PYTHON_USEDEP}]
+	)
+"
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# use the executable from dev-python/uv instead of building
+	# a largely overlapping uv-build executable (at least for now)
+	sed -i -e '/USE_UV_EXECUTABLE/s:False:True:' python/uv_build/__init__.py || die
+
+	# replace the build-system section
+	sed -i -e '/\[build-system\]/,$d' pyproject.toml || die
+	cat >> pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["uv_build<9999"]
+		build-backend = "uv_build"
+		backend-path = ["src"]
+	EOF
+
+	# rename to make uv-build find it
+	mv python src || die
+}
+
+python_test() {
+	"${EPYTHON}" -m build -n || die "Self-build failed with ${EPYTHON}"
+
+	local zip_result=$(
+		unzip -t "dist/uv_build-${PV}-py3-none-any.whl" || die
+	)
+	local zip_expected="\
+Archive:  dist/uv_build-${PV}-py3-none-any.whl
+    testing: uv_build/                OK
+    testing: uv_build/__init__.py     OK
+    testing: uv_build/__main__.py     OK
+    testing: uv_build/py.typed        OK
+    testing: uv_build-${PV}.dist-info/   OK
+    testing: uv_build-${PV}.dist-info/WHEEL   OK
+    testing: uv_build-${PV}.dist-info/METADATA   OK
+    testing: uv_build-${PV}.dist-info/RECORD   OK
+No errors detected in compressed data of dist/uv_build-${PV}-py3-none-any.whl.\
+"
+	if [[ ${zip_result} != ${zip_expected} ]]; then
+		eerror ".zip result:\n${zip_result}"
+		eerror ".zip expected:\n${zip_expected}"
+		die ".whl result mismatch"
+	fi
+
+	local tar_result=$(
+		tar -tf "dist/uv_build-${PV}.tar.gz" || die
+	)
+	local tar_expected="\
+uv_build-${PV}/PKG-INFO
+uv_build-${PV}/
+uv_build-${PV}/README.md
+uv_build-${PV}/pyproject.toml
+uv_build-${PV}/src
+uv_build-${PV}/src/uv_build
+uv_build-${PV}/src/uv_build/__init__.py
+uv_build-${PV}/src/uv_build/__main__.py
+uv_build-${PV}/src/uv_build/py.typed\
+"
+	if [[ ${tar_result} != ${tar_expected} ]]; then
+		eerror ".tar.gz result:\n${tar_result}"
+		eerror ".tar.gz expected:\n${tar_expected}"
+		die ".tar.gz result mismatch"
+	fi
+}
diff --git a/dev-python/uv/Manifest b/dev-python/uv/Manifest
index 7ae6ce25a675..bbb47d9048f7 100644
--- a/dev-python/uv/Manifest
+++ b/dev-python/uv/Manifest
@@ -4,6 +4,8 @@ DIST uv-0.11.11-crates.tar.xz 46797580 BLAKE2B 69c193a4d0d8b81b7ee504ad4439c3647
 DIST uv-0.11.11.gh.tar.gz 5253331 BLAKE2B 4a866f3838bd60630e3ff47ea8e6c754fd986aa242bc9c355f071bed321385d9ef6049a7663777027d49b9fbd80cf0793b2ab0271500d7305873574332b5a48e SHA512 f9129868fb8d343d63e4080deb0e71e71fdb5c71e2ea4f17d05d0f0c20338daf86f521895e8bd69795ffad36ddc94e8cf5ee8fbbb4eb5fdc0692524b21eef9c6
 DIST uv-0.11.12-crates.tar.xz 46797580 BLAKE2B 69c193a4d0d8b81b7ee504ad4439c36474b4bbfd91387b29a498f5cdc1529b3d52d0bbd2249e1ec4163914f63b4c139f68762396ed61e3480e5a813089277d59 SHA512 dbde92b55820f8b507f2c87d35917cf9e43da9add81046c2715a8e542e2d88d5916d90e7c07e9d1dc8331ca7b098e38cc5bcbac0ef66ceb81c5a68d9146bb35b
 DIST uv-0.11.12.gh.tar.gz 5259600 BLAKE2B bf43a4b38e37a45d73820e3d445ac38a56314cefcdc0a734cad5b93200ce9e4b689c8aa3125eb34d8aa150ff4b2b94b786dd518a49aacf6d6ce655f66e9506f9 SHA512 a23c95152f0515645174b85ed8887fe29e3e56d457aaad7992cfe5a59b95e527348ebd7e0ce9d23cf589f20849326a876ae61ed9b10324a48b8021077cd264fe
+DIST uv-0.11.13-crates.tar.xz 46795796 BLAKE2B d087b947c1c673bffb4095ba3ccdd24251a91e382d702511665af5b4d8a38acc3ebd386405a2f98c256524f71d71ad859aead336d3db73d46ae6ca59dc182d81 SHA512 879dc13c29323b7cc7b84331cab40f6ac0519e564024c2ce9e07df2be5d79be0d3ba6615a98bfba976bd108aedae5953997cc86c94c9907ecb16f8b97e7b891f
+DIST uv-0.11.13.gh.tar.gz 5260441 BLAKE2B 36ac78b2857d39b5dc6e24617ed44a0526039723bb5c078713536156524709bca4a8b82f6a9fefa1d66b3e08d6f5c7d2a16ab17c5266d18518e68e3583bd48d0 SHA512 04c6451c1250bf997cd412906d09195234513a160694e31f1dce5dbd04184dfed3307a27948fc32656050cc0d089f05d3f80e31b2ce942e1e93a6de032f90e42
 DIST uv-0.11.6-crates.tar.xz 46830584 BLAKE2B 6fbf2c9aa231588833e5cce30da2a9238af8bd22fd849cf45c3ffab52b405bcd6c5b488a9cc6975e09781ce379405c6323d7cb3c330243ae5a7b53efb775d06e SHA512 243e69e5512d09a48d47c76f100dae390e2ea9de51eb4671a9bc84a8fcbbdafe96832b6afc7222185f09f1c11c5aa6a32be9185f723b7dc67e13a94205f759d2
 DIST uv-0.11.6.gh.tar.gz 5211342 BLAKE2B 43b6cf60e3a97e70c847878e36d5ae854e7458922121b4b85a9d61d48a1e740c47c408600c92458e4a89d69308fef4833da41b2dd0ad5dbb6ac94b5d2e48c549 SHA512 3f370f98b253dd84706f1724155ba4ed5cafb41b612fa75151aef26dd4f18c85f59d93c5bbddae1c59ea594fdc88857d005b6e8728cdd24f5b37b99ba4ef32cd
 DIST uv-0.11.7-crates.tar.xz 46854096 BLAKE2B b4fc06608d3c68910a48af598803b934017787bbf14599f66fa43096aa3ef2cdeca8ee35230ea3b8446da044a29f0b476f58f224732959e8017720e79a0d7cd8 SHA512 9cdcc1f565a3bf4d3490296710a7821e3760164d723057d591bf923e093aac50f51ad209ceed6f8c4e8fd2104ee90363750017bb56de2c76fca5dda7fcee815b
diff --git a/dev-python/uv/uv-0.11.13.ebuild b/dev-python/uv/uv-0.11.13.ebuild
new file mode 100644
index 000000000000..030c2e92591f
--- /dev/null
+++ b/dev-python/uv/uv-0.11.13.ebuild
@@ -0,0 +1,164 @@
+# Copyright 2024-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES="
+"
+RUST_MIN_VER="1.93.0"
+
+inherit cargo check-reqs
+
+CRATE_PV=${PV}
+DESCRIPTION="A Python package installer and resolver, written in Rust"
+HOMEPAGE="
+	https://github.com/astral-sh/uv/
+	https://pypi.org/project/uv/
+"
+# pypi sdist misses scripts/, needed for tests
+SRC_URI="
+	https://github.com/astral-sh/uv/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	${CARGO_CRATE_URIS}
+"
+if [[ ${PKGBUMPING} != ${PVR} ]]; then
+	SRC_URI+="
+		https://github.com/gentoo-crate-dist/uv/releases/download/${CRATE_PV}/uv-${CRATE_PV}-crates.tar.xz
+	"
+fi
+
+# most of the code
+LICENSE="|| ( Apache-2.0 MIT )"
+# crates/pep508-rs is || ( Apache-2.0 BSD-2 ) which is covered below
+# Dependent crate licenses
+LICENSE+="
+	0BSD Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD CC0-1.0
+	CDLA-Permissive-2.0 ISC MIT MPL-2.0 Unicode-3.0 Unicode-DFS-2016
+	ZLIB BZIP2
+"
+# ring crate
+LICENSE+=" openssl"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~x86"
+IUSE="test"
+RESTRICT="test"
+PROPERTIES="test_network"
+
+DEPEND="
+	app-arch/bzip2:=
+	app-arch/xz-utils:=
+	app-arch/zstd:=
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		dev-lang/python:3.9
+		dev-lang/python:3.10
+		dev-lang/python:3.11
+		dev-lang/python:3.12
+		dev-lang/python:3.13
+		!!~dev-python/uv-0.5.0
+	)
+"
+
+QA_FLAGS_IGNORED="usr/bin/.*"
+
+check_space() {
+	local CHECKREQS_DISK_BUILD=3G
+	use debug && CHECKREQS_DISK_BUILD=9G
+	check-reqs_pkg_setup
+}
+
+pkg_pretend() {
+	check_space
+}
+
+pkg_setup() {
+	check_space
+	rust_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# force thin lto, makes build much faster and less memory hungry
+	# (i.e. makes it possible to actually build uv on 32-bit PPC)
+	sed -i -e '/lto/s:fat:thin:' Cargo.toml || die
+
+	# enable system libraries where supported
+	export ZSTD_SYS_USE_PKG_CONFIG=1
+	# TODO: unbundle libz-ng-sys, tikv-jemalloc-sys?
+
+	# remove unbundled sources, just in case
+	find "${ECARGO_VENDOR}"/{bzip2,lzma,zstd}-sys-*/ -name '*.c' -delete || die
+
+	# bzip2-sys requires a pkg-config file
+	# https://github.com/alexcrichton/bzip2-rs/issues/104
+	mkdir "${T}/pkg-config" || die
+	export PKG_CONFIG_PATH=${T}/pkg-config${PKG_CONFIG_PATH+:${PKG_CONFIG_PATH}}
+	cat >> "${T}/pkg-config/bzip2.pc" <<-EOF || die
+		Name: bzip2
+		Version: 9999
+		Description:
+		Libs: -lbz2
+	EOF
+
+	# uv is now forcing bundled liblzma, sigh
+	sed -i -e '/xz/s:"static"::' Cargo.toml || die
+}
+
+src_configure() {
+	local myfeatures=(
+		test-git
+		test-pypi
+		test-python
+	)
+
+	cargo_src_configure --no-default-features
+}
+
+src_compile() {
+	cd crates/uv || die
+	cargo_src_compile
+}
+
+src_test() {
+	cd crates/uv || die
+	cargo_src_test --no-fail-fast
+}
+
+src_install() {
+	cd crates/uv || die
+	cargo_src_install
+
+	insinto /etc/xdg/uv
+	newins - uv.toml <<-EOF || die
+		# These defaults match Fedora, see:
+		# https://src.fedoraproject.org/rpms/uv/pull-request/18
+
+		# By default ("automatic"), uv downloads missing Python versions
+		# automatically and keeps them in the user's home directory.
+		# Disable that to make downloading opt-in, and especially
+		# to avoid unnecessarily fetching custom Python when the distro
+		# package would be preferable.  Python builds can still be
+		# downloaded manually via "uv python install".
+		#
+		# https://docs.astral.sh/uv/reference/settings/#python-downloads
+		python-downloads = "manual"
+
+		# By default ("managed"), uv always prefers self-installed
+		# Python versions over the system Python, independently
+		# of versions.  Since we generally expect users to use that
+		# to install old Python versions not in ::gentoo anymore,
+		# this effectively means that uv would end up preferring very
+		# old Python versions over the newer ones that are provided
+		# by the system.  Default to using the system versions to avoid
+		# this counter-intuitive behavior.
+		#
+		# https://docs.astral.sh/uv/reference/settings/#python-preference
+		python-preference = "system"
+	EOF
+}
author	Liguros - Gitlab CI/CD [develop] <gitlab@liguros.net>	2026-05-11 16:19:27 +0000
committer	Liguros - Gitlab CI/CD [develop] <gitlab@liguros.net>	2026-05-11 16:19:27 +0000
commit	4912a64be738d6ead0cc7a8288de50714c68c0bf (patch)
tree	fbce5346cff87cfba39f064f7422328ef4ccae74 /dev-python
parent	448fc515bcf8058695b0a67d165cfc29f80cc36b (diff)
download	baldeagleos-repo-4912a64be738d6ead0cc7a8288de50714c68c0bf.tar.gz baldeagleos-repo-4912a64be738d6ead0cc7a8288de50714c68c0bf.tar.xz baldeagleos-repo-4912a64be738d6ead0cc7a8288de50714c68c0bf.zip