Adding metadata

26 files changed, 528 insertions, 40 deletions

diff --git a/dev-python/Faker/Faker-22.5.1.ebuild b/dev-python/Faker/Faker-22.5.1.ebuild
new file mode 100644
index 000000000000..b726995539a4
--- /dev/null
+++ b/dev-python/Faker/Faker-22.5.1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A Python package that generates fake data for you"
+HOMEPAGE="
+	https://github.com/joke2k/faker/
+	https://pypi.org/project/Faker/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/python-dateutil-2.4.2[${PYTHON_USEDEP}]
+	!dev-ruby/faker
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP},tiff]
+		dev-python/validators[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=faker.contrib.pytest.plugin
+	epytest
+}
diff --git a/dev-python/Faker/Manifest b/dev-python/Faker/Manifest
index b964a3c784b0..fe576dcc7def 100644
--- a/dev-python/Faker/Manifest
+++ b/dev-python/Faker/Manifest
@@ -2,3 +2,4 @@ DIST Faker-22.0.0.tar.gz 1702044 BLAKE2B 17bb5fe42f3d754358a1cf21a23a6917571bdea
 DIST Faker-22.2.0.tar.gz 1702497 BLAKE2B ed5d215399d168b79661a5db5a0b7c9a8321f5fdba30041eb6640cc9e6700d838aa7291060b022cc76a44ce2dd3c28eabbe30be35e4b0311edf4c09f4c523042 SHA512 c9a97a29885d73cbd9920938574e7615be43243a4d524391a4e51a1dcf8ca3188a9606094e715773fbd81740145813b1920ac35e99e49dc932d95045e14fa546
 DIST Faker-22.4.0.tar.gz 1702616 BLAKE2B 1a50724c0c8faaf4b2e72d3b23f242be19862133c79a1d49b8919512355ec84d565768b1c0868f287708880a13e833bab4dc911a9f4df53d9a225fa3ea75e00c SHA512 a8531b839c46c0403c37d1f5d58b026a2f8bf9ef66c4ce6302673dc7988250d51d069740bf783abf5b610afc2d01e23aa769c7d32ee03927befb13a610adc586
 DIST Faker-22.5.0.tar.gz 1703089 BLAKE2B 8c03883f60fa7ab39cc4dee6f73907b34d8b8a7a2f2f55f3842e9807625ff92dff5e3268f4f48048483ec707f4e0c0d4fb4d4c8b6a52f86ec204b8dbd4cad9b9 SHA512 b3ed913304cca9768b79685e449f49c56ad94274e213d77f64afe713b765e128dd5ef8d02222a3519c87ae5d4f567c64e2f8734972c95072f7a23119cc76cf09
+DIST Faker-22.5.1.tar.gz 1703337 BLAKE2B 603b06512deb04c6e320904aa32b7e210ecbe270ae634814adeaa420d2af342d44744755ad7ae575ef7902bd3ad6d117c88814bb13a1d84952509ec881b402f9 SHA512 469cf1af9535be0610c1b8750874b1623b0746b762a995805a86a9bdb54a2a8cd3d4118254b1a75240f24a6294629669aae3b6e062e8b229eba30de56cb2bbf8
diff --git a/dev-python/argcomplete/Manifest b/dev-python/argcomplete/Manifest
index 986f6ea33669..a22e2cac9179 100644
--- a/dev-python/argcomplete/Manifest
+++ b/dev-python/argcomplete/Manifest
@@ -1 +1,2 @@
 DIST argcomplete-3.2.1.tar.gz 80727 BLAKE2B 61964ebce499f64eda1e54ccfaf811d327fc1af4010d2365ccbc68809b336c079c32907bbbcea510658759f31eb22663876d655cd8d6126a3407740aa72c897a SHA512 6b6a42b0a1f7f4bfa27ce4ab756f1a665c4fdf4592af106908bbcfdd8af94ed1c4404ad602d9405f84abf011a474f191b36dc761aaeef8d18f2fbde71eba4f5e
