Adding metadata

29 files changed, 790 insertions, 2 deletions

diff --git a/dev-python/Faker/Faker-11.1.0.ebuild b/dev-python/Faker/Faker-11.1.0.ebuild
new file mode 100644
index 000000000000..1f1f09ada79c
--- /dev/null
+++ b/dev-python/Faker/Faker-11.1.0.ebuild
@@ -0,0 +1,29 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="A Python package that generates fake data for you"
+HOMEPAGE="https://github.com/joke2k/faker"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/python-dateutil-2.4.2[${PYTHON_USEDEP}]
+	>=dev-python/text-unidecode-1.3[${PYTHON_USEDEP}]
+	!dev-ruby/faker"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP},tiff]
+		dev-python/random2[${PYTHON_USEDEP}]
+		dev-python/validators[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
diff --git a/dev-python/Faker/Manifest b/dev-python/Faker/Manifest
index 4cbd7db26c68..cffc76ec90b8 100644
--- a/dev-python/Faker/Manifest
+++ b/dev-python/Faker/Manifest
@@ -1,2 +1,3 @@
 DIST Faker-10.0.0.tar.gz 1198872 BLAKE2B 60e4f34a597ca11b0699c330f6cdb0f7f387bb6c54d769513f8e091d00242c7ba4e62fa6b3411ad313a4713e9311b729fb6068acfc4a02b66f07c66656677f33 SHA512 0c22b18d16815ee37d2ea79b4142100479c7b9b9f169817dc9e0fe39495f0646e8d61d704ddba7d36eefb6cb3fb744d179a57216abb15c15ee357c8b12b8b5a4
 DIST Faker-11.0.0.tar.gz 1199121 BLAKE2B e5c4e17daa969249dbf1ae69630a79c50e6e51d63db9997872bd22a7e91db1771fdef984ec5912d42815632598339062be20005e4921c846abf3013e6efc8c89 SHA512 687f47ba613bd2117c412da54e293281bf1943eccde8165cc749be5d176a025d250c831d55a509a6923b3542dba4fe5abce23bd80b980bdca742ecaa837d4334
+DIST Faker-11.1.0.tar.gz 1214021 BLAKE2B c4b7b44d19566037135d47bce19895da7bb0eba17c64086ad5f0019bbd49a77aaf4231e6aef8f40aec4811bbe4df209b796773ac5cca6a859ff9b43ea57fe9bc SHA512 646d16bceb3fc5ca8a9004ab7369d7fc6012f0766b2f6b58922a1a415a4bf1ae1af0d5977d58f15792bd794fa2235fb44e626e28f5af168d4e4def8112bab0ca
diff --git a/dev-python/defcon/Manifest b/dev-python/defcon/Manifest
index 4fabdb3b95e2..d7ebac1a235c 100644
--- a/dev-python/defcon/Manifest
+++ b/dev-python/defcon/Manifest
@@ -1 +1,2 @@
+DIST defcon-0.10.0.tar.gz 426111 BLAKE2B 6750ac064677bd1b2a2b49d37792b4e35c923ddd239c521490dd3aa0c40f55a96dcdac156a2511c3bb40605505beb920c66053488bb2bc2508899d4a81f77ddb SHA512 69d48701bdf419080b7acafe2b92c1897358d969d6ea5b78330969b79b9e393a1c53cfb1a17b4d58719329c403ac3a52a4e12828d99b8793d8dd19ddda151c76
 DIST defcon-0.9.0.tar.gz 426109 BLAKE2B ac9e7292a444843f675168120ddb1aee636e3f7569ba9d90660906665b109054c245398ba2de93faf255a412dd9e65569fb0cf68d845636ca1780190b6cdcd21 SHA512 29f0fde5bf9809ef9601497844fed3d537aa02de4404e191f8504808271ad263e3a11ea82f04c78a0fa3e673e511ea6600c707f956f06b3186e87a3ce4d84c13
diff --git a/dev-python/defcon/defcon-0.10.0.ebuild b/dev-python/defcon/defcon-0.10.0.ebuild
new file mode 100644
index 000000000000..e5bd8349f69a
--- /dev/null
+++ b/dev-python/defcon/defcon-0.10.0.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="A set of UFO based objects for use in font editing applications"
+HOMEPAGE="https://github.com/robotools/defcon"
+SRC_URI="https://github.com/robotools/defcon/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE=""
+
+RDEPEND=">=dev-python/fonttools-4.28.5[${PYTHON_USEDEP}]"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/fs[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
diff --git a/dev-python/dns-lexicon/Manifest b/dev-python/dns-lexicon/Manifest
index c07aeccb411f..3d984d62690c 100644
--- a/dev-python/dns-lexicon/Manifest
+++ b/dev-python/dns-lexicon/Manifest
@@ -1 +1,2 @@
 DIST dns-lexicon-3.8.3.tar.gz 7834913 BLAKE2B a72b356d10d0af8367ce9d51d2c4d4a3a1cc8aa26d5edfa2cb1aca4b2eb67acdcadc46f46d5457430708f94fda9654a87ded76fa796c44a4b4e2a0d4f3accd13 SHA512 3035e9c5d073feb0dd910b79d8de02f2e9bfc81f922bce34ad33c22b583896a781e50f85104799a13133121ab5e88a372667cf0014399df50c5a829747d98073
+DIST dns-lexicon-3.8.4.tar.gz 7850337 BLAKE2B f72a338c00346091df2cf53fa01cbc34e81b235cb5100b4993ccf46f738e2588b08b7a57316c07c7eff1c039437e49371193c9952b6fd870f30a2c6b538d3e1e SHA512 7a598b38a847e384fda243b76af523701d80d84a2338ef5745ca9f82284675ace5f84bf93cccfeda101584194c15fdbd0d4d8f69fdd0db60ec42d4c063a7916c
diff --git a/dev-python/dns-lexicon/dns-lexicon-3.8.4.ebuild b/dev-python/dns-lexicon/dns-lexicon-3.8.4.ebuild
new file mode 100644
index 000000000000..223666b993ee
--- /dev/null
+++ b/dev-python/dns-lexicon/dns-lexicon-3.8.4.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_SETUPTOOLS=pyproject.toml
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Manipulate DNS records on various DNS providers in a standardized/agnostic way"
+HOMEPAGE="https://pypi.org/project/dns-lexicon/"
+SRC_URI="https://github.com/AnalogJ/lexicon/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/lexicon-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/tldextract[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/boto3[${PYTHON_USEDEP}]
+		dev-python/zeep[${PYTHON_USEDEP}]
+		dev-python/vcrpy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# Requires the "localzone" module
+	lexicon/tests/providers/test_localzone.py
+	# Requires the "softlayer" module
+	lexicon/tests/providers/test_softlayer.py
+	# Requires the "transip" module
+	lexicon/tests/providers/test_transip.py
+	# Requires the "oci" module
+	lexicon/tests/providers/test_oci.py
+	# Uses tldextract which needs Internet access to download its database
+	lexicon/tests/providers/test_auto.py
+)
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		optfeature_header \
+			"Install the following packages to enable support for additional DNS providers:"
+		optfeature Gransy dev-python/zeep
+		optfeature Route53 dev-python/boto3
+		optfeature DDNS dev-python/dnspython
+	fi
+}
diff --git a/dev-python/git-review/Manifest b/dev-python/git-review/Manifest
index 8ab2955f568a..d1196af7d443 100644
--- a/dev-python/git-review/Manifest
+++ b/dev-python/git-review/Manifest
@@ -1 +1,2 @@
 DIST git-review-2.1.0.tar.gz 62873 BLAKE2B 6685e43da07d4be0ffe3202a6a9be172257a8e665091b457318c118d95f571a9b97e555d4afea85fe590f264039bd86815c5a365fbc484a24b5c4ea748a340c2 SHA512 7beda9e704076285459c29ce2b7c0f07ab180212f24f62fa484430dfb323eb4473f9be030706eeca587d5cfb5cdbba6759aeaec6d377717ebf9a0f0157e1a190
