Adding metadata

27 files changed, 754 insertions, 4 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 008b1a4f26e3..6a83f0a6f92a 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -2,3 +2,4 @@ DIST boto3-1.26.20.gh.tar.gz 572957 BLAKE2B 27286beaeabc0227376640fd3ee583656470
 DIST boto3-1.26.29.gh.tar.gz 578484 BLAKE2B 5914f5f19072268f6b5f90571f0ec573632f8e0546010a754d3116b18bd0d4236af2aa4f94a15778134d2b90f3fa80feadf8355a3015932b33cfec64a8917471 SHA512 a30e783b627bdbe6b723eb635702f0fbbe38d48eaaba7e93c880dd9f462d6257ed5a7ee524a096c42978d43336bfc6327a999de794c39877214e1d71ce1ab363
 DIST boto3-1.26.31.gh.tar.gz 580080 BLAKE2B 30d44e3df131aef363ccc2afdde43ee4b0d11d232b7af532915f1c66090616a3154f85269481f41e00e0553d87a8ad178ab3b9c8296e58c6b68723674450e6e1 SHA512 021b9a5c2d1f1555a7632e2d688ae7cebc0b51e572ccec35b81c75354f68d7fdd4482fb7de6e617bd13334a15cba2db52a2502f6b421df130645ea7d037f810c
 DIST boto3-1.26.32.gh.tar.gz 581235 BLAKE2B f8decc1e924ff5f5f98566084a55c36ea10ca38596e0f8398a9d5865e6246290e9e09ff3e95622eacca9f32b6f8119156b2ba5a6ce0135e988fad0bcdb161030 SHA512 73c6f8f1e1d5f12887e880cc651399fbd147c65740090bd09303540dcc902efc6b04605551f055341e84cb8b72cdcb9d8d444263fc0131b8f5013197e67c1fb5
+DIST boto3-1.26.33.gh.tar.gz 581883 BLAKE2B a2ac93a516932b8cfcb039e215608ebdd3f5427c7abb016359ad2f1a9e5e4ed855a405bb0470b5ba4823ba59c21d21f2b3319dcc8ef0715a1293cb0219261ac1 SHA512 4bb267abfaa01643edd6670dc66c87225845dce31d1d4aa500f60a278326a8fe6f877d8af4bff460cea3b77ef316392a2acf10181d7ae2a7c59ca2f6ca5ec9aa
diff --git a/dev-python/boto3/boto3-1.26.33.ebuild b/dev-python/boto3/boto3-1.26.33.ebuild
new file mode 100644
index 000000000000..3d7d652a3b69
--- /dev/null
+++ b/dev-python/boto3/boto3-1.26.33.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 9582794693fc..3f4e1aaa6830 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -2,3 +2,4 @@ DIST botocore-1.29.20.gh.tar.gz 10956292 BLAKE2B 3453a1051056f8f6bc870c66b66d81b
 DIST botocore-1.29.29.gh.tar.gz 11020243 BLAKE2B f576fb0ba73b4a9c8a65eedf387a432b30b18db3f657e25ada7c5f3ad647b00ab1f0a855f19bd3ebd897d8e267a14a6d467c29bacb30809b61e7e92ef464ac1e SHA512 fa6457d811137906b0e46302ccabe9623d60ed5cbb588004bbddd0d28ebdaa3aabad3491641b4b69798ed371ddda3e23ea41b930db4f5856e2fa8242dc170571
 DIST botocore-1.29.31.gh.tar.gz 11047541 BLAKE2B 7ac038bf914307277db982fa854a6a5832144c1f21b1dc375beb93f3a1c0d765f254066b8741bb5bd98748970611e967882306d11d3f8c9c5f65be318a0dc890 SHA512 cfa49bd47f24cc031d98ce1180fc55f991015b08872ee38024cb70069245f7323d4ac1f9189b0b4dd70516d0bcbe7e5895df221b4eefbfbd83e474d7aee1cd89
 DIST botocore-1.29.32.gh.tar.gz 11048130 BLAKE2B 42c1fd07f0501c5815c05ff8ad2d63d1e90e22835e1df274a7a7dbd77d0edd111c6bd596e2c4489a54982629ad5c525cc558db71f5f06d07cc6a80084f3cb274 SHA512 4ae8f60ee36999848944ebb122fbc3bfde0730d5e2450fa25d7f608e277534bce49fef93e2e21db315edfbda795a130b7ce63644f5a3627cbed4b7905bbb1f99
