Adding metadata

28 files changed, 693 insertions, 13 deletions

diff --git a/dev-python/GitPython/GitPython-3.1.43.ebuild b/dev-python/GitPython/GitPython-3.1.43.ebuild
new file mode 100644
index 000000000000..66ade3a0c3d3
--- /dev/null
+++ b/dev-python/GitPython/GitPython-3.1.43.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+TEST_P=GitPython-${PV}
+GITDB_P=gitdb-4.0.11
+SMMAP_P=smmap-5.0.1
+
+DESCRIPTION="Library used to interact with Git repositories"
+HOMEPAGE="
+	https://github.com/gitpython-developers/GitPython/
+	https://pypi.org/project/GitPython/
+"
+SRC_URI+="
+	test? (
+		https://dev.gentoo.org/~mgorny/dist/${TEST_P}.gitbundle
+		https://dev.gentoo.org/~mgorny/dist/${GITDB_P}.gitbundle
+		https://dev.gentoo.org/~mgorny/dist/${SMMAP_P}.gitbundle
+	)
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-vcs/git
+	>=dev-python/gitdb-4.0.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/ddt-1.1.1[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	git config --global user.email "travis@ci.com" || die
+	git config --global user.name "Travis Runner" || die
+
+	git clone "${DISTDIR}/${TEST_P}.gitbundle" "${T}"/test || die
+	git clone "${DISTDIR}/${GITDB_P}.gitbundle" \
+		"${T}"/test/git/ext/gitdb || die
+	git clone "${DISTDIR}/${SMMAP_P}.gitbundle" \
+		"${T}"/test/git/ext/gitdb/gitdb/ext/smmap || die
+
+	cd "${T}"/test || die
+	git rev-parse HEAD > .git/refs/remotes/origin/master || die
+	TRAVIS=1 ./init-tests-after-clone.sh || die
+	cat test/fixtures/.gitconfig >> ~/.gitconfig || die
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# performance tests are unreliable by design
+		test/performance
+		# unimportant and problematic
+		test/test_installation.py
+		# Internet
+		test/test_quick_doc.py::QuickDoc::test_cloned_repo_object
+		# TODO
+		test/test_submodule.py::TestSubmodule::test_base_rw
+		test/test_submodule.py::TestSubmodule::test_root_module
+	)
+
+	epytest -o addopts= test
+}
diff --git a/dev-python/GitPython/Manifest b/dev-python/GitPython/Manifest
index 143fbc425d2f..3212f57d8398 100644
--- a/dev-python/GitPython/Manifest
+++ b/dev-python/GitPython/Manifest
@@ -1,4 +1,6 @@
 DIST GitPython-3.1.42.gitbundle 10271846 BLAKE2B 72023a523c0bf888d1fa356a303feff19e142018d7d21722510b7fff69174794feed8fdda84c6fc4c8738c551634924331e48eb82dac71d8c5ebcf145296f6bd SHA512 c7b5ce6bf4500f6350bd1b260317e235fb16d4b8d3dfce9849a845a96d466f61eba9d40f18a0c7d302718f856d08f9c50bde811cadedb78d1dd2ebddaf9cfe48
 DIST GitPython-3.1.42.tar.gz 203449 BLAKE2B 7c18cb6cf0cc10b3269889bd7f4b0c3b61fd0ed765b3723c5bdf331a6e030bdc76587ce1c8e3d8ca5d7cb003968b74c6079b466a6afd3326c418f16e81ed9291 SHA512 f83d5fadc5fbd4d7837d42bc78bc07a9609bb0a10f5938de8d6c88da91de5638fafd6df23e468f7c23c19e11b4fbf273c19858336791ff199997dbe4e1aec91e
