Adding metadata

17 files changed, 321 insertions, 5 deletions

diff --git a/dev-python/cliff/cliff-3.9.0.ebuild b/dev-python/cliff/cliff-3.9.0.ebuild
index bcc45d54c2b4..7172b53984ad 100644
--- a/dev-python/cliff/cliff-3.9.0.ebuild
+++ b/dev-python/cliff/cliff-3.9.0.ebuild
@@ -28,8 +28,7 @@ RDEPEND="
 	>=dev-python/pyyaml-3.12.0[${PYTHON_USEDEP}]
 "
 BDEPEND="
-	>=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
-	!~dev-python/pbr-2.1.0
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
 	dev-python/setuptools[${PYTHON_USEDEP}]
 	test? (
 		dev-python/sphinx[${PYTHON_USEDEP}]
diff --git a/dev-python/debtcollector/Manifest b/dev-python/debtcollector/Manifest
index dbd8f1273768..8e0c7c06dc30 100644
--- a/dev-python/debtcollector/Manifest
+++ b/dev-python/debtcollector/Manifest
@@ -1 +1,2 @@
 DIST debtcollector-2.2.0.tar.gz 28833 BLAKE2B 33361daaba12c52a1cc0bac168199ef3dbb959279def29ef782fa421f0aa106038de02217f6321c64e02845abd0573e69f5638b384411e7fbfd194dd3f6b3356 SHA512 6e5fdf38a25406a7a56d18e9b900471e3e4ce513ef62619c9eafa153ea08ff6b4b9bd90c524cfa16e04ff0c9c324e90d4fdd75212fced0b202245cdddae02137
+DIST debtcollector-2.3.0.tar.gz 31537 BLAKE2B 6c4993edf08dd72e8378bd82e4578a491f0540d35165e3c67e918ef5a659de06e4fd83d2737458cddd27ef08dfd01a38679b940e80a4b460e145ab20789940e5 SHA512 d8a9a65ec33bf6bc777d6766842cd6351c265752f552bda3bfd1db86a08c8c89c3f871c6eff15648a8c1a79d7820368711256d404934fd826ee6cb0c7c53f77a
diff --git a/dev-python/debtcollector/debtcollector-2.3.0.ebuild b/dev-python/debtcollector/debtcollector-2.3.0.ebuild
new file mode 100644
index 000000000000..8561a8f73d2d
--- /dev/null
+++ b/dev-python/debtcollector/debtcollector-2.3.0.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Python deprecation patterns and strategies that collect technical debt"
+HOMEPAGE="https://www.openstack.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/wrapt-1.7.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/subunit[${PYTHON_USEDEP}]
+		dev-python/testtools[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
diff --git a/dev-python/nltk/Manifest b/dev-python/nltk/Manifest
index 413360346483..f141c1cf54d8 100644
--- a/dev-python/nltk/Manifest
+++ b/dev-python/nltk/Manifest
@@ -1,2 +1,3 @@
 DIST nltk-3.6.2.tar.gz 2819833 BLAKE2B 9796822c35c524432e9790d0890b4388fbaa85b659e5415037422a22e8edbaf20775196b4416f441d62592b387066de9f7741b988c0d463349fc5c906bfd75b2 SHA512 3fd2cba52377613f35f6574f859482de987f969cfc8d4243a859be365ab1bd8300f9013dcedc6caeff7aa7fc035b331a47b557027209ca9a85b0cc7fbde44d6d
 DIST nltk-3.6.3.tar.gz 2824924 BLAKE2B fcab6647f43f4bf139857e9f4202aee688f564851976ed6a183e47361451fae771318346724e41f198b82cebdd5a47f151aaf932099143ef6faa2a77430fbfb4 SHA512 fe7244967df018670501304d1a8aa50a0f4d42bb0c73cc5e202eeab6a0f5da1eaed9b961f6026e3b8ae4b0393d788bcb58b263ba22a3ce6f5644022736035f98
+DIST nltk-3.6.4.tar.gz 2828051 BLAKE2B f757c9c6d0b5ab6105e90e1a46fc6671d5f661f9b1b58026ccb43c00ff4969a98cbc2005670e0a81218ef4d18e45c37bb380c53be4ca60984344b11a0c8dbc54 SHA512 ba9acaa596c7f9246cd2f8da37b58146021dc2c246306fab68a37ef833a5a346b1aa7033d43b9e72b52aeda1cf8e303c7c690d1ca439f6f58dc673aa63a37298
diff --git a/dev-python/nltk/nltk-3.6.4.ebuild b/dev-python/nltk/nltk-3.6.4.ebuild
new file mode 100644
index 000000000000..9e7544cd8650
--- /dev/null
+++ b/dev-python/nltk/nltk-3.6.4.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="sqlite,tk?,xml(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Natural Language Toolkit"
+HOMEPAGE="https://www.nltk.org/ https://github.com/nltk/nltk/"
+SRC_URI="https://github.com/nltk/nltk/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
+IUSE="tk"
+
+RDEPEND="
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/joblib[${PYTHON_USEDEP}]
+	dev-python/regex[${PYTHON_USEDEP}]
+	dev-python/tqdm[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/joblib[${PYTHON_USEDEP}]
+		>=dev-python/nltk-data-20200312-r1
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pyparsing[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/twython[${PYTHON_USEDEP}]
+		sci-libs/scikit-learn[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	)"
+PDEPEND="dev-python/nltk-data"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# requires unpackaged pycrfsuite
+	sed -i -e '/>>>/s@$@ # doctest: +SKIP@' nltk/tag/crf.py || die
+	# replace fetching from network with duplicate file URL
+	sed -e 's@https://raw.githubusercontent.com/nltk/nltk/develop/nltk/test/toy.cfg@nltk:grammars/sample_grammars/toy.cfg@' \
+		-i nltk/test/data.doctest || die
+	# requires X and hangs in Xvfb
+	sed -e 's:test_plot:_&:' \
+		-i nltk/test/unit/test_cfd_mutation.py || die
+
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	cd nltk/test || die
+	distutils-r1_src_test
+}
diff --git a/dev-python/openstackdocstheme/Manifest b/dev-python/openstackdocstheme/Manifest
index b3293f559245..1e4ec77e590d 100644
--- a/dev-python/openstackdocstheme/Manifest
+++ b/dev-python/openstackdocstheme/Manifest
@@ -1 +1,2 @@
 DIST openstackdocstheme-2.2.5.tar.gz 1244899 BLAKE2B 17e5903719303e459ee2d07b988a5dcd763d8fd2e575d8eab3a9434c1f055ee0deff237cb85058382c1f429561a220d7364019f71735c90f6cb5643b7865d502 SHA512 9dd0ee94f9a8328597647cc4be15fc60ea036f27ea385390c3f537d19ffda8e617f9f748a474c62030b67f33faefef2f222eca7c54b244c95235ffc29b0a1862
+DIST openstackdocstheme-2.3.1.tar.gz 1255622 BLAKE2B cbb03cbbdd2d22c019879b03be87d97fe52e4396cd45e7acf4e138bb50a99444a80a43c3c76f777ea74bd24ec92ca1e4a562dbc91159d1ddf3cf20c3ad86a957 SHA512 d3e190543e83d83b00d247fe79598f302684e2baece50a01c196231625fce9d7bdfe9716a7eea8cf0a9b59319f02b3c0d3cf35086e58c71cb0d958410fd560cb
diff --git a/dev-python/openstackdocstheme/metadata.xml b/dev-python/openstackdocstheme/metadata.xml
index 05ebecbbbecd..83ea509363a4 100644
--- a/dev-python/openstackdocstheme/metadata.xml
+++ b/dev-python/openstackdocstheme/metadata.xml
@@ -16,4 +16,5 @@
   <doc>https://docs.openstack.org/openstackdocstheme/</doc>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/openstackdocstheme/openstackdocstheme-2.3.1.ebuild b/dev-python/openstackdocstheme/openstackdocstheme-2.3.1.ebuild
new file mode 100644
index 000000000000..f56baa4d604a
--- /dev/null
+++ b/dev-python/openstackdocstheme/openstackdocstheme-2.3.1.ebuild
@@ -0,0 +1,19 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Theme and extension support for Sphinx documentation"
+HOMEPAGE="https://docs.openstack.org/openstackdocstheme/latest/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc64 ~x86"
+
+BDEPEND=">dev-python/pbr-2.1.0[${PYTHON_USEDEP}]"
+RDEPEND="${BDEPEND}
+	>=dev-python/dulwich-0.15.0[${PYTHON_USEDEP}]"
diff --git a/dev-python/regex/Manifest b/dev-python/regex/Manifest
index acb8bc96d4b2..d6c87cecf20e 100644
--- a/dev-python/regex/Manifest
+++ b/dev-python/regex/Manifest
@@ -2,3 +2,4 @@ DIST regex-2021.7.6.tar.gz 693843 BLAKE2B 9acbca300632ff45744d509e47de56625b003b
 DIST regex-2021.8.28.tar.gz 694689 BLAKE2B 1aeceeb77df3c67e3ac14811000dc0f0cccf2a4994fd349f01f3a4e793f265dc9a73ea685202c6a7af8f507f0db94d6b74b1ae448ce58dd985ca4122c3454cba SHA512 da95f8ce03200f45b6be8730b65d01170847d074202e9b5f311688e22e3d59c32a8ff93768e2ac0105bac02936cbcde49eb114b762e89e6ebf895d8b799b4bf9
 DIST regex-2021.8.3.tar.gz 693937 BLAKE2B 886dfe1a312bb34d83a3fe9442231215be7e263cbd123da24c454cdceac1055cb4dacfe4a3104699b6b97f86b14e2b723ea1267a13c2395ce2baad4ca367d77e SHA512 3ac33421ca15e47a1d8beeb3841b6e698d492e96965955afe69529dc71cc7d522e5e8236e4f577c934a3fd27036340a8084c84055bcfff0a9572e8fb56ba272b
 DIST regex-2021.9.24.tar.gz 703375 BLAKE2B 77fae095228ad2e83a77d04c337356fda7d5c9c9dbc9ac6645cbb128c87831ad05f9d2fd910163903e56a6b35f5a54bcce6f477aaccb1b5e297d7df414d3f044 SHA512 2adcbca3d2ec5870095a41d357aa219f108b0b39519f73edbf105e2cd9d5b429e19f9967a90dd1654fe04f415d21b59e345a1aa502788f74223a9e55c3cf576c
+DIST regex-2021.9.30.tar.gz 703504 BLAKE2B d958fa97aabb4c25c424591cfc9b6006c72e72d33029902a00e705c0db6786dcca92b006c4d77f98b0dd183405f63e282f33af75361d20d2b61f65d70da40da6 SHA512 3ce87e01a6e90a2519046595548f9ce38fb177db0d5c2359c57df857a2a9f14be1c6d228b7bd724d5bd66f723e33fd6056180fb45c50931bb0ec5e723df2f16a
diff --git a/dev-python/regex/regex-2021.9.30.ebuild b/dev-python/regex/regex-2021.9.30.ebuild
new file mode 100644
index 000000000000..92ae2cbca7dc
--- /dev/null
+++ b/dev-python/regex/regex-2021.9.30.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Alternative regular expression module to replace re"
+HOMEPAGE="https://bitbucket.org/mrabarnett/mrab-regex"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="doc"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2021.4.4-pypy3-fix-test_empty_array.patch"
+	"${FILESDIR}/${PN}-2021.4.4-pypy3-fix-test_issue_18468.patch"
+)
+
+distutils_enable_tests unittest
+
+python_test() {
+	eunittest -s "${BUILD_DIR}"/lib
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/Features.html )
+	local DOCS=( README.rst docs/*.rst )
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/requestsexceptions/requestsexceptions-1.4.0.ebuild b/dev-python/requestsexceptions/requestsexceptions-1.4.0.ebuild
index 075c0b2c2891..53a8bf4c47cf 100644
--- a/dev-python/requestsexceptions/requestsexceptions-1.4.0.ebuild
+++ b/dev-python/requestsexceptions/requestsexceptions-1.4.0.ebuild
@@ -2,9 +2,8 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
-PYTHON_COMPAT=( python3_{6,7,8,9,10} )
-DISTUTILS_USE_SETUPTOOLS=bdepend
 
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
 inherit distutils-r1
 
 DESCRIPTION="Finds the correct path to exceptions in the requests library."
@@ -15,5 +14,5 @@ LICENSE="Apache-2.0"
 SLOT="0"
 KEYWORDS="amd64 ~arm arm64 x86"
 
-DEPEND=">=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]"
 RDEPEND=">=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]"
+BDEPEND="${RDEPEND}"
diff --git a/dev-python/subunit/Manifest b/dev-python/subunit/Manifest
index cfcaf554695e..e59f6c68e1f4 100644
--- a/dev-python/subunit/Manifest
+++ b/dev-python/subunit/Manifest
@@ -1 +1,2 @@
 DIST subunit-1.4.0.tar.gz 488022 BLAKE2B 4c3a714d02eeed9420074c4e032778a69b716a5cad0079193533e9bc8c0f4576d70b165eb413203ce8a916ac28466e9f5a113d4a7746019d7d09409df9860bae SHA512 5d2e3cb96c09067ef4595c86648f13330c810b19e39c0b35bc9546c57bee957ddcf5cad7b8e3f92bda9b54dcdbf175863e2f6ba94020f880230459be7afdbbcf
+DIST subunit-1.4.0_p20210729.tar.gz 112644 BLAKE2B 56e785c029f3f2896d0ed3d8005c37403e6aa32d05b653db0e3b679d2157820558e578b53133f4f79404a660f37a710aeeec03ff941fd7cd0819020a0d474515 SHA512 90b1ad071fb5246a7446a4c999142566b9d96c39838905e9020b80f2f0aba0b86dd5185bbd25ff7fc65f69ae68e1e53dfde5b2de05755aa97db9248c6faaa9d7
diff --git a/dev-python/subunit/subunit-1.4.0_p20210729.ebuild b/dev-python/subunit/subunit-1.4.0_p20210729.ebuild
new file mode 100644
index 000000000000..d2cc1ae1a8c6
--- /dev/null
+++ b/dev-python/subunit/subunit-1.4.0_p20210729.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1 multilib-minimal autotools
+
+MY_COMMIT="c87ffbd904627d777aa1430963dced92a36aa033"
+
+DESCRIPTION="A streaming protocol for test results"
+HOMEPAGE="https://launchpad.net/subunit https://pypi.org/project/python-subunit/"
+SRC_URI="
+	https://github.com/testing-cabal/subunit/archive/${MY_COMMIT}.tar.gz
+		-> ${P}.tar.gz
+"
+S="${WORKDIR}/${PN}-${MY_COMMIT}"
+
+LICENSE="Apache-2.0 BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/testtools-0.9.34[${PYTHON_USEDEP}]
+	dev-python/extras[${PYTHON_USEDEP}]
+	dev-lang/perl:="
+
+DEPEND="
+	${RDEPEND}
+	>=dev-libs/check-0.9.11[${MULTILIB_USEDEP}]
+	>=dev-util/cppunit-1.13.2[${MULTILIB_USEDEP}]
+	>=virtual/pkgconfig-0-r1
+	test? (
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=(
+	"${FILESDIR}/subunit-1.4.0-werror.patch"
+)
+
+src_prepare() {
+	sed -i -e 's/os.chdir(os.path.dirname(__file__))//' setup.py || die
+
+	# Install perl modules in vendor_perl, bug 534654.
+	export INSTALLDIRS=vendor
+
+	# fails on py3.6
+	sed -i -e 's:test_add_tag:_&:' \
+		python/subunit/tests/test_subunit_tags.py || die
+
+	mv all_tests.py python/ || die
+
+	distutils-r1_src_prepare
+	eautoreconf
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		--enable-shared \
+		$(use_enable static-libs static)
+}
+
+multilib_src_compile() {
+	default
+	multilib_is_native_abi && distutils-r1_src_compile
+}
+
+python_test() {
+	cd python || die
+	"${PYTHON}" -m testtools.run -v all_tests.test_suite || die "Testing failed with ${EPYTHON}"
+}
+
+multilib_src_test() {
+	multilib_is_native_abi && distutils-r1_src_test
+}
+
+multilib_src_install() {
+	local targets=(
+		install-include_subunitHEADERS
+		install-pcdataDATA
+		install-exec-local
+		install-libLTLIBRARIES
+	)
+	emake DESTDIR="${D}" "${targets[@]}"
+
+	multilib_is_native_abi && distutils-r1_src_install
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${D}" -name '*.la' -delete || die
+}
diff --git a/dev-python/tikzplotlib/Manifest b/dev-python/tikzplotlib/Manifest
index 2f1da02baf57..fc0bbfecb856 100644
--- a/dev-python/tikzplotlib/Manifest
+++ b/dev-python/tikzplotlib/Manifest
@@ -1,3 +1,4 @@
 DIST tikzplotlib-0.9.11.gh.tar.gz 97761 BLAKE2B 95454a9181b219e99970d06a0e40d518284ff62c7b06d9cbf5b3125b11a711e67f9df1676dc1bd73a9ec632fa01786890e3eef030f8a52ffe809835e3890359c SHA512 05fa8285f4912f2593a00ec5961f4ca94964c2ff8271158c6c1e0447f1f2b54088a76192bcda4f893adc2ad78b9240742962eee1e56043777b0df145808f42ba
 DIST tikzplotlib-0.9.12.gh.tar.gz 97773 BLAKE2B 85d85445e313a41ede8c2d61d8db0d92a8f4fbb0722f716845f0fff3204e603e8b21998a588137eb67bdbc4d8f31bc5bfc82e29fc803b3c54c416191b6e5310b SHA512 4754707727eda29796a49809473b840c07b2cb7de606089d79aeb05daa6ded95a3f110deffb13ca2640e44d91c43b53520d6f29b175e200862492cb986b6c574
+DIST tikzplotlib-0.9.13.gh.tar.gz 97787 BLAKE2B ef767737b8d222773f2d5e02dbf80ac8a48ea8a00077eb245e5817337805deb5b9be27e7ed76354808647ea1ed6b17d3bbca9b33799d294bd924c18b224e3621 SHA512 f9b4c46b3179626222713dd771dccfa6b0c34ff55658838aba74867c7cd5b91dddfaefdcd2c41824c9f13a795cadd6720240beaf3d504a7f735a2169c441b449
 DIST tikzplotlib-0.9.9.tar.gz 591659 BLAKE2B c8ed8069387aedc154ea1541c7e4f97cd43a74c384be4810029acf2dd1de348d732c004850b3248ba6a892451afec56fc4de0c6b05c3f4edc7b72b741e46b558 SHA512 3b6bc8b23693b1817b7f8969352bfe45f81762f86d30b9329c3c57fb1897ee5965f5759e357bbe68d21b84ac3e53e5ce80ffafccfac22d9a4a36ce104d5a2966
diff --git a/dev-python/tikzplotlib/tikzplotlib-0.9.13.ebuild b/dev-python/tikzplotlib/tikzplotlib-0.9.13.ebuild
new file mode 100644
index 000000000000..d541e4f1aa2d
--- /dev/null
+++ b/dev-python/tikzplotlib/tikzplotlib-0.9.13.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2019-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=pyproject.toml
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Convert matplotlib figures into TikZ/PGFPlots"
+HOMEPAGE="https://github.com/nschloe/tikzplotlib"
+SRC_URI="
+	https://github.com/nschloe/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	app-text/texlive[extra]
+	dev-python/matplotlib[latex,${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/exdown[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+)"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc dev-python/mock
+
+python_test() {
+	local -x MPLBACKEND=Agg
+	local EPYTEST_DESELECT=(
+		tests/test_barchart_errorbars.py::test
+		tests/test_colorbars.py::test
+		tests/test_fillstyle.py::test
+	)
+
+	virtx epytest
+}
diff --git a/dev-python/toposort/Manifest b/dev-python/toposort/Manifest
index 6e30f532eec2..524a1795c6fb 100644
--- a/dev-python/toposort/Manifest
+++ b/dev-python/toposort/Manifest
@@ -1 +1,2 @@
 DIST toposort-1.6.tar.gz 11690 BLAKE2B a9a57fd182a3324d43112c3f84a20039f032d99bf2c35c6678a6a08c23b123f18610f460529dd39c769b935d98270a25ded2f1a483e4e6f06d3ccc501b340cb8 SHA512 8dc30b5d5a6f476756520236bc93840243690779783ec8f0b5ef0f72c64d774177b25d10d2e024cda968f81352abbc4f89f3069760fc3a86bd5ee387e7951928
+DIST toposort-1.7.tar.gz 10671 BLAKE2B 89da22e803c334cec77d5ac8ad6a9ab8013f7516555c2822bd6d511edf28230c85c2eaeabad3dc4a24a58ae3ce3850d407ad957d0e28491574557140a286843a SHA512 a585d1c103b2162fa3f37f6b0ef60a8709f08d9543d7fab619af3718bf9f752a293e50061d370fd08872b2d8a8db504cb9d9c1cce5446885b46fe8e833813833
diff --git a/dev-python/toposort/toposort-1.7.ebuild b/dev-python/toposort/toposort-1.7.ebuild
new file mode 100644
index 000000000000..4bb6e0e3e541
--- /dev/null
+++ b/dev-python/toposort/toposort-1.7.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=pyproject.toml
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Implements a topological sort algorithm"
+HOMEPAGE="https://gitlab.com/ericvsmith/toposort"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+python_test() {
+	"${EPYTHON}" test/test_toposort.py || die
+}