+DIST git-review-2.2.0.tar.gz 64905 BLAKE2B a08b489bb4b53a9cc6510b11238bc947334a187e0ec7dad7e1240cf3efb110a5310cfe4f3278af9311108fcb0b915a9d1eabdd2aeabab3fed0a939cba9f88ae2 SHA512 9a33f6a1e60b0679b248db818a2a4559b4ee6a6b765f2e6a16fd566fd85587be363f837da2118e75bd3e6d54ba3dcc177d3d678d927d75cca6d8ad6ed4e8d4f7
diff --git a/dev-python/git-review/git-review-2.2.0.ebuild b/dev-python/git-review/git-review-2.2.0.ebuild
new file mode 100644
index 000000000000..a9471b4b7ee6
--- /dev/null
+++ b/dev-python/git-review/git-review-2.2.0.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_SETUPTOOLS=
+
+inherit distutils-r1
+
+DESCRIPTION="Tool to submit code to Gerrit"
+HOMEPAGE="https://git.openstack.org/cgit/openstack-infra/git-review"
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://opendev.org/opendev/${PN}.git"
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86 ~x64-cygwin ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE=""
+
+DEPEND=">=dev-python/pbr-4.1.0[${PYTHON_USEDEP}]"
+RDEPEND=">=dev-python/requests-1.1[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	sed -i -e '/manpages/,+1d' setup.cfg || die
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/git-review/git-review-9999.ebuild b/dev-python/git-review/git-review-9999.ebuild
new file mode 100644
index 000000000000..a9471b4b7ee6
--- /dev/null
+++ b/dev-python/git-review/git-review-9999.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_SETUPTOOLS=
+
+inherit distutils-r1
+
+DESCRIPTION="Tool to submit code to Gerrit"
+HOMEPAGE="https://git.openstack.org/cgit/openstack-infra/git-review"
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://opendev.org/opendev/${PN}.git"
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86 ~x64-cygwin ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE=""
+
+DEPEND=">=dev-python/pbr-4.1.0[${PYTHON_USEDEP}]"
+RDEPEND=">=dev-python/requests-1.1[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	sed -i -e '/manpages/,+1d' setup.cfg || die
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index 430e977b9136..cb2877b71ee2 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1 +1,2 @@
 DIST kombu-5.2.1.tar.gz 420402 BLAKE2B 00ddc4418f31c2ddc9d154aed2d4c0cb8555cdf143d08c969f8e79aa7aa44f60c0bfe40d92a4dfa2f6c2a60b9e4f0590468e2016bd0a84e255cb57c570597904 SHA512 12fc3480651475ce8476424665ccf692a5bf1cbf4cd31c35eaa24419c316dc380357cfab0ca5d58ea275e870fa703d3ac258cb84f04886f9342e730aaaba6bf5
