Adding metadata

29 files changed, 619 insertions, 71 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 1a6187458733..d897507dea43 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -15,3 +15,4 @@ DIST boto3-1.24.58.gh.tar.gz 530450 BLAKE2B 82746de410c03fd0757d088781a5a2ab8d60
 DIST boto3-1.24.59.gh.tar.gz 531080 BLAKE2B a5efbe215f2a88c6a48640a4b459c426ce3954a2337c84626f39228437d392fab8ec1cf4aaf53887db00bba70500a57ddfd0752d0f09226c78f70d5875ec852a SHA512 6999fc12826072cfd1b06a89a323cc9f28a0874cca07b1ffd94e223e717cc874701f57c1d7b4f63724e329c1f51522631502e8ef19f640fe75c8c4c14e7ff38c
 DIST boto3-1.24.60.gh.tar.gz 531790 BLAKE2B b1734cb085e49609f46dea3ecc0ffdf5e197d31c69a5514d93b026282b0e1ddf04b72282a339b8076f9318f97548457d3e3db314e899e8eceb3e05d2bfced400 SHA512 a82ad5433ef31abfeacc885c8d5540568ec96c5e6b21a23de8f04eb48569f92dda740862d93c5e8e506e70e60e7d5e55e7cfba17b73e471ef49fc2a827846473
 DIST boto3-1.24.61.gh.tar.gz 531957 BLAKE2B b8cff8dea6b74ce1238a734cf1e2fb41ede27243216bf6c5b0e0d99a43948a6dc6999fe3ff0a13616b3a4ba0e1c675963faef5a299b9c1a86e3713eee9f07741 SHA512 7d957b9c9a120698fb2f7d1368500e456ea5e7834e4fc09c1680333b16056f089eea60480e50919c1dcc4596c72e43a74f6b57d433ed01f1ef53c7804b6dc2dc
+DIST boto3-1.24.63.gh.tar.gz 533004 BLAKE2B f678fbea81cf1be2f28d2463fbf50ff841d0a2c027f2f80cb99364b686aa8b72cd02345e6f8532e2d3b2b6c4a676f50640e1c3d3fc50d53a1aa549d90b8f7bc0 SHA512 771b3911180df5bc85b0ee1a4b8762bf387a1f55f37501b8b10bb3971e5cfb91fb072c4f9ea405d16b6351b1d34c8dce6e9564dfabd2414f6162ca8cc5ba3bc9
diff --git a/dev-python/boto3/boto3-1.24.56.ebuild b/dev-python/boto3/boto3-1.24.56.ebuild
index e4a98e2e28f5..ec8f4d61c530 100644
--- a/dev-python/boto3/boto3-1.24.56.ebuild
+++ b/dev-python/boto3/boto3-1.24.56.ebuild
@@ -25,7 +25,7 @@ else
 		https://github.com/boto/boto3/archive/${PV}.tar.gz
 			-> ${P}.gh.tar.gz
 	"
-	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+	KEYWORDS="amd64 arm arm64 ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux"
 
 	# botocore is x.(y+3).z
 	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
diff --git a/dev-python/boto3/boto3-1.24.63.ebuild b/dev-python/boto3/boto3-1.24.63.ebuild
new file mode 100644
index 000000000000..e4a98e2e28f5
--- /dev/null
+++ b/dev-python/boto3/boto3-1.24.63.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 5482b47b4cc9..6611c77c713a 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -15,3 +15,4 @@ DIST botocore-1.27.58.gh.tar.gz 9563088 BLAKE2B 66aecb836cac7bcddbba1fc6b29ce3a2
 DIST botocore-1.27.59.gh.tar.gz 9566420 BLAKE2B f8142d7cc16d3cefa9a39a830db97656a920d192d22cccc355dd093c1bc8b49c62af75b3e097ec615c546ff70018e6a9976282fb92c6f29a96f70eb9852b62de SHA512 b330e53fc06f0b067c3bb6ea8981424dc0bd891b7e9ac324201386f6fba12ca74bd9aadf10aaaabd7dc8b18bc943826480648e0a4f82da9ec9a4c5a8ac954cdb
 DIST botocore-1.27.60.gh.tar.gz 9574977 BLAKE2B 6dda9bdc9104a4c1deed365a7973008fb07aa3e72d9d47193480c394563ac9dfd61d27e70c906b8c9eeb73e26cae8e250d8249c532a128e14e1819525053e940 SHA512 d271a116cc4c954a49a1d136348cdc42b60f1904f0c7f425e7457008af412eae37dd77740c91ceab3f44f0c97e4ca0e5b117bdf3bc1415e6e44911e1ab830078
 DIST botocore-1.27.61.gh.tar.gz 9575336 BLAKE2B bbc2bb49ee84293d9d7d9f0cc3da70a141778bd68ecc45117a9e99bd8ceba7576b52ed0d5381b085c6a7ae32195a6709e76144f27681cd8d07338ed404b1b236 SHA512 1e1ce615a2b02bab2587bb475e783d197cf27496cb1c0c1b06c51453e545ed293b1fab555f23a67246a4a5babb6c5d12fafee2d6f8b997d168e43f62a5e16bfd