+DIST GitPython-3.1.43.gitbundle 10674326 BLAKE2B c430e6fec138077502dce16a1a100459c30134af7865a2e228646791465a7176ee3ef4db5cc83081f56b5e9877aeb4ba7e54b0526d6c2f594520335db4b48e9e SHA512 8c4b2fdf2e382393420bee1cb19929171d72e72669ac3ef96ff112119d803775aae92a14908b9bd51873f102ab85dfadd940b0789da6179b0f99354ae4b6d469
+DIST GitPython-3.1.43.tar.gz 214149 BLAKE2B bc95520b839a43b88571678d7dadd3998a613a4e4f5b0e59f8740add7794767db2820e2d68a98940976ed27fa57b6e487895b1f3d2894b55f1d7f4e06757a461 SHA512 c193418bbb6ebb4f202c4f6aa95b731acf319d6560db176aa7126cf848a1f11eea9f432c4ff6812e8ddb5f8386b1fa5e10335fbf170f3ec3ac5fd2dcde783415
 DIST gitdb-4.0.11.gitbundle 1620355 BLAKE2B 8095193318d4262b8ebb04f35a0500eda8757057ed472dbaaece53e6afa6227e2b2c02a2be5daa5e4c0cc43dcbb5046555407d3d7c8dbed0bc5c415515032b8d SHA512 17e404b335a3c081f4058aeba5c57e5697a580f8ad7a280fde868968cf48f5a0852bfa45019eab730279582c0c536f8204e973d93af09da05908477329d73360
 DIST smmap-5.0.1.gitbundle 362567 BLAKE2B 72c8b48ad3250a33b94218c145c02033dee84c1da5f1eea57983a58699262d51844be675330d95c7d64924b6aeaacd4b0a57e9a5acad3be184aaad62102202e7 SHA512 9ca8386bfec25d1562cdf1c2ee85f7edb15fd3f44ecd1abbef738979f12b82f0b0f39a06589203a39f89518d981d7129e35f64f2d855cd162cd964bdd87c8d18
diff --git a/dev-python/aiodns/Manifest b/dev-python/aiodns/Manifest
index 247d546a18e6..238836382033 100644
--- a/dev-python/aiodns/Manifest
+++ b/dev-python/aiodns/Manifest
@@ -1 +1,2 @@
 DIST aiodns-3.1.1.tar.gz 7363 BLAKE2B bb5a465be00ff61406b61cef133cb5eed8e007114ddcd1475a12fed5481ec377bc96291fdc7fd6cc5936de865118f7008625ec5d69c09f96eacdb83b4b29c786 SHA512 7c28cc6256a575681778376cc197a9504133b1127eb3508f6e5cd1c992c95adef66cf8399b7e90ca012347485e476f71e3f032f7e2f555954ad9a0cade8df5f9
+DIST aiodns-3.2.0.tar.gz 7823 BLAKE2B 8bafeebbf6ef69001670dffe8df3bd89b817bca921e266e218eaf2a53653d5bb150cef0c99b2fd498d39befb57c6e2edb4d94fbf4b4548e1debce69bcd114ff3 SHA512 ca6ae2d53cc0a0e5b8cd5f47da56d7db43236eb6738509d5cc088e56db996c49eba8b024cfe368e5acf44ad4de4cb5d6f949c7f0d4cd16ff4d5cc42ae3b27cb1
diff --git a/dev-python/aiodns/aiodns-3.2.0.ebuild b/dev-python/aiodns/aiodns-3.2.0.ebuild
new file mode 100644
index 000000000000..1787cda6f44d
--- /dev/null
+++ b/dev-python/aiodns/aiodns-3.2.0.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Simple DNS resolver for asyncio"
+HOMEPAGE="
+	https://pypi.org/project/aiodns/
+	https://github.com/saghul/aiodns/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+# Tests fail with network-sandbox, since they try to resolve google.com
+PROPERTIES="test_network"
+RESTRICT="test"
+
+RDEPEND=">=dev-python/pycares-3[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet changed, https://github.com/saghul/aiodns/issues/107
+		tests.py::DNSTest::test_query_bad_chars
+	)
+
+	epytest tests.py
+}
diff --git a/dev-python/boltons/Manifest b/dev-python/boltons/Manifest
index 5ead3f526069..8e780c05c64d 100644
--- a/dev-python/boltons/Manifest
+++ b/dev-python/boltons/Manifest
@@ -1 +1,2 @@
 DIST boltons-23.1.1.tar.gz 244629 BLAKE2B 458e40179e98cfa914d9f66de18f89b2e6192a7ef38e4c827466fd2eabfa05245a9e592f2d0ff570f0d2288039f6564dd931404de7119730d6e4dbe6a9ddd886 SHA512 bc07d46f08f4883cfbaa54cf27dfb53fba57538d7d98b846840efad5ade64fecc6f9cc5d7dd3271236a1e12111d9e537f847995f28df2d7779026e0939e4ca98