+DIST kombu-5.2.3.tar.gz 421943 BLAKE2B f5b8f27e2b1e79d7dc7c92716f90f260454508769e52c0d78ebe94dd0da150cdd6121cc2db30c80cb290c15fc7d94de37973ac180635498b53f171ac8d884c1d SHA512 0e882063e89a25d324ccdf8745f11e1ea51443cc9a80b215e7f31c85053411cf1d5f26b5ffcd52165a15827ee036300a69a8a192af60d975a495a5a0b5ce3954
diff --git a/dev-python/kombu/kombu-5.2.3.ebuild b/dev-python/kombu/kombu-5.2.3.ebuild
new file mode 100644
index 000000000000..4daffb6f4d41
--- /dev/null
+++ b/dev-python/kombu/kombu-5.2.3.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1 optfeature
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="https://pypi.org/project/kombu/ https://github.com/celery/kombu"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/py-amqp-5.0.6[${PYTHON_USEDEP}]
+	<dev-python/py-amqp-6.0.0[${PYTHON_USEDEP}]
+	dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		>=dev-python/boto3-1.4.4[${PYTHON_USEDEP}]
+		>=dev-python/case-1.5.2[${PYTHON_USEDEP}]
+		dev-python/kazoo[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+		dev-python/pycurl[${PYTHON_USEDEP}]
+		>=dev-python/pymongo-3.3.0[${PYTHON_USEDEP}]
+		dev-python/Pyro4[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+		>=dev-python/redis-py-3.3.11[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/zstandard[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx_celery
+
+EPYTEST_IGNORE=(
+	# Unpackaged azure-servicebus
+	t/unit/transport/test_azureservicebus.py
+	# Unpackaged librabbitmq
+	t/unit/transport/test_librabbitmq.py
+	# Unpackaged python-consul
+	t/unit/transport/test_consul.py
+	# AttributeError: test_Etcd instance has no attribute 'patch'
+	t/unit/transport/test_etcd.py
+)
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+	optfeature "Etcd backend" dev-python/python-etcd
+	optfeature "MongoDB backend" dev-python/pymongo
+	optfeature "Pyro 4 backend" dev-python/Pyro4
+	optfeature "Redis backend" dev-python/redis-py
+	optfeature "sqlalchemy backend" dev-python/sqlalchemy
+	optfeature "yaml backend" dev-python/pyyaml
+	optfeature "Zookeeper backend" dev-python/kazoo
+	optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+	optfeature "brotli compression" "app-arch/brotli[python]"
+	optfeature "zstd compression" dev-python/zstandard
+}
diff --git a/dev-python/nltk/Manifest b/dev-python/nltk/Manifest
index 51bbfb48957c..7f55e3a26d6d 100644
--- a/dev-python/nltk/Manifest
+++ b/dev-python/nltk/Manifest
@@ -3,3 +3,4 @@ DIST nltk-3.6.3.tar.gz 2824924 BLAKE2B fcab6647f43f4bf139857e9f4202aee688f564851
 DIST nltk-3.6.4.tar.gz 2828051 BLAKE2B f757c9c6d0b5ab6105e90e1a46fc6671d5f661f9b1b58026ccb43c00ff4969a98cbc2005670e0a81218ef4d18e45c37bb380c53be4ca60984344b11a0c8dbc54 SHA512 ba9acaa596c7f9246cd2f8da37b58146021dc2c246306fab68a37ef833a5a346b1aa7033d43b9e72b52aeda1cf8e303c7c690d1ca439f6f58dc673aa63a37298
 DIST nltk-3.6.5.tar.gz 2830237 BLAKE2B 9396e916fa847af727f1ca52075aed0bf708266512e62fd3f4c64bb3a5be3f2e7d6820108ab5418f6c6d44626de6fe7be9831a5acd33e6ebb898d910b1d68e91 SHA512 5614eca28576ba8783f847ec7a149ea4b83d57bb8af0f7af79ccdd75234b9f1cf957c63cb4b178f5455e2311da430344d8209b081a7097759959857ffb10005e
 DIST nltk-3.6.6.tar.gz 2847793 BLAKE2B 63807a39752be582ec8a4bb5edc1b89552b47a7743f5c0661bf3334febbf499e174f5e334d7669352cb81543c3f885168f1cf0fed993f2b54e3d7524c7a0bec0 SHA512 0b39eeb039d8b42d063aadf251aa3cb80b5aaee9171554009b282df70a0d6e3f7d335534b82cb8c5b474de28b37b0a38ef62d580d1145fba1effd54fb770bc5d
+DIST nltk-3.6.7.tar.gz 2848416 BLAKE2B 8bc6672c17741c93da15b3c4ec9af484915ffd9fc857dbbfa94d949063c8e44c5f672e076b69213a033b7bec8e14baa099c69748eef4688fa09635de662f5037 SHA512 07f117835e1bf99d73a03f1279da0104a955e36f41c9648be19652481c58758900d5d2ff4633203254cee1e27c6cc129fe5d6e388de0711f2052e3e76a746edf
diff --git a/dev-python/nltk/nltk-3.6.7.ebuild b/dev-python/nltk/nltk-3.6.7.ebuild
new file mode 100644
index 000000000000..041b2d4b4550
--- /dev/null
+++ b/dev-python/nltk/nltk-3.6.7.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="sqlite,tk?,xml(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Natural Language Toolkit"
+HOMEPAGE="https://www.nltk.org/ https://github.com/nltk/nltk/"
+SRC_URI="https://github.com/nltk/nltk/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
+IUSE="tk"
+
+RDEPEND="
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/joblib[${PYTHON_USEDEP}]
+	dev-python/regex[${PYTHON_USEDEP}]
+	dev-python/tqdm[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/joblib[${PYTHON_USEDEP}]
+		>=dev-python/nltk-data-20211221
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pyparsing[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/twython[${PYTHON_USEDEP}]
+		sci-libs/scikit-learn[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+	)"
+PDEPEND="dev-python/nltk-data"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Internet
+	unit/test_downloader.py::test_downloader_using_existing_parent_download_dir
+	unit/test_downloader.py::test_downloader_using_non_existing_parent_download_dir
+)
+
+src_prepare() {
+	# requires unpackaged pycrfsuite
+	sed -i -e '/>>>/s@$@ # doctest: +SKIP@' nltk/tag/crf.py || die
+	# replace fetching from network with duplicate file URL
+	sed -e 's@https://raw.githubusercontent.com/nltk/nltk/develop/nltk/test/toy.cfg@nltk:grammars/sample_grammars/toy.cfg@' \
+		-i nltk/test/data.doctest || die
+
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	cd nltk/test || die
+	distutils-r1_src_test
+}
diff --git a/dev-python/pip/pip-21.3.1-r1.ebuild b/dev-python/pip/pip-21.3.1-r1.ebuild
index aab618a25419..7893c0df21b7 100644
--- a/dev-python/pip/pip-21.3.1-r1.ebuild
+++ b/dev-python/pip/pip-21.3.1-r1.ebuild
@@ -32,7 +32,7 @@ SRC_URI="
 "
 
 LICENSE="MIT"
-KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~sparc x86"
+KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ppc64 ~riscv ~sparc x86"
 SLOT="0"
 IUSE="test vanilla"
 RESTRICT="!test? ( test )"
diff --git a/dev-python/pybind11/Manifest b/dev-python/pybind11/Manifest
index 0e1154459ca6..bad20830777f 100644
--- a/dev-python/pybind11/Manifest
+++ b/dev-python/pybind11/Manifest
@@ -1 +1,2 @@
 DIST pybind11-2.8.1.tar.gz 693075 BLAKE2B 00f691121858bbe019b5398ab5418523b352f29716901ec6572817e3a35efeb953a9a1542ad37830aab6b9e5a6d6dd56c7aee390772f1d992ef570e03472ebd8 SHA512 6738b4551a1ca2fdf6676be78216b9056cecf8b4d125f0d1aaae9929614bcbf4a9b233fc3c52b8f9dfd19a9ca1496515e6748c1afd8968b9c52c9a1e8b28da10
+DIST pybind11-2.9.0.tar.gz 698784 BLAKE2B bfbe173d580131e445d759bd9b1a8929ceb9fc357a1ed8873aa8024fb9226a37bb97293dc0189a67ae61a232f3790ca6f635a30d0a0401c867cde98f1010438c SHA512 87184c9e09e1340f2d34786a66560fe77684a3629b517f78321073a1f0dfdb766365d3698dcf6f08e5141b1f4da50ec917e61b36538e5a1ec9fd1b68f29cd396
diff --git a/dev-python/pybind11/pybind11-2.9.0.ebuild b/dev-python/pybind11/pybind11-2.9.0.ebuild
new file mode 100644
index 000000000000..544bf8c0793a
--- /dev/null
+++ b/dev-python/pybind11/pybind11-2.9.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit cmake distutils-r1
+
+DESCRIPTION="AST-based Python refactoring library"
+HOMEPAGE="https://pybind11.readthedocs.io/en/stable/"
+SRC_URI="https://github.com/pybind/pybind11/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+
+RDEPEND="
+	dev-cpp/eigen:3
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	export PYBIND11_USE_CMAKE=1
+
+	cmake_src_prepare
+	distutils-r1_python_prepare_all
+}
+
+python_configure() {
+	local mycmakeargs=(
+		# disable forced lto
+		-DPYBIND11_LTO_CXX_FLAGS=
+		-DPYBIND11_INSTALL=ON
+		-DPYBIND11_TEST=$(usex test)
+	)
+	cmake_src_configure
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	# Compilation only does anything for tests
+	use test && cmake_src_compile
+}
+
+python_test() {
+	cmake_build check
+}
+
+python_install() {
+	distutils-r1_python_install
+	cmake_src_install
+}
diff --git a/dev-python/pytables/Manifest b/dev-python/pytables/Manifest
index bb12893a62e8..0ef697796364 100644
--- a/dev-python/pytables/Manifest
+++ b/dev-python/pytables/Manifest
@@ -1 +1,2 @@
 DIST tables-3.6.1.tar.gz 4641089 BLAKE2B 4ef44b1263f40babe6719bac911ab191e9cb0c58c377705b755fa83f1fba5af1d0fab10b0b45bd6af619a9dce4842a80afad8d8fbab64c3be4f35a1b3f117ee3 SHA512 7f018b70251095049bce9075be4e19f72efba9d39121a35c4521f634b1dd5b81ab6de47df3bb44ad6b8b2dbdbff4e6d0985ad1a7b2f13b44f920c0935e5830ff
+DIST tables-3.7.0.tar.gz 8227955 BLAKE2B 0d5b7b765375c4787f1210138e5fd02e3c0ce429ef209a3a8d4fd3bc094f68486ab6f4d0a960ce86efea6991ed691ef2a3e9e8f37a49fe91cb8d6372cadea80e SHA512 eaa368d063b5fad87e6d0f9ab6f02da0b2a3542740a52fe8c2bb58e41121495d07b6d2710ad402a28891294aa61a11238c6a7e2cf2933a1bb11391b79cf4fd13
diff --git a/dev-python/pytables/pytables-3.7.0.ebuild b/dev-python/pytables/pytables-3.7.0.ebuild
new file mode 100644
index 000000000000..a183fe972d6c
--- /dev/null
+++ b/dev-python/pytables/pytables-3.7.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="threads(+)"
+
+MY_PN=tables
+MY_P=${MY_PN}-${PV}
+inherit distutils-r1
+
+DESCRIPTION="Hierarchical datasets for Python"
+HOMEPAGE="https://www.pytables.org/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	app-arch/bzip2:0=
+	app-arch/lz4:0=
+	>=app-arch/zstd-1.0.0:=
+	>=dev-libs/c-blosc-1.11.1:0=
+	dev-libs/lzo:2=
+	>=dev-python/numpy-1.19[${PYTHON_USEDEP}]
+	>=sci-libs/hdf5-1.8.4:=
+"
+RDEPEND="${DEPEND}
+	>=dev-python/numexpr-2.6.2[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]"
+BDEPEND="
+	>=dev-python/cython-0.21[${PYTHON_USEDEP}]
+	virtual/pkgconfig
+	test? (
+		${RDEPEND}
+	)
+"
+
+python_prepare_all() {
+	export {BLOSC,BZIP2,LZO,HDF5}_DIR="${ESYSROOT}"/usr
+	export PYTABLES_NO_EMBEDDED_LIBS=1
+	export USE_PKGCONFIG=TRUE
+
+	rm tables/*.c || die
+	sed -e "s:/usr:${EPREFIX}/usr:g" \
+		-i setup.py || die
+	rm -r c-blosc/{blosc,internal-complibs} || die
+	sed -i -e '/_version/ s/\\s\*/\\s\+/' setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile -j1
+}
+
+python_test() {
+	cd "${BUILD_DIR}"/lib* || die
+	"${EPYTHON}" tables/tests/test_all.py -v || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r contrib examples
+		docompress -x /usr/share/doc/${PF}/{contrib,examples}
+	fi
+}
diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index 7528c397b80c..d17acb7a3d51 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -7,3 +7,4 @@ DIST setuptools-59.5.0.tar.gz 2281671 BLAKE2B 51b3435a1d7962a06f7cf07c31487a1404
 DIST setuptools-59.6.0.tar.gz 2281973 BLAKE2B 1e7ffc94626684f7e82a1bbba14889af052898f87f79205618fb76d78252397d3fb555778cb3920d2eed55bc1ee2c95ceec9206940269a4ba35b3bc44eb91226 SHA512 25472ec7c167e07113c6645880952458969b146766b64224ec8f40dfc2a29b23e47104b63e806292ec81ee4e9dbbdc4663228f39b4412b586cba644f69b52309
 DIST setuptools-59.8.0.tar.gz 2282358 BLAKE2B 2f1b49285fc70420e24f958c4955200ef0407a7f3aa52fd581a165fd47c7bbde8366c26963f1bbb36f0f77797c12cbb9016fdc69e1a5cc696bb67aacca16d140 SHA512 d906558b498bda8abf28831224502c6f0290a4cdbf087fe07af8321dba3dfd1e19fa5b4a820033e54c4561b82ea8ec54c287b4fd657892ed28c2a7de91a9107e
 DIST setuptools-60.1.0.tar.gz 2281751 BLAKE2B d6302564ccb841232561c479959d2ed412888b49c07f774f194214ded659d7d45c5328570318ded9ff7eb81fc08e20b8be576f7a38099cfb855833955bbdb3a6 SHA512 9dba9022be345f5e0c9a915cfd8a24b441e813e703c817f40cd36236d1de1af8a5227acd886ca5910f1900e0c6ed5836f181117c11486009588a9777d6855032
+DIST setuptools-60.1.1.tar.gz 2282219 BLAKE2B 0e24774592fc10cccccd5b4be24ca11d7d2831962f7ca41e92c859488aeee6c133657a2971258d1954f8f1c6092459ea5e0fd7be549b0d74e5e2689b36f10571 SHA512 94804f82d1debbeefce0fc4101b9e9854425fd85ba59eec221c8f596826af8a44b03d80c367ff7948fd121f84573426c704140d6fdfc8c022040cc32ba14f634
diff --git a/dev-python/setuptools/setuptools-60.1.1.ebuild b/dev-python/setuptools/setuptools-60.1.1.ebuild
new file mode 100644
index 000000000000..d386091769f9
--- /dev/null
+++ b/dev-python/setuptools/setuptools-60.1.1.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+# Set to 'manual' to avoid triggering install QA check
+DISTUTILS_USE_SETUPTOOLS=manual
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 multiprocessing
+
+CPY_PATCHSET="python-gentoo-patches-3.10.0_p1"
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="https://github.com/pypa/setuptools https://pypi.org/project/setuptools/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+	https://dev.gentoo.org/~floppym/python/${CPY_PATCHSET}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/jaraco-envs[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+		' python3_{8..10} pypy3)
+	)
+"
+PDEPEND="
+	>=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]"
+
+# Force in-source build because build system modifies sources.
+DISTUTILS_IN_SOURCE_BUILD=1
+
+DOCS=( {CHANGES,README}.rst )
+
+src_prepare() {
+	# apply distutils patches to the bundled distutils
+	pushd setuptools/_distutils >/dev/null || die
+	# TODO: distutils C++ patch?
+	eapply -p3 "${WORKDIR}/${CPY_PATCHSET}/0006-distutils-make-OO-enable-both-opt-1-and-opt-2-optimi.patch"
+	popd >/dev/null || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x SETUPTOOLS_USE_DISTUTILS=stdlib
+
+	# keep in sync with python_gen_cond_dep above!
+	has "${EPYTHON}" python3.{8..10} pypy3 || continue
+
+	distutils_install_for_testing
+	local EPYTEST_DESELECT=(
+		# network
+		setuptools/tests/test_distutils_adoption.py
+		'setuptools/tests/test_virtualenv.py::test_pip_upgrade_from_source[None]'
+		# unhappy with pytest-xdist?
+		setuptools/tests/test_easy_install.py::TestUserInstallTest::test_local_index
+		# TODO
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+		setuptools/tests/test_test.py::test_tests_are_run_once
+	)
+
+	# test_easy_install raises a SandboxViolation due to ${HOME}/.pydistutils.cfg
+	# It tries to sandbox the test in a tempdir
+	HOME="${PWD}" epytest \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" setuptools
+}
+
+python_install() {
+	export DISTRIBUTE_DISABLE_VERSIONED_EASY_INSTALL_SCRIPT=1
+	distutils-r1_python_install
+}
diff --git a/dev-python/sphinxcontrib-spelling/Manifest b/dev-python/sphinxcontrib-spelling/Manifest
index 9bd0c65c6c40..3f8598b49bb2 100644
--- a/dev-python/sphinxcontrib-spelling/Manifest
+++ b/dev-python/sphinxcontrib-spelling/Manifest
@@ -1,2 +1,3 @@
 DIST sphinxcontrib-spelling-7.2.1.tar.gz 49584 BLAKE2B 7211acfe344b157c0d44f356aef4c31fabcb1b30256cec1693fa67d2652d80c8f3657441c193f82ef26e0e7acd7d141732bef0704462a292355d70a18ab3c2be SHA512 e9b9709b627545e1191d64753c97c0cf65e100d5379e7cc1da46faf9c5d5ea0eeb6c7aafe99331f9518488fb0801c245e0c1fa9853360bb6cf373515a4fed2ed
 DIST sphinxcontrib-spelling-7.3.0.tar.gz 49853 BLAKE2B 3bf7c6433a5de6b109891f1546f109ce7dc5870c0932f49a2dfbc1356c365ba48f885af21e0873284112d8b7b67dbb24730373a16e6786ba7e15f2bc23dc8360 SHA512 25b1902547e4ed172ec437aca0868f458c60aab8dacbeeec7ec1c57a93716672986b815aadb9c129fc6b068b5e4d7e96f6200160c0b688e67314abf290e4ff17
+DIST sphinxcontrib-spelling-7.3.1.tar.gz 51104 BLAKE2B 8d757b492ce5bcb103bc604923da928f0440d4d0b882743d14b60fef21cfb423ea93a1e79f309b7cf27e8385ac94c01b24163a17407609ee20b9ec82dff63f62 SHA512 53f2532ff31a82c1cf568400a6066f319da3331c960446478bcd37e9293f4d080061b9c4914ac308e89878f432b6573ff782c5faba0f557384da55f202e68479
diff --git a/dev-python/sphinxcontrib-spelling/sphinxcontrib-spelling-7.3.1.ebuild b/dev-python/sphinxcontrib-spelling/sphinxcontrib-spelling-7.3.1.ebuild
new file mode 100644
index 000000000000..e477c7b5d2b5
--- /dev/null
+++ b/dev-python/sphinxcontrib-spelling/sphinxcontrib-spelling-7.3.1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Sphinx spelling extension"
+HOMEPAGE="https://github.com/sphinx-contrib/spelling"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/pyenchant[${PYTHON_USEDEP}]
+	dev-python/sphinx[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/pbr[${PYTHON_USEDEP}]
+	test? (
+		app-dicts/myspell-en
+	)
+"
+
+# The doc can only be built from a git repository
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# requires the git repo
+	tests/test_filter.py::test_contributors
+	# fails when started via "python -m pytest"
+	"tests/test_filter.py::test_importable_module_skip[__main__-False]"
+)
+
+# We don't want distutils_enable_tests to add the namespace
+# package to BDEPEND under "test?". Therefore we add it to RDEPEND
+# after running distutils_enable_tests.
+RDEPEND+="
+	dev-python/namespace-sphinxcontrib[${PYTHON_USEDEP}]
+"
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${ED}" -name '*.pth' -delete || die
+}
diff --git a/dev-python/tappy/Manifest b/dev-python/tappy/Manifest
index 74f6caad1353..79eeb27bb084 100644
--- a/dev-python/tappy/Manifest
+++ b/dev-python/tappy/Manifest
@@ -1 +1,2 @@
 DIST tap.py-3.0.tar.gz 141764 BLAKE2B 0d65d9c0691deef31475cf6db172e41340e112cacda240d32a55338665632613f09c98d0c7dcfbf28be997079f789054d71f1059fb74228507041163df9710a1 SHA512 58b0928dd28ba525d9bb5edfab5606cb67af15e75a5f03d2648280d30377e2aa23b314ed41dba3b09b7dfa1aefead53674df43b6087e552b9aa937472838e7db