+DIST botocore-1.29.33.gh.tar.gz 11053602 BLAKE2B 746a59340b7a01c46b15d36d735c67db107ccc99ffa20983a15196561f48a3974d5f9d7b82a2eba07ca04b0a9d068bc742fcafe19259b3e76643cd0ca0bb1baf SHA512 efbeeca34ecd759735f91b6dae5bd4f2b32831cdbdc1eb621242b158bc1a707c50de68ab07e894cb207b65601a5b96f592350bd2f2b395a959344d06699ab7e0
diff --git a/dev-python/botocore/botocore-1.29.33.ebuild b/dev-python/botocore/botocore-1.29.33.ebuild
new file mode 100644
index 000000000000..40131f66e350
--- /dev/null
+++ b/dev-python/botocore/botocore-1.29.33.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+		# fails on unrelated warnings
+		tests/unit/test_client.py::TestAutoGeneratedClient::test_BOTO_DISABLE_COMMONNAME
+		tests/unit/test_client.py::TestClientErrors::test_BOTO_DISABLE_COMMONNAME
+		# TODO
+		tests/functional/test_credentials.py::SSOSessionTest::test_token_chosen_from_provider
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/easy-thumbnails/Manifest b/dev-python/easy-thumbnails/Manifest
index ed7001e3c284..edaabb5444f5 100644
--- a/dev-python/easy-thumbnails/Manifest
+++ b/dev-python/easy-thumbnails/Manifest
@@ -1 +1,2 @@
 DIST easy-thumbnails-2.8.3.tar.gz 76935 BLAKE2B 33cbbd80e322ac9e417a4e06001c9f2429cb51d1812b65eb70c0f96b1906b474c36593290493cff1e4c6b7c1b0c8097cc2f05f4a2c8d61097dbc4e3d2c12a13a SHA512 953f7eea9ec99213439a8f645c1b70618f7655d2ee417596d6dc9e6eeb797fdb4b87fe7380098dc4682934759acbd6f63cd44b19b3fed5ded5b86eea0bdcd0d4
