Adding metadata

23 files changed, 682 insertions, 150 deletions

diff --git a/dev-python/aws-sam-translator/Manifest b/dev-python/aws-sam-translator/Manifest
index 1fcf7d6161e5..3287697ef239 100644
--- a/dev-python/aws-sam-translator/Manifest
+++ b/dev-python/aws-sam-translator/Manifest
@@ -1 +1,2 @@
 DIST serverless-application-model-1.86.0.gh.tar.gz 5490164 BLAKE2B f784adc234080d447b33e375acf62ab65728655aeef2d6a4c1210535e55558f1afb85c011038b42435d5aaff8d69a179769a03d3c885e1fa487be434492c1c3c SHA512 e4ec2eca9f5531402f34e37c1bc7c9257f3120c3863f18bf2661b9f8757a680c6433d59c2a3f1b31e1ffeeffaa02fbd87f6407b3faf6ba5909bfefb79462ca18
+DIST serverless-application-model-1.87.0.gh.tar.gz 5497979 BLAKE2B 96e62bd2c8b7497524f3fcd2fb805d5904d69b875049783e424859e3a038b704bebe212db4d0325050665104f9cfa9a0c746e65c33f3d7934deab3840479e975 SHA512 5577447575bd58a574f912250062d58a2ad087a4322f178580ca13bed16f60683f120c9d11006c7ebdd25937f229dfd3b308a4cc5fca2d09b7771f19e1739842
diff --git a/dev-python/aws-sam-translator/aws-sam-translator-1.87.0.ebuild b/dev-python/aws-sam-translator/aws-sam-translator-1.87.0.ebuild
new file mode 100644
index 000000000000..f01bb1ccf394
--- /dev/null
+++ b/dev-python/aws-sam-translator/aws-sam-translator-1.87.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 multiprocessing
+
+MY_P=serverless-application-model-${PV}
+DESCRIPTION="A library that transform SAM templates into AWS CloudFormation templates"
+HOMEPAGE="
+	https://github.com/aws/serverless-application-model/
+	https://pypi.org/project/aws-sam-translator/
+"
+SRC_URI="
+	https://github.com/aws/serverless-application-model/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	<dev-python/boto3-2[${PYTHON_USEDEP}]
+	>=dev-python/boto3-1.19.5[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2[${PYTHON_USEDEP}]
+	<dev-python/pydantic-3[${PYTHON_USEDEP}]
+	>=dev-python/pydantic-1.8[${PYTHON_USEDEP}]
+	<dev-python/typing-extensions-5[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.4[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# so much noise...
+	sed -i -e '/log_cli/d' pytest.ini || die
+
+	# deps are installed by ebuild, don't try to reinstall them via pip
+	truncate --size=0 requirements/*.txt || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x AWS_DEFAULT_REGION=us-east-1
+	epytest -o addopts= -o filterwarnings= \
+		-p xdist -n "$(makeopts_jobs)" --dist=worksteal
+}
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 6336a64a224d..aa25de8667bf 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -4,3 +4,4 @@ DIST boto3-1.34.74.gh.tar.gz 790202 BLAKE2B 4368db3e11d6bda6eee4ccde82bcc0c2c5a6
 DIST boto3-1.34.75.gh.tar.gz 790632 BLAKE2B 846170851c821e72b05b2c94470bc48ed542722ccec5360f03d6f5d6393a4163b21b40ac68f586748106991e501cfc5c66c5dc15e9931605a062c2cd1ef1f46d SHA512 581c5a823297066deeaf832b46d1f14db54df279ccd25c9ae2ba4896389a37f453a732e5291bbd2bec1bfa2107ce1f0efcbaee7b765ba101bec31fac40ca37dc
 DIST boto3-1.34.76.gh.tar.gz 790998 BLAKE2B fb4db194a2b8257400c0d15b266b1017d93eebf1171d9be26917e2aca7b5bb9f4c7986b035c99c4fdfc1b9eecbf0b4a26dfaaac4871712c6da72ff803e4f60c8 SHA512 bbd0868db23812ee706b8adf9221606b07a5da288c673fee2287c44c23c1023782fd00bd341486900f4ef2e87c1b6392cc59996b22588947ccd6f50c58d3b5cd
 DIST boto3-1.34.77.gh.tar.gz 791765 BLAKE2B 2c4c9f81e027403c6fe910d369644ad682bfc8edc4a6c8385eac98db3df3e17029d24e0b7f162537d88eb4b49680eee79ab3e3fcbbd413d8e8100f455960cfab SHA512 c3beec62805e943e50035d1754e582d361dde8bc6a165c7203cbeeab2aa1f4e0d67788fa7f53d10d875db1c4332e07a43b1224b9a46dfa825bb02187d5134e36
+DIST boto3-1.34.78.gh.tar.gz 792523 BLAKE2B 294770b0ca88b0e36f22796955954315a5487066af1da5b4214672a5083afc3f02cbf4f1990f5c721d09c7cfe388fc71317989e2e75461dea31767276133923c SHA512 e105f2002c654d617ddd6a115ef0bf1510b349088a8aec80653ed154cbbbcbd01c65818c6cd33db8aaacdbcadb865d858ec96bb86de2bc2b33f2762a96be04b0
diff --git a/dev-python/boto3/boto3-1.34.78.ebuild b/dev-python/boto3/boto3-1.34.78.ebuild
new file mode 100644
index 000000000000..c6201d2c5818
--- /dev/null
+++ b/dev-python/boto3/boto3-1.34.78.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+SRC_URI="
+	https://github.com/boto/boto3/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.10.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index b1276fc42045..eb4eee712072 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -4,3 +4,4 @@ DIST botocore-1.34.74.gh.tar.gz 12820469 BLAKE2B e9d7a35e82aee30666952ea6f74d8d0
 DIST botocore-1.34.75.gh.tar.gz 12864283 BLAKE2B bc5a64b704e1ae4ceebfe65d748e2e904a151343fe4543ceea1955f8d06521b2f562ee75e0384d187c7fde9f7b5d79d5f02e323059ccd9ad332416deb27de066 SHA512 21847f64ce8f6cb6732f57de6f9d53b00b0ca0d669e6cac2b0edf1a3431c0d5081e6fd7c1c7cb6d664aec7fcb2d0d5b359a40a4abfda2767bbf27f43589eaed2
 DIST botocore-1.34.76.gh.tar.gz 12868763 BLAKE2B f6a73414b8ae0dd6628dd55575809461919a2208b57633b34cf3de70712660053040a636d037fb65c4ff37a85ae48e048308935b9e3f8911397b5ba1cccd24bd SHA512 adccbd547f6ac73d1d55f51f9fb3ba8da6ad7ac5e34f3b5c8e50ebaf00893c87762ab44443a0420174816cf5c6ee9a5453cd84deac70b517e72eb5d58e595cb5
 DIST botocore-1.34.77.gh.tar.gz 12880716 BLAKE2B a4c1210921147003ca032a16eb2d67df23f7c0b8c5cdccb0eeee9e9adc93758e74560c3d5dc70bd16b69d281cceb62949f6c1c288cd2ee29e0d6b2ecbeb020bd SHA512 caf25f5958790e2b893a7378dfd55204d1dd332dfe346c1efec1d9158ef4aa53a3f214f4926380e424a921fa8561365236ff450ec3726bac054289d824c82c4d
+DIST botocore-1.34.78.gh.tar.gz 12882559 BLAKE2B 88d75c9c7e2e7132bdeab5d58b791a3af7c387b90c1e1551cda81eb364d9d177e6e3165c87fa9619731cf95f9d47759edfd22ea5deb9af2a5817a822e91fa4b6 SHA512 95b0b608ea1949092a948dc9aefb452a8db661868360f64e2dd9cf456a0e8b9177309e7d6a12b9e10d4f75bfdfe86ee3bd684f8a15ca0a83dea5fe101ad3953a
diff --git a/dev-python/botocore/botocore-1.34.78.ebuild b/dev-python/botocore/botocore-1.34.78.ebuild
new file mode 100644
index 000000000000..857224b496b7
--- /dev/null
+++ b/dev-python/botocore/botocore-1.34.78.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+SRC_URI="
+	https://github.com/boto/botocore/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+# unbundled packages
+RDEPEND+="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/hatchling/Manifest b/dev-python/hatchling/Manifest
index 6de3acbd5e05..862438fd5d78 100644
--- a/dev-python/hatchling/Manifest
+++ b/dev-python/hatchling/Manifest
@@ -1,2 +1,3 @@
 DIST hatch-hatchling-v1.21.1.gh.tar.gz 774577 BLAKE2B 31e2b50598b4fe120ecea407a37e3262876a2ec1e8cf02f272c25838e73afc37f2fef1f8fab08b2e3b83bfd828f6c558ce303b084081b83504343a8bb057c341 SHA512 91b5684737fac19758d7095b357f99031d46e9f981e093cab848ce770fd1f9440b69212f3ef2217e3700e7dd7985a97c2735bbd27b306c7b8aa7bffc5c950fb4
 DIST hatch-hatchling-v1.22.4.gh.tar.gz 782805 BLAKE2B 06cf7b07cdb35223c6ffb9403a26b50ec93decb19e58199dc17ae4d924bfaf20625270d4721bc27adfcdd3a345b80409fe9487bb457644077f6a4b7d2ee082c0 SHA512 e33dec3494cd760fdf07de532367fccc63a91a67e408fe5c7ac60bf568093ea0419f6e9d5bfd49aa9c9415d79f006c4b3794b96e91aa97af4e7b87b129c4b448
+DIST hatch-hatchling-v1.22.5.gh.tar.gz 782757 BLAKE2B 3431ef7c4e5f0754e51507e29d88ed0277b530d220eb75bdeab459d88172ba51de3cf2456074fa88483cc89e72726f3e147b97e995f9ccaf699b6c2699776a8c SHA512 d4e77872e34e3aba3fce286f911861b795005c37550a2ca72a83216cea67d53be891afc8861b11582c66d38748f9c8d4980548d216c0fb21b2b4e1cadc314e58
diff --git a/dev-python/hatchling/hatchling-1.22.5.ebuild b/dev-python/hatchling/hatchling-1.22.5.ebuild
new file mode 100644
index 000000000000..1389ba78396b
--- /dev/null
+++ b/dev-python/hatchling/hatchling-1.22.5.ebuild
@@ -0,0 +1,87 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1
+
+TAG=${P/-/-v}
+MY_P=hatch-${TAG}
+DESCRIPTION="Modern, extensible Python build backend"
+HOMEPAGE="
+	https://pypi.org/project/hatchling/
+	https://github.com/pypa/hatch/
+"
+SRC_URI="
+	https://github.com/pypa/hatch/archive/${TAG}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}/backend
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+
+# deps are listed in backend/src/hatchling/ouroboros.py
+# editables are optional but required for editable installs
+RDEPEND="
+	>=dev-python/editables-0.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+	' 3.10)
+	dev-python/trove-classifiers[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/atomicwrites[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+			dev-python/httpx[${PYTHON_USEDEP}]
+			dev-python/platformdirs[${PYTHON_USEDEP}]
+			dev-python/pytest-mock[${PYTHON_USEDEP}]
+			dev-python/rich[${PYTHON_USEDEP}]
+			dev-python/tomli-w[${PYTHON_USEDEP}]
+			dev-python/virtualenv[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
+	local -x EPYTEST_DESELECT=(
+		# these run pip to install stuff
+		tests/backend/dep/test_core.py::test_dependency_found
+		tests/backend/dep/test_core.py::test_extra_met
+		tests/backend/dep/test_core.py::test_extra_no_dependencies
+		tests/backend/dep/test_core.py::test_extra_unmet
+		tests/backend/dep/test_core.py::test_unknown_extra
+		tests/backend/dep/test_core.py::test_version_unmet
+		# broken if CARGO is set
+		tests/backend/builders/test_binary.py::TestBuildBootstrap::test_no_cargo
+	)
+
+	# top-level "tests" directory contains tests both for hatch
+	# and hatchling
+	cd "${WORKDIR}/${MY_P}" || die
+	local -x PYTHONPATH="src:${PYTHONPATH}"
+	# sigh; standalone test suites are overrated, right?
+	echo "__version__ = '${PV}'" > src/hatch/_version.py || die
+	# tests mock cargo subprocess call but the backend raises if CARGO
+	# is not set and shutil.which() can't find it
+	local -x CARGO=cargo
+	epytest tests/backend
+}
diff --git a/dev-python/jaraco-context/Manifest b/dev-python/jaraco-context/Manifest
index 1564c9707741..7325d33c0f5d 100644
--- a/dev-python/jaraco-context/Manifest
+++ b/dev-python/jaraco-context/Manifest
@@ -1 +1,2 @@
 DIST jaraco.context-4.3.0.tar.gz 9764 BLAKE2B 2905723ec54c6ae63b2088d677cd486dcdc06dfea06bb058eeb512da508b2ae74990894cb62f3751321cb4c813b66ffe9a3084b21eb0cb4236a9515969432dfc SHA512 8882229fa1a68f2733ec4103fbeaf47625b19790f4461ab18df4c1f1a99d4d26d10d7381ab68ba5df48616a1fdb2d5e4a767496a0e40658fd011ed9cd39255de
+DIST jaraco.context-5.1.0.tar.gz 11626 BLAKE2B c6ac691c6493e0aed5d606784f8418e55fb0c6c8094aa75251ffb12008fb9b4fbfe0912e6ef316d7799d2c0f55be6ba542202f6b8b2bc93afa3a79da4224d35f SHA512 b92c72947060e2219c172c43104055d026f66b119676fcfa31dff34640539d34376b61d209291fffeb558e6051fb92a2a34390fbd3a72f87ee15c5926cb387e5
diff --git a/dev-python/jaraco-context/jaraco-context-5.1.0.ebuild b/dev-python/jaraco-context/jaraco-context-5.1.0.ebuild
new file mode 100644
index 000000000000..c31718fe4b8e
--- /dev/null
+++ b/dev-python/jaraco-context/jaraco-context-5.1.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYPI_NO_NORMALIZE=1
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Context managers by jaraco"
+HOMEPAGE="
+	https://github.com/jaraco/jaraco.context/
+	https://pypi.org/project/jaraco.context/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+
+distutils_enable_tests pytest
+
+src_configure() {
+	grep -q 'build-backend = "setuptools' pyproject.toml ||
+		die "Upstream changed build-backend, recheck"
+	# write a custom pyproject.toml to ease setuptools bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "jaraco.context"
+		version = "${PV}"
+		description = "Context managers by jaraco"
+	EOF
+}
+
+python_install() {
+	distutils-r1_python_install
+	# rename to workaround a bug in pkg_resources
+	# https://bugs.gentoo.org/834522
+	mv "${D}$(python_get_sitedir)"/jaraco{_,.}context-${PV}.dist-info || die
+}
diff --git a/dev-python/lmfit/Manifest b/dev-python/lmfit/Manifest
index 551f6cecb01d..2ad85a8f206c 100644
--- a/dev-python/lmfit/Manifest
+++ b/dev-python/lmfit/Manifest
@@ -1 +1,2 @@
 DIST lmfit-1.2.2.tar.gz 336346 BLAKE2B 78819c8be935f330b2f0eaad09ff9201c80e12d571571d8ee5088100c4d19a6a78d2e860e7b240fb6f2eea5f27bd0fc72538fdb04e6cc4e3e1d801f4f5fc5110 SHA512 f667bf8eb9c4090beda33de8a32c284a1f1eb2f1643085191943517acf61e125c7bafed37b634267fdc69e49338397248673fc62f8afc8fc8cc6733726cd0313
+DIST lmfit-1.3.0.tar.gz 628754 BLAKE2B e5fa707c8f778227e89c996e4c2763b71562b01e67cbe3558825e2ee278999c5732717953607104ba553faee2984151a978e04c44a624ea95d1bc4fc9f2feb60 SHA512 198b290a8970dc954705824f09b86ee2bd9e12fc71635fe89e38a5911f88103861daab6f292a6e4c93bc3e3413676b33f680cea7adae3137feb251d792f76270
diff --git a/dev-python/lmfit/lmfit-1.3.0.ebuild b/dev-python/lmfit/lmfit-1.3.0.ebuild
new file mode 100644
index 000000000000..dfb7467e66a9
--- /dev/null
+++ b/dev-python/lmfit/lmfit-1.3.0.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Non-Linear Least-Squares Minimization and Curve-Fitting for Python"
+HOMEPAGE="
+	https://lmfit.github.io/lmfit-py/
+	https://github.com/lmfit/lmfit-py/
+	https://pypi.org/project/lmfit/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/asteval-0.9.28[${PYTHON_USEDEP}]
+	>=dev-python/dill-0.3.4[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.19[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.6[${PYTHON_USEDEP}]
+	>=dev-python/uncertainties-3.1.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools-scm-6.2[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -o addopts=
+}
diff --git a/dev-python/numexpr/numexpr-2.10.0.ebuild b/dev-python/numexpr/numexpr-2.10.0.ebuild
index a4e590060a3a..943c541d0280 100644
--- a/dev-python/numexpr/numexpr-2.10.0.ebuild
+++ b/dev-python/numexpr/numexpr-2.10.0.ebuild
@@ -19,10 +19,9 @@ SRC_URI="https://github.com/pydata/numexpr/archive/v${PV}.tar.gz -> ${P}.gh.tar.
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
 
 DEPEND="
-	>=dev-python/numpy-1.19.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-2.0.0_rc[${PYTHON_USEDEP}]
 "
 RDEPEND="
 	${DEPEND}
diff --git a/dev-python/pipdeptree/Manifest b/dev-python/pipdeptree/Manifest
index 4c7064829cf4..c9f50bf22109 100644
--- a/dev-python/pipdeptree/Manifest
+++ b/dev-python/pipdeptree/Manifest
@@ -1,4 +1 @@
-DIST pipdeptree-2.15.1.tar.gz 34461 BLAKE2B e437785e609bacc31b5ca32fd03b7d69c3b0f597725d021ef978d49037e0d9e6e6b0c6545f5c7a93b4a26befa019156156d554e2d3470282758ed535097377f9 SHA512 ed8482c811758fc94adf196315f022cc6a07029ece9246bab04a64949faa22fc9b6811dd357d0a51803f305c837d6fa1267cf38d5a5cd728c3bf00e65d46d05d
-DIST pipdeptree-2.16.0.tar.gz 34872 BLAKE2B 91401cf9ac05e365332956b874b17b40c62a8a6573b69adeae1d451d2878e887ee180239926962a2b7caae67b45619f715f8ade5c9df5b13683f167ee6592d0e SHA512 c3c1d6377cd3a30980c36fc4935f4aa4b96c402f09017f6e9e3d1c12c56580b1f56b1ea0edcbd6b588dbb96a9f5afa7a727c83faaf110d4a5e7f51df36628a03
-DIST pipdeptree-2.16.1.tar.gz 32145 BLAKE2B 8892433bbd858566c1b7dde26d42617c2f075808b8df047c750f4c482cc326f9dd4248c50bacef385f518644898893a31ee701f070a7a80215e13be0c6329b03 SHA512 d0c7d05d818f1118b1897b5ad0a09459f2c8e0fb98486555783659a68ab2d24edc3299ef747e438c4669dc34fb8833d6a217ddbf900f21bc8954d63661494a60
 DIST pipdeptree-2.16.2.tar.gz 32151 BLAKE2B 18715b0c7835e19bd5b6846922990e321a7e06315642204e7d79375a50b692f87e2ba1ec5884c4f69ff6e8d75e863c8cf372152aca7561ab94ef265d3c1df9fb SHA512 06d72f94a9165fe52cc15b9f539e3adb6da99e4a63cae78928bf68be3499b2828a5d471f270455b94a960ba2fe2f6319f5319c20ed270029a38a81173a7cd403
diff --git a/dev-python/pipdeptree/pipdeptree-2.15.1.ebuild b/dev-python/pipdeptree/pipdeptree-2.15.1.ebuild
deleted file mode 100644
index a6f2a82f6555..000000000000
--- a/dev-python/pipdeptree/pipdeptree-2.15.1.ebuild
+++ /dev/null
@@ -1,43 +0,0 @@
-# Copyright 2022-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
-
-inherit distutils-r1 pypi optfeature
-
-DESCRIPTION="Utility for displaying installed packages in a dependency tree"
-HOMEPAGE="
-	https://github.com/tox-dev/pipdeptree/
-	https://pypi.org/project/pipdeptree/
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~riscv"
-
-BDEPEND="
-	dev-python/hatch-vcs[${PYTHON_USEDEP}]
-	test? (
-		dev-python/graphviz[${PYTHON_USEDEP}]
-		dev-python/pip[${PYTHON_USEDEP}]
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		dev-python/virtualenv[${PYTHON_USEDEP}]
-	)
-"
-
-PATCHES=(
-	# https://github.com/tox-dev/pipdeptree/pull/302
-	"${FILESDIR}/pipdeptree-2.13.1-expect-hpy-in-pypy-7.3.3.patch"
-	"${FILESDIR}/pipdeptree-2.13.2-fix-pypy-7.3.14.patch"
-)
-
-distutils_enable_tests pytest
-
-pkg_postinst() {
-	optfeature \
-		"visualising the dependency graph with --graph-output" \
-		dev-python/graphviz
-}
diff --git a/dev-python/pipdeptree/pipdeptree-2.16.0.ebuild b/dev-python/pipdeptree/pipdeptree-2.16.0.ebuild
deleted file mode 100644
index 5ca4e9ace380..000000000000
--- a/dev-python/pipdeptree/pipdeptree-2.16.0.ebuild
+++ /dev/null
@@ -1,54 +0,0 @@
-# Copyright 2022-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
-
-inherit distutils-r1 pypi optfeature
-
-DESCRIPTION="Utility for displaying installed packages in a dependency tree"
-HOMEPAGE="
-	https://github.com/tox-dev/pipdeptree/
-	https://pypi.org/project/pipdeptree/
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~riscv"
-
-BDEPEND="
-	dev-python/hatch-vcs[${PYTHON_USEDEP}]
-	test? (
-		dev-python/graphviz[${PYTHON_USEDEP}]
-		dev-python/pip[${PYTHON_USEDEP}]
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		dev-python/virtualenv[${PYTHON_USEDEP}]
-	)
-"
-
-PATCHES=(
-	# https://github.com/tox-dev/pipdeptree/pull/302
-	"${FILESDIR}/pipdeptree-2.13.1-expect-hpy-in-pypy-7.3.3.patch"
-	"${FILESDIR}/pipdeptree-2.13.2-fix-pypy-7.3.14.patch"
-)
-
-distutils_enable_tests pytest
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# broken when flufl.lock is actually installed
-		# https://github.com/tox-dev/pipdeptree/issues/326
-		tests/_models/test_dag.py::test_package_dag_from_pkgs_uses_pep503normalize
-	)
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest -p pytest_mock
-}
-
-pkg_postinst() {
-	optfeature \
-		"visualising the dependency graph with --graph-output" \
-		dev-python/graphviz
-}
diff --git a/dev-python/pipdeptree/pipdeptree-2.16.1.ebuild b/dev-python/pipdeptree/pipdeptree-2.16.1.ebuild
deleted file mode 100644
index 651a6603eb68..000000000000
--- a/dev-python/pipdeptree/pipdeptree-2.16.1.ebuild
+++ /dev/null
@@ -1,48 +0,0 @@
-# Copyright 2022-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
-
-inherit distutils-r1 pypi optfeature
-
-DESCRIPTION="Utility for displaying installed packages in a dependency tree"
-HOMEPAGE="
-	https://github.com/tox-dev/pipdeptree/
-	https://pypi.org/project/pipdeptree/
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~riscv"
-
-BDEPEND="
-	dev-python/hatch-vcs[${PYTHON_USEDEP}]
-	test? (
-		dev-python/graphviz[${PYTHON_USEDEP}]
-		dev-python/pip[${PYTHON_USEDEP}]
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		dev-python/virtualenv[${PYTHON_USEDEP}]
-	)
-"
-
-PATCHES=(
-	# https://github.com/tox-dev/pipdeptree/pull/302
-	"${FILESDIR}/pipdeptree-2.13.1-expect-hpy-in-pypy-7.3.3.patch"
-	"${FILESDIR}/pipdeptree-2.13.2-fix-pypy-7.3.14.patch"
-)
-
-distutils_enable_tests pytest
-
-python_test() {
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest -p pytest_mock
-}
-
-pkg_postinst() {
-	optfeature \
-		"visualising the dependency graph with --graph-output" \
-		dev-python/graphviz
-}
diff --git a/dev-python/sqlglot/Manifest b/dev-python/sqlglot/Manifest
index 273d886a0ecc..95de235c385d 100644
--- a/dev-python/sqlglot/Manifest
+++ b/dev-python/sqlglot/Manifest
@@ -24,6 +24,7 @@ DIST sqlglot-23.2.0.tar.gz 12887764 BLAKE2B b8aa9af7fe52d8318a99aba2407011bb11d2
 DIST sqlglot-23.3.0.tar.gz 12889395 BLAKE2B 269e532708e1d7413f91407676fdbf90a93e22115a497255316ca50a3d864a7c8e99dc6009761ae3db92195f603f9013654269c4277d03f93b3fab9b3e951fe6 SHA512 3040b9dcb8f622c5a5e9b9ecc28f4b07a7e1cc9bce537689325ace3f4d851af168629b489cf245cbfa5e2abfd48df0c98c0e0c46abe0d473a7bc3d3341845ba4
 DIST sqlglot-23.6.3.tar.gz 12928641 BLAKE2B dd6ea9e42eb231cb57d35d90442edcd33081ce09750fad58283f09963853faa9c600fdb1ee816c6489703a34a1216f7e0934221e36717f897e5a4f63a0611aae SHA512 589dc2578bd221de734ed7ac6dc9b0ae7ba52d735c809a43b3757ced29aff86b52aa41140a2951601a86088236e86e0f164f5f4257376b5e46619640934d651d
 DIST sqlglot-23.6.4.tar.gz 12929221 BLAKE2B abfac6a52263d93f25beb2c0d9198d73c7bc24f9d9086597a50f12319249869177f3a48e4ac5dc548923842b5fb43b91bed5888d18abb0daddc476ad24aab509 SHA512 45ae26c5cf6635e564cbf1ae68ca6792969cfdeb1dbfb3b8ded7ef18222e6d257ab773274a73f77425858304140ebc65f50e39b795dbec0c11c221cf18b0cac7
+DIST sqlglot-23.7.0.tar.gz 12930040 BLAKE2B 2edd122e351286948f7adeaea6ead40a4c4ffbe9ff141f8fb0ded2ba8153ff90d051b4c6e5335f0ebb07c816956cb39164918bddc7ab2ef6c805e8713338243e SHA512 31d7eba56a74943cbff4275280c527a1ceeaa69b26fc992b7b227e9bcb836487ce57dfb1f562df1b6780128b1479d2c7f65a8497cb237e6618d8be9ad972130d
 DIST syn-2.0.41.crate 246016 BLAKE2B 9d389f2e2a0acb4c84c309456e8ffcc88c5d4d541535ed136832d7a6054dde45a598bb68e8a6f3062ca2a96e1ceae947d54b3aec9bad65b0c51d6733aa6c80db SHA512 6bbaf69ca783025dfb81ac3612ac60bfbed31b2d87792909b35c12892dadebdaff2ddf9463105e536b671dce5870610ab90fe29471284bbd3014dca8d6993f1a
 DIST target-lexicon-0.12.12.crate 25156 BLAKE2B f3803596c75f6c89438592a1176c3748fc2c0524d7d50a20056de1cd26d40c572b05bafcdf6dd702752864bea37c8b4f28f96dadc12a5b3bb1d279b25e489f85 SHA512 6147295c43ba1b7b087a3c5ab51534b2985e4e77e5e15687978cfb9d07e21c4fd9bc7191576d6cabd268d08a44dc733c4a957e59dba8b948c2055d8bb433aeca
 DIST unicode-ident-1.0.12.crate 42168 BLAKE2B 4cede03c08758ccd6bf53a0d0057d7542dfdd0c93d342e89f3b90460be85518a9fd24958d8b1da2b5a09b5ddbee8a4263982194158e171c2bba3e394d88d6dac SHA512 bc1824e1e4452a40732fc69874d7e1a66f7803717a314790dcf48867eba34bc9441331ef031e386912e52c385645c25b6ed39d4f149973b5b97371b1b96b1920
diff --git a/dev-python/sqlglot/sqlglot-23.7.0.ebuild b/dev-python/sqlglot/sqlglot-23.7.0.ebuild
new file mode 100644
index 000000000000..c040bab3734b
--- /dev/null
+++ b/dev-python/sqlglot/sqlglot-23.7.0.ebuild
@@ -0,0 +1,121 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+CARGO_OPTIONAL=1
+CRATES="
+	autocfg@1.1.0
+	bitflags@1.3.2
+	cfg-if@1.0.0
+	heck@0.4.1
+	indoc@2.0.4
+	libc@0.2.150
+	lock_api@0.4.11
+	memoffset@0.9.0
+	once_cell@1.19.0
+	parking_lot@0.12.1
+	parking_lot_core@0.9.9
+	proc-macro2@1.0.70
+	pyo3-build-config@0.20.0
+	pyo3-ffi@0.20.0
+	pyo3-macros-backend@0.20.0
+	pyo3-macros@0.20.0
+	pyo3@0.20.0
+	quote@1.0.33
+	redox_syscall@0.4.1
+	scopeguard@1.2.0
+	smallvec@1.11.2
+	syn@2.0.41
+	target-lexicon@0.12.12
+	unicode-ident@1.0.12
+	unindent@0.2.3
+	windows-targets@0.48.5
+	windows_aarch64_gnullvm@0.48.5
+	windows_aarch64_msvc@0.48.5
+	windows_i686_gnu@0.48.5
+	windows_i686_msvc@0.48.5
+	windows_x86_64_gnu@0.48.5
+	windows_x86_64_gnullvm@0.48.5
+	windows_x86_64_msvc@0.48.5
+"
+
+inherit cargo distutils-r1 pypi optfeature
+
+DESCRIPTION="An easily customizable SQL parser and transpiler"
+HOMEPAGE="
+	https://sqlglot.com/
+	https://github.com/tobymao/sqlglot/
+	https://pypi.org/project/sqlglot/
+"
+SRC_URI+="
+	native-extensions? (
+		${CARGO_CRATE_URIS}
+	)
+"
+
+LICENSE="MIT"
+LICENSE+=" native-extensions? ("
+# Dependent crate licenses
+LICENSE+=" Apache-2.0-with-LLVM-exceptions MIT Unicode-DFS-2016"
+LICENSE+=" )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+native-extensions"
+
+BDEPEND="
+	native-extensions? (
+		${RUST_DEPEND}
+		dev-util/maturin[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+QA_FLAGS_IGNORED="usr/lib.*/py.*/site-packages/sqlglotrs/sqlglotrs.*.so"
+
+src_unpack() {
+	cargo_src_unpack
+}
+
+src_prepare() {
+	# remove fragile timing check
+	sed -i -e '/assertLessEqual(time\.time/d' tests/test_parser.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+
+	if use native-extensions; then
+		local DISTUTILS_USE_PEP517=maturin
+		cd sqlglotrs || die
+		distutils-r1_python_compile
+		cd - >/dev/null || die
+	fi
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# Tests require pyspark or duckdb which aren't in the tree.
+		# Pandas would be a requirement normally, but it gets ignored by proxy.
+		"tests/dataframe/integration/test_dataframe.py"
+		"tests/dataframe/integration/test_grouped_data.py"
+		"tests/dataframe/integration/test_session.py"
+		"tests/test_executor.py"
+		"tests/test_optimizer.py"
+	)
+
+	# make sure not to use an earlier installed version
+	local -x SQLGLOTRS_TOKENIZER=$(usex native-extensions 1 0)
+	rm -rf sqlglotrs || die
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "simplifying timedelta expressions" dev-python/python-dateutil
+}
diff --git a/dev-python/stripe/Manifest b/dev-python/stripe/Manifest
index ed92d3eb63c3..ce2d570a16b3 100644
--- a/dev-python/stripe/Manifest
+++ b/dev-python/stripe/Manifest
@@ -1,2 +1,3 @@
+DIST stripe-8.10.0.tar.gz 1208587 BLAKE2B 844f220b8d7a5c53fda9d5d11418098dada8702813d29a44c839d309c13faf988112522de6bbfede094b50b8ce05d4f66ef0f47514a32f5f66eee43d67724fd6 SHA512 58c9d7b2b28304b37f616e4017a6119ec7efdb8d32d0a19c1c8e2511c72d3b0af5876407ada6db8150bb83b0fa04ac45789635d53766a1c7cc1721478b701a2b
 DIST stripe-8.7.0.tar.gz 1080685 BLAKE2B 0d91f852ad88cf09fb5230a421f9b9b5ade3e7617e95f6f0b5ff3bb14e307d272c1d8600a2673d63a408ca24501e71383fa18f527433e9fbc816f6a48fb9c576 SHA512 977c57a4bad1b572dbee566609f28a9b7e3bffea6516ac48b1f69c51a8ee8fb44d342ce886e2809f6c18b633c30f57e35c565817f2dd67d82c23048dc47d66e5
 DIST stripe-8.9.0.tar.gz 1124248 BLAKE2B 158b070256404dfa7f5d2a13f076c08834fc0ec5c3f0564912bcd461276d790faf0530260f291f8681c357de727465ab900339b4d53ddf93972ace7411748ff8 SHA512 e4505262720eaccffd5b5e12858df1ca81117bdb9103ac7f9425ae50f93ac621b13587a314edc80546f1f6c4b28c5908fcd34f31dacc8e2c80b4532bf56fb63e
diff --git a/dev-python/stripe/stripe-8.10.0.ebuild b/dev-python/stripe/stripe-8.10.0.ebuild
new file mode 100644
index 000000000000..4665daf58dc6
--- /dev/null
+++ b/dev-python/stripe/stripe-8.10.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Stripe python bindings"
+HOMEPAGE="
+	https://github.com/stripe/stripe-python/
+	https://pypi.org/project/stripe/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="telemetry"
+
+RDEPEND="
+	>=dev-python/requests-2.20[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.5.0[${PYTHON_USEDEP}]
+"
+# please bump dev-util/stripe-mock dep to the latest version on every bump
+BDEPEND="
+	test? (
+		>=dev-util/stripe-mock-0.183.0
+		dev-python/anyio[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		net-misc/curl
+	)
+"
+
+distutils_enable_tests pytest
+
+DOCS=( LONG_DESCRIPTION.rst CHANGELOG.md README.md )
+
+src_prepare() {
+	if ! use telemetry; then
+		sed -i -e '/enable_telemetry/s:True:False:' stripe/__init__.py || die
+	fi
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests -p anyio -p pytest_mock
+}
+
+src_test() {
+	local stripe_mock_port=12111
+	local stripe_mock_max_port=12121
+	local stripe_mock_logfile="${T}/stripe_mock_${EPYTHON}.log"
+	# Try to start stripe-mock until we find a free port
+	while [[ ${stripe_mock_port} -le ${stripe_mock_max_port} ]]; do
+		ebegin "Trying to start stripe-mock on port ${stripe_mock_port}"
+		stripe-mock --http-port "${stripe_mock_port}" &> "${stripe_mock_logfile}" &
+		local stripe_mock_pid=${!}
+		sleep 2
+		# Did stripe-mock start?
+		curl --fail -u "sk_test_123:" \
+			"http://127.0.0.1:${stripe_mock_port}/v1/customers" &> /dev/null
+		eend ${?} "Port ${stripe_mock_port} unavailable"
+		if [[ ${?} -eq 0 ]]; then
+			einfo "stripe-mock running on port ${stripe_mock_port}"
+			break
+		fi
+		(( stripe_mock_port++ ))
+	done
+	if [[ ${stripe_mock_port} -gt ${stripe_mock_max_port} ]]; then
+		eerror "Unable to start stripe-mock for tests"
+		die "Please see the logfile located at: ${stripe_mock_logfile}"
+	fi
+
+	local -x STRIPE_MOCK_PORT=${stripe_mock_port}
+	distutils-r1_src_test
+
+	# Tear down stripe-mock
+	kill "${stripe_mock_pid}" || die "Unable to stop stripe-mock"
+}
diff --git a/dev-python/uv/Manifest b/dev-python/uv/Manifest
index 0d910430f3b8..d2675244f055 100644
--- a/dev-python/uv/Manifest
+++ b/dev-python/uv/Manifest
@@ -1,6 +1,7 @@
 DIST pubgrub-aab132a3d4d444dd8dd41d8c4e605abd69dacfe1.gh.tar.gz 73856 BLAKE2B 9e30babd5159de0f80a69de082e990cade3768a4f62c64ecec46253b1c8a3da56a61d096f0cd2e74da436cbabb444c5acbfe27cc55160a5c0c99205c0317612a SHA512 f49c63df7394fcd4ce6a616e3c8d7893274f4bbe4d451f3fb46eed80a3e03eb345818c5ff87e9d3ac23c80ea7ffee5de01237a5dfff40f740f88a6d61eab5f81
 DIST pubgrub-c26e485213e39582c6f2e4d45c0328422670e7a7.gh.tar.gz 86123 BLAKE2B 743bb61460903d276f467b23bb001313598b50cb54fd1a56bcadbc732dd606bafd48a2d9960add3424bd03222450b455f9f1bc8716a80933e5ed0cfb76dcc50a SHA512 9f9c8b58dd2ddeb3ed89abcd790641bd9b7b2cf4fc66dcc4d964a1b69d879adcdaf2775545631ca20f06a8ab5d6bc1df6b2eb272207d2642584c269b358f4d76
 DIST pubgrub-e981e4dfe315582e84e2fd724832fb0e0c50b7aa.gh.tar.gz 76914 BLAKE2B e7039f3b2fdc2a702f4824ff99acba9549e916c211290b79ec710060369b2c76e518c210c109103bf5ba50cbb373d0a4e3185df09935d7e47241ec25da259776 SHA512 94cfc88b6736ffd78bcbcc3f4cd9940d27c902bf2dfca38dddb470b8a6a0bb3a8e4a61dd1b2654e49327c9386c3ac2a7f090f9a6c2426b19ecf00d9f9716d400
+DIST rs-async-zip-1dcb40cfe1bf5325a6fd4bfcf9894db40241f585.gh.tar.gz 96766 BLAKE2B f9efab73c65394e33e090a6292875ebf35e6669b15c356f102eb109784a4503606ae39106cd0ebe3d7d479cb0b30806d7baaaebf22d826836a24f7ed49100934 SHA512 3b845b05d97c5ab5cea286a7c11846838b40bb1fac98a51782600849a53231be8fa205094c6bdd00f6e193c807b10b28f947698696382be99cae0a8d681dabdc
 DIST rs-async-zip-d76801da0943de985254fc6255c0e476b57c5836.gh.tar.gz 95906 BLAKE2B a5a0e4d20926d637cbfa25cb486580de6682365c588a9653c873622424ec28ac8c7380d1c99ec260cd342b214aacd5124b51fc5e5646f15f76db4148aada2f41 SHA512 dd5b61bfc913a94822d74f1dac3b30f7a3979a641c3b08ccb5fa84cfbb2bfd8c0f807a30cc4ae0abfe5df7079011c20e1f8a642fd439ce6ba2c404ddee06baf5
 DIST uv-0.1.13-crates.tar.xz 47903460 BLAKE2B da7a2f023054197820cd1bcd13c6e4ff6d4c4bc4780fa109b2c5b796830333f21bc4c7f426052f7ed31a6c02f4e28694cfd94b1aa9d3044ebde49570e565c04b SHA512 cce73590c12a082fed36092bada42b878437cc44137f47c47b4e0e6fae214295867fbda90576d8ed47b025d873dc5655ab74c9914d6ccbaf6cea994b793800d5
 DIST uv-0.1.13.gh.tar.gz 1860446 BLAKE2B e5c209e11ea10a0aa8a88d4d40b40fe84cdd764cab1e852b49a52d8ff8749aac59d62234626fa768e6b1c304ee7b7a54cf99f5af4ecf21b368a1b521a8f903df SHA512 dc00cc26bc3b8e30edcc619bd49ff44962180623be8d1e2d7dc7c2b1c29969c8b393eda31b1392d90f0d72c15f2cb19af489e1e44f857225e461393c4b4b96c1
@@ -8,3 +9,4 @@ DIST uv-0.1.24-crates.tar.xz 64420840 BLAKE2B 7324461092a07c86aadaddf051aaa7454e
 DIST uv-0.1.24.gh.tar.gz 899637 BLAKE2B fab26ba9934fc5f586505b5ac1fa386c11f07e51ca2bb2a79f46d5dec9475ba8d75ad8587223d5149df5f2a225146d020a49b7ff81ed26b949cff55892738c2d SHA512 520b47a096b50fce9e7b7af5bca203df9bf4c2d0aafbe28a3dcfe0592d8ddcaa7b58d52300c67454f6aeecfd196f1592be18e45c95b7c67257361917cdb0154d
 DIST uv-0.1.28-crates.tar.xz 64374368 BLAKE2B 6eceb9eba6d746007eb983ae704fc96496e29e86d219af19af01cafdb230bf2e5f572d07fac2ee5cdb42e5e553dbc266233425084acd98d73039a761c5e2907e SHA512 0966ece30f0ac1111ac6eb0d3f5aeea3a3a443962e0a477c66b62dae09374f1dccf1a0ac355d5c684e76759f64b6921ed192de8d0363682d0aafe1de31c019be
 DIST uv-0.1.28.gh.tar.gz 925800 BLAKE2B 5e30573a198057261fe7716dc6dc5d8b7bd8700fabc4f061129d5e15475eeee96ea6424fc7321425348103796a2a6278118cc1c3399f8c3858c3816450e068c7 SHA512 3de0df5ca3c69bedc30d20c199251060a35d82ede8fa9f7f4907eee8e0bd55c7f10fbee0e870e1145c88c8526ab4729af4be393bc2a6508fa008050691ccf06a
+DIST uv-0.1.29.gh.tar.gz 929681 BLAKE2B 647588a8c34d77cfa43ee7b459da19b6365c7ae451d2acb609c4ba1a67a0065be2d52925302a77cc716659b4cf217022bc9794d1d234c6aa43734dd5fca936ef SHA512 6a39347daa3922a594b318b7a56547d32b97fd81822265e8b0899c6cfe9e5e072e96b49fd2db74eeaf88f6f42a3b2c60aa7e7e338a38d0af4256a42a703a7d95
diff --git a/dev-python/uv/uv-0.1.29.ebuild b/dev-python/uv/uv-0.1.29.ebuild
new file mode 100644
index 000000000000..af1ced8243df
--- /dev/null
+++ b/dev-python/uv/uv-0.1.29.ebuild
@@ -0,0 +1,109 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES="
+"
+
+declare -A GIT_CRATES=(
+	[async_zip]='https://github.com/charliermarsh/rs-async-zip;1dcb40cfe1bf5325a6fd4bfcf9894db40241f585;rs-async-zip-%commit%'
+	[pubgrub]='https://github.com/astral-sh/pubgrub;c26e485213e39582c6f2e4d45c0328422670e7a7;pubgrub-%commit%'
+)
+
+inherit cargo check-reqs
+
+DESCRIPTION="A Python package installer and resolver, written in Rust"
+HOMEPAGE="
+	https://github.com/astral-sh/uv/
+	https://pypi.org/project/uv/
+"
+# pypi sdist misses scripts/, needed for tests
+SRC_URI="
+	https://github.com/astral-sh/uv/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	${CARGO_CRATE_URIS}
+"
+if [[ ${PKGBUMPING} != ${PVR} ]]; then
+	CRATE_P=${PN}-0.1.28
+	SRC_URI+="
+		https://dev.gentoo.org/~mgorny/dist/${CRATE_P}-crates.tar.xz
+	"
+fi
+
+# most of the code
+LICENSE="|| ( Apache-2.0 MIT )"
+# crates/pep508-rs is || ( Apache-2.0 BSD-2 ) which is covered below
+# Dependent crate licenses
+LICENSE+="
+	0BSD Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD ISC MIT
+	MPL-2.0 Unicode-DFS-2016
+"
+# ring crate
+LICENSE+=" openssl"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="test"
+PROPERTIES="test_network"
+
+DEPEND="
+	dev-libs/libgit2:=
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	>=virtual/rust-1.77
+	test? (
+		dev-lang/python:3.8
+		dev-lang/python:3.9
+		dev-lang/python:3.10
+		dev-lang/python:3.11
+		dev-lang/python:3.12
+	)
+"
+
+QA_FLAGS_IGNORED="usr/bin/.*"
+
+check_space() {
+	local CHECKREQS_DISK_BUILD=3G
+	use debug && CHECKREQS_DISK_BUILD=9G
+	check-reqs_pkg_setup
+}
+
+pkg_pretend() {
+	check_space
+}
+
+pkg_setup() {
+	check_space
+}
+
+src_prepare() {
+	local PATCHES=(
+		# skip broken tests:
+		# - requiring pinned CPython versions (3.8.12, 3.11.7, 3.12.1)
+		# - requiring specific terminal width (COLUMNS don't seem to work)
+		# - other (perhaps failing because of other skipped tests?)
+		"${FILESDIR}/uv-0.1.28-skip-tests.patch"
+	)
+
+	rm crates/uv/tests/pip_compile_scenarios.rs || die
+	default
+}
+
+src_compile() {
+	cd crates/uv || die
+	cargo_src_compile
+}
+
+src_test() {
+	cd crates/uv || die
+	cargo_src_test --no-fail-fast
+}
+
+src_install() {
+	cd crates/uv || die
+	cargo_src_install
+}