Adding metadata

29 files changed, 805 insertions, 39 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 07832a00bd7c..8674d19f011e 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -5,3 +5,4 @@ DIST boto3-1.28.26.gh.tar.gz 687954 BLAKE2B 04e87223eac560264ef55c80d5d258b028b9
 DIST boto3-1.28.27.gh.tar.gz 689084 BLAKE2B 5e6c824aedd92f429a5e932a8839d2f855624d4e821a3b9e8e434d6d47c9dfbc44fd5f93df451fe19be089513dad56f5291186f734b696914ce867f5e4a436e2 SHA512 6233f4da3fcb84b24bdc5c3aa3914de0cdd31212b1927eafb82972a4c751556699cd653be014d7d838836a92a5a35368d6874e19f6fb04a730606868a656c53e
 DIST boto3-1.28.28.gh.tar.gz 689176 BLAKE2B 21a951604fb2c5f6435d6c27dfbab5a4d16071fc9a4260374529902dd3715bd9ae8b724e75ad1c550696b8f781b54fc31f8ede6e489f950c263be44fbb387dcf SHA512 3b6a736de618ef094203c04b8c5408b20d3ca006514266423c20d3716269bad70532a90fec66a2a8bc168830ceb128b4dd314d23132656ab8c45d19bdaca345f
 DIST boto3-1.28.29.gh.tar.gz 689353 BLAKE2B 6d8816cd1857b2c9b968730488ccc6822a721e65275a247284a85702f16462a7075e72a53d575ab5ecf450666a80b7d750503a315c5205b09a5850ff37cae684 SHA512 624060c702af72ab083f2bbbf9d406485db2df953f3fde1f9c32bfeff4c9bd4ef1498052c8cb7356ab1aec51132cb77f4af34da15af0aa92da67724646643cd8
+DIST boto3-1.28.30.gh.tar.gz 689629 BLAKE2B 03081369f995ae470717c32ffd0e80c1bac6677467cd4af57b4a7e19d5c0249c825a2db787d5e6d7319b1af808936043e07b1d5ff13eb413125478710a18a416 SHA512 ace77ea7898cd7baa47c256affe553bbec2410f0143caf3b06311d66c306dfe2d4ce8b47820d6c8ceb3f4a7a195d94610b46db2bb0ed2e3716dcee99b8841468
diff --git a/dev-python/boto3/boto3-1.28.30.ebuild b/dev-python/boto3/boto3-1.28.30.ebuild
new file mode 100644
index 000000000000..75cdaca5d9b7
--- /dev/null
+++ b/dev-python/boto3/boto3-1.28.30.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 6dec54cfbd70..b915fd06a8de 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -5,3 +5,4 @@ DIST botocore-1.31.26.gh.tar.gz 11865968 BLAKE2B ead40328750793f1cb6e4b533d3cced
 DIST botocore-1.31.27.gh.tar.gz 11871182 BLAKE2B 818464a312ebf32eb38956fe6d58a1c784e9f2c746e8a03070ceaba89f3a3aee6fd5ff190f6001d32c46a92c12958c5655b5f07c9545b7f8ab6c8b060f1f3656 SHA512 9a175150ada4b21c3c2992671c69bea8717a934009fbf1fa30955735bf732285301e1a7013c631d6422c911b5e62f2980c191e41b9af4479bbe3a0ee8c44e71a
 DIST botocore-1.31.28.gh.tar.gz 11872151 BLAKE2B 97541606ddc488cc1b07f02a1ab55939596f6fcf8515b19579e7c836b4b5fb7cb41c04b1b15e4836b8bf33982044db93694371a8c966682ad4f22ab973041f30 SHA512 88956b9537e6db15c0a5976b25a63d01a0fbe12f8220a5ee3028b6ab6118a3384db3749a8cd2ff2ad32393a419145f9c8027842d290e7bf655b063adf50fd984
 DIST botocore-1.31.29.gh.tar.gz 11874948 BLAKE2B a4a2dabdfdb574814878009a29cee4dfd2014a45b40e10f4769b49d487de1f58e75f27ac897cc140590b03922dd1c2bfc6e28ad211d45743f5358b80fef238c4 SHA512 5796b5b985b68ebde998133c6b33ef2bcc3b7f64615198e0e73f6e24fd2782b796a3acd8a3603cce0890ad820d00c2021da5bdf408ea89154ad21bfafb71c738
+DIST botocore-1.31.30.gh.tar.gz 11873788 BLAKE2B 0e0f7500c838c1dc1978956a1b191b30f217ff55ae17a3f601956362b0be2058bf895477db486f532dbb334d925da2ebe7c24c5a8e08585e2c817bb2539b4f3c SHA512 310d5c23ad1ca38550032b9810106fefd5f6431b717c8296bf6e7d208d5c7d1a6b4a97684f2386f4dac27463e1005e08fd67b0e6be07a5c625fa3c8c3a383378
diff --git a/dev-python/botocore/botocore-1.31.30.ebuild b/dev-python/botocore/botocore-1.31.30.ebuild
new file mode 100644
index 000000000000..cfff2c3537d6
--- /dev/null
+++ b/dev-python/botocore/botocore-1.31.30.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+		# fails on unrelated warnings
+		tests/unit/test_client.py::TestAutoGeneratedClient::test_BOTO_DISABLE_COMMONNAME
+		tests/unit/test_client.py::TestClientErrors::test_BOTO_DISABLE_COMMONNAME
+		# TODO
+		tests/functional/test_credentials.py::SSOSessionTest::test_token_chosen_from_provider
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/dask/Manifest b/dev-python/dask/Manifest
index a7e7ccbdd8bd..8860473ea074 100644
--- a/dev-python/dask/Manifest
+++ b/dev-python/dask/Manifest
@@ -1,3 +1,4 @@
 DIST dask-2023.6.1.gh.tar.gz 8528028 BLAKE2B 50326b83fc60ab5d615433f1d44d504e9b05c8e6e8f662277b999394c6eb170bd7b9947402f187971c79c96b3a7cc15fcb0970cceb0c70c09341c447b79d4035 SHA512 eb4f01183429f64acf2b779b3e20c16bc0597c13516a79128eadd93176be3a65ddac7a113cbe946051fd7b6b5f1dbcc0e0dfcac8930c90ecbeffc5d1d1539be4
 DIST dask-2023.7.1.gh.tar.gz 8535789 BLAKE2B 6841a126cc245ff578408f0a30d973f18be0c3d62acb115562fd1a35fcc0262d07678c128428f4caeda78a1bdceec2bd885234f265fbd7d16be12238f1b623bd SHA512 54fca9d54d83ec89705f44df00050fd1d696a555809945a1e0139c565703f2af8ca503ed8e586b72aff0b670e64073877ed4d5713212d21765a859fdb7247ec1
 DIST dask-2023.8.0.gh.tar.gz 8539262 BLAKE2B 3ce61191bca458e32ac88904460f8ee843f34ddc9be88d0de7f56a90897dd599d70012f92b5063b5df996bc61c85c16b2d6b745e1a334847d8b66f66721bc422 SHA512 9afee3571e58b0f923347e2ec06c80ab5e4f35abb23e0635777170def0561cf1df6c940844cad1efe112059909020cf6435147b9003c4a449eba98d38d9eefab