+DIST tap.py-3.1.tar.gz 133208 BLAKE2B a41e4d6e06cfc4283ea8e1df1895569a35d7041721760a16a626d99e60bde0f4b45dc517408b67c893d1eafc3aebe9e7fab4eb158d1e13a0b99a85602beaf440 SHA512 4a3b5c5fb54ee1343cfee9bc154e812066d745c020a2c3391761c3e407b7b8428412c799df4963a385e4563ffe3b31e16055cb76ab5940ab6156e57dcf4a4d3a
diff --git a/dev-python/tappy/tappy-3.1.ebuild b/dev-python/tappy/tappy-3.1.ebuild
new file mode 100644
index 000000000000..dc69450a801b
--- /dev/null
+++ b/dev-python/tappy/tappy-3.1.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1 optfeature
+
+MY_PN=tap.py
+DESCRIPTION="Test Anything Protocol (TAP) tools"
+HOMEPAGE="https://github.com/python-tap/tappy https://pypi.org/project/tap.py/"
+SRC_URI="mirror://pypi/${MY_PN::1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+S=${WORKDIR}/${MY_PN}-${PV}
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	dev-python/Babel[${PYTHON_USEDEP}]
+	test? (
+		dev-python/more-itertools[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests unittest
+distutils_enable_sphinx docs
+
+pkg_postinst() {
+	optfeature "YAML blocks associated with test results" \
+		"dev-python/more-itertools dev-python/pyyaml"
+}
diff --git a/dev-python/tomli-w/tomli-w-1.0.0.ebuild b/dev-python/tomli-w/tomli-w-1.0.0.ebuild
index f736f3e1ae22..3ff114a38600 100644
--- a/dev-python/tomli-w/tomli-w-1.0.0.ebuild
+++ b/dev-python/tomli-w/tomli-w-1.0.0.ebuild
@@ -18,7 +18,7 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~sparc x86"
+KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ppc64 ~riscv ~sparc x86"
 
 BDEPEND="
 	test? ( dev-python/tomli[${PYTHON_USEDEP}] )"
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index f10eb6c02733..9c408f778335 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1 +1,2 @@
 DIST tox-3.24.4.tar.gz 306760 BLAKE2B 332c99d021bc3c25549fd95d051baaa1f0dc3aaf776928320826bb7e6bce6444fd5a993e1dbff3a4ebbde9dbb59e30d07eae4b04096294b3a186b130b8312587 SHA512 49e2cb74f119b5cc049d2a64479e56307cea1f36a5586840cca12cb8f4ce8a2ba991cc6142bef7f095a7d32b44f7513f89cce56d89deaff0e12194ceb3da6249
+DIST tox-3.24.5.tar.gz 306305 BLAKE2B a6d3338d21068d9123505a29da3beec4fd5a15c263bcaf5ba62f65a253d04e11d453bef159d06e88b2cbac9a895d786d0d9444cc16cd3de7a868eac6919b82ea SHA512 4e1ef81c978977e905edbdc00ff971eb4132b9009ce21456fcebf95d8ee2c583e04e464f1db5ca6e5454f4f1ad0353ffc9df7898f6389fe8084dc5b9726ca59b
diff --git a/dev-python/tox/tox-3.24.5.ebuild b/dev-python/tox/tox-3.24.5.ebuild
new file mode 100644
index 000000000000..385cb1adde98
--- /dev/null
+++ b/dev-python/tox/tox-3.24.5.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="https://tox.readthedocs.io https://github.com/tox-dev/tox https://pypi.org/project/tox/"
+SRC_URI="https://github.com/tox-dev/tox/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+# doc disabled because of missing deps in tree
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-0.12[${PYTHON_USEDEP}]
+	dev-python/pip[${PYTHON_USEDEP}]
+	dev-python/py[${PYTHON_USEDEP}]
+	>=dev-python/six-1.14[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-16.0.0[${PYTHON_USEDEP}]"
+# TODO: figure out how to make tests work without the package being
+# installed first.
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/flaky-3.4.0[${PYTHON_USEDEP}]
+		>=dev-python/freezegun-0.3.11[${PYTHON_USEDEP}]
+		>=dev-python/pytest-4.0.0[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)"
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# broken without Internet
+		tests/unit/session/test_provision.py::test_provision_non_canonical_dep
+		tests/integration/test_provision_int.py::test_provision_interrupt_child
+
+		# expects python2 to exist
+		tests/unit/interpreters/test_interpreters.py::test_tox_get_python_executable
+
+		# fragile and relies on checking stdout
+		tests/unit/util/test_spinner.py::test_spinner_progress
+	)
+
+	[[ ${EPYTHON} != pypy3 ]] && EPYTEST_DESELECT+=(
+		# TODO?
+		tests/unit/interpreters/test_interpreters.py::test_find_alias_on_path
+
+		# broken without tox installed first
+		# TODO: why it can't import itself?
+		tests/integration/test_parallel_interrupt.py::test_parallel_interrupt
+	)
+
+	distutils_install_for_testing --via-venv
+	epytest --no-network
+}
diff --git a/dev-python/virtualenv/Manifest b/dev-python/virtualenv/Manifest
index 952885585766..c571b96f5701 100644
--- a/dev-python/virtualenv/Manifest
+++ b/dev-python/virtualenv/Manifest
@@ -1 +1,2 @@
 DIST virtualenv-20.10.0.tar.gz 9007218 BLAKE2B 1fd37b38679b7375c1eb6e9644418b1653cb6a8dab194c8553fa113cf4a801a7c1d5e6490067767cfb198a0ef2b5ab9cf166783b9c6fac0b2c8b538949c11804 SHA512 df940aa29801a39d39be46d3518a99e93efb2113650abf81d00b4545183ec6806823ce8b754c5a3c951cb64e941944421046c709ed3de6a925489e5ac1988d48
+DIST virtualenv-20.11.1.tar.gz 9952979 BLAKE2B d8e44f5a8fedfca4eed79798be74ccfca86af2cacc076d797832028363c2d5269194e711d4511a415420285bc408373a641248a5a96cfaea326f60e023129d65 SHA512 c378bd088d9f2f6a07128d6d04b71554ad7c4de6227baea68ea486c8e10c99c40818eb9bf98cb4c950e64d0aeed4d2be40c101fbd6005d48d2eccaea0382d581
diff --git a/dev-python/virtualenv/virtualenv-20.11.1.ebuild b/dev-python/virtualenv/virtualenv-20.11.1.ebuild
new file mode 100644
index 000000000000..be2cf623ac94
--- /dev/null
+++ b/dev-python/virtualenv/virtualenv-20.11.1.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+DISTUTILS_USE_SETUPTOOLS=manual
+
+inherit distutils-r1
+
+DESCRIPTION="Virtual Python Environment builder"
+HOMEPAGE="
+	https://virtualenv.pypa.io/en/stable/
+	https://pypi.org/project/virtualenv/
+	https://github.com/pypa/virtualenv/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/backports-entry_points_selectable-1.0.4[${PYTHON_USEDEP}]
+	>=dev-python/distlib-0.3.1[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-41[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]"
+# coverage is used somehow magically in virtualenv, maybe it actually
+# tests something useful
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		>=dev-python/pip-20.0.2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-freezegun-0.4.1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-1.3.4[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+		>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+	)"
+
+# (unpackaged deps)
+#distutils_enable_sphinx docs \
+#	dev-python/sphinx-argparse \
+#	dev-python/sphinx_rtd_theme \
+#	dev-python/towncrier
+distutils_enable_tests pytest
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		tests/unit/activation/test_xonsh.py
+		tests/unit/seed/embed/test_bootstrap_link_via_app_data.py::test_seed_link_via_app_data
+		tests/unit/create/test_creator.py::test_cross_major
+	)
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-pypy3-posix-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-pypy3-posix-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-pypy3-posix-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-pypy3-posix-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-venv-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-venv-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-venv-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-venv-copies-global]'
+		'tests/unit/create/test_creator.py::test_zip_importer_can_import_setuptools'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.9-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.9--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.10-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.10--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.9-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.9--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.10-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.10--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3--bin-]'
+	)
+
+	distutils_install_for_testing
+	epytest
+}
+
+pkg_postinst() {
+	elog "Please note that while virtualenv package no longer supports"
+	elog "Python 2.7, you can still create py2.7 virtualenvs via:"
+	elog "  $ virtualenv -p 2.7 ..."
+}