+DIST botocore-1.27.63.gh.tar.gz 9581263 BLAKE2B 3b225160fe0095aa77754c874ceff558c56f547e0454a67fd13c8f093abbef975ff5cf878576b4b6235b1783aaae2278d05026b29d41a95e6168928b035cd1fb SHA512 b3698a0d5ea2e63de3fe94441a1781034d24c0ae5ff06a427ac55eb2cdd05bf917b01fcd9e1bbd389a1d4ac6b625d534b37c1d6c8c72b23670b66d892d5fe6da
diff --git a/dev-python/botocore/botocore-1.27.56.ebuild b/dev-python/botocore/botocore-1.27.56.ebuild
index 6a8e7e93c947..2ca74b90b2f8 100644
--- a/dev-python/botocore/botocore-1.27.56.ebuild
+++ b/dev-python/botocore/botocore-1.27.56.ebuild
@@ -24,7 +24,7 @@ else
 		https://github.com/boto/botocore/archive/${PV}.tar.gz
 			-> ${P}.gh.tar.gz
 	"
-	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+	KEYWORDS="amd64 arm arm64 ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux"
 fi
 
 RDEPEND="
diff --git a/dev-python/botocore/botocore-1.27.63.ebuild b/dev-python/botocore/botocore-1.27.63.ebuild
new file mode 100644
index 000000000000..ba4830d69cb3
--- /dev/null
+++ b/dev-python/botocore/botocore-1.27.63.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+		# fails on unrelated warnings
+		tests/unit/test_client.py::TestAutoGeneratedClient::test_BOTO_DISABLE_COMMONNAME
+		tests/unit/test_client.py::TestClientErrors::test_BOTO_DISABLE_COMMONNAME
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/botocore-9999.ebuild b/dev-python/botocore/botocore-9999.ebuild
index 6a8e7e93c947..ba4830d69cb3 100644
--- a/dev-python/botocore/botocore-9999.ebuild
+++ b/dev-python/botocore/botocore-9999.ebuild
@@ -63,6 +63,9 @@ python_test() {
 		# rely on bundled six
 		tests/functional/test_six_imports.py::test_no_bare_six_imports
 		tests/functional/test_six_threading.py::test_six_thread_safety
+		# fails on unrelated warnings
+		tests/unit/test_client.py::TestAutoGeneratedClient::test_BOTO_DISABLE_COMMONNAME
+		tests/unit/test_client.py::TestClientErrors::test_BOTO_DISABLE_COMMONNAME
 	)
 
 	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
diff --git a/dev-python/cfn-lint/Manifest b/dev-python/cfn-lint/Manifest
index cafd2ea824fe..ed21a1baf63c 100644
--- a/dev-python/cfn-lint/Manifest
+++ b/dev-python/cfn-lint/Manifest
@@ -1,3 +1,4 @@
 DIST cfn-lint-0.61.5.gh.tar.gz 9580886 BLAKE2B 0e83a604bc8761cd6007039cc28d90e471ef3cd3c542e7ce977d290638bcbff2b196c5d3c5f23b8d6db064b867ab594360dedb86494aba955c065c7cbad8b519 SHA512 14a1c282f1d87ce5ddd231f92e01a4edd85a62802f2335ba95470acaa0d8deb0306433124f3d1bea6c965ebfe5b30145431087a71cb1e8b953bf94b5d691bcbf
 DIST cfn-lint-0.62.0.gh.tar.gz 9610430 BLAKE2B fdeed685abab1bb701698b02ba961d0460c2fbf631ee6c8c51d17e8087bdbd2a26d366afd6916ff118e047bc1e45e0ac4124cf5140b7dede5cb116e5e49bec3e SHA512 830f3929330cbb6d3ae74c9d172c4540272def94bae4f5a0d181fd41688479bf9e9a82ccb9ccea20b823b8580743722a8cb551d790cab92322c7e472e679d28a
 DIST cfn-lint-0.63.0.gh.tar.gz 9613588 BLAKE2B 96f36310b9201e39a03fb9ca4e102feed68bd71c6af10f48875055d8e5ce42dff61772d5ba702b3f390a49c5e10077a70eb86206145c132d03f6998ea3f26f4a SHA512 daa8412254234d36b3e65a27fc93dc6af2283830afa6de58c979759b7dc02ec220ebf18b1d116f38356a368223efec787135b36aaac4d2a6444ec6820a0303fb