+DIST dask-2023.8.1.gh.tar.gz 8541743 BLAKE2B 485a88354d3aa54ff1f6afb1bd4a8b3317a6a48b519bef4dadf1bcbb240f21e54eb165f2c076ea8aa9b5753fd8714af26453858d7fe154bb015489f89b8114be SHA512 4ca231236e5d868f8fbb69b38721e495a44fbc982a53ea087ef68085c4df2cc99526b5a66b7fee93a3b63a6cd621f8448b877b98370b3dfe1a32e386dd91e73e
diff --git a/dev-python/dask/dask-2023.8.1.ebuild b/dev-python/dask/dask-2023.8.1.ebuild
new file mode 100644
index 000000000000..b2012b98ed2a
--- /dev/null
+++ b/dev-python/dask/dask-2023.8.1.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Task scheduling and blocked algorithms for parallel processing"
+HOMEPAGE="
+	https://www.dask.org/
+	https://github.com/dask/dask/
+	https://pypi.org/project/dask/
+"
+SRC_URI="
+	https://github.com/dask/dask/archive/${PV}.tar.gz -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/click-8.0[${PYTHON_USEDEP}]
+	>=dev-python/cloudpickle-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/fsspec-2021.9.0[${PYTHON_USEDEP}]
+	>=dev-python/importlib-metadata-4.13.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.21[${PYTHON_USEDEP}]
+	>=dev-python/pandas-1.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+	>=dev-python/partd-1.2.0[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.3.1[${PYTHON_USEDEP}]
+	>=dev-python/toolz-0.10.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/toolz[${PYTHON_USEDEP}]
+	>=dev-python/versioneer-0.28[${PYTHON_USEDEP}]
+	test? (
+		dev-python/moto[${PYTHON_USEDEP}]
+		dev-python/numexpr[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# fails with sqlalchemy-2.0, even though we don't use it x_x
+	sed -i -e '/RemovedIn20Warning/d' pyproject.toml || die
+	sed -i -e 's:--cov-config=pyproject.toml::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# more tests relying on -Werror
+		"dask/array/tests/test_overlap.py::test_map_overlap_no_depth[None]"
+		dask/array/tests/test_random.py::test_RandomState_only_funcs
+		# TODO
+		dask/array/tests/test_reductions.py::test_mean_func_does_not_warn
+		dask/tests/test_config.py::test__get_paths
+		dask/array/tests/test_linalg.py::test_solve_assume_a
+		"dask/dataframe/tests/test_dataframe.py::test_repartition_npartitions[<lambda>0-float-5-1-True]"
+		"dask/dataframe/tests/test_dataframe.py::test_repartition_npartitions[<lambda>1-float-5-1-True]"
+		dask/array/tests/test_image.py::test_preprocess
+		dask/tests/test_system.py::test_cpu_count_cgroups_v2
+		# require sqlalchemy<2.0
+		dask/dataframe/io/tests/test_sql.py
+	)
+
+	if ! has_version -b "dev-python/pyarrow[parquet,${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			# fails if pyarrow is installed without USE=parquet
+			# (optional dep, skipped if it's not installed at all)
+			dask/dataframe/io/tests/test_parquet.py::test_pyarrow_filter_divisions
+		)
+	fi
+
+	epytest -p no:flaky -m "not network"
+}
diff --git a/dev-python/ensurepip-setuptools/Manifest b/dev-python/ensurepip-setuptools/Manifest
index 6c40e91b0f3b..03e9eebd9d11 100644
--- a/dev-python/ensurepip-setuptools/Manifest
+++ b/dev-python/ensurepip-setuptools/Manifest
@@ -1,3 +1,4 @@
 DIST setuptools-67.8.0-py3-none-any.whl 1093916 BLAKE2B d02bd5ccfe27c116497f8ae46603e5863c88795a489523d4cdaef3bad1bfabd5dfccf7a00f17290e58cce89a6348fbc194c00ae5ccb4c5e89a083fbb84c2cca6 SHA512 a80fc8d632ee6d1947689bb3f27ffb85206e518bf6c153ad43dd5e9f1825fa6e45d9df2baedd1fa9a8afb12a7854215bc4f56bb73d9033704745954890267c9a
 DIST setuptools-68.0.0-py3-none-any.whl 804037 BLAKE2B 743ab93b17f2e53e612c518d2d2fee73259dc4eef3de5ccb6587c84a91056072106d72def7189d2173c8bb53457da5b0010badaaca6a28c01aaff124dcb3bd10 SHA512 352b87cba8c4c9e1e0f14fb85a9f7c5bb3f874f09a8107c84df8051bba9d38b8da420babc66458bf2f51ef11b7089d1ecbbec4077a5982d73e1e63316a99c79e
 DIST setuptools-68.1.0-py3-none-any.whl 805159 BLAKE2B 0fcf1492ce9a9d23700b2c6ebfc487f4e6be6fdd7b3a9601bb7966e06ad9f790fc5d5f96f859e28da47e1afb03e1ca73fe73d7cff53f5173b65986c05f6de011 SHA512 6d66b29a9f7a17dbb077f4f6c2626d27a17b40f9688afd22ca05371c9fb01159cd8f2e20d2d2584958343322a8a081bbf98d204fcf929ce112c71b0523525c62
