Adding metadata

4 files changed, 110 insertions, 0 deletions

diff --git a/dev-python/ipykernel/Manifest b/dev-python/ipykernel/Manifest
index cae6fe247b28..a3d58a63e81f 100644
--- a/dev-python/ipykernel/Manifest
+++ b/dev-python/ipykernel/Manifest
@@ -1,2 +1,3 @@
 DIST ipykernel-6.16.2.tar.gz 136606 BLAKE2B 596cae97c6e4d170c51a2f2f481c306a93833cf62959837bde129ed080f70e730cb083ff0a608b7539f633898b7f79f8c5ee3495580fe2821382f0be10417ccc SHA512 3a3bae6cc8ace33b7b8c9d335c7da73c1983824b74b29b77c14cbe24239d556c9c967a759a37a60745823cb6ab698a21262457082464cf33ec1b02ebbe2240d9
 DIST ipykernel-6.17.0.tar.gz 136711 BLAKE2B 2d037334e3fbff0cdd3e2a99cb0987c2c647bf04e3eaa85ff56a202d2b2c88383ffd81f8ba74565fee9ade19ab9d6bcfcb862bd92fdea00892f0195f1c97a752 SHA512 52ff2cbf2aa8f1d02c0d25866e91e2eccddca55b70a226145b99165b3514ab1b87e797abac4423bfb7090152e7eafbc47aacde8c3373f5b2bdf0ff642c07d0ba
+DIST ipykernel-6.17.1.tar.gz 137131 BLAKE2B 0805f04b685fdfd8e43b733962e096035f900a4f8a525cf6f52980bffeedb88d5f33eb75a311dda26fe482ee2625c9f3ade15d1b449165f8050c5e83b20e0b39 SHA512 f1293ac6c4744fe3c79e0886d55a15f6c19ac73c07f5bd4a09f4f0c26c8ed0935b5c0924c55efc2097257737d6a59caba1cf9fba004b5f368a62840a269908f7
diff --git a/dev-python/ipykernel/ipykernel-6.17.1.ebuild b/dev-python/ipykernel/ipykernel-6.17.1.ebuild
new file mode 100644
index 000000000000..663cc93062e0
--- /dev/null
+++ b/dev-python/ipykernel/ipykernel-6.17.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="
+	https://github.com/ipython/ipykernel/
+	https://pypi.org/project/ipykernel/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/debugpy-1.0[${PYTHON_USEDEP}]
+	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-6.1.12[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
+	dev-python/nest_asyncio[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.1.0[${PYTHON_USEDEP}]
+"
+# RDEPEND seems specifically needed in BDEPEND, at least jupyter
+# bug #816486
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/ipyparallel[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# TODO
+	ipykernel/inprocess/tests/test_kernel.py::InProcessKernelTestCase::test_pylab
+	ipykernel/tests/test_debugger.py::test_attach_debug
+	ipykernel/tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
+	ipykernel/tests/test_debugger.py::test_rich_inspect_at_breakpoint
+	ipykernel/tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
+	ipykernel/tests/test_debugger.py::test_set_breakpoints
+	ipykernel/tests/test_debugger.py::test_stop_on_breakpoint
+)
+
+src_prepare() {
+	sed -i -e 's:^TIMEOUT = .*:TIMEOUT = 120:' ipykernel/tests/*.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	# Use python3 in kernel.json configuration, bug #784764
+	sed -i -e '/python3.[0-9]\+/s//python3/' \
+		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
+}
diff --git a/dev-python/pytest-bdd/Manifest b/dev-python/pytest-bdd/Manifest
index aeee3d8121b0..79bed2fd1871 100644
--- a/dev-python/pytest-bdd/Manifest
+++ b/dev-python/pytest-bdd/Manifest
@@ -1,2 +1,3 @@
 DIST pytest-bdd-6.0.1.gh.tar.gz 60932 BLAKE2B 67e0dbc251ce94da40033641f37e6c9ad70ca947f71db1a78907a6890d96d8d3112d57a2a63dda526c8f846010d39a575cb5d93a102f4653705d4229ee14ab07 SHA512 30bc697ae177e3f311af0c781e99bde5b491dfef28109359c0d80f33feb8b0b170ffe15c288fe73a624144a1d1c3223b220d591b4acc30d1ad53600482bef87d
 DIST pytest-bdd-6.1.0.gh.tar.gz 79270 BLAKE2B 145d1adc6dae8098b30bfd68ce78dcf3c0b6626a32f8da05805f78f176111dd367a62e76eb61d520391c88bf9eda234f63d983bcfa36f00d39d85a026c78f883 SHA512 957b39a9c7c48b8d5e42d301de875579d062744766c55ffa32aed78a5a8a5c9fd9bb3ba281183841bc1da19604659c94ecaa4487dfc7a6dd69b507f5fc9f2dc7
+DIST pytest-bdd-6.1.1.gh.tar.gz 79549 BLAKE2B 0de77a2a46c852dcd7b344b385deea6473ec32dfec2eec610ae04d9d192d42eaf7aa3b1455549dc602e46c24edf078c558f2564aa9dd7f42a2beea36458438ea SHA512 69cd345d4a819a84a811ca2a5825f87a46fa4d063b9a852308d36e4f15058a27c45b170dadf684e68322d3380654f985b8ef153e34ad42ef33e0b595f8dc9d96
diff --git a/dev-python/pytest-bdd/pytest-bdd-6.1.1.ebuild b/dev-python/pytest-bdd/pytest-bdd-6.1.1.ebuild
new file mode 100644
index 000000000000..7e0b761698d5
--- /dev/null
+++ b/dev-python/pytest-bdd/pytest-bdd-6.1.1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+inherit distutils-r1
+
+DESCRIPTION="BDD library for the pytest runner"
+HOMEPAGE="https://pypi.org/project/pytest-bdd/"
+SRC_URI="https://github.com/pytest-dev/pytest-bdd/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/mako[${PYTHON_USEDEP}]
+	dev-python/parse[${PYTHON_USEDEP}]
+	dev-python/parse_type[${PYTHON_USEDEP}]
+	dev-python/pytest[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]"
+BDEPEND="test? ( dev-python/packaging[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
+
+DOCS=( AUTHORS.rst CHANGES.rst README.rst )
+
+src_test() {
+	# terminal_reporter test needs exact wrapping
+	local -x COLUMNS=80
+
+	# hooks output parsing may be affected by other pytest-*, e.g. tornasync
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=pytest_bdd.plugin
+
+	distutils-r1_src_test
+}