+DIST cfn-lint-0.63.2.gh.tar.gz 9672817 BLAKE2B dcd445c2372bf044bc4eab4b33056d2113914cdeeb1a2b376643cc4bbb3d92dcfdaaf2e6aa5f0d0473be00b42ecea0eda2a5ae3fa493d4e648be12db81b9d9e7 SHA512 d9bff0c43f7c2b710536fb7212e3d78d3827d7838ef8246767625c3de1a2ee0e5056df42b6b94e0efd7e7b2933d477a9962e0e3d53a78a3cca774fd52706a330
diff --git a/dev-python/cfn-lint/cfn-lint-0.63.2.ebuild b/dev-python/cfn-lint/cfn-lint-0.63.2.ebuild
new file mode 100644
index 000000000000..a98bb23dc7cd
--- /dev/null
+++ b/dev-python/cfn-lint/cfn-lint-0.63.2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="CloudFormation Linter"
+HOMEPAGE="
+	https://github.com/aws-cloudformation/cfn-lint/
+	https://pypi.org/project/cfn-lint/
+"
+SRC_URI="
+	https://github.com/aws-cloudformation/cfn-lint/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/aws-sam-translator-1.47.0[${PYTHON_USEDEP}]
+	dev-python/jsonpatch[${PYTHON_USEDEP}]
+	>=dev-python/jschema_to_python-1.2.3[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]
+	dev-python/junit-xml[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	>dev-python/pyyaml-5.4[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.15.0[${PYTHON_USEDEP}]
+	>=dev-python/sarif_om-1.0.4[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# TODO
+	test/unit/module/test_template.py::TestTemplate::test_build_graph
+	# requires git repo
+	test/unit/module/maintenance/test_update_documentation.py::TestUpdateDocumentation::test_update_docs
+	# Internet
+	test/unit/module/formatters/test_formatters.py::TestFormatters::test_sarif_formatter
+	test/unit/module/maintenance/test_update_resource_specs.py::TestUpdateResourceSpecs::test_update_resource_specs_python_2
+	test/unit/module/maintenance/test_update_resource_specs.py::TestUpdateResourceSpecs::test_update_resource_specs_python_3
+)
+
+src_prepare() {
+	# unpin the deps
+	sed -e 's:~=[0-9.]*::' -i setup.py || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/cython/cython-0.29.32.ebuild b/dev-python/cython/cython-0.29.32.ebuild
index 00100a03c54a..0f5d7f9d469e 100644
--- a/dev-python/cython/cython-0.29.32.ebuild
+++ b/dev-python/cython/cython-0.29.32.ebuild
@@ -22,7 +22,7 @@ SRC_URI="
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris ~x86-solaris"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris ~x86-solaris"
 IUSE="emacs test"
 RESTRICT="!test? ( test )"
 
diff --git a/dev-python/dirty-equals/Manifest b/dev-python/dirty-equals/Manifest
index 1dea98855f88..49f57823e8d6 100644
--- a/dev-python/dirty-equals/Manifest
+++ b/dev-python/dirty-equals/Manifest
@@ -1 +1,2 @@
 DIST dirty-equals-0.4.gh.tar.gz 41864 BLAKE2B 0b916d37b323e9f587a977b46415432bc11367a6d0c95ac49e47fe604b3ee16c26eaecbbe74464076834c6186f5f0eecc049b211699a3f515ef7fdadc492537a SHA512 f98fa8c9850f26efc44dc2c5cc0ea6d687c07b49980c3eeaa71eaae78930e418c03bb35cb88aab065905443fa354b9b05d44a588458ed37d140d376b943c9da9
+DIST dirty-equals-0.5.0.gh.tar.gz 44684 BLAKE2B ccd0d4e254a529e2b3d1014390d3e21a869e145fc0d9913e01e896ce103d853315d496264fdf611aa1fded8c66673bcb9e38dc41984ebfc566a9621b99240f81 SHA512 5d89105e3eb4e3dd52423aafed6c3ddf50890cfb3c03623723d0ab79f9814e892ba91cf789fa495ecc663b03c49516687fc2c1bc548816d60ade4f64df561ab9
diff --git a/dev-python/dirty-equals/dirty-equals-0.5.0.ebuild b/dev-python/dirty-equals/dirty-equals-0.5.0.ebuild
new file mode 100644
index 000000000000..53205c3e030d
--- /dev/null
+++ b/dev-python/dirty-equals/dirty-equals-0.5.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Doing dirty (but extremely useful) things with equals"
+HOMEPAGE="
+	https://dirty-equals.helpmanual.io/
+	https://github.com/samuelcolvin/dirty-equals/
+	https://pypi.org/project/dirty-equals/
+"
+SRC_URI="
+	https://github.com/samuelcolvin/dirty-equals/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/pytz-2021.3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x TZ=UTC
+	epytest
+}
diff --git a/dev-python/fsspec/Manifest b/dev-python/fsspec/Manifest
index c841bd8670da..a4e0c9a88d31 100644
--- a/dev-python/fsspec/Manifest
+++ b/dev-python/fsspec/Manifest
@@ -1 +1,2 @@
 DIST filesystem_spec-2022.7.1.gh.tar.gz 338526 BLAKE2B ef19c41a4e9fe3fb1a5146967bab505c26590aa4c074152523b705d8cac5eeb6e30834e1adbbb1669f5bbb58891cabd3960208cdfa9f619e0bbc5cbfe5f4ef55 SHA512 07178bf22e07091935256296b303e273c03e2ddc15a5aa1110f84c27cadaf9c650204e37c472cb10280e92f24b01fa8b16fe32db21a30d14d232c5a11e05a45c
+DIST filesystem_spec-2022.8.0.gh.tar.gz 338839 BLAKE2B 6d70e20a435caab098db2437137fcd80efdcb08ff3018daf5c72ceb958fcca354eb6a12a525ea023fd042cf54099fe991a444c3627989bc3f0e38bddd8d57aca SHA512 843ee51d7dec362623ebe584def6bb7c8b5521434befd89bba178969bb9fbe53b9b488f0f8d301d600fe2f97e876a6b74f92c9d0e9b8941aaa70f5514e6516ee
diff --git a/dev-python/fsspec/fsspec-2022.8.0.ebuild b/dev-python/fsspec/fsspec-2022.8.0.ebuild
new file mode 100644
index 000000000000..e6bba4b5cfd5
--- /dev/null
+++ b/dev-python/fsspec/fsspec-2022.8.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_P=filesystem_spec-${PV}
+DESCRIPTION="A specification that python filesystems should adhere to"
+HOMEPAGE="
+	https://github.com/fsspec/filesystem_spec/
+	https://pypi.org/project/fsspec/
+"
+SRC_URI="
+	https://github.com/fsspec/filesystem_spec/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/tqdm[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	git config --global user.email "you@example.com" || die
+	git config --global user.name "Your Name" || die
+	distutils-r1_src_test
+}
+
+EPYTEST_DESELECT=(
+	fsspec/tests/test_spec.py::test_find
+)
+
+EPYTEST_IGNORE=(
+	# sftp and smb require server started via docker
+	fsspec/implementations/tests/test_dbfs.py
+	fsspec/implementations/tests/test_sftp.py
+	fsspec/implementations/tests/test_smb.py
+	# unhappy about dev-python/fuse-python (?)
+	fsspec/tests/test_fuse.py
+)
diff --git a/dev-python/jupyterlab/Manifest b/dev-python/jupyterlab/Manifest
index db3f63fcddeb..8097140e6b27 100644
--- a/dev-python/jupyterlab/Manifest
+++ b/dev-python/jupyterlab/Manifest
@@ -1 +1,2 @@
 DIST jupyterlab-3.4.3.tar.gz 17074198 BLAKE2B 08a0aa4ddaeb6b48a742ef78e1b8cefb95fbf89ec077a1f3687c4498b7c4dbdd50e1773194c4f3c2e21d36a2010dcbcf2be0141df9383b2d05159bcb7f99ab9c SHA512 27c8d6b6636e14ea9a500764ea97b6ef16a1580728077264b662cc23b0e34ac0fd9eebe1eb5a79a64b18a2d93acc996553a6152fa135e2688b5eae21d184da57
+DIST jupyterlab-3.4.5.tar.gz 17108960 BLAKE2B 83f4e99a1f98265df50857988dcd011862a0be4212abd8217cc330b3b536f5c7de2486f5c19e692c78eb8305f73c11a11772b510847ec25d756c81c828425ce3 SHA512 17428899b577a9e661ea755e3d6e2e3d640ca4ae28cd51e197520b9a388088e2a0d52a799f14b128d94f0c1ee2ec7580e309586c63e1d2e3b6019ae1075abc1c
diff --git a/dev-python/jupyterlab/jupyterlab-3.4.5.ebuild b/dev-python/jupyterlab/jupyterlab-3.4.5.ebuild
new file mode 100644
index 000000000000..0a4477b93c99
--- /dev/null
+++ b/dev-python/jupyterlab/jupyterlab-3.4.5.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+DISTUTILS_USE_PEP517=jupyter
+inherit distutils-r1
+
+DESCRIPTION="JupyterLab computational environment"
+HOMEPAGE="https://jupyter.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD MIT GPL-3 Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="dev-python/jupyter_packaging[${PYTHON_USEDEP}]"
+
+RDEPEND="
+	dev-python/ipython[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	>=dev-python/jupyterlab_server-2.10[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_server-1.16[${PYTHON_USEDEP}]
+	>=dev-python/nbclassic-0.2[${PYTHON_USEDEP}]
+	<dev-python/notebook-7[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.1[${PYTHON_USEDEP}]
+	>=www-servers/tornado-6.1[${PYTHON_USEDEP}]
+	net-libs/nodejs
+"
+
+BDEPEND="test? (
+	dev-python/check-manifest[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/jupyterlab_server[${PYTHON_USEDEP}]
+	dev-python/openapi-core[${PYTHON_USEDEP}]
+	dev-python/openapi-spec-validator[${PYTHON_USEDEP}]
+	dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+	dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+	dev-python/pytest-timeout[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	dev-python/requests-cache[${PYTHON_USEDEP}]
+	dev-python/strict-rfc3339[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+)"
+
+EPYTEST_DESELECT=(
+	# These tests call npm and want internet
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_uninstall_core_extension
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_install_and_uninstall_pinned_folder
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_install_and_uninstall_pinned
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build_custom_minimal_core_config
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build_custom
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build_check
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build
+	jupyterlab/tests/test_build_api.py::TestBuildAPI::test_clear
+	jupyterlab/tests/test_build_api.py::TestBuildAPI::test_build
+)
+
+distutils_enable_tests pytest
+# TODO: package sphinx_copybutton
+#distutils_enable_sphinx docs/source dev-python/sphinx_rtd_theme dev-python/myst_parser
+
+python_install_all() {
+	distutils-r1_python_install_all
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
diff --git a/dev-python/jupyterlab_server/Manifest b/dev-python/jupyterlab_server/Manifest
index fd2008f67a4c..e66a9d51a509 100644
--- a/dev-python/jupyterlab_server/Manifest
+++ b/dev-python/jupyterlab_server/Manifest
@@ -1,2 +1,3 @@
 DIST jupyterlab_server-2.14.0.tar.gz 62704 BLAKE2B 93277a6880a9395622e6c0ec1da9522c5e30e7a8144c8629de89f45845964008f0a435ec84289efe56043c8ebb998ea65df1d09f3da72096f255fcafa29fab53 SHA512 21ecf749879663378d865bd06161fb3e331f3675038917e405df0cb77d4a4cec55340a35d6511676fa4d91ecaedcd1e7f8aec3a13ad3a39298d10911ab215cc6
 DIST jupyterlab_server-2.15.0.tar.gz 61443 BLAKE2B 48ead96f13caf747cc14f7d65dc6104822dcd0fe17315a2cee4111598b40f05119998f169aef90411e84fe24e8f09736c857325752cfa3f22047acb2a9e2e3c1 SHA512 27530b293ad7c171b280a4c165d7f983c85238c4cb0bc89bb2eda8493b2988f047045c842ba456df9d0bfef00b5ee28b061c537ef6293d726c3a4f3d6572727c
+DIST jupyterlab_server-2.15.1.tar.gz 62345 BLAKE2B 14d82bc9cc7566312c4f434b78f396bb822f150653e3be6f1e328d620d1d8b205a8dca8c0b4a1e84a52562e04f76cb63154fd1b58f45da3a4f787a32468595cc SHA512 b4fba8a09562a70a705170406b69cbfaad4fcee290ca74e7949155698af616e4ce650a75c06bfa613e1a307980a4769418587ccf33a964868053ded9a7648095
diff --git a/dev-python/jupyterlab_server/jupyterlab_server-2.15.1.ebuild b/dev-python/jupyterlab_server/jupyterlab_server-2.15.1.ebuild
new file mode 100644
index 000000000000..1d731fd17066
--- /dev/null
+++ b/dev-python/jupyterlab_server/jupyterlab_server-2.15.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+DISTUTILS_USE_PEP517=hatchling
+
+inherit distutils-r1
+
+DESCRIPTION="Server components for JupyterLab and JupyterLab like applications"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyterlab/jupyterlab_server/
+	https://pypi.org/project/jupyterlab-server/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/Babel[${PYTHON_USEDEP}]
+	>=dev-python/importlib_metadata-3.6[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0.3[${PYTHON_USEDEP}]
+	dev-python/json5[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.0.1[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_server-1.8[${PYTHON_USEDEP}]
+	<dev-python/jupyter_server-2[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/jupyter_server[${PYTHON_USEDEP}]
+		dev-python/openapi-core[${PYTHON_USEDEP}]
+		dev-python/openapi-spec-validator[${PYTHON_USEDEP}]
+		dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+		dev-python/strict-rfc3339[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+# TODO: package autodoc_traits
+#distutils_enable_sphinx docs/source dev-python/pydata-sphinx-theme dev-python/myst_parser
+
+python_prepare_all() {
+	# This seems to not work for us, can only find english
+	rm tests/test_translation_api.py || die
+
+	# Do not depend on pytest-cov
+	sed -i -e '/addopts/d' pyproject.toml || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/nptyping/Manifest b/dev-python/nptyping/Manifest
index dc08bf3190cb..9fce06dcaa91 100644
--- a/dev-python/nptyping/Manifest
+++ b/dev-python/nptyping/Manifest
@@ -1,2 +1,3 @@
 DIST nptyping-2.2.0.gh.tar.gz 65224 BLAKE2B 11b77690dc83492a13f5a58839655c210d3bd48368e14d0c97be4b5e51f4de54d4e4a238f5865826309b40dc7bb50376ca45827e9e74360dad215bd798610809 SHA512 3c29689994ca87418614e55811b66d03087d127b9e620c2dc3407e3e3ff984cdecd789b0dbd955db460f865a34941f061a7496362ef9944351f59a0e4c3ef483
 DIST nptyping-2.3.0.gh.tar.gz 66275 BLAKE2B 404ed4bfc1947d2a50216f7f84d712c1ae2e38e4a45cb0a3971e575f73724f32bdb41fa6c1e647c88f6d99047d898e286e165ad5dc70b7a579417a40ebd0b299 SHA512 853cbc2aa4887d68e737b57d49f16cd2e9c9c817c3126697f7bd63ed7e6755b56b081a68cad876e35fa064497ea990933d0a0d794e53ca7604b1b79ccf9dbb22
+DIST nptyping-2.3.1.gh.tar.gz 66951 BLAKE2B 781e2e84b7d89337c4753a050e95f3f9cad3a1aca22ea235e203ebe231bfc7dc4e91f5455603c4f7fe833b7b97ea9e8e561eea62eef4d0b2dce4ade077b8526d SHA512 a80df18cba3d427668be0f44f3ca315cf80daf7e3aed90d76b159479de069054cb4a2442abf7b658ddc853736fc7c3be2b0d1db2d7c9e54938cb1883eb0cb2c9
diff --git a/dev-python/nptyping/nptyping-2.3.1.ebuild b/dev-python/nptyping/nptyping-2.3.1.ebuild
new file mode 100644
index 000000000000..52aea1ac89ec
--- /dev/null
+++ b/dev-python/nptyping/nptyping-2.3.1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Type hints for Numpy"
+HOMEPAGE="
+	https://pypi.org/project/nptyping/
+	https://github.com/ramonhagenaars/nptyping/
+"
+SRC_URI="
+	https://github.com/ramonhagenaars/nptyping/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+"
+BDEPEND="
+	test? (
+		dev-python/mypy[${PYTHON_USEDEP}]
+		dev-python/typeguard[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# TODO: package beartype?
+	tests/test_beartype.py
+	# TODO: package pyright?
+	tests/test_pyright.py
+	# test for... whether the release is on pypi?
+	# requires Internet + feedparser, meaningless for users
+	tests/test_package_info.py
+	# relies on Internet access to fetch packages for pip
+	tests/test_wheel.py
+)
+
+distutils_enable_tests pytest
diff --git a/dev-python/pathspec/Manifest b/dev-python/pathspec/Manifest
index a3d7b80ee86d..910c47d3710f 100644
--- a/dev-python/pathspec/Manifest
+++ b/dev-python/pathspec/Manifest
@@ -1 +1,2 @@
+DIST pathspec-0.10.0.tar.gz 41552 BLAKE2B 28f53bc760f2ad474223f80c46f8be473e3723898b7ea923fe86f25a46c71d9f69687fdb4a7962b1922e2e35595d0b6134c97d29c60b08fd7e0b6cb2ca75ec14 SHA512 5a02de5b55ff58185e9821de09d9f7b6acb494eb65e73c7340b0c91fb06badcfc93a6804cf5a77a37be3ecfe7b76afa1ed42fd364c3384e193f4ef7488ba33b3
 DIST pathspec-0.9.0.tar.gz 29483 BLAKE2B 00b48f6987a074e23ac6f344a44ac8f265463bdd87907cb8a602c690a739d1a9a673182fc4d61a6e2ffc02acb6632591b873e435f9fc3893e1cc48015e120a16 SHA512 660f13525325c27b598048a3576fd704c3843e0b07770187d005f0e93996a90cee44e9a0725b6bf775982f586ed3b4ba7cccee966d7149e71e2b95d48030b2f2
diff --git a/dev-python/pathspec/pathspec-0.10.0.ebuild b/dev-python/pathspec/pathspec-0.10.0.ebuild
new file mode 100644
index 000000000000..29d8b95ef398
--- /dev/null
+++ b/dev-python/pathspec/pathspec-0.10.0.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Utility library for gitignore style pattern matching of file paths"
+HOMEPAGE="
+	https://github.com/cpburnz/python-pathspec/
+	https://pypi.org/project/pathspec/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+distutils_enable_tests unittest
diff --git a/dev-python/poetry-core/Manifest b/dev-python/poetry-core/Manifest
index 64fbfa17da5b..85e9266688c4 100644
--- a/dev-python/poetry-core/Manifest
+++ b/dev-python/poetry-core/Manifest
@@ -1 +1,2 @@
 DIST poetry-core-1.0.8.gh.tar.gz 414941 BLAKE2B 1f663d927aee1f18a9ff38cbf95809538bf9c9e8079d040c240fbc1ffa9e492c6fd20c69f89ddf7e68ddea05beee3b909fdee02e93f47437fffa687dc492ec9a SHA512 6dfed1e1124c37a5f0ec535ede8848e25466da3df6fa6629f6330ce32f05a4d82725d64407e5bcf294d6e467b52966642505ee29f563d3794c4e7aca78045285
+DIST poetry-core-1.1.0.gh.tar.gz 534348 BLAKE2B c5dc37579da5d260577c8027520ee9b4a31ca0c4f20f3dc6f233f4f686060aa2c2ae5af46f1d906939364f26cd04155f2c84dea9d209e8d09564b28c19d2220a SHA512 ac8f9797167572bffaaa955e70ba0ab9a509a26ae7905108b43a211b2c93bf29d418da1154bf08f3b4ff744f88c9d6fd0d58408513ffd30e1c4e309ff2784c08
diff --git a/dev-python/poetry-core/poetry-core-1.1.0.ebuild b/dev-python/poetry-core/poetry-core-1.1.0.ebuild
new file mode 100644
index 000000000000..d32d8bfd589d
--- /dev/null
+++ b/dev-python/poetry-core/poetry-core-1.1.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Poetry PEP 517 Build Backend"
+HOMEPAGE="
+	https://github.com/python-poetry/poetry-core/
+	https://pypi.org/project/poetry-core/
+"
+SRC_URI="
+	https://github.com/python-poetry/poetry-core/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# check inside src/poetry/core/_vendor/vendor.txt
+# (note that some are indirect deps)
+RDEPEND="
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/lark[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pep517[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# These "fail" bacause of glob file path resulting from newer versions
+	# in our tree than vendored. But those don't affect anything.
+	tests/masonry/builders/test_sdist.py::test_default_with_excluded_data
+	tests/masonry/builders/test_wheel.py::test_default_src_with_excluded_data
+)
+
+src_prepare() {
+	# remove vendoring of dependencies
+	rm -r src/poetry/core/_vendor || die
+	sed -e '/__vendor_site__/d' -i src/poetry/core/__init__.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# needed for migration from <1.1
+	distutils_write_namespace poetry
+	epytest
+}
diff --git a/dev-python/psycopg/psycopg-3.0.16.ebuild b/dev-python/psycopg/psycopg-3.0.16.ebuild
index 7008eef40317..0a82f4f12bfb 100644
--- a/dev-python/psycopg/psycopg-3.0.16.ebuild
+++ b/dev-python/psycopg/psycopg-3.0.16.ebuild
@@ -22,7 +22,7 @@ S=${WORKDIR}/${P}/psycopg
 
 LICENSE="LGPL-3+"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
+KEYWORDS="~alpha ~amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
 
 DEPEND="
 	>=dev-db/postgresql-8.1:*
diff --git a/dev-python/versioneer/Manifest b/dev-python/versioneer/Manifest
index f3505aa4ac87..ee69893d8688 100644
--- a/dev-python/versioneer/Manifest
+++ b/dev-python/versioneer/Manifest
@@ -1,2 +1,3 @@
+DIST python-versioneer-0.24.gh.tar.gz 68202 BLAKE2B 9a946ca2d99c614635431bdac8b87ca7a0c9d60f7161e615f69aa664b0191e33e6c8823efa0f436f8f1897318698497b5fc7db6135beac37bfdfa78cc37d343e SHA512 e8b99ca83675744ef2b4e342621ccf276c5319d7fc603c02c983aff88b57fb62dba192aaf9c6b53af5e0771690d0592b86b8772fc1e628944fe3a9479018e2be
 DIST versioneer-0.22.tar.gz 50847 BLAKE2B 3508ac89e65df7a936168fefc1a557191d9362ba69fc9b79eea495cb340c9e314ba5fbac28041bc502aee3adff555e56b43e4ff7fb0d682e96fc3e2ad6bddbad SHA512 f02d50a47c1990275ebf9e720bdb7f13e5fbfc344b361197ecb7602e5ff02e438e43983b4e1cbfde5aa6fa4328a1ffdac60009d6925cf027e484b0ce12587484
 DIST versioneer-0.23.tar.gz 52097 BLAKE2B 05762e7033e023760c118f060ad869a64e6d2b052e0a3150661364802ecad161169bd756a80284b506bb05ffa64019a6ecd56c215ae2cd1a18648e900f806d18 SHA512 c01f1eb1fca1c4ff55169742fd016796556b2178c21eb9d89b9fd83faf90c0bd3bfb0fe178c6078a776a7d2ccd61443d1c645d5f371b062fe06df970f1d3b323
diff --git a/dev-python/versioneer/versioneer-0.24.ebuild b/dev-python/versioneer/versioneer-0.24.ebuild
new file mode 100644
index 000000000000..55c705f7f444
--- /dev/null
+++ b/dev-python/versioneer/versioneer-0.24.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_P=python-versioneer-${PV}
+DESCRIPTION="Easy VCS-based management of project version strings"
+HOMEPAGE="
+	https://pypi.org/project/versioneer/
+	https://github.com/python-versioneer/python-versioneer/
+"
+SRC_URI="
+	https://github.com/python-versioneer/python-versioneer/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+SLOT="0"
+LICENSE="Unlicense"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-vcs/git
+		!!dev-python/nose[${PYTHON_USEDEP}]
+	)
+"
+
+python_test() {
+	esetup.py make_versioneer
+
+	git config --global user.email "you@example.com" || die
+	git config --global user.name "Your Name" || die
+	git config --global init.defaultBranch whatever || die
+
+	"${EPYTHON}" test/git/test_git.py -v || die
+}
diff --git a/dev-python/werkzeug/Manifest b/dev-python/werkzeug/Manifest
index 734af7fa47ac..7e9551fb2a90 100644
--- a/dev-python/werkzeug/Manifest
+++ b/dev-python/werkzeug/Manifest
@@ -1,2 +1 @@
-DIST werkzeug-2.2.0.gh.tar.gz 839619 BLAKE2B b6eae91d9a44d030517be5da13c448cf4a2778db7cde61ce36add8dea6f2ac251b31e71d128c4156f44083a4c1b77e546a7e6c55787d8beb93c49538d45b51fd SHA512 2de05269ccd3d83728d435d2f155887a5fd3f3bda9b71c32ffd64b089116c80e89319870fa082f1c6feeeb797b665521b9692ce6c87dcb48b7fa49b2fc63516b
 DIST werkzeug-2.2.2.gh.tar.gz 844463 BLAKE2B 84da3dd89375d6925e7e7018701339ddfd2b608acf6b3f126bd56c2020056511de6ab157de9024069d1342f9bce4b481ba91a06089fff1a3b31f4a851af7f935 SHA512 cded6c7e0b00871366b70a41de45e31323c0fc09300413d0efca98f5a2f8207026fd77c7e5670fde727da377fd02b9b636f390a2524d2b5778e9e3bdbdfe3e3a
diff --git a/dev-python/werkzeug/werkzeug-2.2.0.ebuild b/dev-python/werkzeug/werkzeug-2.2.0.ebuild
deleted file mode 100644
index e0119523823f..000000000000
--- a/dev-python/werkzeug/werkzeug-2.2.0.ebuild
+++ /dev/null
@@ -1,66 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
-
-inherit distutils-r1
-
-DESCRIPTION="Collection of various utilities for WSGI applications"
-HOMEPAGE="
-	https://palletsprojects.com/p/werkzeug/
-	https://pypi.org/project/Werkzeug/
-	https://github.com/pallets/werkzeug/
-"
-SRC_URI="
-	https://github.com/pallets/werkzeug/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ppc ppc64 ~riscv ~s390 sparc x86"
-
-RDEPEND="
-	>=dev-python/markupsafe-2.1.1[${PYTHON_USEDEP}]
-"
-# NOTE: remove the loong mask after greenlet gains support for loong
-# see https://github.com/python-greenlet/greenlet/pull/257
-BDEPEND="
-	test? (
-		dev-python/ephemeral-port-reserve[${PYTHON_USEDEP}]
-		dev-python/pytest-timeout[${PYTHON_USEDEP}]
-		dev-python/pytest-xprocess[${PYTHON_USEDEP}]
-		dev-python/watchdog[${PYTHON_USEDEP}]
-		!alpha? ( !arm? ( !hppa? ( !ia64? ( !s390? (
-			$(python_gen_cond_dep '
-				dev-python/cryptography[${PYTHON_USEDEP}]
-			' python3_{8..10} pypy3 # TODO: add py3.11 when ported
-			)
-		) ) ) ) )
-		!hppa? ( !ia64? ( !loong? (
-			$(python_gen_cond_dep '
-				dev-python/greenlet[${PYTHON_USEDEP}]
-			' python3_{8..10})
-		) ) )
-	)
-"
-
-distutils_enable_tests pytest
-
-python_test() {
-	local EPYTEST_DESELECT=()
-	if ! has_version "dev-python/cryptography[${PYTHON_USEDEP}]"; then
-		EPYTEST_DESELECT+=(
-			"tests/test_serving.py::test_server[https]"
-			tests/test_serving.py::test_ssl_dev_cert
-			tests/test_serving.py::test_ssl_object
-		)
-	fi
-
-	# the default portage tempdir is too long for AF_UNIX sockets
-	local -x TMPDIR=/tmp
-	epytest -p no:django -p no:httpbin tests
-}