+DIST boltons-24.0.0.tar.gz 239550 BLAKE2B e7001b3aa04834f1d234ff7ce996cebd32293189cdf000c8b36719d24b51ab24098c58ad3df58e938a58f319a575b8a0f2f09cec423d33b876103b89ad7d85bb SHA512 afc7f9d495d91e38219378f9f4f287918d6e5b19feb1299c5f504cab1d4a3e0a5fb9fa1c073d46f941c86a18086af5be3a44506d986b010b2595da0c2b908b48
diff --git a/dev-python/boltons/boltons-24.0.0.ebuild b/dev-python/boltons/boltons-24.0.0.ebuild
new file mode 100644
index 000000000000..23355f0ca7f2
--- /dev/null
+++ b/dev-python/boltons/boltons-24.0.0.ebuild
@@ -0,0 +1,26 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+inherit distutils-r1 pypi
+
+DESCRIPTION="Pure-python utilities in the same spirit as the standard library"
+HOMEPAGE="https://boltons.readthedocs.io/"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+distutils_enable_tests pytest
+
+DOCS=( CHANGELOG.md README.md TODO.rst )
+
+src_test() {
+	# tests break with pytest-qt, django, and likely more
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+
+	distutils-r1_src_test
+}
diff --git a/dev-python/coverage/coverage-7.4.4.ebuild b/dev-python/coverage/coverage-7.4.4.ebuild
index 7577803bd732..838a273e543e 100644
--- a/dev-python/coverage/coverage-7.4.4.ebuild
+++ b/dev-python/coverage/coverage-7.4.4.ebuild
@@ -19,7 +19,7 @@ HOMEPAGE="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~x64-macos"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
 
 RDEPEND="
 	$(python_gen_cond_dep '
diff --git a/dev-python/cssutils/Manifest b/dev-python/cssutils/Manifest
index 327c6757a006..b4f1fa7094af 100644
--- a/dev-python/cssutils/Manifest
+++ b/dev-python/cssutils/Manifest
@@ -1 +1,2 @@
+DIST cssutils-2.10.2.tar.gz 723055 BLAKE2B 7064f1928bf8496bef8eccf4663f944ed79e5e8065808254d12b68f32e9c8f308724e652b24fa584af54a0976ff3ab2f2751a9102e0f31a5f4a8fabf8f417b23 SHA512 c678b6953b13e8a7ac7b2abbe0b8be26283973537089071828e618b359bcce27df636f382d8b0dc50b13962e0d2dffcce991a47f678954ec018849e57026446d
 DIST cssutils-2.9.0.tar.gz 723452 BLAKE2B fc3593dec7a61b1a23b346b5a77160248760a934f01e6135a6478eb1164333a910c6c3fb403e3e06c8c7c90214a7c30ddc481dc9623c26091d62c8d092d8cea3 SHA512 d13d53b3e4f133afb5b72faba1e41a95cf2b146efb075dd3b328fc424eccd371194e1e14fd9e607b207b5c7d473e64f1e4c63975173d8491fa8036a16dc94d38
diff --git a/dev-python/cssutils/cssutils-2.10.2.ebuild b/dev-python/cssutils/cssutils-2.10.2.ebuild
new file mode 100644
index 000000000000..4b40256aff73
--- /dev/null
+++ b/dev-python/cssutils/cssutils-2.10.2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A CSS Cascading Style Sheets library"
+HOMEPAGE="
+	https://pypi.org/project/cssutils/
+	https://github.com/jaraco/cssutils/
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
+
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/cssselect[${PYTHON_USEDEP}]
+		>=dev-python/jaraco-test-5.1[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# network
+		encutils/__init__.py::encutils
+		cssutils/tests/test_parse.py::TestCSSParser::test_parseUrl
+		examples/website.py::examples.website.logging
+	)
+	local EPYTEST_IGNORE=(
+		# path mismatch with "parse" package
+		examples/parse.py
+	)
+
+	epytest
+}
diff --git a/dev-python/flufl-lock/Manifest b/dev-python/flufl-lock/Manifest
index 5f165a0164fe..f447c57ef3c1 100644
--- a/dev-python/flufl-lock/Manifest
+++ b/dev-python/flufl-lock/Manifest
@@ -1 +1,2 @@
 DIST flufl_lock-8.0.2.tar.gz 34369 BLAKE2B e16af81933141628664bfcbece3ede038b150df468af00b840b9b7ad4aaa7e0e10c8a0ce415c685e2aa1e556198b2ac4f8339bdfa3e41c004c32592f0bd025bf SHA512 2ef382cf22be72ceace89ad01646db31186fa7f505d72306025b90e47dad46fa0831d951f515fc321b873acc4a339e2ae1ed1a4861c355bc9961e0a3ab209d7c
