Adding metadata

12 files changed, 221 insertions, 0 deletions

diff --git a/dev-python/cfn-lint/Manifest b/dev-python/cfn-lint/Manifest
index 08a30413f645..c0ee18d44e7f 100644
--- a/dev-python/cfn-lint/Manifest
+++ b/dev-python/cfn-lint/Manifest
@@ -1,2 +1,3 @@
 DIST cfn-lint-0.56.3.tar.gz 8278034 BLAKE2B 894d30add7a193d256dc2195c0cd1d4b75f10f60abe9e37c5b0bdd84178d9559759326ad3e55d2321b99588094b436dc2dc8dff1cc561ae56dd4cee98d6b43bd SHA512 8aeaf44a626f9bfc05ebeefc8aec9211fcac1a65de681d5d700f3621631bff15e74ed644b9d0dc8af4d9b0b14802c2259dbc4ccf38594705040f5fd3af1cf482
 DIST cfn-lint-0.56.4.tar.gz 8550039 BLAKE2B 99efd99b423e068717f3050e4da444436463c16b0a55dfc36ca7ca45b1136d08bbce84441c8c4170eff7c82cbd4ecf87b6f78504b1d09d850d803a7e957903c9 SHA512 b7c94d85d58f9e44ff8d5575bb33c8c7fafcb908afe144d585765f02d645436d6583ecc802f0fa376597b75c72ada9a23862141cf1170c1ac1f64f2467d346fb