+DIST easy-thumbnails-2.8.4.tar.gz 77392 BLAKE2B cb6a66e868a524ed9ec6ee8832b1d364a8432eac844f94bb45ccb43e8b2ac61bc2d534025a28325b7f3bf395261ee67bc705101574ebea1f0d926feff10b7b3a SHA512 875976a3679f5004feaf8524abf09c8bfd76513680dfda2b7fe94715a88abefa8570a85b7c6936e72890a31c73e31fcbfa0c04e227ec23d707a0b62d945cbce3
diff --git a/dev-python/easy-thumbnails/easy-thumbnails-2.8.4.ebuild b/dev-python/easy-thumbnails/easy-thumbnails-2.8.4.ebuild
new file mode 100644
index 000000000000..3a12d822f246
--- /dev/null
+++ b/dev-python/easy-thumbnails/easy-thumbnails-2.8.4.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Easy thumbnails for Django"
+HOMEPAGE="
+	https://pypi.org/project/easy-thumbnails/
+	https://github.com/SmileyChris/easy-thumbnails/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="svg test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/django-2.2[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	svg? (
+		dev-python/reportlab[${PYTHON_USEDEP}]
+		dev-python/svglib[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/reportlab[${PYTHON_USEDEP}]
+		dev-python/svglib[${PYTHON_USEDEP}]
+		dev-python/testfixtures[${PYTHON_USEDEP}]
+	)
+"
+
+python_test() {
+	local -x DJANGO_SETTINGS_MODULE=easy_thumbnails.tests.settings
+	local -x PYTHONPATH="${S}"
+	django-admin test -v 2 || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/httpx-socks/httpx-socks-0.7.5.ebuild b/dev-python/httpx-socks/httpx-socks-0.7.5.ebuild
index 4ddee7e9aafb..cf57e6f6a907 100644
--- a/dev-python/httpx-socks/httpx-socks-0.7.5.ebuild
+++ b/dev-python/httpx-socks/httpx-socks-0.7.5.ebuild
@@ -20,7 +20,7 @@ SRC_URI="
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
 
 RDEPEND="
 	<dev-python/httpx-0.24.0[${PYTHON_USEDEP}]
diff --git a/dev-python/identify/Manifest b/dev-python/identify/Manifest
index b5229d11a8a7..eef956030f11 100644
--- a/dev-python/identify/Manifest
+++ b/dev-python/identify/Manifest
@@ -1,3 +1,4 @@
 DIST identify-2.5.10.gh.tar.gz 101506 BLAKE2B e98d3d3ac1bed827041e9eb527dc45e252c71ad565aea226d335fa6ac5e280c8256a571cab620e579c4beb2d16fd1f6a103b53504116ac89342d1d0f5d80e7b3 SHA512 68ee7de92455565fa545e19ebe7b121ff7ffb2aecad0daf033292b0d97bb6676bde57b3a202ceed288d2358354592252040f2d912cc71f1dcbc37b9ced810190
+DIST identify-2.5.11.gh.tar.gz 101504 BLAKE2B 0415e9ab67c4254f3dd096364f518b131568c2180b8fdc5096405bae11854d5ef953eae01ad13292b6948d76f02adeee4607cd9485b705b1a303c44bc7110409 SHA512 cba8df5abacfc4db4305501eb6566ef3c9b3e0557796c046159f60a88ee3d0e206e13b070a01c3f7da74f8abf7a17e1374c40dc61814b5b580d1f8508034c402
 DIST identify-2.5.8.gh.tar.gz 101476 BLAKE2B 2b59ac3cb416c7e3d6bd4031bfed30594b9be70f94d1e0d8e9f436b76e9241cde32f847c0f6b40607d2cb37ff7d67270a35a4d22be4cd6b216324e4eba30f136 SHA512 b43b8ba50d4d58a6d82c99141c708a45317f64693aea567105ed7f3957446e00102ddd303120a9f1238b04b6e0655e1dd6f807f6d878e972c7967a510f8b24b2
 DIST identify-2.5.9.gh.tar.gz 101496 BLAKE2B 045e32b6aa84cedee100332c9b26d1fbbc32f704ef1048ce380fcc40c8a3fcf2e5c96db83058b04d7ead6dea0681ea114e6469d89aa7cd10458ce98cb3f77c58 SHA512 fdecd728bed3828d3a5465943b390ce3aab05255ba06249f462a2367dcd3702ef85fbe57e06562a951e3eeb24f7f417b04d54e30bd711802a8afe37c2e1eb1f0
diff --git a/dev-python/identify/identify-2.5.11.ebuild b/dev-python/identify/identify-2.5.11.ebuild
new file mode 100644
index 000000000000..83479ee1e55e
--- /dev/null
+++ b/dev-python/identify/identify-2.5.11.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="File identification library for Python"
+HOMEPAGE="
+	https://github.com/pre-commit/identify/
+	https://pypi.org/project/identify/
+"
+SRC_URI="
+	https://github.com/pre-commit/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/ukkonen[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/ipykernel/Manifest b/dev-python/ipykernel/Manifest
index 7d1e02caa26d..cc0e4d4bafb1 100644
--- a/dev-python/ipykernel/Manifest
+++ b/dev-python/ipykernel/Manifest
@@ -1,2 +1,3 @@
 DIST ipykernel-6.18.3.tar.gz 141999 BLAKE2B da5b0b2a36a58f2c91fdeab95a7e4bb33e09f9663eccb6d394f69a5a25e7e55e3f18315d017aaf435607efa73acca955665f7720b75ac4aa3256aa034698082d SHA512 0687ac146bac38bbdd6abad11df31572cb105bd41b79de98b40c18b60cdcb550b7ea10d68acf99f26d70c00ed4ef371d6dc2b6a4ce27eccae3f736955754ca1a
 DIST ipykernel-6.19.2.tar.gz 143367 BLAKE2B f6f38f5eed3a11951d303f49c58131d9473040b34032c133cf0f788bb648fc7c8529e3879dce315dcd3eda4eb1be45eb4891d10d4a2d006bb7947f2b342a47a7 SHA512 67ccbffb2d9eba27e9b87c7bd9dc471955c0109ea30caf77412f74c803dc25ab526de90d8351c9459b5d7b2009c746f73ac4a08ae8c277d2e2de8344aef71834
+DIST ipykernel-6.19.3.tar.gz 143840 BLAKE2B 9736d1ae2a2ef3c807bcea78aafc4ca2e3813693bddf9eac82425aed78382c36d736d5b4351989d9fdf3343335c503fef92f76ebff5a313e5af222aa78a04a04 SHA512 5c37e60ee353e469c0d7fce20a66d8e71dc57120ace6d518ed98816280c794ffafe8e8226545d978fc822760b5874371eafcb20cb7195328e505073eb70b4f06
diff --git a/dev-python/ipykernel/ipykernel-6.19.3.ebuild b/dev-python/ipykernel/ipykernel-6.19.3.ebuild
new file mode 100644
index 000000000000..caf88dc23796
--- /dev/null
+++ b/dev-python/ipykernel/ipykernel-6.19.3.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="
+	https://github.com/ipython/ipykernel/
+	https://pypi.org/project/ipykernel/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/debugpy-1.0[${PYTHON_USEDEP}]
+	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-6.1.12[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
+	dev-python/nest_asyncio[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
+"
+# RDEPEND seems specifically needed in BDEPEND, at least jupyter
+# bug #816486
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/ipyparallel[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# TODO
+	ipykernel/tests/test_debugger.py::test_attach_debug
+	ipykernel/tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
+	ipykernel/tests/test_debugger.py::test_rich_inspect_at_breakpoint
+	ipykernel/tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
+	ipykernel/tests/test_debugger.py::test_set_breakpoints
+	ipykernel/tests/test_debugger.py::test_stop_on_breakpoint
+)
+
+src_prepare() {
+	sed -i -e 's:^TIMEOUT = .*:TIMEOUT = 120:' ipykernel/tests/*.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	# Use python3 in kernel.json configuration, bug #784764
+	sed -i -e '/python3.[0-9]\+/s//python3/' \
+		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
+}
diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index e140084e4c69..0789b44f597e 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -1,4 +1,5 @@
 DIST moto-4.0.10.tar.gz 2501634 BLAKE2B 02fcd7e4f77589a8cae459d74832d72c8835e4357533023803733e3dfad30a44f264356c5dbb0f535ef441384692b4dafbfe33ef9a9e7077f1c61b342c61fa99 SHA512 f8d9817d8b10eb1a2f87d41453f8e3facfa1075a330cb44b46a1306105c059fcf6d9bf94e66ad8e893cf7eddfc4fdf0fc483988455db5f9c6f42d239fe57915a
 DIST moto-4.0.11.tar.gz 2540794 BLAKE2B 3b68e3fc6ab75b7ada2548c0807936fc5ad0d296385357ffb8b8c490fd3611f1333a78e99a093d3cd3ee8e65a2115ae66a4d3338bdf23dfe3ce8a0ebde43bad1 SHA512 fa721bc8cf8256a120870256770adf165f9a3f5d75ea5c83d76303d32a6869d417bec73fca4b09c5d08794cf2e8e530fd73ac53939271785e31f024217c97fa1
+DIST moto-4.0.12.tar.gz 2559220 BLAKE2B 475097f498bc648d6a29db36343135372f0881069ee02b21f0361df0215e852c344edfb7661154c150da88c4de86f832765169dfa9bc159213f15599a21ea0cb SHA512 ea404e603450791956cca9701825afad523ee99358597a3c627af2fda8732c2bbcca41f5d0fe67130a06a225f1ced35a9d35fa520130ff311120c8d6d5863a0a
 DIST moto-4.0.8.tar.gz 2488253 BLAKE2B ae707de8f0917b62904f38f977eded8f3e995271da8a7d6be47f05a24e3cb8bb8121e5e52625deb6c8f836e5f328352a7e6ea0855a4278c32dc9363da0faa8cc SHA512 9d3d3164bb6a77901bb55b8c536bfc8822e5b5292d79fedfe89a4a7fefaeab24b740d9a898e9487152a45c5a3bfd15d8aaca042a485bea389e1a82bb0a90bdd0
 DIST moto-4.0.9.tar.gz 2496530 BLAKE2B 596dc00ce0c931d4405d1ad6fdfcff4acc5c7421b1f1d67f442e090249d3df81f89c570368b5e981ec49f14a35aed32621ff3dbedc7003e3c870f891e4eda20a SHA512 fedf2c97779a93b1ab3492122be5425f3d91219eb207cc21bf2822ffa52c6efe2c3c8ca233acafd02c725c46e77e883f8f941c29638bb3e32ffa774ed8a5ff69
diff --git a/dev-python/moto/moto-4.0.12.ebuild b/dev-python/moto/moto-4.0.12.ebuild
new file mode 100644
index 000000000000..1045d1bcb690
--- /dev/null
+++ b/dev-python/moto/moto-4.0.12.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="
+	https://github.com/spulec/moto/
+	https://pypi.org/project/moto/
+"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-python-0.93[${PYTHON_USEDEP}]
+	>=dev-python/cfn-lint-0.40.0[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.3.1[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	>=dev-python/docker-py-2.5.1[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/jsondiff-1.1.2[${PYTHON_USEDEP}]
+	dev-python/boto3[${PYTHON_USEDEP}]
+	dev-python/botocore[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3.0.7[${PYTHON_USEDEP}]
+	>=dev-python/openapi-spec-validator-0.2.8[${PYTHON_USEDEP}]
+	dev-python/pretty-yaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	dev-python/python-sshpubkeys[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		>=dev-python/sure-1.4.11[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_firehose/test_firehose_put.py::test_put_record_http_destination
+		tests/test_firehose/test_firehose_put.py::test_put_record_batch_http_destination
+		tests/test_swf/responses/test_decision_tasks.py::test_respond_decision_task_completed_with_schedule_activity_task_boto3
+		tests/test_swf/responses/test_timeouts.py::test_activity_task_heartbeat_timeout_boto3
+		tests/test_swf/responses/test_timeouts.py::test_decision_task_start_to_close_timeout_boto3
+		tests/test_swf/responses/test_timeouts.py::test_workflow_execution_start_to_close_timeout_boto3
+		# broken code (local variable used referenced before definition)
+		tests/test_appsync/test_appsync_schema.py
+		tests/test_appsync/test_server.py::test_appsync_list_tags_for_resource
+		# Needs network (or docker?) but not marked as such, bug #807031
+		# TODO: report upstream
+		tests/test_batch/test_batch_jobs.py::test_terminate_job
+		tests/test_batch/test_batch_jobs.py::test_cancel_pending_job
+		tests/test_batch/test_batch_jobs.py::test_cancel_running_job
+		tests/test_batch/test_batch_jobs.py::test_dependencies
+		tests/test_batch/test_batch_jobs.py::test_container_overrides
+		tests/test_cloudformation/test_cloudformation_custom_resources.py::test_create_custom_lambda_resource__verify_cfnresponse_failed
+		tests/test_cloudformation/test_cloudformation_stack_integration.py::test_lambda_function
+		tests/test_events/test_events_lambdatriggers_integration.py::test_creating_bucket__invokes_lambda
+		tests/test_sqs/test_integration.py::test_invoke_function_from_sqs_exception
+		tests/test_sqs/test_sqs_integration.py::test_invoke_function_from_sqs_exception
+		tests/test_s3/test_server.py::test_s3_server_post_to_bucket_redirect
+		tests/test_s3/test_multiple_accounts_server.py::TestAccountIdResolution::test_with_custom_request_header
+		"tests/test_s3/test_s3_lambda_integration.py::test_objectcreated_put__invokes_lambda[match_events0-ObjectCreated:Put]"
+		"tests/test_s3/test_s3_lambda_integration.py::test_objectcreated_put__invokes_lambda[match_events1-ObjectCreated:Put]"
+		"tests/test_s3/test_s3_lambda_integration.py::test_objectcreated_put__invokes_lambda[match_events3-ObjectCreated:Put]"
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -m 'not network'
+}
diff --git a/dev-python/pyglet/Manifest b/dev-python/pyglet/Manifest
index d72cac1d5e5c..5f223c8b4f8b 100644
--- a/dev-python/pyglet/Manifest
+++ b/dev-python/pyglet/Manifest
@@ -1,3 +1,4 @@
 DIST pyglet-1.5.27.gh.tar.gz 6532179 BLAKE2B f1dc668530a69e275860befe11f4c86003c5de2dadede706df7abac9eb6fb1729ea030c7053f0149926f3ffdd12985d9abea4afac65de3b6b7541fe871eda369 SHA512 98896dab06873cbf3cdd0d4015cb0b9e062cffb1110908bd422ecdc4f0e16943adc8a4986e7dbfdae4392e82ac115bad6f937896e166989ad2c4d73a0f45c8be
 DIST pyglet-2.0.0.gh.tar.gz 6201132 BLAKE2B e72436804688e9022f0efc7da7fac5eb31ed2d35632612149b52431167db98f1d2e8bc3824ef6bd69851a8bf609d5098ea5f5c77aa7bcf5a527457c62ed47586 SHA512 2dde724f0b5f284d0094109a7077464ac4ec76ea905c91ddc096032ac849ee9720ee36926e9f11969169906c7e45580789001dfc657edc2e737ad116c48c588a
 DIST pyglet-2.0.1.gh.tar.gz 6202313 BLAKE2B be77d8b1736a41ff97c91db2019716eb85be87c91847f1588ffa8c502224b127aa04b038a207890a7abd099f9a956cfa8836d25e50a913f3a8439edfc078942e SHA512 a8670a8845b1743347b1b8cac19ee62056b2ea819ba2e14e567bc2d42f4ff7d1dc2c10e782b1bd670aef69e78971dca8d740787065ef1c2923cb62a3570e7bec
+DIST pyglet-2.0.2.1.gh.tar.gz 6206090 BLAKE2B e671e1800f8f9e80ff301692973e6085c63b751944d221added744edf3910dd13c15f741637b23f04777b64bfe2865698410be1859009bc1455cf51458e8916a SHA512 4b6d4883025b55d7e1515c65c0b18a5b24d152a5e7f547379329388046c2f1818f9e203d2913825a1156eb3271100b6257f334310959c2e7a1b4ba2b61f2d398
diff --git a/dev-python/pyglet/pyglet-2.0.2.1.ebuild b/dev-python/pyglet/pyglet-2.0.2.1.ebuild
new file mode 100644
index 000000000000..f83b2dd63795
--- /dev/null
+++ b/dev-python/pyglet/pyglet-2.0.2.1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 virtualx xdg-utils
+
+DESCRIPTION="Cross-platform windowing and multimedia library for Python"
+HOMEPAGE="
+	https://pyglet.org/
+	https://github.com/pyglet/pyglet/
+	https://pypi.org/project/pyglet/
+"
+SRC_URI="https://github.com/pyglet/pyglet/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples image +sound"
+
+BDEPEND="
+	test? (
+		dev-python/pillow[${PYTHON_USEDEP}]
+		media-libs/fontconfig
+	)
+"
+RDEPEND="
+	virtual/glu
+	virtual/opengl
+	image? ( || (
+		dev-python/pillow[${PYTHON_USEDEP}]
+		x11-libs/gtk+:2
+	) )
+	sound? ( || (
+		media-libs/openal
+		media-sound/pulseaudio
+	) )
+"
+#	ffmpeg? ( media-libs/avbin-bin )
+
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	xdg_environment_reset
+
+	local EPYTEST_DESELECT=(
+		# lacking device/server permissions
+		tests/unit/media/test_listener.py::test_openal_listener
+		tests/unit/media/test_listener.py::test_pulse_listener
+		# fragile to load
+		tests/unit/test_clock_freq.py::test_elapsed_time_between_tick
+	)
+	if [[ ${EPYTHON} == python3.11 ]]; then
+		EPYTEST_DESELECT+=(
+			# broken test
+			# https://github.com/pyglet/pyglet/issues/606
+			tests/unit/test_events.py::test_push_handlers_instance
+		)
+	fi
+
+	# Specify path to avoid running interactive tests
+	# We could add in integration tests, but they're slow
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	nonfatal epytest tests/unit || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/python-multipart/python-multipart-0.0.5.ebuild b/dev-python/python-multipart/python-multipart-0.0.5.ebuild
index c1c0901ecbc1..4dbedaeadc5e 100644
--- a/dev-python/python-multipart/python-multipart-0.0.5.ebuild
+++ b/dev-python/python-multipart/python-multipart-0.0.5.ebuild
@@ -20,7 +20,7 @@ SRC_URI="
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
 
 BDEPEND="
 	test? (
diff --git a/dev-python/python-socks/Manifest b/dev-python/python-socks/Manifest
index 090cccec82f9..b40774a02960 100644
--- a/dev-python/python-socks/Manifest
+++ b/dev-python/python-socks/Manifest
@@ -1,2 +1,3 @@
 DIST python-socks-2.0.3.gh.tar.gz 40697 BLAKE2B c1e6f72763d1bd767af78ea1188e411814a6d41f703488dd67165d5a9b9ce1e2f9070b35a46cd72859b65c10519cdb02c91d1702a97c2d82cb5891b46187d02a SHA512 9d51e61d03b4a46e94a66fc037ac759715db2e2c5d631aaf6088a0363ad13140c00da44a513088a40c0f149b9d4ee2bb4165f59f76c3956f0aede8104772fc5d
 DIST python-socks-2.1.0.gh.tar.gz 31251 BLAKE2B b32b35c746066c10fa1e52677e42058e6196eb1c19cfc120a670e86daf8f920a4d6be3d1d92f984b68d635496da992b33f196277a1b22b254fe045988a15d2f1 SHA512 66da2da1d8103570e44d0a2ace03c24695b7319c562d7f96242c713b9d03ea693a2ece3cf6869cea686c330a9fb05aa35a443bad5a638d843b4fc7b24a8e6a82
+DIST python-socks-2.1.1.gh.tar.gz 31306 BLAKE2B f42f88089b0438722b076bcbbbe194b6ed621dec34f850861d791418ff453e6f97aa4e2f2ccf69024c5c562f7d1c8e1110e9930360252556bc77dd44b9a20fc0 SHA512 d68c5d0b0975283a8a86f701db5a8037beb9368edef591876abba2524593114fdcc933fa3dc5eca8123afcc6fc0eb3eacfbbf40e54acb87e973fc7b49ed3c8dc
diff --git a/dev-python/python-socks/python-socks-2.1.1.ebuild b/dev-python/python-socks/python-socks-2.1.1.ebuild
new file mode 100644
index 000000000000..5c59e31a16f8
--- /dev/null
+++ b/dev-python/python-socks/python-socks-2.1.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="SOCKS4, SOCKS5, HTTP tunneling functionality for Python"
+HOMEPAGE="
+	https://github.com/romis2012/python-socks/
+	https://pypi.org/project/python-socks/
+"
+SRC_URI="
+	https://github.com/romis2012/python-socks/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
+
+# curio is not packaged
+# asyncio is the only backend we have, so dep on its deps unconditionally
+# TODO: revisit
+RDEPEND="
+	dev-python/async-timeout[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/anyio-3.4.0[${PYTHON_USEDEP}]
+		>=dev-python/async-timeout-3.0.1[${PYTHON_USEDEP}]
+		>=dev-python/flask-1.1.2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-asyncio-0.18.3[${PYTHON_USEDEP}]
+		>=dev-python/pytest-trio-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/tiny-proxy-0.1.1[${PYTHON_USEDEP}]
+		>=dev-python/trio-0.16.0[${PYTHON_USEDEP}]
+		>=dev-python/trustme-0.9.0[${PYTHON_USEDEP}]
+		>=dev-python/yarl-1.4.2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/pytoolconfig/pytoolconfig-1.2.4-r1.ebuild b/dev-python/pytoolconfig/pytoolconfig-1.2.4-r2.ebuild
index fc84afa08671..d3ee86a0c8b6 100644
--- a/dev-python/pytoolconfig/pytoolconfig-1.2.4-r1.ebuild
+++ b/dev-python/pytoolconfig/pytoolconfig-1.2.4-r2.ebuild
@@ -35,3 +35,9 @@ BDEPEND="
 "
 
 distutils_enable_tests pytest
+
+src_prepare() {
+	# remove overstrict dep
+	sed -i -e '/packaging/s:>=22.0::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/sentry-sdk/Manifest b/dev-python/sentry-sdk/Manifest
index 6cfd29bdd562..1a8730d95fde 100644
--- a/dev-python/sentry-sdk/Manifest
+++ b/dev-python/sentry-sdk/Manifest
@@ -1,3 +1,4 @@
 DIST sentry-sdk-1.10.1.gh.tar.gz 292186 BLAKE2B 03181c0118294d4221b176b1e4fd38b4b2147a3a1b6eae709153f92717da77e889d17e715ad1795c8d9bdf24ed2ca5718a88b4f3fa25d240ec8e5804d1041a56 SHA512 135dff6db284439812d74b54f301ba0ce25444f71ad0b7d3ff8869399dba97affa40673fd306960bc6665118e0aabd1a3420976effc9a501d51d9f2174d615f4
 DIST sentry-sdk-1.11.1.gh.tar.gz 296633 BLAKE2B 8325b75d58bb4c587c5d27698b775a76aaf840fc69a910567243fcac2d6fbb7fe00fbfe008c70fc5b67d999167cc3474e5a18817832dfe2c768ffc750c7af128 SHA512 9fd3e1aa9a7287ae21d1a7274f12b9d309d95615e5611ee098c8e2d0577f7c3928a6d5c7256b18d4f0de0ac48d44eb9e38f94709e8982a0c09a5b1cfb5dba114
 DIST sentry-sdk-1.12.0.gh.tar.gz 305342 BLAKE2B 1ed91383dfe674f16a28f5d9c98da44c06bddcd3a609ad9e7dedb7b2d1e174e777bac0f14e4b2e7051db5675080e2ba7754df87f8ee76818e7db19945e645f78 SHA512 84f4e95ed6c42fda85cd3c4b22b1f18ffd6018daa21091fbea2b79e3e86b45ce4c79e5770eeb62f093119492d73964528f820fe12ff4e9867f255a7c7b89da92
+DIST sentry-sdk-1.12.1.gh.tar.gz 306457 BLAKE2B e0c4e92fcf8f0213f27ccf6f03cfbdc66999469357cfdf82e4b923f34d79c44e0824a50caf437dded4404e77cd1cbdede240b1e98bd8408d467b754b3586d598 SHA512 c4fb0d13c1e40e0220ef56c29c2c5235aba0c7be598a545e08af783da0732266455d6b9aa73f2aaa068bf63105369517a12e8abbc7a31410ef3c4bea1a0b3018
diff --git a/dev-python/sentry-sdk/sentry-sdk-1.12.1.ebuild b/dev-python/sentry-sdk/sentry-sdk-1.12.1.ebuild
new file mode 100644
index 000000000000..7e7d0664556f
--- /dev/null
+++ b/dev-python/sentry-sdk/sentry-sdk-1.12.1.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python client for Sentry"
+HOMEPAGE="
+	https://sentry.io/
+	https://github.com/getsentry/sentry-python/
+	https://pypi.org/project/sentry-sdk/
+"
+SRC_URI="
+	https://github.com/getsentry/sentry-python/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/sentry-python-${PV}"
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/asttokens[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/executing[${PYTHON_USEDEP}]
+		dev-python/fakeredis[${PYTHON_USEDEP}]
+		dev-python/flask-login[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pyrsistent[${PYTHON_USEDEP}]
+		dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+		dev-python/pytest-django[${PYTHON_USEDEP}]
+		dev-python/pytest-forked[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/werkzeug[${PYTHON_USEDEP}]
+		dev-python/zope-event[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# tests require Internet access
+	tests/integrations/httpx/test_httpx.py
+	tests/integrations/requests/test_requests.py
+	tests/integrations/stdlib/test_httplib.py
+	tests/integrations/flask/test_flask.py
+	tests/integrations/django/test_basic.py
+	# wtf is it supposed to do?!
+	tests/integrations/gcp/test_gcp.py
+	# broken by rq-1.10.1 (optional dep)
+	tests/integrations/rq/test_rq.py
+	# fastapi is not packaged
+	tests/integrations/asgi/test_fastapi.py
+	# TODO
+	tests/integrations/bottle
+	# TODO: causes breakage in other tests
+	tests/integrations/starlette
+	# TODO
+	tests/integrations/tornado
+	# requires mockupdb
+	tests/integrations/pymongo
+)
+
+EPYTEST_DESELECT=(
+	# hangs
+	'tests/test_transport.py::test_transport_works'
+	# TODO
+	'tests/test_basics.py::test_auto_enabling_integrations_catches_import_error'
+	tests/test_client.py::test_databag_depth_stripping
+	tests/test_client.py::test_databag_string_stripping
+	tests/test_client.py::test_databag_breadth_stripping
+	tests/integrations/asgi/test_asgi.py::test_auto_session_tracking_with_aggregates
+	tests/integrations/asgi/test_asgi.py::test_websocket
+	tests/integrations/aiohttp/test_aiohttp.py::test_transaction_style
+	tests/integrations/aiohttp/test_aiohttp.py::test_traces_sampler_gets_request_object_in_sampling_context
+	# incompatible version?
+	tests/integrations/falcon/test_falcon.py
+	tests/integrations/sqlalchemy/test_sqlalchemy.py::test_too_large_event_truncated
+	# test_circular_references: apparently fragile
+	'tests/integrations/threading/test_threading.py::test_circular_references'
+	# test for new feature, fails with IndexError
+	tests/integrations/wsgi/test_wsgi.py::test_session_mode_defaults_to_request_mode_in_wsgi_handler
+	# TODO
+	tests/integrations/wsgi/test_wsgi.py::test_auto_session_tracking_with_aggregates
+	tests/integrations/wsgi/test_wsgi.py::test_profile_sent_when_profiling_enabled
+	tests/test_profiler.py::test_sample_buffer
+	tests/test_profiler.py::test_thread_scheduler_takes_first_samples
+	tests/test_profiler.py::test_thread_scheduler_takes_more_samples
+	tests/test_profiler.py::test_thread_scheduler_single_background_thread
+)
diff --git a/dev-python/starlette/starlette-0.23.1.ebuild b/dev-python/starlette/starlette-0.23.1.ebuild
index dc05d61fd355..3f72a5f3bc76 100644
--- a/dev-python/starlette/starlette-0.23.1.ebuild
+++ b/dev-python/starlette/starlette-0.23.1.ebuild
@@ -21,7 +21,7 @@ SRC_URI="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
 
 RDEPEND="
 	<dev-python/anyio-5[${PYTHON_USEDEP}]
diff --git a/dev-python/tiny-proxy/tiny-proxy-0.1.1.ebuild b/dev-python/tiny-proxy/tiny-proxy-0.1.1.ebuild
index a6333ea3a57c..a77e2c9b1953 100644
--- a/dev-python/tiny-proxy/tiny-proxy-0.1.1.ebuild
+++ b/dev-python/tiny-proxy/tiny-proxy-0.1.1.ebuild
@@ -20,7 +20,7 @@ SRC_URI="
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
 
 RDEPEND="
 	<dev-python/anyio-4.0.0[${PYTHON_USEDEP}]
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 78484cc30326..c44ddc31b0f8 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -3,3 +3,4 @@ DIST tox-3.28.0.gh.tar.gz 309472 BLAKE2B 9896411426f6aebb3efa468c01696ecc5f17ec3
 DIST tox-4.0.12.gh.tar.gz 282817 BLAKE2B 7237f33086c9e0147457bf46db47f6b4e6fcaf33929d0950e439e04950119e3199c3d41c4f6856935bb4cd27f613a9c925f4e366a61f22067d5837f1f5f2307c SHA512 7ffc0ed622c59df8ab0b1692dc774ab8efa1753dd4f872e0baaca213b4da29b9c3718b63eb3f655802a23d6493c61e3d3e003d192d73bb536f0da16411db2685
 DIST tox-4.0.13.gh.tar.gz 283017 BLAKE2B 2bf55f1514cbc1806404f4106b2af701f28698da0fd9789a71d582612b7eeb2356d15b26a9dd0e663b19cdcb90e975138c15cd80ee5f10c261a8b203bef0d830 SHA512 a08139b490ab2e967cb9fdb9ffb290fa1dcce3102d41b07fdfd566f9d270873d6371229dacae5e00a4816bf37eb7cca12bae0948e5b4e6c1879e96b444070d4b
 DIST tox-4.0.14.gh.tar.gz 283154 BLAKE2B 8701f25b00152c283503f082765e28b46f2c01b01bc86129dee6b28fd623bb2ae2c2726401b69e278edbc4fffbaad672aa02504870a1c05ec965a819dc812933 SHA512 3ed0a80b438ac11804b56f6b55a504c0246b0a8cfa9bb4fa8246758bd942ac0b0b5c203e89069303faa47a2dcd009ea81ef9f8e3e38e6d9a30dd4f05c0b79510
+DIST tox-4.0.15.gh.tar.gz 283422 BLAKE2B 7efe3d50d0d08ba32f462e8d533ed97779e65c3830ae3af211dbb164828bcb1158cf0cc8581aa2dc727aea595b2e942a5c581c310b9afe8384a711e53a38d9a9 SHA512 5232abc6f7824a576bb40d2615c0c90a189a516faa9089cc7e3d1eadebe95e44cbcbb02792c0b34753448b8269f0b6035c2755c2d3bd48a49aa1b656db6d57f7
diff --git a/dev-python/tox/tox-4.0.15.ebuild b/dev-python/tox/tox-4.0.15.ebuild
new file mode 100644
index 000000000000..620c2a4536f4
--- /dev/null
+++ b/dev-python/tox/tox-4.0.15.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+SRC_URI="
+	https://github.com/tox-dev/tox/archive/${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/cachetools-5.2[${PYTHON_USEDEP}]
+	>=dev-python/chardet-5.1[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3.8.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.6[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-api-1.2.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+	>=dev-python/virtualenv-20.17.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-vcs-0.2.1[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		>=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+		>=dev-python/flaky-3.7[${PYTHON_USEDEP}]
+		>=dev-python/psutil-5.9.4[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-3.1[${PYTHON_USEDEP}]
+		>=dev-python/re-assert-1.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/time-machine-2.8.2[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+	# the minimal bounds in tox are entirely meaningless and new packaging
+	# breaks setuptools
+	sed -i -e '/packaging/s:>=22::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+	if ! has_version "dev-python/time_machine[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			tests/util/test_spinner.py
+		)
+	fi
+
+	epytest
+}
diff --git a/dev-python/traitlets/Manifest b/dev-python/traitlets/Manifest
index fd54c6c22af3..ebc9d066f0f5 100644
--- a/dev-python/traitlets/Manifest
+++ b/dev-python/traitlets/Manifest
@@ -2,3 +2,4 @@ DIST traitlets-5.5.0.tar.gz 131686 BLAKE2B 1206c2f86367eb421202070a48fe12b20b214
 DIST traitlets-5.6.0.tar.gz 133316 BLAKE2B 736ef860ed8f7d9cfde990c755d50f47d09344edf1d2f55347d693cc3c453ae1f2315c168bd52dc82ea4e29ee7ab1d2494c9fd095bf56d03cf8b52b89d209ff2 SHA512 7af0fb619ddb2991b6285bb07642f700b0bb822c0eb5770fe6d337f42ac9c2fbb59cd971e9a8991277c47f3a9be2cfde21712080cca4733f8bba3339f91c8311
 DIST traitlets-5.7.0.tar.gz 136290 BLAKE2B ddc7190f0c14b6dae36effca4966801834d868f5072e3780ecaf10e5aadc2a05372e49028a7e08719e6d8a7536cd0e6a3dc36815322fc62933bca3311e55dee8 SHA512 252d6d93b863e099a739d0f1ad2a97421791ae9349c8720bc41dfeacfd3ee22f966cb75ee3895449a0e1b987f8d2db9d8665cbdacaed6a46ab05638e382d2e9e
 DIST traitlets-5.7.1.tar.gz 136382 BLAKE2B 28a9c125134aff644f0bc5fd7310378936c3bfd79dea33c96124c22630d9b21384a742e7576d7a62a9da9678da19199bbaaaa98a09526d78a46833a03bb331b5 SHA512 c3a3f7014bcf894381bef3f96fafd814b8aaeec66ad67e12f94308a741549fa89b4446a994d2ec6162c7e43b74c43491b533d35fa61ec0ac5435f71c96f82cb4
+DIST traitlets-5.8.0.tar.gz 149460 BLAKE2B 4e5d0344e2c6a2236202875708b28e2966cc8c9ee365ece423aa091dcbc9a3215c236ee63c5e88cf72a3ef9873671fadd83953e700e613360da90da4954b065d SHA512 e65efb5c52940bc2b12e64c932d55c3e5f7b7a3d5cbd49b3c7cbae972ac22e3c2b374f5a35f7c685e7f9ecb9c0b697e626ee942dc6f7f281c9b7857b9a4487d8
diff --git a/dev-python/traitlets/traitlets-5.8.0.ebuild b/dev-python/traitlets/traitlets-5.8.0.ebuild
new file mode 100644
index 000000000000..110117d05a8e
--- /dev/null
+++ b/dev-python/traitlets/traitlets-5.8.0.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="A configuration system for Python applications"
+HOMEPAGE="
+	https://github.com/ipython/traitlets/
+	https://pypi.org/project/traitlets/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	test? (
+		>=dev-python/argcomplete-2.0[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	dev-python/myst_parser \
+	dev-python/pydata-sphinx-theme
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pytest_mock
+}