+DIST setuptools-68.1.2-py3-none-any.whl 805130 BLAKE2B 215d46c49094a6f5b5748354f598082e3740840901b8c8af627308ec4879bd0f23e370c9b1ce5c8c00c5299d4e2fd21800d20b56b93d78da2ab26246e30c0b03 SHA512 acce5ba5d446479988ac2f16ab38cdb8750bd6b1cdaab259f05f840ac86071c8b5f036913f83764c30a172df2111c50192852c17a69abc8980bc87c3a5ba3358
diff --git a/dev-python/ensurepip-setuptools/ensurepip-setuptools-68.1.2.ebuild b/dev-python/ensurepip-setuptools/ensurepip-setuptools-68.1.2.ebuild
new file mode 100644
index 000000000000..8346a1bd0f6d
--- /dev/null
+++ b/dev-python/ensurepip-setuptools/ensurepip-setuptools-68.1.2.ebuild
@@ -0,0 +1,24 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit pypi
+
+DESCRIPTION="Shared setuptools wheel for ensurepip Python module"
+HOMEPAGE="https://pypi.org/project/setuptools/"
+SRC_URI="$(pypi_wheel_url "${PN#ensurepip-}")"
+S=${DISTDIR}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+
+RDEPEND="
+	!<dev-python/ensurepip-wheels-100
+"
+
+src_install() {
+	insinto /usr/lib/python/ensurepip
+	doins "${A}"
+}
diff --git a/dev-python/furo/Manifest b/dev-python/furo/Manifest
index 249da06eadcb..53ed841e261b 100644
--- a/dev-python/furo/Manifest
+++ b/dev-python/furo/Manifest
@@ -1,3 +1,4 @@
 DIST furo-2023.5.20-py3-none-any.whl 326767 BLAKE2B cc8eb3816bf99039e1a312f9fed21538b0154ece228e351107df89f5770c382614efc7202bae742d28d2fc8fceabc8b748b2bfbe8a230aeb70f280b622d42c11 SHA512 1a97b37aa9ce55878f34e3276eebeb4b138bd9e397b6711469fed4523ab8dadcd91e77234a1eca20561276f6660410a31f48f34ae320c6772d1055699cdd7125
 DIST furo-2023.7.26-py3-none-any.whl 326996 BLAKE2B 1da4cbbdcab66973e87228a423042f58499c95a0a4287ad4e5ff4b87a3ae27b31b68dfc1a267a1642b35455f420659755ef4791c519496799331379c806e8f2c SHA512 761c3b276d4db86dea0201c2f10e2958fe8ef784243687e6884406bdd11b009296158585ae865fc754c0b7674fe65cc2d6beaf3d997da672d2e4e319b1813fa1
 DIST furo-2023.8.17-py3-none-any.whl 327018 BLAKE2B 6a96b341b5f78581adb534154bbe56a6eaf5a21a8384597fc8e0f3106db0751619927dac536846fbe60ec0eb2f8769cb2efc0a65de36a00a3264abe90911400c SHA512 15165c5b212890264242d71ecb3ba43e1241683e3fd25bafb20f617b1e8fe59a3705fcbb9353d25c1318c9057407c7336e8a4c3a3aab0b18e7a0e6f24e9de850
+DIST furo-2023.8.19-py3-none-any.whl 323684 BLAKE2B 56b05551a4be4e01492a85f25bdb3057dffab4c66a98fc196c8d486ccfab6d8eec86184bc4b99308b3522b4eb21edadfd231aba8c9cdb3ffdcdac7c90e6a5a91 SHA512 6134271db8fb60b1fddfff1af0d4394192251d0942c070c29af29313ff7abd14f46f12823b90e8d56f03c92a22732af0b39f754c513513f2437487c6adb070f8
diff --git a/dev-python/furo/furo-2023.8.19.ebuild b/dev-python/furo/furo-2023.8.19.ebuild
new file mode 100644
index 000000000000..5d83ec5d2f65
--- /dev/null
+++ b/dev-python/furo/furo-2023.8.19.ebuild
@@ -0,0 +1,36 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# sphinx-theme-builder is completely unusable, as it requires pinning
+# to a very-specific nodejs version number, and ofc loves fetching
+# everything from the Internet
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Clean customisable Sphinx documentation theme"
+HOMEPAGE="
+	https://pypi.org/project/furo/
+	https://github.com/pradyunsg/furo/
+"
+SRC_URI="$(pypi_wheel_url)"
+S=${WORKDIR}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/sphinx[${PYTHON_USEDEP}]
+	dev-python/sphinx-basic-ng[${PYTHON_USEDEP}]
+"
+
+python_compile() {
+	distutils_wheel_install "${BUILD_DIR}/install" \
+		"${DISTDIR}/${P}-py3-none-any.whl"
+}
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index 846b6b6a5f1b..d83e4f69e42f 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -1,3 +1,4 @@
 DIST hypothesis-6.81.2.gh.tar.gz 9378154 BLAKE2B d4654e8de621af93fa6ab013bf45ea1c2e8b273f38cf0dddbe00853d197487acf2a9457a33e59fd59b9c5c7dca08a84867a835cdfa8e4a63181df5105889c360 SHA512 41f5e6b8382c08dd0e4285836a3f1308f6666d86387e10899c5ef8839598e097d31a5360cf7d47f2d30c287ad575787ecb44c236ad83c52202cf8895046c56a0
 DIST hypothesis-6.82.3.gh.tar.gz 9378981 BLAKE2B bb73131f9982e8df71e24a5f329a2f34b7e895ffa231d55724f84a3d692608e59a4494a820ea5ee449db4c40f2521548b2dece2f1bcfa9fbd4f0ddbc4dbb9756 SHA512 02b649116630dc6be3cbd659a00c9c55d68c85a9cbf029558fc1c065909a1cadd2fb120615fa3bf7fe4a11f51d26d264cf6730ac4d3165798668d38e62c5d955
 DIST hypothesis-6.82.4.gh.tar.gz 9379010 BLAKE2B 0da8b3ff53f6f2019019ade9a8b42ef62eb90993ca1835b89938d0a36387958e4b32bc6c7ac6345f465682c5fd4d549befa30d083d81fa4af611d16c3df07007 SHA512 22d186203b23409e315bf7341bd51e084785c833318cb32a88c81123cdefb1ae757c89bb025209d36adf720e2a407fe28fabf1d3fb2ae0d2e4363cf69adfe72e
+DIST hypothesis-6.82.5.gh.tar.gz 9378852 BLAKE2B b40cd8cce2c84f535be7f73e91b354fe2688f3bfb8d70f9765de437b8547a77a720ade4263a067e61ee9204ab998cd798917795ea4e7e47c07b897d8bc932434 SHA512 2934c05cb387aff8151a13b03c5a04b07aa54d82a6a41c7e33a2b823f4bb17c534ebaf36672a76392dba7b109ccaf4d808fe7005146ef76f30a1b66e0b7a76c1
diff --git a/dev-python/hypothesis/hypothesis-6.82.5.ebuild b/dev-python/hypothesis/hypothesis-6.82.5.ebuild
new file mode 100644
index 000000000000..19caaada81bf
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.82.5.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{10..12} )
+PYTHON_COMPAT=( python3_{8,9,10,11} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/requests-toolbelt-0.10.1
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
+	local -x HYPOTHESIS_NO_PLUGINS=1
+
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# failing due to warnings from numpy/cython
+				hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+			)
+			;;
+	esac
+
+	epytest -o filterwarnings= -n "$(makeopts_jobs)" \
+		tests/cover tests/pytest tests/quality
+}
+
+python_install() {
+	distutils-r1_python_install
+	if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/mkdocstrings-python/Manifest b/dev-python/mkdocstrings-python/Manifest
index 079a5b4942cd..745ae4a94932 100644
--- a/dev-python/mkdocstrings-python/Manifest
+++ b/dev-python/mkdocstrings-python/Manifest
@@ -1,2 +1,3 @@
 DIST mkdocstrings-python-1.2.1.gh.tar.gz 132468 BLAKE2B 287cae20510818c085bf505fea0f74e39df86538e19bfcb90aa7f6d46fb237158979dc65c7f955d73461fadb4ed35263ef47b9771f224b5793026a9f0b3c86e1 SHA512 147849a88c3bb5347c1cb4293c9ee9c54cb33933bc274dc5bc933f72deb64016c7f7b8ba817311e282c68606d0980571d5713dec7a47e8d6c51168d524af7d97
 DIST mkdocstrings-python-1.3.0.gh.tar.gz 132776 BLAKE2B 894068067f301f40ed9535cd929fdbd40aa396c9c09c0cee7887f50669465cd0422c0b9b240553193df7e7d4c90f0bf2b591000e6568ee3c47256fc5d1f79179 SHA512 caf806d6285281ef84ed78bd6295ec6732d454a602f55f825436d0a17e9ab62e33ac21510d0ccee5d33fb3c117ec416859ad90ce75d608649a277342d1dc5a1c
+DIST mkdocstrings-python-1.4.0.gh.tar.gz 133783 BLAKE2B 6f9f0e157f9b9baa097366690c46e6fd3b8a2a7626eb3cc2c182a37ebb8d9fca55d8eb040f4c43aa1ef52c956e4d258c51a427ce7e7e04eec97d1ab32a2355f6 SHA512 c949180cc3fcfa809fad00374de9030ef6f2f8061251cf0e5857272908fdf9db6626d1f8c8de2a438dd8f7a5256b9e5daa2930519a4ab6324039b6555f547f6b
diff --git a/dev-python/mkdocstrings-python/mkdocstrings-python-1.4.0.ebuild b/dev-python/mkdocstrings-python/mkdocstrings-python-1.4.0.ebuild
new file mode 100644
index 000000000000..63874b5d0ed9
--- /dev/null
+++ b/dev-python/mkdocstrings-python/mkdocstrings-python-1.4.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+DISTUTILS_USE_PEP517=pdm-backend
+
+inherit distutils-r1
+
+DESCRIPTION="Python handler for dev-python/mkdocstrings"
+HOMEPAGE="
+	https://mkdocstrings.github.io/python/
+	https://github.com/mkdocstrings/python/
+	https://pypi.org/project/mkdocstrings-python/
+"
+# Tests need files absent from the PyPI tarballs
+SRC_URI="
+	https://github.com/mkdocstrings/python/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/python-${PV}"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+
+RDEPEND="
+	>=dev-python/griffe-0.33[${PYTHON_USEDEP}]
+	dev-python/mkdocstrings[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mkdocs-material[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export PDM_BUILD_SCM_VERSION=${PV}
diff --git a/dev-python/prettytable/Manifest b/dev-python/prettytable/Manifest
index 888a4abb13a2..32b1a44a79f5 100644
--- a/dev-python/prettytable/Manifest
+++ b/dev-python/prettytable/Manifest
@@ -1,2 +1 @@
-DIST prettytable-3.3.0.tar.gz 54305 BLAKE2B 4d131c16b6c6a0fd64aae1f9f54e286bf27b562888af56a6944d192a24c05d6138c3bdb8f298dcc060db7609d72b8d86ab9664bf6bcf43cd2105bdd433bae3cf SHA512 e190717e2ea89e8faddc7015fd5118e0d93ac5f5318641ce5960b22b4ea3740ff12c4d15812b33655252f258c96f9e848f554d1e678d39761c28025ba7772609
 DIST prettytable-3.8.0.tar.gz 47735 BLAKE2B df31c77eaa4c0b4e7dc5845255383c13d5eff23c7fb8743c4cdd9f726229c84d98a0b4e66e8d42ec4d3e2d43db703d55706705d2e79c4ae8682b7b8b794217a4 SHA512 4719f16e98d4e7b89d8a7f6b2e1d15fd2c44410e5c9edc29a4dbb8ef2899eccff524932afe179bea7a6bbe607a809274b805e76e9ef2e3bf2c77f054635f8f04
diff --git a/dev-python/prettytable/prettytable-3.3.0.ebuild b/dev-python/prettytable/prettytable-3.3.0.ebuild
deleted file mode 100644
index cbd9b3ba6efd..000000000000
--- a/dev-python/prettytable/prettytable-3.3.0.ebuild
+++ /dev/null
@@ -1,32 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{8,9,10,11} pypy3 )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="Easily displaying tabular data in a visually appealing ASCII table format"
-HOMEPAGE="
-	https://github.com/jazzband/prettytable/
-	https://pypi.org/project/prettytable/
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~ia64 ~mips ppc64 ~riscv ~s390 sparc x86"
-
-RDEPEND="
-	dev-python/wcwidth[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	dev-python/setuptools-scm[${PYTHON_USEDEP}]
-	test? (
-		$(python_gen_impl_dep sqlite)
-		dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
diff --git a/dev-python/pydantic-core/Manifest b/dev-python/pydantic-core/Manifest
index 2ab77d849f76..c920445271ac 100644
--- a/dev-python/pydantic-core/Manifest
+++ b/dev-python/pydantic-core/Manifest
@@ -36,6 +36,7 @@ DIST pydantic_core-2.3.1.tar.gz 313680 BLAKE2B 90b7ed134e6dd891dd184f651b4907292
 DIST pydantic_core-2.4.0.tar.gz 322367 BLAKE2B 199f023cb789f742c47f494c02a30a61f2a5d2c50dd557ce21e2ee8c9c4701461b659bebcc7787cb007cda79c56bc8079badd062e23175233c3f2d70b5657f59 SHA512 cb4c8cee8ebc897133600176da3863158d1f7bee4842283a3f793a435860c136519cd9b457080128e8c8cebe9ca3775f6acc918d27e418ab80c76d1960ac21ea
 DIST pydantic_core-2.5.0.tar.gz 329533 BLAKE2B 54881511a5b84b22d7df5be6f7835361810daa7be4d5b73539b20ffc13825026ba5faef03e222fa12a584fa942141d833a3074c1676e1b9113c3aa0adf9aa66f SHA512 02eae124626d55b16b335a2364ae5b23dc9ee28e0dc84b201a01d9c8b7becdaf0d2fdb3f753e48deb11836c500e2a5a3b3a47df1e3f289d17df2b5613269029c
 DIST pydantic_core-2.6.0.tar.gz 334615 BLAKE2B 749ac2213f13c460460ebc45284e1356809907081ade1a3d8178769e4e83adb8ccf47a16f82b8df1fe169113a06154acbd5e604a9df0da9d9070e1c052f5b220 SHA512 9828dc8923c96e3c7716186106467483621e3bab8e5869401476e655edbf6beac4a5f43093b05b2d00054cd92827c2fffe905068d52bf9bcd4d1846fd8d9e626
+DIST pydantic_core-2.6.1.tar.gz 334288 BLAKE2B 663ccdc9adc52d12c1f060f62845a0b9a65b9c39c62e33cec0fc0f7d3b0a7342f80b4ce89f207962382fef3e30e2b0ace8e4ded4ff5e66b61280a182d5dd09fa SHA512 a6207e8e19540e5bdec5e555f7c93342af4810753c4e9a8846416f0badef9174e3907f02a1100b8a86f25d5c44e99142162d128a71037fdc45e2a6f6e4775a20
 DIST pyo3-0.19.1.crate 418297 BLAKE2B 19ad6aa4fba175961b7fe97ae0bc45050f930859972b1b25cf0139bb3436c050ba76b63894f0df26174f141a52ac6abf10fd84c03c056af5a0665e723ae24195 SHA512 b27500cf49f1c6f217d21344d24ac96c07b82c157dd36fa4550b94059da5715ba7d0e085ec07dd5f8a8ac9de4d7e9239c1cceac4337294eb0dc9f6102049d5ff
 DIST pyo3-0.19.2.crate 418228 BLAKE2B ee018b33383fada78cd22643aea9231a8c8a2f19d1eb297f40eec9206c5220f322fff4c926d939a93a24ac6d231a207ebb25afcc0709191151c7ed9af7465efa SHA512 58698183e0f2f0507f8f765bf3e90185c933e78d62f0a9be65c4b1ce8eea19a98fe0341abe7c58cafdacb63a012ec417876dccb7be6facc1360fcb22796fcaf9
 DIST pyo3-build-config-0.19.1.crate 29205 BLAKE2B f88cbf9763fd68f7b30d109ae608efc29e0d4bf6672ee5f31b77342b5f37baa4f981916124af6897ccea3d93990ff889815fc3abbe9ce3fdbd860b6d5698b7da SHA512 311fef01ac2c3ce12485849cb99eba038a36260206308c5af4621fc5393f942e03aae4f6a5fe24ef3005eb781d2161453667ad552d6a371ddd96460b05a2e710
diff --git a/dev-python/pydantic-core/pydantic-core-2.6.1.ebuild b/dev-python/pydantic-core/pydantic-core-2.6.1.ebuild
new file mode 100644
index 000000000000..214950b28f53
--- /dev/null
+++ b/dev-python/pydantic-core/pydantic-core-2.6.1.ebuild
@@ -0,0 +1,137 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=maturin
+# pypy3 is waiting for new pyo3 release
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+CRATES="
+	ahash@0.8.3
+	aho-corasick@1.0.2
+	autocfg@1.1.0
+	base64@0.21.2
+	bitflags@1.3.2
+	cc@1.0.79
+	cfg-if@1.0.0
+	enum_dispatch@0.3.12
+	equivalent@1.0.1
+	form_urlencoded@1.2.0
+	getrandom@0.2.10
+	hashbrown@0.14.0
+	heck@0.4.1
+	idna@0.4.0
+	indexmap@2.0.0
+	indoc@1.0.9
+	itoa@1.0.8
+	libc@0.2.147
+	lock_api@0.4.10
+	memchr@2.5.0
+	memoffset@0.9.0
+	num-bigint@0.4.3
+	num-integer@0.1.45
+	num-traits@0.2.15
+	once_cell@1.18.0
+	parking_lot@0.12.1
+	parking_lot_core@0.9.8
+	percent-encoding@2.3.0
+	proc-macro2@1.0.64
+	pyo3-build-config@0.19.2
+	pyo3-ffi@0.19.2
+	pyo3-macros-backend@0.19.2
+	pyo3-macros@0.19.2
+	pyo3@0.19.2
+	python3-dll-a@0.2.9
+	quote@1.0.29
+	redox_syscall@0.3.5
+	regex-automata@0.3.6
+	regex-syntax@0.7.4
+	regex@1.9.3
+	rustversion@1.0.13
+	ryu@1.0.14
+	scopeguard@1.1.0
+	serde@1.0.183
+	serde_derive@1.0.183
+	serde_json@1.0.104
+	smallvec@1.11.0
+	speedate@0.12.0
+	strum@0.25.0
+	strum_macros@0.25.2
+	syn@1.0.109
+	syn@2.0.28
+	target-lexicon@0.12.9
+	tinyvec@1.6.0
+	tinyvec_macros@0.1.1
+	unicode-bidi@0.3.13
+	unicode-ident@1.0.10
+	unicode-normalization@0.1.22
+	unindent@0.1.11
+	url@2.4.0
+	uuid@1.4.1
+	version_check@0.9.4
+	wasi@0.11.0+wasi-snapshot-preview1
+	windows-targets@0.48.1
+	windows_aarch64_gnullvm@0.48.0
+	windows_aarch64_msvc@0.48.0
+	windows_i686_gnu@0.48.0
+	windows_i686_msvc@0.48.0
+	windows_x86_64_gnu@0.48.0
+	windows_x86_64_gnullvm@0.48.0
+	windows_x86_64_msvc@0.48.0
+"
+
+inherit cargo distutils-r1 pypi
+
+DESCRIPTION="Core validation logic for pydantic written in Rust"
+HOMEPAGE="
+	https://github.com/pydantic/pydantic-core/
+	https://pypi.org/project/pydantic-core/
+"
+SRC_URI+="
+	${CARGO_CRATE_URIS}
+"
+
+LICENSE="MIT"
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0 Apache-2.0-with-LLVM-exceptions MIT Unicode-DFS-2016
+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/typing-extensions-4.7.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=virtual/rust-1.70.0
+	test? (
+		>=dev-python/dirty-equals-0.5.0[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-6.63.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-3.10.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-2.1.0[${PYTHON_USEDEP}]
+		>=dev-python/pydantic-1.10.4[${PYTHON_USEDEP}]
+		>=dev-python/pytz-2022.7.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+QA_FLAGS_IGNORED="usr/lib.*/py.*/site-packages/pydantic_core/_pydantic_core.*.so"
+
+src_prepare() {
+	sed -i -e '/--benchmark/d' pyproject.toml || die
+	sed -i -e '/^strip/d' Cargo.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		tests/benchmarks
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	rm -rf pydantic_core || die
+	epytest -p pytest_mock -p timeout
+}
diff --git a/dev-python/pyfakefs/Manifest b/dev-python/pyfakefs/Manifest
index 792ce1f912d4..84849dc1d808 100644
--- a/dev-python/pyfakefs/Manifest
+++ b/dev-python/pyfakefs/Manifest
@@ -1 +1,2 @@
 DIST pyfakefs-5.2.3.gh.tar.gz 222076 BLAKE2B 01d24021be074058d865ac068f77de69721ad2f826f835f04776e8d17a8f4cfaeb85bce9a948d679951b8f028ef6d6b3377428d76c5d2d46afea3b78dffcee1e SHA512 5e4adeecb1e2341f3dee20d48b387de870cdab4ad27791951f98ba516f8f4cbe4f5e303c83725c2ce5a9cfaf34f771814b07c553983eb283aa7c3fd7f4e7690d
+DIST pyfakefs-5.2.4.gh.tar.gz 222882 BLAKE2B 780f3952886dfb263be97fbcaa99ed0f0bcb804b075b71822d8a5b0db2bd1e12c57daf88b96d3eb8eb4b7fefdde6fb343cec8429bcf4380e4981bea7ca4f780d SHA512 2b933c420393b329d2c3ac6523e650124cce84424e298e1525591be02033d1bbb5d5cc354170ac6875d63e1729f6f79edcf8400d1cb0e419c586ae1cdd491baa
diff --git a/dev-python/pyfakefs/pyfakefs-5.2.4.ebuild b/dev-python/pyfakefs/pyfakefs-5.2.4.ebuild
new file mode 100644
index 000000000000..99d472532735
--- /dev/null
+++ b/dev-python/pyfakefs/pyfakefs-5.2.4.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A fake file system that mocks the Python file system modules"
+HOMEPAGE="
+	https://github.com/pytest-dev/pyfakefs/
+	https://pypi.org/project/pyfakefs/
+"
+SRC_URI="
+	https://github.com/pytest-dev/pyfakefs/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# test for regression with opentimelineio package
+		pyfakefs/pytest_tests/segfault_test.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pyfakefs.pytest_plugin
+}
diff --git a/dev-python/python-cinderclient/python-cinderclient-9.3.0.ebuild b/dev-python/python-cinderclient/python-cinderclient-9.3.0.ebuild
index cc0819bc7ffd..0f11b1c24c42 100644
--- a/dev-python/python-cinderclient/python-cinderclient-9.3.0.ebuild
+++ b/dev-python/python-cinderclient/python-cinderclient-9.3.0.ebuild
@@ -29,7 +29,6 @@ RDEPEND="
 	>=dev-python/requests-2.25.1[${PYTHON_USEDEP}]
 	>=dev-python/stevedore-3.3.0[${PYTHON_USEDEP}]
 "
-# Tests fail with dev-python/prettytable-3.4.0
 BDEPEND="
 	dev-python/pbr[${PYTHON_USEDEP}]
 	test? (
@@ -38,7 +37,6 @@ BDEPEND="
 		dev-python/oslo-serialization[${PYTHON_USEDEP}]
 		dev-python/requests-mock[${PYTHON_USEDEP}]
 		dev-python/testtools[${PYTHON_USEDEP}]
-		<dev-python/prettytable-3.4.0[${PYTHON_USEDEP}]
 	)
 "
 
diff --git a/dev-python/python-glanceclient/python-glanceclient-4.4.0.ebuild b/dev-python/python-glanceclient/python-glanceclient-4.4.0-r1.ebuild
index b557bafc7bae..012eb5d989a2 100644
--- a/dev-python/python-glanceclient/python-glanceclient-4.4.0.ebuild
+++ b/dev-python/python-glanceclient/python-glanceclient-4.4.0-r1.ebuild
@@ -29,7 +29,6 @@ RDEPEND="
 	>=dev-python/pyopenssl-17.1.0[${PYTHON_USEDEP}]
 	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
 	>=dev-python/warlock-1.2.0[${PYTHON_USEDEP}]
-	<dev-python/warlock-2[${PYTHON_USEDEP}]
 	>=dev-python/wrapt-1.7.0[${PYTHON_USEDEP}]
 "
 BDEPEND="
@@ -41,7 +40,6 @@ BDEPEND="
 		dev-python/tempest[${PYTHON_USEDEP}]
 		dev-python/testscenarios[${PYTHON_USEDEP}]
 		dev-python/testtools[${PYTHON_USEDEP}]
-		dev-python/prettytable[${PYTHON_USEDEP}]
 	)
 "
 
diff --git a/dev-python/python-novaclient/python-novaclient-18.3.0.ebuild b/dev-python/python-novaclient/python-novaclient-18.3.0.ebuild
index 0539a5aeb5f8..4bacd3ca0d27 100644
--- a/dev-python/python-novaclient/python-novaclient-18.3.0.ebuild
+++ b/dev-python/python-novaclient/python-novaclient-18.3.0.ebuild
@@ -31,7 +31,6 @@ RDEPEND="
 	>dev-python/requests-2.12.2[${PYTHON_USEDEP}]
 	>=dev-python/stevedore-2.0.1[${PYTHON_USEDEP}]
 "
-# Tests fail with dev-python/prettytable-3.4.0
 BDEPEND="
 	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
 	test? (
@@ -47,7 +46,6 @@ BDEPEND="
 		dev-python/testscenarios[${PYTHON_USEDEP}]
 		dev-python/testtools[${PYTHON_USEDEP}]
 		dev-python/tempest[${PYTHON_USEDEP}]
-		<dev-python/prettytable-3.4.0[${PYTHON_USEDEP}]
 	)
 "
 
diff --git a/dev-python/readme-renderer/Manifest b/dev-python/readme-renderer/Manifest
index f552841985ee..452b85694e7e 100644
--- a/dev-python/readme-renderer/Manifest
+++ b/dev-python/readme-renderer/Manifest
@@ -1 +1,2 @@
 DIST readme_renderer-40.0.tar.gz 32300 BLAKE2B feacff6f82bc59e1e21da99a702004f409b19868356a47c37e01ff1bb52e3b896eaeef2815ccc8d7f20009ce5faf8f3a75d56d1c5f4acbc38b90116d2bef45d1 SHA512 8b598f7882e5e4a3a6c3b010c2252fd4a4babd5e90426dcf35f0586391cc0c2f2f106e016cef24d8fc5f4ed2712e5f88fada4cda160f42158979b6ec14672d36
+DIST readme_renderer-41.0.tar.gz 32420 BLAKE2B 130585144f2344a3991abca2e62a8f2b41db395a440d5e81082e3e8f3f40adb93cb1ad1d68e32f922937e6ae994a916d409de1ab2e780747f7de461c1ad52d6a SHA512 1c40084d75b864d942ea698efdae44ae33046bcdd1515afc78274ae1c5c3a921e19fe709feef1c6e7c1b14a26a1e2fc0c02e16e8476611a036a3e74f50dbea44
diff --git a/dev-python/readme-renderer/readme-renderer-41.0.ebuild b/dev-python/readme-renderer/readme-renderer-41.0.ebuild
new file mode 100644
index 000000000000..a4fbeb6f00e4
--- /dev/null
+++ b/dev-python/readme-renderer/readme-renderer-41.0.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A library for rendering 'readme' descriptions for Warehouse"
+HOMEPAGE="
+	https://github.com/pypa/readme_renderer/
+	https://pypi.org/project/readme-renderer/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/bleach-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/docutils-0.13.1[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.5.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/docutils-0.19[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( README.rst )
+
+distutils_enable_tests pytest
diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index f700df231e59..3eddbe5c3f6f 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -1,3 +1,4 @@
 DIST setuptools-67.8.0.tar.gz 2492475 BLAKE2B 37c34605a58b41e14300e389402fe6debf9eeed20c72ddf53fa798b41484d1522d2b5313c74eb69a687eaf32c225f0931f901f452aebf6f7023b2419d127b808 SHA512 5dda7082fc563ce73d810efc9cdbccb8649fef2eac52f1a902c76ab5ec67a87ff64e36e918d0e3b168f5214d787bdc22e8ef9adeccb77d8d368dcbb48f5fb35d
 DIST setuptools-68.0.0.tar.gz 2194111 BLAKE2B 614a1c69f640ce8d0e510c444e058fecd3810421983a03cd345e43e1148799bed7e5d53ac689a4fe3ce3174d16f2bb719236bd5442b5f06ffc7659d0f4c7d15f SHA512 da6d535a0db6eaf477c8c2148efbc2100fd88a14f3adad44d20e22bf52bee3f00fe86547ea650fe653519bd6ff5f9ef033a55bb3a05fed041e88e78cdfb81d7e
 DIST setuptools-68.1.0.tar.gz 2197742 BLAKE2B 51bb614aac55dd593f49a5b34e6f31d79deea2b379c6c762e35e650e508d69119ce1e7d2ea3bfe501f41780511454e12a3a60d8fa4759a4e17cf4f2925c57d74 SHA512 827e1ed6724f1b6149515ec15528d29648041a9bb674957e2463b2424222378aeff185005c1277ff8fb4b44b5752276d99c1d9aa6d8a152ab80b2d7b1d5b5cc3
+DIST setuptools-68.1.2.tar.gz 2198001 BLAKE2B bd21de32246eb7bd17289536a65e87636c39d8d7712dffa61b07b052fa7e9020fc06fe2de294a4e4782738c4385ff31e6552a6d3f403c3b1da98ea07405d57e8 SHA512 a5a84102ce72f38162b190b91286013cb8660b45f383df04fba65e38c658a5c5b93cdf05f789436618fa596b3ca6688a7c54d31d6d10b729124d3b135660c328
diff --git a/dev-python/setuptools/setuptools-68.1.2.ebuild b/dev-python/setuptools/setuptools-68.1.2.ebuild
new file mode 100644
index 000000000000..1d3366ff48b1
--- /dev/null
+++ b/dev-python/setuptools/setuptools-68.1.2.ebuild
@@ -0,0 +1,123 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+# please bump dev-python/ensurepip-setuptools along with this package!
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{8,9,10,11} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 multiprocessing pypi
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="
+	https://github.com/pypa/setuptools/
+	https://pypi.org/project/setuptools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/nspektr-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/ordered-set-4.0.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3-r2[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.6.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	>=dev-python/wheel-0.37.1-r1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/build[${PYTHON_USEDEP}]
+			>=dev-python/ini2toml-0.9[${PYTHON_USEDEP}]
+			>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/pip-run[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+			dev-python/pytest-timeout[${PYTHON_USEDEP}]
+			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+PDEPEND="
+	>=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+"
+
+src_prepare() {
+	local PATCHES=(
+		# TODO: remove this when we're 100% PEP517 mode
+		"${FILESDIR}"/setuptools-62.4.0-py-compile.patch
+	)
+
+	distutils-r1_src_prepare
+
+	# remove bundled dependencies
+	rm -r */_vendor || die
+
+	# remove the ugly */extern hack that breaks on unvendored deps
+	rm -r */extern || die
+	find -name '*.py' -exec sed \
+		-e 's:from \w*[.]\+extern ::' -e 's:\w*[.]\+extern[.]::' \
+		-i {} + || die
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		return
+	fi
+
+	local EPYTEST_DESELECT=(
+		# network
+		# TODO: see if PRE_BUILT_SETUPTOOLS_* helps
+		setuptools/tests/config/test_apply_pyprojecttoml.py::test_apply_pyproject_equivalent_to_setupcfg
+		setuptools/tests/integration/test_pip_install_sdist.py::test_install_sdist
+		setuptools/tests/test_build_meta.py::test_legacy_editable_install
+		setuptools/tests/test_distutils_adoption.py
+		setuptools/tests/test_editable_install.py
+		setuptools/tests/test_setuptools.py::test_its_own_wheel_does_not_contain_tests
+		setuptools/tests/test_virtualenv.py::test_clean_env_install
+		setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+		setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+		# TODO
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
+		setuptools/tests/test_extern.py::test_distribution_picklable
+		# expects bundled deps in virtualenv
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
+		setuptools/tests/test_editable_install.py::test_editable_with_pyproject
+		# fails if python-xlib is installed
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+		# fails with importlib-metadata-6.6.0
+		setuptools/tests/test_egg_info.py::TestWriteEntries::test_invalid_entry_point
+		# TODO, probably some random package
+		setuptools/tests/config/test_setupcfg.py::TestOptions::test_cmdclass
+	)
+
+	if has_version "<dev-python/packaging-22"; then
+		EPYTEST_DESELECT+=(
+			# old packaging is more lenient
+			setuptools/tests/config/test_setupcfg.py::TestOptions::test_raises_accidental_env_marker_misconfig
+		)
+	fi
+
+	epytest -n "$(makeopts_jobs)" setuptools
+}
diff --git a/dev-python/sphinx-gallery/Manifest b/dev-python/sphinx-gallery/Manifest
index aeaadc8b7cda..8943418154a6 100644
--- a/dev-python/sphinx-gallery/Manifest
+++ b/dev-python/sphinx-gallery/Manifest
@@ -1 +1,2 @@
 DIST sphinx-gallery-0.13.0.tar.gz 403284 BLAKE2B fac67eab0c49a756f4b73b05434c80b5876d241afae66bfd4d2f50b5ffb715f03da3e87146531c90632ecef0d092c5d087c3ada0d01a6df21c8032b3b60d1890 SHA512 26168e25ff46a34d7cf1d2d70e59d5e81bab6e57ec497f2a6e55e5356fb832b8fefc5a19976cc4fb495fdc1ef8b44a33de93cc7a6f376f72c9dbcaa94ed723ef
+DIST sphinx-gallery-0.14.0.tar.gz 408734 BLAKE2B f527eb58b565353722d669edf81a667b7c3e784480500ff03b5567b9214c27951438052db3f2dcba92b24e7224d5cd0017bfbe770132dc96ce3427ca463329a8 SHA512 c8a69af9dec9adf042214de0cb48d510ebb41d7bc4bb1e5767f3982b0e83d9dfa1a26028d939a1785d3894894d396840e437dc5c196bfc5318152d06240d84b9
diff --git a/dev-python/sphinx-gallery/sphinx-gallery-0.14.0.ebuild b/dev-python/sphinx-gallery/sphinx-gallery-0.14.0.ebuild
new file mode 100644
index 000000000000..37802f6f4874
--- /dev/null
+++ b/dev-python/sphinx-gallery/sphinx-gallery-0.14.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Sphinx extension to automatically generate an examples gallery"
+HOMEPAGE="
+	https://github.com/sphinx-gallery/sphinx-gallery/
+	https://sphinx-gallery.github.io/
+	https://pypi.org/project/sphinx-gallery/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/sphinx[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/joblib[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		sphinx_gallery/tests/test_docs_resolv.py::test_embed_code_links_get_data
+		sphinx_gallery/tests/test_full.py::test_run_sphinx
+		sphinx_gallery/tests/test_full.py::test_embed_links_and_styles
+		# require jupyterlite_sphinx
+		sphinx_gallery/tests/test_full.py
+		sphinx_gallery/tests/test_full_noexec.py
+		sphinx_gallery/tests/test_gen_gallery.py::test_create_jupyterlite_contents
+		sphinx_gallery/tests/test_gen_gallery.py::test_create_jupyterlite_contents_non_default_contents
+		sphinx_gallery/tests/test_gen_gallery.py::test_create_jupyterlite_contents_with_jupyterlite_disabled_via_config
+	)
+
+	epytest -o addopts=
+}