+DIST flufl_lock-8.1.0.tar.gz 32884 BLAKE2B 9d5f557d4664cda5fb31b4f73d79e99acac342462a94b4c1405f1032c25fd60785986e6ae9e48629b2bae0977517ec888eacc6e52d4f75b41887d14521a85f54 SHA512 3238d4c89c3702584c19882caa903a8efd33ad49ad9286d7965694f2cfdf626adee887d6a524d293457b3cd176fc02fc71edfdc0b807c3aaaed0aa77f2188a3b
diff --git a/dev-python/flufl-lock/flufl-lock-8.1.0.ebuild b/dev-python/flufl-lock/flufl-lock-8.1.0.ebuild
new file mode 100644
index 000000000000..4d23a71fc8f9
--- /dev/null
+++ b/dev-python/flufl-lock/flufl-lock-8.1.0.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="NFS-safe file locking with timeouts for POSIX systems"
+HOMEPAGE="
+	https://gitlab.com/warsaw/flufl.lock/
+	https://pypi.org/project/flufl.lock/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/atpublic[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/sybil[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -e '/addopts/d' -i pyproject.toml || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index b8d965dbc723..09b1626af468 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -1,2 +1,3 @@
+DIST hypothesis-6.100.0.gh.tar.gz 9450559 BLAKE2B c26324339dfc770feb51de103227b58ea1be3deb0dc6c54a7ba6a7be6a719ab33503358978da2cc040a93af7c169238e7401ec9567d08c6b51889e42f29b7c7b SHA512 697ff894d1e1033f3f6f8d9d7a301d8874c61d340cac2746ede4a4c8a6b77d7b95044edc3a467c39e5d570f554f07eb7321eb5cfb9de4b648ce31b914ec491c4
 DIST hypothesis-6.98.18.gh.tar.gz 9434436 BLAKE2B 45861775caa1657d06469fc8cd0062aee1b408c3b02a58ff4d50b9de9ce62d8fd351c6b8f4b1b7f543fe70d6b8f2c663ad8e9252b833d5c567d3c28449fc3eaf SHA512 cff5cad9308e7b030e38f09a9544ed84f468bc4bd6391a2347777bb7781b116bd64f41338ad32535d427ebda507ce3f0f5bafc0af5a8179976c17d36762679e9
 DIST hypothesis-6.99.13.gh.tar.gz 9450425 BLAKE2B cb8d559d95c60a931640c978ad3ed4c9898cc048254f105f9cb79cd8e36c8b28712d48304b17f5a837a1fd69b88102461a057d5d9ea3786a846d61362137d426 SHA512 0d74dcb6c5d8015c8c660b66298a3053fce1ad04191f81b216a05b08f24fdaaccc7470937459614b95810dad4e37c4712da67eeff414ca50af1d1e5fa81b4d64
