Adding metadata

4 files changed, 91 insertions, 6 deletions

diff --git a/dev-python/nbclient/nbclient-0.7.2.ebuild b/dev-python/nbclient/nbclient-0.7.2.ebuild
index 67c577fd24ad..591102c48b3c 100644
--- a/dev-python/nbclient/nbclient-0.7.2.ebuild
+++ b/dev-python/nbclient/nbclient-0.7.2.ebuild
@@ -26,7 +26,7 @@ KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc
 RDEPEND="
 	>=dev-python/jupyter_client-6.1.12[${PYTHON_USEDEP}]
 	>=dev-python/jupyter_core-4.12[${PYTHON_USEDEP}]
-	<dev-python/jupyter_core-5.0[${PYTHON_USEDEP}]
+	!=dev-python/jupyter_core-5.0*[${PYTHON_USEDEP}]
 	>=dev-python/nbformat-5.0[${PYTHON_USEDEP}]
 	>=dev-python/traitlets-5.3[${PYTHON_USEDEP}]
 "
diff --git a/dev-python/redis-py/redis-py-4.4.0.ebuild b/dev-python/redis-py/redis-py-4.4.0.ebuild
index a810c0f54573..8f5977343ab0 100644
--- a/dev-python/redis-py/redis-py-4.4.0.ebuild
+++ b/dev-python/redis-py/redis-py-4.4.0.ebuild
@@ -27,7 +27,7 @@ RDEPEND="
 "
 BDEPEND="
 	test? (
-		<dev-db/redis-7
+		dev-db/redis
 		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
 		dev-python/pytest-timeout[${PYTHON_USEDEP}]
 	)
@@ -41,6 +41,8 @@ python_test() {
 		tests/test_pubsub.py::TestPubSubDeadlock::test_pubsub_deadlock
 		# TODO
 		tests/test_commands.py::TestRedisCommands::test_acl_list
+		# redis-7 different return
+		tests/test_commands.py::TestRedisCommands::test_xautoclaim
 	)
 
 	# TODO: try to run more servers?
@@ -51,17 +53,22 @@ src_test() {
 	local redis_pid="${T}"/redis.pid
 	local redis_port=6379
 
+	if has_version ">=dev-db/redis-7"; then
+		local extra_conf="
+			enable-debug-command yes
+			enable-module-command yes
+		"
+	fi
+
 	# Spawn Redis itself for testing purposes
-	# NOTE: On sam@'s machine, spawning Redis can hang in the sandbox.
-	# I'm not restricting tests yet because this doesn't happen for anyone else AFAICT.
 	einfo "Spawning Redis"
 	einfo "NOTE: Port ${redis_port} must be free"
-	# "${EPREFIX}"/usr/sbin/redis-server - <<< "${redis_test_config}" || die
 	"${EPREFIX}"/usr/sbin/redis-server - <<- EOF || die "Unable to start redis server"
 		daemonize yes
 		pidfile ${redis_pid}
 		port ${redis_port}
-		bind 127.0.0.1
+		bind 127.0.0.1 ::1
+		${extra_conf}
 	EOF
 
 	# Run the tests
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 383426d340a6..dbd19aa6f56e 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,2 +1,3 @@
 DIST tox-3.27.1.gh.tar.gz 309006 BLAKE2B fa8aaa9cd5b03e54c166bb6b748290420b91498b26d2d124d9f88a64806b9ac0578c1886845b25aa024907f6a782c45609fa6c7657d9e1f538b59c2d9f0f4e14 SHA512 5f568bc6c53f871aae91928681dd6f2419b876a8e6ca925e65abae845b548ee3d00513741882875bbbacb78bf64935228d98213f940d3da8c3f788b73f177b79
 DIST tox-4.0.0rc1.gh.tar.gz 273212 BLAKE2B c9123aa23185655c32ebac36adf24ba8cfc57e8a94c011657acff6a5ce5bede8b14218a21a8cae099fdc2af938343336bea7fed802f8f73bc7769cd17b52d918 SHA512 6619fad1a080a095b827968972dd0d854ca5b48b81ef6548d8c39accc30c0279f9e0cc4208b148920e51fe304328dbdf4f4a8c4554b32398baf243484bba338d
+DIST tox-4.0.0rc3.gh.tar.gz 274520 BLAKE2B 374db4d553f2fa5188fa911058f5bca8230a88f88607d0d633801e504e4a55db29942cc359bc825d94cf2004c357cc32ec1550a83bdd03df23b2e068d787de70 SHA512 0f8ba364d0bcf25eff241361a567863f70bd9443724ebdef04b94d91ecc8b1e7b34804a0d47b7d78fd391962fda0409ce1ab95b45dc6ba2d4738a474a814c0af
diff --git a/dev-python/tox/tox-4.0.0_rc3.ebuild b/dev-python/tox/tox-4.0.0_rc3.ebuild
new file mode 100644
index 000000000000..fdfd50d4230b
--- /dev/null
+++ b/dev-python/tox/tox-4.0.0_rc3.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+SRC_URI="
+	https://github.com/tox-dev/tox/archive/${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/cachetools-5.2[${PYTHON_USEDEP}]
+	>=dev-python/chardet-5.1[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3.8.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.5.4[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-api-1.2.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+	>=dev-python/virtualenv-20.17.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		>=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+		>=dev-python/flaky-3.7[${PYTHON_USEDEP}]
+		>=dev-python/psutil-5.9.4[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-3.1[${PYTHON_USEDEP}]
+		>=dev-python/re-assert-1.1[${PYTHON_USEDEP}]
+		>=dev-python/time-machine-2.8.2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	epytest
+}