+DIST argcomplete-3.2.2.tar.gz 80764 BLAKE2B 0e059439c64301026fd238b070adb84f69c81f2f8fe6e27d31426abb71d4fadf8b34ff84465d9a9f5757550f6f55330ab17e204b7be18b459cddfb06c3851e25 SHA512 dd94795c561a692286341be234cd15ae684f0af6b11475322e6d616e640c27e7c9d9c73686790cecc09535b7f1287f95be2faa8b62329b12a6dbf9e2d403e439
diff --git a/dev-python/argcomplete/argcomplete-3.2.2.ebuild b/dev-python/argcomplete/argcomplete-3.2.2.ebuild
new file mode 100644
index 000000000000..7c1ca19cd6e2
--- /dev/null
+++ b/dev-python/argcomplete/argcomplete-3.2.2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Bash tab completion for argparse"
+HOMEPAGE="
+	https://github.com/kislyuk/argcomplete/
+	https://pypi.org/project/argcomplete/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# pip is called as an external tool
+BDEPEND="
+	test? (
+		app-shells/fish
+		app-shells/tcsh
+		app-shells/zsh
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/pip-19
+	)
+"
+
+PATCHES=(
+	# increase test timeouts -- this is particularly necessary
+	# for entry point tests because they read metadata of all installed
+	# packages which can take real long on systems with lots of packages
+	"${FILESDIR}/argcomplete-3.1.6-timeout.patch"
+)
+
+python_test() {
+	"${EPYTHON}" test/test.py -v || die
+}
diff --git a/dev-python/bandit/Manifest b/dev-python/bandit/Manifest
index 684db449dde1..cc8bfd947229 100644
--- a/dev-python/bandit/Manifest
+++ b/dev-python/bandit/Manifest
@@ -1 +1,2 @@
 DIST bandit-1.7.6.tar.gz 1977532 BLAKE2B 2580641ee0e19364d36988ff3757a55bd7ff8c0a3e47d564873940b5f9c1b8335a2eb724c9394ff76e341a766054bec27ef296a9502fec60d96a5eb65a015f4b SHA512 6635704e2e60e23f5d21de345152e13ef1bde5efb92ccc0e6dde46e8405c1e5dd9530830af4d2a3c5d6e0bb0eb106ccce4cde3a7be678cce499486e752a26428
+DIST bandit-1.7.7.tar.gz 1980358 BLAKE2B 78330ff515a5b8200a05615c8fbad0a65011ffd9c29cf40464fee372417982738de7fd616d1b5f8910dbe45937ba6da6a87252f471e7d762a905f4683d3892f0 SHA512 32682a9a4c54532be398444799bc6d46d06e2806d3e3e851dd09f0151b21df5974eaa4c940307f32cd6c58b36b99a361cbd8c48f189c27071565be6de63b0db5
diff --git a/dev-python/bandit/bandit-1.7.7.ebuild b/dev-python/bandit/bandit-1.7.7.ebuild
new file mode 100644
index 000000000000..883be66ca64c
--- /dev/null
+++ b/dev-python/bandit/bandit-1.7.7.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A security linter from OpenStack Security"
+HOMEPAGE="
+	https://github.com/PyCQA/bandit/
+	https://pypi.org/project/bandit/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/GitPython-3.1.30[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.3.1[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.5.0[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.3.0[${PYTHON_USEDEP}]
+		>=dev-python/beautifulsoup4-4.8.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-1.9.4[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
+		' 3.10)
+	)
+"
+
+distutils_enable_tests unittest
diff --git a/dev-python/html5lib/files/html5lib-1.1-pytest6.patch b/dev-python/html5lib/files/html5lib-1.1-pytest6.patch
index a511b40abeaa..d8df5f2cf2f6 100644
--- a/dev-python/html5lib/files/html5lib-1.1-pytest6.patch
+++ b/dev-python/html5lib/files/html5lib-1.1-pytest6.patch
@@ -1,41 +1,7 @@
 # https://github.com/html5lib/html5lib-python/pull/506
 # https://bugs.gentoo.org/754144
-From e6bd99e8f2497194ffd0a06c6954ebb28d7526bb Mon Sep 17 00:00:00 2001
-From: =?UTF-8?q?Miro=20Hron=C4=8Dok?= <miro@hroncok.cz>
-Date: Sat, 8 Aug 2020 13:39:22 +0200
-Subject: [PATCH] Use Node.from_parent() constructor to support pytest 6
 