diff --git a/dev-python/hypothesis/hypothesis-6.100.0.ebuild b/dev-python/hypothesis/hypothesis-6.100.0.ebuild
new file mode 100644
index 000000000000..29919aa8ec05
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.100.0.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{10..12} )
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/pytest-8[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/requests-toolbelt-0.10.1
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,_hypothesis_pytestplugin
+	local -x HYPOTHESIS_NO_PLUGINS=1
+
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# failing due to warnings from numpy/cython
+				hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+			)
+			;;
+	esac
+
+	epytest -o filterwarnings= -n "$(makeopts_jobs)" --dist=worksteal \
+		tests/cover tests/pytest tests/quality
+}
+
+python_install() {
+	distutils-r1_python_install
+	if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/inflect/Manifest b/dev-python/inflect/Manifest
index 38f75d1b5a45..c7a30ab3dc63 100644
--- a/dev-python/inflect/Manifest
+++ b/dev-python/inflect/Manifest
@@ -1 +1,2 @@
 DIST inflect-7.0.0.tar.gz 70963 BLAKE2B ae896109acd33946e05902d121ecbd95e04dc33a1d6da6035148521de5baff8cff877a5c56c104bde29d56025e231e20f97e0ee50686de0ec19b567d53612314 SHA512 b2ca39d0e36cda8c8c42d208443d3b84b10d659dcd0d368273503d6e76df19c61ac3c623d526ea918ca8b347d6db8bdfb691609e480eaa33dd4f1c37e008473b
+DIST inflect-7.2.0.tar.gz 71448 BLAKE2B 33d7d8cf4b4de05a035e1929fd6c70c3635290cf1387927e5fe15315c06135a6b2daf6b67f044b9ea004c2345bdeb8b2f17e5f54daa9cb18f0d3bc1935295439 SHA512 13b698637a8049987675dd419359907baba6d8a9805c3602bbc414ed8fb422bfaa32ec26bcc309508ead5cb72bed632d9142f7796c981269551f1238b88c9019
diff --git a/dev-python/inflect/inflect-7.2.0.ebuild b/dev-python/inflect/inflect-7.2.0.ebuild
new file mode 100644
index 000000000000..ad9f10867295
--- /dev/null
+++ b/dev-python/inflect/inflect-7.2.0.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Correctly inflect words and numbers"
+HOMEPAGE="
+	https://pypi.org/project/inflect/
+	https://github.com/jaraco/inflect/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+
+RDEPEND="
+	>=dev-python/pydantic-1.9.1[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+	dev-python/typeguard[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools-scm-3.4.1[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# broken upstream
+	# https://github.com/jaraco/inflect/issues/204
+	inflect/__init__.py::inflect.engine.compare
+)
diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index 79cc881021f3..fc48e57709ee 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -1 +1,2 @@
 DIST ipython-8.22.2.tar.gz 5490399 BLAKE2B 61d7d30d77c0b422ba174ac3c3f17c753502d9469d1d2ba8e3f2583761ab1f26230172b7e2efa680bb8f7ef23ef47cfe56241344380591e3da0da5d15f385727 SHA512 ff9c56b0594e63dbb26aad466eb9449d41db4002da61837363aaff817b99a54f310152994e4d361dfd5b6c40452dedf3eb74825c6d0a7d8c5fff84c1ac20f7ff
+DIST ipython-8.23.0.tar.gz 5491405 BLAKE2B c4273d20bccdf07283abf9a69b8d64a27be3aa2e0672d14781cd9035ff39a5392518d7e22f45cdd20c8e110111a601d4bdbc36659efde153742de731d574e4be SHA512 4e6f061dba024f5e717f6497706a144c5568c9d650215d898fe8e5efc85b92445f64e2c8eb6ef3c9bfe1a305c9098cc49e79b6d1cc25c8be5add1497682fce28
diff --git a/dev-python/ipython/ipython-8.23.0.ebuild b/dev-python/ipython/ipython-8.23.0.ebuild
new file mode 100644
index 000000000000..03fb8a8111eb
--- /dev/null
+++ b/dev-python/ipython/ipython-8.23.0.ebuild
@@ -0,0 +1,177 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE='readline(+),sqlite,threads(+)'
+
+inherit distutils-r1 optfeature pypi virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="
+	https://ipython.org/
+	https://github.com/ipython/ipython/
+	https://pypi.org/project/ipython/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+IUSE="doc examples notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	>=dev-python/prompt-toolkit-3.0.41[${PYTHON_USEDEP}]
+	<dev-python/prompt-toolkit-3.1[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
+	dev-python/stack-data[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.13.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/exceptiongroup[${PYTHON_USEDEP}]
+	' 3.10)
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.10 3.11)
+"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.23[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		dev-python/pickleshare[${PYTHON_USEDEP}]
+		<dev-python/pytest-8[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+		dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? (
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	$(python_gen_cond_dep '
+		notebook? (
+			dev-python/notebook[${PYTHON_USEDEP}]
+			dev-python/ipywidgets[${PYTHON_USEDEP}]
+			dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+		)
+		qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	' 'python*')
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/2.1.0-substitute-files.patch
+)
+
+python_prepare_all() {
+	# Remove out of date insource files
+	#rm IPython/extensions/cythonmagic.py || die
+	#rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
+	local EPYTEST_DESELECT=(
+		# TODO: looks to be a regression due to a newer dep
+		IPython/core/tests/test_oinspect.py::test_class_signature
+		IPython/core/tests/test_oinspect.py::test_render_signature_long
+		IPython/terminal/tests/test_shortcuts.py::test_modify_shortcut_with_filters
+	)
+
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# https://github.com/numpy/numpy/issues/25164
+				IPython/lib/tests/test_display.py::TestAudioDataWithoutNumpy
+			)
+			;;
+	esac
+
+	# nonfatal implied by virtx
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	nonfatal epytest || die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "code formatting" dev-python/black
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line-profiler
+	optfeature "%matplotlib magic command" dev-python/matplotlib-inline
+
+	if use nbconvert; then
+		if ! has_version virtual/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}
diff --git a/dev-python/jaraco-classes/Manifest b/dev-python/jaraco-classes/Manifest
index b07c57f866a0..e95945d6c19e 100644
--- a/dev-python/jaraco-classes/Manifest
+++ b/dev-python/jaraco-classes/Manifest
@@ -1 +1,2 @@
 DIST jaraco.classes-3.3.1.tar.gz 11699 BLAKE2B 4510bc79d9fb0697aabfa5211c250e362048091b38dc1f6d404abc80ded078744dda29e91bc82ff30fbfe352614f3be14e1cf2cebea0ce7bd839d21b6897817d SHA512 368a45965e321506bb4a66c80ddf79e8e58f25f92bf9bbd1cffc9118f696ea23dcca6f9277544d1c2af1cbc18fe0cc5a2bdc7b9ad865f54ac0776b0b58aca90b
+DIST jaraco.classes-3.4.0.tar.gz 11780 BLAKE2B e16f76f58fae8b42864e5055e8fd97fff634223aa28499fcc8a204f52aec9f2cc66b5cdf53e08acac85bfdeff46b7bdeb8b5bcc9da10fee16f3a5bd84026cd1d SHA512 94e5163120117c51f129d43e85f92ee19efcf8b10683142679511f8b33f4a1fd6c51516b7551aeab9d68c1936791bafc47328b5560ee3fe28e553fe463ea968f
diff --git a/dev-python/jaraco-classes/jaraco-classes-3.4.0.ebuild b/dev-python/jaraco-classes/jaraco-classes-3.4.0.ebuild
new file mode 100644
index 000000000000..7d6434f24341
--- /dev/null
+++ b/dev-python/jaraco-classes/jaraco-classes-3.4.0.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Classes used by other projects by developer jaraco"
+HOMEPAGE="
+	https://github.com/jaraco/jaraco.classes/
+	https://pypi.org/project/jaraco.classes/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index e9da2ac43cac..a11d7c268c91 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1,3 +1 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
-EBUILD langdetect-1.0.9.ebuild 493 BLAKE2B 0df8bce19bc80f79f8e76bcef5a4c2caf333365fe0cb9a3c076b7858bceded5a3e58921474f866a2709dd657b7ed330c1ec4a7f9d7bab0fcf1bc92d77cabc32d SHA512 ea2a1adcb133ac5fc951ba1aa90ef1ce3dfcc424e59727591763d4875aa044a74188be2d15fd89c6b2e83ed6ea04ec3d9851ed584ae79d2c2c127bde7d994b48
-MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch b/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
new file mode 100644
index 000000000000..637368d2f237
--- /dev/null
+++ b/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
@@ -0,0 +1,13 @@
+Fix "Package 'langdetect.profiles' is absent from the `packages` configuration."
+
+--- a/setup.py
++++ b/setup.py
+@@ -18,7 +18,7 @@ setup(
+     author_email='michal.danilak@gmail.com',
+     url='https://github.com/Mimino666/langdetect',
+     keywords='language detection library',
+-    packages=['langdetect', 'langdetect.utils', 'langdetect.tests'],
++    packages=['langdetect', 'langdetect.utils', 'langdetect.tests', 'langdetect.profiles'],
+     include_package_data=True,
+     install_requires=['six'],
+     license='MIT',
diff --git a/dev-python/langdetect/langdetect-1.0.9.ebuild b/dev-python/langdetect/langdetect-1.0.9.ebuild
index c09b7356f549..630fe63c6f53 100644
--- a/dev-python/langdetect/langdetect-1.0.9.ebuild
+++ b/dev-python/langdetect/langdetect-1.0.9.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2022 Gentoo Authors
+# Copyright 2022-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -19,4 +19,6 @@ KEYWORDS="~amd64"
 
 RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
 
+PATCHES=( "${FILESDIR}/${P}-explicit-config.patch" )
+
 distutils_enable_tests unittest
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index 020e07f2a3dd..736a1167c898 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -1,12 +1,6 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- <maintainer type="person">
-  <email>marcin.deranek@slonko.net</email>
-  <name>Marcin Deranek</name>
- </maintainer>
- <upstream>
-  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
- </upstream>
- <origin>slonko-overlay</origin>
+ 
+ <origin>gentoo-guru-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/pyalsa/pyalsa-1.2.7-r1.ebuild b/dev-python/pyalsa/pyalsa-1.2.7-r1.ebuild
index 1ea48087a3f5..3283cf4eeba3 100644
--- a/dev-python/pyalsa/pyalsa-1.2.7-r1.ebuild
+++ b/dev-python/pyalsa/pyalsa-1.2.7-r1.ebuild
@@ -16,7 +16,7 @@ SRC_URI="https://www.alsa-project.org/files/pub/pyalsa/${P}.tar.bz2"
 
 LICENSE="LGPL-2.1+"
 SLOT="0"
-KEYWORDS="~alpha amd64 ~arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv ~sparc x86"
+KEYWORDS="~alpha amd64 ~arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv sparc x86"
 # Needs access to system's alsa configuration/devices
 RESTRICT="test"
 
diff --git a/dev-python/python-redmine/Manifest b/dev-python/python-redmine/Manifest
index e754b6d19e35..1b7da8ce29ba 100644
--- a/dev-python/python-redmine/Manifest
+++ b/dev-python/python-redmine/Manifest
@@ -1 +1,2 @@
 DIST python-redmine-2.4.0.tar.gz 67730 BLAKE2B 22c74ad194af9b56affab39de38b13a8f5a46e79b8ea8d9f9f47eb12c4ad4c91156db9ef0e8dfd013602b8cc06e0636a724ae34969f385dc9f8ffc63514ccc63 SHA512 afb03ca8a3bdacace3c12b7295ba08953ab2040971b57988deb9955df24e5ac1782a9b3fbf0f5070eb22c640e88f489cda12cdec38449f9e3bcf7189dc422642
+DIST python-redmine-2.5.0.tar.gz 73643 BLAKE2B aae400a68385fa98d454820081abacfabe69be473de8ee21feb47dfd8b3372cb0b8dfca168fc9daebd37da04a4fcca84235eb555262489dc1b717fd589dc849a SHA512 8c610efe5e4362ab27a33a04e78347e2962b9e766cea81c725b5b34bdff1d2c6a2e68e5d928b5aed97af569f5c6656dc2b39347a76cb371a3069bba3fd02c8e2
diff --git a/dev-python/python-redmine/python-redmine-2.5.0.ebuild b/dev-python/python-redmine/python-redmine-2.5.0.ebuild
new file mode 100644
index 000000000000..da46465bb175
--- /dev/null
+++ b/dev-python/python-redmine/python-redmine-2.5.0.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python interface to the Redmine REST API"
+HOMEPAGE="
+	https://github.com/maxtepkeev/python-redmine/
+	https://pypi.org/project/python-redmine/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/requests-2.28.2[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# https://github.com/maxtepkeev/python-redmine/pull/332
+	sed -i -e 's:assertEquals:assertEqual:' tests/*.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	epytest -o addopts=
+}
diff --git a/dev-python/trimesh/Manifest b/dev-python/trimesh/Manifest
index eca32fbc413e..4426ee6ead88 100644
--- a/dev-python/trimesh/Manifest
+++ b/dev-python/trimesh/Manifest
@@ -2,3 +2,4 @@ DIST trimesh-4.1.8.gh.tar.gz 13440336 BLAKE2B aa4bddc3d613144a0e304ec320a2b38df2
 DIST trimesh-4.2.0.gh.tar.gz 13553809 BLAKE2B 141aec46cb8bf2342251a72e5e4c1fbee1e33e4ff63d420cfa4db1758fc324d572d54932ce1526ba2df75d9770f001d9dbe41a79835837931c4c46221fbb6871 SHA512 75efd00ef5ff8f9c25bdfb06ab92fa09db154771356b18ebcf457cba4c2f366645084eb078e5e324cfb41fe101797694aa6b00005f7ccd1290ba4d2d6c088ebd
 DIST trimesh-4.2.1.gh.tar.gz 13554447 BLAKE2B 02b75d8768963c250bbc1ebb75815567736a74b288da2a781b83fc3d31934059ebb85115c2e556a29da6c0e3034714226addba062d776acca4953414d1ed3492 SHA512 bdcd8436869849e8e8897732e0b9f8390d0771ea8dcadabb108ee8245d75c4d0ac915456473b6b0ed4f2f27fad48e123511e0bcfc79d485119376290c6f6d311
 DIST trimesh-4.2.3.gh.tar.gz 13554586 BLAKE2B 2c82690a17d8c62c80c99e87d9347ab85c14b2170fbdccc7967f893f6d83bed9aa2e38ef3f024567893d926511b34b20109bb94c8e976ced9d7a77190a653f14 SHA512 541438e5f5bd577af693bb238b308c7094b334530d7a962881e05db81331e1c896c82f76b0dcd4bfa17abcfec9eadf869bb0cad01e1402e99852c3ff2d184e5f
+DIST trimesh-4.2.4.gh.tar.gz 13554819 BLAKE2B 233f4d5404793ed1b5dc475da2dd371ca3a792239ae9ffea95ef3609a19b2701f66ad7aeb72b7b078b7a58d812ebe59b3bc12fedc6b9c34213c60378a2959d1c SHA512 3d37a429a21250a26f0a46c29c432b97158849bc0fbba7dec441bdd2453c4ef6a917483604f1c7ecb0e2415b9a270a80e36225cb951e59af1db54d20ebf60902
diff --git a/dev-python/trimesh/trimesh-4.2.4.ebuild b/dev-python/trimesh/trimesh-4.2.4.ebuild
new file mode 100644
index 000000000000..3c64a487b0bc
--- /dev/null
+++ b/dev-python/trimesh/trimesh-4.2.4.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for loading and using triangular meshes"
+HOMEPAGE="
+	https://trimesh.org/
+	https://github.com/mikedh/trimesh/
+	https://pypi.org/project/trimesh/
+"
+SRC_URI="
+	https://github.com/mikedh/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorlog[${PYTHON_USEDEP}]
+	dev-python/httpx[${PYTHON_USEDEP}]
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.20[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycollada[${PYTHON_USEDEP}]
+	dev-python/pyglet[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/shapely-1.8.2[${PYTHON_USEDEP}]
+	dev-python/svg-path[${PYTHON_USEDEP}]
+	dev-python/sympy[${PYTHON_USEDEP}]
+	dev-python/xxhash[${PYTHON_USEDEP}]
+	sci-libs/rtree[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mapbox_earcut[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_TIMEOUT=1800
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+pkg_postinst() {
+	optfeature_header "${PN} functionality can be extended by installing the following packages:"
+	optfeature "making GUI applications with 3D stuff" dev-python/glooey
+	optfeature "2D triangulations of polygons" dev-python/mapbox_earcut
+	optfeature "loading a number of additional mesh formats" dev-python/meshio
+	optfeature "figuring out how much memory we have" dev-python/psutil
+	optfeature "marching cubes and other nice stuff" dev-python/scikit-image
+}