+DIST cfn-lint-0.57.0.tar.gz 8579636 BLAKE2B 5e9cadcbd695b1047c4cf51132fcdf5a254a89fcd89a86e3c5d86096e8cd376f7f02422757f7daaf98490ff82df88933a976faba1ea6504a463ed7c485c83631 SHA512 11ec66bc5a98c928e059778462766100fb47f4b45a4cc7023d3d2b70ae664a1b199ec4df0d95cb9ada5a09a1f7a609fcec7d76339b3d9d6430bbe85462e1c020
diff --git a/dev-python/cfn-lint/cfn-lint-0.57.0.ebuild b/dev-python/cfn-lint/cfn-lint-0.57.0.ebuild
new file mode 100644
index 000000000000..3cfa9d084dea
--- /dev/null
+++ b/dev-python/cfn-lint/cfn-lint-0.57.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="CloudFormation Linter"
+HOMEPAGE="https://pypi.org/project/cfn-lint/ https://github.com/aws-cloudformation/cfn-lint/"
+SRC_URI="
+	https://github.com/aws-cloudformation/cfn-lint/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/aws-sam-translator-1.42.0[${PYTHON_USEDEP}]
+	dev-python/jsonpatch[${PYTHON_USEDEP}]
+	>=dev-python/jschema_to_python-1.2.3[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]
+	dev-python/junit-xml[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	>dev-python/pyyaml-5.4[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.15.0[${PYTHON_USEDEP}]
+	>=dev-python/sarif_om-1.0.4[${PYTHON_USEDEP}]
+	>=dev-python/six-1.11[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests --install pytest
+
+EPYTEST_DESELECT=(
+	# TODO
+	test/unit/module/test_template.py::TestTemplate::test_build_graph
+	# requires git repo
+	test/unit/module/maintenance/test_update_documentation.py::TestUpdateDocumentation::test_update_docs
+	# Internet
+	test/unit/module/formatters/test_formatters.py::TestFormatters::test_sarif_formatter
+	test/unit/module/maintenance/test_update_resource_specs.py::TestUpdateResourceSpecs::test_update_resource_specs_python_2
+	test/unit/module/maintenance/test_update_resource_specs.py::TestUpdateResourceSpecs::test_update_resource_specs_python_3
+)
+
+src_prepare() {
+	# unpin the deps
+	sed -e 's:~=[0-9.]*::' -i setup.py || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/google-api-python-client/Manifest b/dev-python/google-api-python-client/Manifest
index b7a968d1f3a4..6925c3156afb 100644
--- a/dev-python/google-api-python-client/Manifest
+++ b/dev-python/google-api-python-client/Manifest
@@ -1,2 +1,3 @@
 DIST google-api-python-client-2.34.0.tar.gz 28469433 BLAKE2B aa2c8849b629fe489cf39cddd410a40a0af0bddfa5f370a4a41c1446aeadf69cd4592eeb1d76e6c63da9737906801aea9c8a4d706328b63a7bf5b34a43b83e00 SHA512 321dfdd3ba821beabc6c3a96575afd06c75a0c8e3db61b1ff5fa9db472e62de81b037c435a1051d6294c2a37e471bcaa068cd27ad7434a3416231d31931dd74e
 DIST google-api-python-client-2.35.0.tar.gz 28553015 BLAKE2B 8ff92145f280e090b8f43c10e425dd4a8fe65b4cf565c5b5a0df2813cdb8ba1bcea50e37556efb9dd0b270a21fe11b7d6d1b445c8fdaa83326c7dc6230ee1fdb SHA512 4d0325b79250a26ae252568759e8345d31d692aa1d8f1d7aae623bb9a1a950efae654cd689d39f30450789c6d4fa9ca264111f8a9e798820cf6d0c3acba904f6
+DIST google-api-python-client-2.36.0.tar.gz 28624616 BLAKE2B 738d89e740ded848683a4bc5c1d4b27f57acb817c54397ed563de376fa395d1202c47fd4b42046f313b31c826fb3d0fc2e3761c0779bf9c9718b3b2923fc63a3 SHA512 bdca303fa84f5cb510102265ebb7629b48b939c8d7a01420e61635ef4c461f62b6dfa6f29e96060a80d86baf0ea6587d88b0ec64a7b4c6b32563921c3a1a53ca
diff --git a/dev-python/google-api-python-client/google-api-python-client-2.36.0.ebuild b/dev-python/google-api-python-client/google-api-python-client-2.36.0.ebuild
new file mode 100644
index 000000000000..838a3e9d9626
--- /dev/null
+++ b/dev-python/google-api-python-client/google-api-python-client-2.36.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Google API Client for Python"
+HOMEPAGE="https://github.com/googleapis/google-api-python-client"
+SRC_URI="https://github.com/googleapis/google-api-python-client/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/httplib2-0.15[${PYTHON_USEDEP}]
+	<dev-python/httplib2-1[${PYTHON_USEDEP}]
+	dev-python/google-api-core[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.35.0[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-httplib2-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/uritemplate-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/uritemplate-5[${PYTHON_USEDEP}]
+	"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/oauth2client[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# require Internet access (and credentials)
+		tests/test_discovery.py::DiscoveryErrors::test_credentials_and_credentials_file_mutually_exclusive
+		tests/test_discovery.py::DiscoveryFromDocument::test_api_endpoint_override_from_client_options_mapping_object
+	)
+
+	epytest tests
+}
diff --git a/dev-python/httpcore/Manifest b/dev-python/httpcore/Manifest
index be406716d1ae..28b4c9816f4c 100644
--- a/dev-python/httpcore/Manifest
+++ b/dev-python/httpcore/Manifest
@@ -1,3 +1,4 @@
 DIST httpcore-0.13.7.tar.gz 64734 BLAKE2B e6c4b1720ce4bf62689995d3e1c648c4702bb416f3b3586eb8dd2f0cfd2155046e64181c4c04e65f721a5f0fcbc23b5ffd01c2930c7c69d37ee4c36e37b7d0d4 SHA512 0cc48828d0710066b3ef89998ec85975285763ac63a8b59106952ef2dac5a02dac71e7e106c4b6ea1022eb4d06a9cb5ee3e634eb564bad49c5508beff75279d6
 DIST httpcore-0.14.3.tar.gz 64650 BLAKE2B 140c55af60f54ff13db958cecef50af2b8857837c00c2e5b1ec48d8866bc08146f608864a3dcaed0014505ba0ea10b8d457a763ecf434a0d40a2e11debdd4003 SHA512 05e92109839c2e2f7ec81fea9507fb15a12d1bf6ae92048170953b1cb0139237b81c892feff1bc3840e06887e8916cadcc4124725874344524e45e3640a00379
 DIST httpcore-0.14.4.tar.gz 68463 BLAKE2B cc6c17da3b97c2a8fb9edb0aeb6247904240748645f605b2f3c84194fc06bab10f568ce21b8beaf1dee9a8d68166f1691e00f17e44d89efce0a18a6fbd91d5a5 SHA512 4dfb2d0dd10df1de45f4e78ddedddf02bf500a81a0132919894bd5c07f02a2975ce589ba3f6d79dd92ec882128f86f338bd32f35cdecb6618307e446ed369310
+DIST httpcore-0.14.5.tar.gz 74227 BLAKE2B 8e54b6b40d35a9228b96682d87651a6d3967441b74f3544a21b378620b417b48978f51d25b1980d87fad4748537036c6f2a4751e8b58e622c7c76389ff1afb67 SHA512 1705cf83df3ead454065e2ed4c300697c5d0a6609846a3eadfca2af2d9c1578f951c2f4bf3ac018c3cc984d2d2ccd39c4b2de781747588a6116eebe1007afff0
diff --git a/dev-python/httpcore/httpcore-0.14.5.ebuild b/dev-python/httpcore/httpcore-0.14.5.ebuild
new file mode 100644
index 000000000000..27463b0e40e3
--- /dev/null
+++ b/dev-python/httpcore/httpcore-0.14.5.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1 optfeature
+
+DESCRIPTION="A minimal low-level HTTP client"
+HOMEPAGE="https://www.encode.io/httpcore/"
+SRC_URI="https://github.com/encode/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64"
+
+RDEPEND="
+	=dev-python/anyio-3*[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	<dev-python/h11-0.13[${PYTHON_USEDEP}]
+	<dev-python/h2-5[${PYTHON_USEDEP}]
+	=dev-python/sniffio-1*[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
+		dev-python/pytest-trio[${PYTHON_USEDEP}]
+		dev-python/socksio[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+pkg_postinst() {
+	optfeature "SOCKs support" dev-python/socksio
+}
diff --git a/dev-python/pytest-codeblocks/pytest-codeblocks-0.13.0.ebuild b/dev-python/pytest-codeblocks/pytest-codeblocks-0.13.0.ebuild
index 1f6d2d753927..7085dd0ad224 100644
--- a/dev-python/pytest-codeblocks/pytest-codeblocks-0.13.0.ebuild
+++ b/dev-python/pytest-codeblocks/pytest-codeblocks-0.13.0.ebuild
@@ -18,6 +18,9 @@ LICENSE="MIT"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
 
+BDEPEND="
+	dev-python/pytest[${PYTHON_USEDEP}]"
+
 distutils_enable_tests pytest
 
 python_test() {
diff --git a/dev-python/socksio/Manifest b/dev-python/socksio/Manifest
new file mode 100644
index 000000000000..13d23662b672
--- /dev/null
+++ b/dev-python/socksio/Manifest
@@ -0,0 +1 @@
+DIST socksio-1.0.0.tar.gz 19055 BLAKE2B aa6bff92ae19611151070fc8e9661d532bd970d5d9d7ab8752fe77f7b4444957710ceff09d76b9f69ff71b48daf54659b4d523bc6dd01a28580d25f1e0ac055f SHA512 89bce7294555e2623df68e99352c27b83af38a4fcc4e3b86c8826c9c4bf545eeaf0a6328b000cfe1d286fa442c756c4579b4887cff03bc9e559cd66414a7ac6f
diff --git a/dev-python/socksio/metadata.xml b/dev-python/socksio/metadata.xml
new file mode 100644
index 000000000000..f233aefd84ed
--- /dev/null
+++ b/dev-python/socksio/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+  <email>python@gentoo.org</email>
+  <name>Python</name>
+ </maintainer>
+ <upstream>
+  <remote-id type="pypi">socksio</remote-id>
+ </upstream>
+ <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/socksio/socksio-1.0.0.ebuild b/dev-python/socksio/socksio-1.0.0.ebuild
new file mode 100644
index 000000000000..47d2df82b4a7
--- /dev/null
+++ b/dev-python/socksio/socksio-1.0.0.ebuild
@@ -0,0 +1,25 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_PEP517=flit
+inherit distutils-r1
+
+DESCRIPTION="Sans-I/O implementation of SOCKS4, SOCKS4A, and SOCKS5"
+HOMEPAGE="https://pypi.org/project/socksio/ https://github.com/sethmlarson/socksio"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# remove coverage args for tests
+	rm pytest.ini || die
+
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/zstandard/Manifest b/dev-python/zstandard/Manifest
index 093e0aae667c..e1832b9534a5 100644
--- a/dev-python/zstandard/Manifest
+++ b/dev-python/zstandard/Manifest
@@ -1 +1,2 @@
 DIST zstandard-0.16.0.tar.gz 563633 BLAKE2B 8d896dcbd8ef9f9b28825d35792d02c3c447fa82ccef067deb925394c21da8f19a7faa4fbe84700fe5a0871af6d33d218c6134829d08eed93fd5ef43c3d0058c SHA512 f528cace58c1f1ec0fbea96e1646d92b05077ab6f5919eec07dc7b4fcfadf97dc848238928276fdb4333fb2cd035509af472ee352608661c3de681bc8dbed318
+DIST zstandard-0.17.0.tar.gz 629456 BLAKE2B 2b19c017b6255eaa22037e633f1f1dea1322c21dda3f1129e9593c5782b6cf3dbba12003711f6192bfa474a918cbf1eae2b5dd21fbf78731b8dfc62e69a27048 SHA512 312aa02c7309fac64cf70ca901942118d4b3f12f27d20cc18dcaba5ce155ad81ea8d7657501a33a5fb6cdc8bcca11f91141ea9d6c3fc09c28a84d698b9050391
diff --git a/dev-python/zstandard/zstandard-0.17.0.ebuild b/dev-python/zstandard/zstandard-0.17.0.ebuild
new file mode 100644
index 000000000000..7d0339895c27
--- /dev/null
+++ b/dev-python/zstandard/zstandard-0.17.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Zstandard Bindings for Python"
+HOMEPAGE="https://pypi.org/project/zstandard/ https://github.com/indygreg/python-zstandard"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+DEPEND="
+	app-arch/zstd:="
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '>=dev-python/cffi-1.14.0-r2:=[${PYTHON_USEDEP}]' 'python*')
+"
+BDEPEND="
+	test? ( dev-python/hypothesis[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests setup.py
+
+src_prepare() {
+	# the C backend is repeatedly broken, so force CFFI instead
+	sed -e '/PYTHON_ZSTANDARD_IMPORT_POLICY/s:default:cffi:' \
+		-i zstandard/__init__.py || die
+	# unreliable, fails on x86
+	sed -e 's:test_estimated_compression_context_size:_&:' \
+		-i tests/test_data_structures.py || die
+
+	distutils-r1_src_prepare
+
+	DISTUTILS_ARGS=(
+		--no-c-backend
+		--system-zstd
+	)
+}