-Add a wrapper not to break pytest 4 (needed for Python 2 support).
-
-    ============================= test session starts ==============================
-    platform linux -- Python 3.9.0b5, pytest-6.0.1, py-1.9.0, pluggy-0.13.1
-    rootdir: /builddir/build/BUILD/html5lib-1.1, configfile: pytest.ini
-    plugins: expect-1.1.0
-    collected 0 items / 1 error
-
-    ==================================== ERRORS ====================================
-    ________________________ ERROR collecting test session _________________________
-    /usr/lib/python3.9/site-packages/pluggy/hooks.py:286: in __call__
-        return self._hookexec(self, self.get_hookimpls(), kwargs)
-    /usr/lib/python3.9/site-packages/pluggy/manager.py:93: in _hookexec
-        return self._inner_hookexec(hook, methods, kwargs)
-    /usr/lib/python3.9/site-packages/pluggy/manager.py:84: in <lambda>
-        self._inner_hookexec = lambda hook, methods, kwargs: hook.multicall(
-    html5lib/tests/conftest.py:105: in pytest_collect_file
-        return TokenizerFile(path, parent)
-    /usr/lib/python3.9/site-packages/_pytest/nodes.py:95: in __call__
-        warnings.warn(NODE_USE_FROM_PARENT.format(name=self.__name__), stacklevel=2)
-    E   pytest.PytestDeprecationWarning: Direct construction of TokenizerFile has been deprecated, please use TokenizerFile.from_parent.
-    E   See https://docs.pytest.org/en/stable/deprecations.html#node-construction-changed-to-node-from-parent for more details.
-
-Fixes https://github.com/html5lib/html5lib-python/issues/505
----
- html5lib/tests/conftest.py          | 15 ++++++++++++---
- html5lib/tests/sanitizer.py         |  2 +-
- html5lib/tests/tokenizer.py         | 10 +++++-----
- html5lib/tests/tree_construction.py | 20 ++++++++++----------
- requirements-test.txt               |  2 +-
- 5 files changed, 29 insertions(+), 20 deletions(-)
+and part of 4a87368b71090f1432df6302f178c4babfcec93f
 
 diff --git a/html5lib/tests/conftest.py b/html5lib/tests/conftest.py
 index dad167c5..fffeb50c 100644
@@ -151,3 +117,33 @@ index 1ef6e725..fb0657bf 100644
          item.add_marker(pytest.mark.treewalker)
          yield item
 
+diff --git a/html5lib/tests/tokenizer.py b/html5lib/tests/tokenizer.py
+index cc9897a..b49d2e6 100644
+--- a/html5lib/tests/tokenizer.py
++++ b/html5lib/tests/tokenizer.py
+@@ -246,7 +246,9 @@ class TokenizerTest(pytest.Item):
+     def repr_failure(self, excinfo):
+         traceback = excinfo.traceback
+         ntraceback = traceback.cut(path=__file__)
+-        excinfo.traceback = ntraceback.filter()
++        pytest_ver = getattr(pytest, "version_tuple", ())
++        filter_args = (excinfo,) if pytest_ver >= (7, 4, 0) else ()
++        excinfo.traceback = ntraceback.filter(*filter_args)
+ 
+         return excinfo.getrepr(funcargs=True,
+                                showlocals=False,
+diff --git a/html5lib/tests/tree_construction.py b/html5lib/tests/tree_construction.py
+index fb0657b..363b48c 100644
+--- a/html5lib/tests/tree_construction.py
++++ b/html5lib/tests/tree_construction.py
+@@ -135,7 +135,9 @@ class ParserTest(pytest.Item):
+     def repr_failure(self, excinfo):
+         traceback = excinfo.traceback
+         ntraceback = traceback.cut(path=__file__)
+-        excinfo.traceback = ntraceback.filter()
++        pytest_ver = getattr(pytest, "version_tuple", ())
++        filter_args = (excinfo,) if pytest_ver >= (7, 4, 0) else ()
++        excinfo.traceback = ntraceback.filter(*filter_args)
+ 
+         return excinfo.getrepr(funcargs=True,
+                                showlocals=False,
diff --git a/dev-python/html5lib/html5lib-1.1-r1.ebuild b/dev-python/html5lib/html5lib-1.1-r1.ebuild
index 9e834e0ef7f6..23514c946833 100644
--- a/dev-python/html5lib/html5lib-1.1-r1.ebuild
+++ b/dev-python/html5lib/html5lib-1.1-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -36,3 +36,8 @@ BDEPEND="
 "
 
 distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pytest_expect
+}
diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index a11d7c268c91..e9da2ac43cac 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1 +1,3 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
+EBUILD langdetect-1.0.9.ebuild 493 BLAKE2B 0df8bce19bc80f79f8e76bcef5a4c2caf333365fe0cb9a3c076b7858bceded5a3e58921474f866a2709dd657b7ed330c1ec4a7f9d7bab0fcf1bc92d77cabc32d SHA512 ea2a1adcb133ac5fc951ba1aa90ef1ce3dfcc424e59727591763d4875aa044a74188be2d15fd89c6b2e83ed6ea04ec3d9851ed584ae79d2c2c127bde7d994b48
+MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index 736a1167c898..020e07f2a3dd 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -1,6 +1,12 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- 
- <origin>gentoo-guru-overlay</origin>
+ <maintainer type="person">
+  <email>marcin.deranek@slonko.net</email>
+  <name>Marcin Deranek</name>
+ </maintainer>
+ <upstream>
+  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
+ </upstream>
+ <origin>slonko-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/linode-metadata/Manifest b/dev-python/linode-metadata/Manifest
index afa5b393bdfb..60052f4f1ce1 100644
--- a/dev-python/linode-metadata/Manifest
+++ b/dev-python/linode-metadata/Manifest
@@ -1 +1 @@
-DIST linode_metadata-0.1.0.tar.gz 12710 BLAKE2B 7ab40a1268b66e7cba3b0b9bf89066ab5d69d96d5ae2b5e1cc65044f67953e3a35d09b48eae113585a41369700badb21a367a9b7ae82e3f344c15e51305ef562 SHA512 6253ab6c5e5e7be9a3a2ca1faf2140462f17553cec49359bdbba26e4b06e082d1b99259913df7ff1d1421c6e42c358f60fa09d16754b59c0375422ed5d0e1ec6
+DIST linode_metadata-0.2.0.tar.gz 12759 BLAKE2B 0fcb1744f893564151766b1398cacda88bd79c90f2ec1abdf7939c7562ac78dd88ad0dbb0cabc8b597a5d9b47fcbf6c6f9db667c3df21065c9ff3b86317848cf SHA512 ed648b9f67a23c87fab0eeba7f8a0ff1a9e98a5f3832a316e585aa8ac505a2cfbbc13966d287a43cecbd1a6f392991a11f5a590385ca71087f9f7c65bff5d76e
diff --git a/dev-python/linode-metadata/linode-metadata-0.1.0.ebuild b/dev-python/linode-metadata/linode-metadata-0.2.0.ebuild
index 59ad01ae78fe..59ad01ae78fe 100644
--- a/dev-python/linode-metadata/linode-metadata-0.1.0.ebuild
+++ b/dev-python/linode-metadata/linode-metadata-0.2.0.ebuild
diff --git a/dev-python/mkdocs-material/Manifest b/dev-python/mkdocs-material/Manifest
index 2129556aa86f..25a9a8b35be2 100644
--- a/dev-python/mkdocs-material/Manifest
+++ b/dev-python/mkdocs-material/Manifest
@@ -1,2 +1,3 @@
 DIST mkdocs-material-9.5.3.gh.tar.gz 14676809 BLAKE2B 340e1a1e8527797e9256f034d39c0fedb97e4ff667f608fc6d7d2d94a9d24f35afc9d7372002623fba3f6da171fc5062d5ad7d3a843bfcafa4a2d423d41845c4 SHA512 5e5745193e661eab7016346cee619ad9b9d848cf49956aa9f9a3c3bb647525a0fa39c63afc6569c8973e566f6061e368d4512149f8634a463af98602c52d2163
 DIST mkdocs-material-9.5.4.gh.tar.gz 14681148 BLAKE2B 1b4b652a446a71986256dd53d87258519176b415758105ae644d2bb0fb39dd32a94462307dbcfa8011a6ba136e5f00ab8379c4937123a1435d66a94f660a9640 SHA512 79167e6751765830eb4defb6d82f7204d38dfa664a95f9e576179a9c6ee65e3dfcbce90a095e78a76c04201244400c8d67c3337130ce8f8a7dc1ac213b09581b
+DIST mkdocs-material-9.5.5.gh.tar.gz 14707046 BLAKE2B 34c5287ac701a06ddb7713fd1a7b18307cbb62de12f4e455cff6380255bfe7d28249c86e922c394d581dd0b95368309396f5f5055cb3c6edb283345ddd6a7e9c SHA512 73a4a513eed242fb690aae6a338636baf049bb510a7779ded6cefbedcdeb2cd1c681646b3587527d8e2a251315e70fa347acff4aeaa6959a26c9bfabd9ef3a64
diff --git a/dev-python/mkdocs-material/mkdocs-material-9.5.5.ebuild b/dev-python/mkdocs-material/mkdocs-material-9.5.5.ebuild
new file mode 100644
index 000000000000..eec1908ef846
--- /dev/null
+++ b/dev-python/mkdocs-material/mkdocs-material-9.5.5.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="
+	dev-python/mkdocs-material-extensions
+	dev-python/mkdocs-minify-plugin
+	dev-python/mkdocs-redirects
+"
+
+inherit distutils-r1 docs
+
+DESCRIPTION="A Material Design theme for MkDocs"
+HOMEPAGE="
+	https://github.com/squidfunk/mkdocs-material/
+	https://pypi.org/project/mkdocs-material/
+"
+SRC_URI="
+	https://github.com/squidfunk/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="social"
+
+RDEPEND="
+	>=dev-python/Babel-2.10.3[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.6[${PYTHON_USEDEP}]
+	>=dev-python/markdown-3.2[${PYTHON_USEDEP}]
+	>=dev-python/mkdocs-1.5.3[${PYTHON_USEDEP}]
+	>=dev-python/paginate-0.5.6[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.16[${PYTHON_USEDEP}]
+	>=dev-python/pymdown-extensions-10.2[${PYTHON_USEDEP}]
+	>=dev-python/readtime-2.0[${PYTHON_USEDEP}]
+	>=dev-python/regex-2022.4.24[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.26[${PYTHON_USEDEP}]
+	social? (
+		>=dev-python/pillow-10.2[${PYTHON_USEDEP}]
+		>=media-gfx/cairosvg-2.5[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	>=dev-python/trove-classifiers-2023.10.18[${PYTHON_USEDEP}]
+"
+# mkdocs-material-extensions depends on mkdocs-material creating a circular dep
+PDEPEND="
+	>=dev-python/mkdocs-material-extensions-1.2[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	# simplify pyproject to remove extra deps for metadata
+	"${FILESDIR}/${PN}-8.5.7-simplify-build.patch"
+)
+
+src_prepare() {
+	echo "__version__ = '${PV}'" > gentoo_version.py || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/moto/files/moto-4.2.12-32bit-time.patch b/dev-python/moto/files/moto-4.2.12-32bit-time.patch
new file mode 100644
index 000000000000..fc9470c1ecab
--- /dev/null
+++ b/dev-python/moto/files/moto-4.2.12-32bit-time.patch
@@ -0,0 +1,46 @@
+From 7afd91fd23ad73550fcc621422e04a3734dc890d Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
+Date: Thu, 18 Jan 2024 13:32:07 +0100
+Subject: [PATCH] Fix more test failures on platforms with 32-bit time_t
+ (#7222)
+
+---
+ tests/test_acm/test_acm.py                      | 5 ++++-
+ tests/test_sagemaker/test_sagemaker_pipeline.py | 5 ++++-
+ 2 files changed, 8 insertions(+), 2 deletions(-)
+
+diff --git a/tests/test_acm/test_acm.py b/tests/test_acm/test_acm.py
+index d0c46d20c..d2943d801 100644
+--- a/tests/test_acm/test_acm.py
++++ b/tests/test_acm/test_acm.py
+@@ -92,7 +92,10 @@ def test_list_certificates():
+     issued_arn = _import_cert(client)
+     pending_arn = client.request_certificate(DomainName="google.com")["CertificateArn"]
+ 
+-    certs = client.list_certificates()["CertificateSummaryList"]
++    try:
++        certs = client.list_certificates()["CertificateSummaryList"]
++    except OverflowError:
++        pytest.skip("This test requires 64-bit time_t")
+     assert issued_arn in [c["CertificateArn"] for c in certs]
+     assert pending_arn in [c["CertificateArn"] for c in certs]
+     for cert in certs:
+diff --git a/tests/test_sagemaker/test_sagemaker_pipeline.py b/tests/test_sagemaker/test_sagemaker_pipeline.py
+index 8323eb29b..31443b26b 100644
+--- a/tests/test_sagemaker/test_sagemaker_pipeline.py
++++ b/tests/test_sagemaker/test_sagemaker_pipeline.py
+@@ -515,7 +515,10 @@ def test_list_pipelines_created_after(sagemaker_client):
+     _ = create_sagemaker_pipelines(sagemaker_client, pipelines)
+ 
+     created_after_str = "2099-12-31 23:59:59"
+-    response = sagemaker_client.list_pipelines(CreatedAfter=created_after_str)
++    try:
++        response = sagemaker_client.list_pipelines(CreatedAfter=created_after_str)
++    except OverflowError:
++        pytest.skip("This test requires 64-bit time_t")
+     assert not response["PipelineSummaries"]
+ 
+     created_after_datetime = datetime.strptime(created_after_str, "%Y-%m-%d %H:%M:%S")
+-- 
+2.43.0
+
diff --git a/dev-python/moto/moto-4.2.12.ebuild b/dev-python/moto/moto-4.2.12.ebuild
index 2a4614116fa6..0d21a9b67468 100644
--- a/dev-python/moto/moto-4.2.12.ebuild
+++ b/dev-python/moto/moto-4.2.12.ebuild
@@ -58,6 +58,11 @@ BDEPEND="
 EPYTEST_XDIST=1
 distutils_enable_tests pytest
 
+PATCHES=(
+	# https://github.com/getmoto/moto/pull/7222
+	"${FILESDIR}/${PN}-4.2.12-32bit-time.patch"
+)
+
 python_test() {
 	local EPYTEST_DESELECT=(
 		# TODO
diff --git a/dev-python/moto/moto-4.2.13.ebuild b/dev-python/moto/moto-4.2.13.ebuild
index 510420bac6e5..4acd18352573 100644
--- a/dev-python/moto/moto-4.2.13.ebuild
+++ b/dev-python/moto/moto-4.2.13.ebuild
@@ -58,6 +58,11 @@ BDEPEND="
 EPYTEST_XDIST=1
 distutils_enable_tests pytest
 
+PATCHES=(
+	# https://github.com/getmoto/moto/pull/7222
+	"${FILESDIR}/${PN}-4.2.12-32bit-time.patch"
+)
+
 python_test() {
 	local EPYTEST_DESELECT=(
 		# TODO
diff --git a/dev-python/polib/polib-1.2.0.ebuild b/dev-python/polib/polib-1.2.0.ebuild
index 2a9fc24c074d..747ff681e22f 100644
--- a/dev-python/polib/polib-1.2.0.ebuild
+++ b/dev-python/polib/polib-1.2.0.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -18,6 +18,8 @@ HOMEPAGE="
 LICENSE="MIT"
 SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 ~ia64 ~loong ~mips ppc ppc64 ~riscv sparc x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
 
 distutils_enable_sphinx docs
 
@@ -25,6 +27,12 @@ PATCHES=(
 	"${FILESDIR}"/${PN}-1.0.7-BE-test.patch
 )
 
+BDEPEND="
+	test? (
+		<sys-devel/gettext-0.22
+	)
+"
+
 python_test() {
 	"${EPYTHON}" tests/tests.py -v || die "Tests failed under ${EPYTHON}"
 }
diff --git a/dev-python/pytest-salt-factories/Manifest b/dev-python/pytest-salt-factories/Manifest
index 556d3f94fcc7..c89c1aa324dc 100644
--- a/dev-python/pytest-salt-factories/Manifest
+++ b/dev-python/pytest-salt-factories/Manifest
@@ -2,3 +2,4 @@ DIST pytest-salt-factories-1.0.0_rc20.gh.tar.gz 160140 BLAKE2B 7ecd9af695626c465
 DIST pytest-salt-factories-1.0.0_rc23.gh.tar.gz 162711 BLAKE2B 28610679d7717d7a6f97a2f14a1ac838aec5101171ae65f2328d9b902d04b272c5e37f08d8ff3414af52ff7af954da24c083dfdc4afd1a9342b09cce0bf5aec3 SHA512 22d8f4a1c48a144437b9ff7d064760b59bb2a1003838e07f446a6150a77c162bffa7f21c570f796d8214d870d5b029e92abf7b0410ce19726085b607628364f0
 DIST pytest-salt-factories-1.0.0_rc25.gh.tar.gz 166148 BLAKE2B 11935c0164727968b9f2bd6f77498ea9ed4dbafd48bd6bb2730716fbcb1bb69b1ab09ef9ea2e2519368f4b6408bbb03f41fb0e52fc3cf75695f2b9c2b8d37294 SHA512 dd18688731b6bd2384abff9d739154b1ca7786bc3843d9fa8c293d1950925fff6c5820680a8095d4d5f3b75bcaeb07d8b3c7703ecab64a5f3a28bad11da18397
 DIST pytest-salt-factories-1.0.0_rc28.gh.tar.gz 168150 BLAKE2B c286c2a3933f8a987f1073ba97097cec29bf494cac9c4ba21ec4c261e22570ac3445900cacf629cce6253fb1a5fb95eb3d637b4d26e8835648dd11c569a7255e SHA512 ea362daa83007d9054b023ca9c11864ba304d802fa359c8cb883aa929f339c5347d50560a2d4a9cbc151a7b05bc46d1dc2f7693dd32d26383766cb5f249f3484
+DIST pytest-salt-factories-1.0.0_rc29.gh.tar.gz 168690 BLAKE2B d365cdef727e6ed0c0d2d06ce3c8731ddf67181d4d8386d106b7569c709fc5336529c72e907d44496463b47b18659376a64c79b08d45aaa5aa7d8d927a646db3 SHA512 7dd0e9d5bb6e4b292ef145f6fec770435f1cd23a07be67c98e155b1aa3a34bec1c542d97a6cae0302ad46e5c2f4e35eadb45bd7ea8979c05c6ddf1aacde9f755
diff --git a/dev-python/pytest-salt-factories/pytest-salt-factories-1.0.0_rc29.ebuild b/dev-python/pytest-salt-factories/pytest-salt-factories-1.0.0_rc29.ebuild
new file mode 100644
index 000000000000..2d4750a74622
--- /dev/null
+++ b/dev-python/pytest-salt-factories/pytest-salt-factories-1.0.0_rc29.ebuild
@@ -0,0 +1,86 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+DESCRIPTION="The new generation of the pytest-salt Plugin"
+HOMEPAGE="
+	https://github.com/saltstack/pytest-salt-factories/
+	https://pypi.org/project/pytest-salt-factories/
+"
+SRC_URI="
+	https://github.com/saltstack/pytest-salt-factories/archive/${PV//_/}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/${P//_/}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/attrs[${PYTHON_USEDEP}]
+	dev-python/docker[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pytest-7.0.0[${PYTHON_USEDEP}]
+	dev-python/pytest-helpers-namespace[${PYTHON_USEDEP}]
+	dev-python/pytest-skip-markers[${PYTHON_USEDEP}]
+	dev-python/pytest-system-statistics[${PYTHON_USEDEP}]
+	>=dev-python/pytest-shell-utilities-1.4.0[${PYTHON_USEDEP}]
+	dev-python/pyzmq[${PYTHON_USEDEP}]
+	dev-python/msgpack[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+	>=app-admin/salt-3005.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/importlib-metadata[${PYTHON_USEDEP}]
+		dev-python/pyfakefs[${PYTHON_USEDEP}]
+		dev-python/pytest-subtests[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+	sed -i -e 's:helpers_namespace:pytest_&.plugin:' tests/conftest.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		tests/integration/factories/daemons/ssh/test_salt_ssh.py::test_salt_ssh
+		tests/integration/factories/daemons/sshd/test_sshd.py::test_connect
+		tests/scenarios/examples/test_echoext.py::test_echoext
+	)
+
+	local ret tempdir x
+	# ${T} is too long a path for the tests to work
+	tempdir="$(mktemp -du --tmpdir=/tmp salt-XXX)" || die
+	addwrite "${tempdir}"
+
+	local -x SHELL="/bin/bash" TMPDIR="${tempdir}"
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=saltfactories.plugins
+	PYTEST_PLUGINS+=,pytest_helpers_namespace.plugin
+	PYTEST_PLUGINS+=,pytestsysstats.plugin
+	PYTEST_PLUGINS+=,pytest_subtests
+	for x in factories markers sysinfo event_listener log_server loader
+	do
+		PYTEST_PLUGINS+=,saltfactories.plugins.${x}
+	done
+
+	nonfatal epytest --no-sys-stats
+	ret=${?}
+
+	rm -rf "${tempdir}" || die
+	[[ ${ret} -ne 0 ]] && die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/scikit-build-core/Manifest b/dev-python/scikit-build-core/Manifest
index a1cd23b3705b..3797d9e9af13 100644
--- a/dev-python/scikit-build-core/Manifest
+++ b/dev-python/scikit-build-core/Manifest
@@ -1,2 +1,3 @@
 DIST scikit_build_core-0.7.0.tar.gz 197884 BLAKE2B f632cc131af9db03db2c84b32e451c6369273f9d5db0bca2991cface419c5f9faa5d98239a8a5edd8a36749bc368c0f3c25b3813f33ed63f125731ba4e3d11ae SHA512 ee50070156030fe6c8e07db428902bec67e2267bf36338e62bd936e63f402da869fc4c629c0bc274ab6f798642d163906cc8d6695a62228580ba979878e5d6f8
 DIST scikit_build_core-0.7.1.tar.gz 197949 BLAKE2B bcce5c5f71ce1417e5912d9c60c1f1c8bd656feb16b255e7d94f8fe49f75354c940a940fedd07f9c03b200c8858e24537686067463a47699e9285178e64f32f8 SHA512 30b479708b2265789ad4d43ab0ef8a433cf6745223b9812e95b0e45356ab9ad0689ee8f546f3c3af0bd482342d5518d381481b58480b715023c6baa87235952a
+DIST scikit_build_core-0.8.0.tar.gz 202019 BLAKE2B 92eded3ca562cb3089502cdf017e33ceca6a816e8ee73a62e780a7c291b4606710598fb357585fcfb83362bd5c4275d31b602ad7243aadce94a78bcae1ae5cd3 SHA512 82a20d54a699403ce97e71b95288935e5f0fb3ebafa897d9620612727d4aee5a003384e65665b002b1f2db2b0672d9b05c0428d26f00bc5300cbd884cef6e519
diff --git a/dev-python/scikit-build-core/scikit-build-core-0.8.0.ebuild b/dev-python/scikit-build-core/scikit-build-core-0.8.0.ebuild
new file mode 100644
index 000000000000..1f2236b06f88
--- /dev/null
+++ b/dev-python/scikit-build-core/scikit-build-core-0.8.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Build backend for CMake based projects"
+HOMEPAGE="
+	https://github.com/scikit-build/scikit-build-core/
+	https://pypi.org/project/scikit-build-core/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# we always want [pyproject] extra
+RDEPEND="
+	>=dev-python/packaging-20.9[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-metadata-0.5[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/exceptiongroup[${PYTHON_USEDEP}]
+		>=dev-python/tomli-1.1[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		>=dev-python/cattrs-22.2.0[${PYTHON_USEDEP}]
+		dev-python/pybind11[${PYTHON_USEDEP}]
+		>=dev-python/pytest-subprocess-1.5[${PYTHON_USEDEP}]
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO / we don't package validate_pyproject anyway
+		tests/test_schema.py::test_compare_schemas
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p subprocess -m "not isolated and not network"
+}
diff --git a/dev-python/starlette/Manifest b/dev-python/starlette/Manifest
index c692eaeae87b..6b6bd6b13392 100644
--- a/dev-python/starlette/Manifest
+++ b/dev-python/starlette/Manifest
@@ -1,3 +1,4 @@
 DIST starlette-0.34.0.gh.tar.gz 2841390 BLAKE2B c7eb980fe0a1a6fff0e2bb0c2bb0af4a409933a51de28d2641698f39f8280e7e1d767927f6f919cbb6e5817d34f81b48835c3ad8600c05c6194f70e4f0475d39 SHA512 bf8ce6b665f91e0410dca7b4f427f07cf977f5e9dd6614cf7c06ef2521e359410cdfc2008d7324a500c68bb8b1ecfd9b3a165c7dfc62a84c01762910debb981e
 DIST starlette-0.35.1.gh.tar.gz 2842796 BLAKE2B 1ea63f30d65103754559700eb2db699b3d03ce1dfc78081e7d2b9a680839dd0a453059d858e8b1390da2779ba755d5074033c53b5392ee7071fee27cc6739935 SHA512 75703c2ee23dd19e9c8bdd24a0a3d84f50486c0df0cad9609e0e08eb1fd3c61a4f56887d60018fbec4227bde2b3e12fb09decc865b8d5073bc4a1e066b6d5f69
 DIST starlette-0.36.0.gh.tar.gz 2843462 BLAKE2B 2a60d3cb8c4b838acfa0ece25d18be779aff43e80db1c3fd1d04b54a47bffac6e5eb78d1e1c3531cccaa487bd8f37f85ac0ef143906ece133e42e94e5d91e64f SHA512 acef48e3c0a4d9853a8aca4ae7afdfe4089aaed47c682795b3b307ec1d4529fbf8c5b340070f6ba561f826b7622c215ffd8243e509eff1194450e50822d4c49f
+DIST starlette-0.36.1.gh.tar.gz 2843494 BLAKE2B 633cd664785f32423c0dfeab04b400340b5e3197f4ef07edca9fcda20954444ccfef1ff9afc62969d5b2914f2091e08946420931ee1ee22e1ab771fe02db13ec SHA512 9a990098a1faa179bcf8df64237147d59e3114b1336f491ca358ffd0016412f18323845eb5f8691aa41810fef455e97cb47ff34d9456a0e3a5be3eb6b23027bb
diff --git a/dev-python/starlette/starlette-0.36.1.ebuild b/dev-python/starlette/starlette-0.36.1.ebuild
new file mode 100644
index 000000000000..0106c8d8c43b
--- /dev/null
+++ b/dev-python/starlette/starlette-0.36.1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="The little ASGI framework that shines"
+HOMEPAGE="
+	https://www.starlette.io/
+	https://github.com/encode/starlette/
+	https://pypi.org/project/starlette/
+"
+# no docs or tests in sdist, as of 0.27.0
+SRC_URI="
+	https://github.com/encode/starlette/archive/${PV/_p/.post}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	<dev-python/anyio-5[${PYTHON_USEDEP}]
+	>=dev-python/anyio-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/httpx-0.22.0[${PYTHON_USEDEP}]
+	dev-python/itsdangerous[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/python-multipart[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/trio[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# Unpackaged 'databases' dependency
+	tests/test_database.py
+)
+
+distutils_enable_tests pytest
diff --git a/dev-python/toolz/Manifest b/dev-python/toolz/Manifest
index 4fba9d39ac8d..1214c6fb5cf7 100644
--- a/dev-python/toolz/Manifest
+++ b/dev-python/toolz/Manifest
@@ -1 +1,2 @@
 DIST toolz-0.12.0.tar.gz 66264 BLAKE2B a68bd895a4d500baebae02dce389adabbebe3eaa103ed2753ebd42d84dba54d9ef0b1467738b6a2eed14af24e197a12ef6b6c6907bcf4633252256793e1eac5f SHA512 6c1376f978a1ab469a6fcca9a5ccaf8b8f1bdf92e4484ff0bad947d6727f390ed6571426070a81a0e123725269043ded28294e57921bde2bb9ff87b048a5405f
+DIST toolz-0.12.1.tar.gz 66550 BLAKE2B 41b2002147cd453c2a8300c7ec247e06dfc8fba69a772df4a8f5c35349e991453bbbd0d7ed0162391d9314873bf0e169d20c86b875e4d4eca01aaadc76edea61 SHA512 c514934d1a8069cd70e4d8b9ca32cd2c96e85b1dabb45bbbe4b0644581eb7e7f9f6a6d9230483f1872695edf25ff77ad7643cffb3041a012ed64424097a23e9e
diff --git a/dev-python/toolz/toolz-0.12.1.ebuild b/dev-python/toolz/toolz-0.12.1.ebuild
new file mode 100644
index 000000000000..1c3b9a66be9f
--- /dev/null
+++ b/dev-python/toolz/toolz-0.12.1.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="List processing tools and functional utilities"
+HOMEPAGE="
+	https://github.com/pytoolz/toolz/
+	https://pypi.org/project/toolz/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}