Updating liguros repo

21 files changed, 677 insertions, 12 deletions

diff --git a/dev-python/ctypesgen/ctypesgen-1.0.2.ebuild b/dev-python/ctypesgen/ctypesgen-1.0.2.ebuild
index 1f6581cff640..ebc0c80ba479 100644
--- a/dev-python/ctypesgen/ctypesgen-1.0.2.ebuild
+++ b/dev-python/ctypesgen/ctypesgen-1.0.2.ebuild
@@ -17,7 +17,7 @@ SRC_URI="https://github.com/davidjamesca/ctypesgen/archive/${P}.tar.gz"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 arm arm64 hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+KEYWORDS="~alpha ~amd64 arm arm64 hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc x86"
 IUSE=""
 
 DEPEND=""
diff --git a/dev-python/easyprocess/easyprocess-0.3.ebuild b/dev-python/easyprocess/easyprocess-0.3.ebuild
index fae5b3fe4c7f..782b70b19a95 100644
--- a/dev-python/easyprocess/easyprocess-0.3.ebuild
+++ b/dev-python/easyprocess/easyprocess-0.3.ebuild
@@ -19,6 +19,7 @@ BDEPEND="test? (
 	dev-python/pytest-timeout[${PYTHON_USEDEP}]
 	dev-python/pyvirtualdisplay[${PYTHON_USEDEP}]
 	dev-python/six[${PYTHON_USEDEP}]
+	x11-base/xorg-server[xvfb]
 )"
 
 S="${WORKDIR}/EasyProcess-${PV}"
diff --git a/dev-python/feedparser/Manifest b/dev-python/feedparser/Manifest
index ac48e8f7661d..2414c6bf8418 100644
--- a/dev-python/feedparser/Manifest
+++ b/dev-python/feedparser/Manifest
@@ -1,3 +1,4 @@
 DIST feedparser-5.2.1.tar.gz 252956 BLAKE2B 182ebefa8a44276e758f277c203c28b274c580b667b039e4fc6ed9bd059b15e35e775e9efb784a97d712dc57e7b176ff91d6e094ddd225735f4315ffa770ae83 SHA512 1fd0c4324e2eff8ef4b15e3793c767290bca562af4a5056fdbdfa12411095530c87a113bb1b9757e532ff63aecb399b18f1e6b753884798eb6b8d3fdf575af81
 DIST feedparser-6.0.0.tar.gz 252195 BLAKE2B 144c1d914518efe651bbd2c28ecf526be9cdc3422453d8e4208104b9a7832d787c8de093f0acf43f786460841852dc5a45076b96c12e1aedfb6124ce18c9034d SHA512 13f19264a52d97094dac9a0692ca4edc5ae2b5ce1a89b12207da8e994904d5c24382e304e62bfc7160ce67812b861352650f61c0273ca17fd091bde7133b2ffa
 DIST feedparser-6.0.0b1.tar.gz 250065 BLAKE2B 54e955f011af0755e0f627caa1491be15a073984d5c7c2b4edd6e9dcd6054e19b5c77cea9741d0bf7af151f9c79b22739c12db94619373f195e024df65b1cff1 SHA512 580e02bd77dcba547eb8295f958c6d30e55c62bd7fdbe25eda7687d0654b9342edf82ab637902175fc90b86a8ae9cbae8ba2c7c9a83009d25ab5c007c37cf02d
+DIST feedparser-6.0.1.tar.gz 251457 BLAKE2B e159ecae5cfdb6828a17bd26494218db78bcb2542b75161878ce9eb8f126ba0285772a4c99584654de53e297fcb308ed50baaf9f208459237a0447721e32f1f3 SHA512 562748e079b44bd249406cf15d88bd4bb338a1e5a9a9b2c606514b054edf6cdd78d66f1cf6f00320c24a9d8519069e44b730a86f92e47775614bee680b9d8b7b
diff --git a/dev-python/feedparser/feedparser-6.0.1.ebuild b/dev-python/feedparser/feedparser-6.0.1.ebuild
new file mode 100644
index 000000000000..6c78badee827
--- /dev/null
+++ b/dev-python/feedparser/feedparser-6.0.1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
+
+inherit distutils-r1
+
+MY_PV=${PV/_beta/b}
+MY_P=${PN}-${MY_PV}
+DESCRIPTION="Parse RSS and Atom feeds in Python"
+HOMEPAGE="https://github.com/kurtmckee/feedparser
+	https://pypi.org/project/feedparser/"
+SRC_URI="
+	https://github.com/kurtmckee/feedparser/archive/${MY_PV}.tar.gz
+		-> ${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+RDEPEND="dev-python/sgmllib3k[${PYTHON_USEDEP}]"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# broken
+	rm \
+		tests/illformed/chardet/big5.xml \
+		tests/illformed/undeclared_namespace.xml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	"${EPYTHON}" tests/runtests.py || die
+}
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index 332328ad8daa..8bc98bd01ab7 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -3,3 +3,4 @@ DIST hypothesis-python-5.24.4.tar.gz 9054743 BLAKE2B 5c64c86ed58d8f0e4a07390b1b1
 DIST hypothesis-python-5.29.4.tar.gz 9071060 BLAKE2B 0668f3c7859fae7024c15f693b1f56ce8d02d6f3b8187d24b2d84e38e7bdb73c0824d2b02cfecc6b40bdfbbb1c91c0aa83d40848c499a97ab7e9223aaa6c78d4 SHA512 9da4b487fd3c56540a20e2fbff635704f0720f422d8a398d0accd24a1fb9517476b0d29135b9113a96e8dc98fcfc31cc53215ad82cb727be54e4e77b44d4c8e4
 DIST hypothesis-python-5.35.0.tar.gz 9081292 BLAKE2B 8f1d50d76f589103f7b734cea6008b3533d3c0d62f45ab95a71f079833cb20b766d398a1b9492d592a93156d097d58c14041caf609f035b547f2234cbef2d602 SHA512 e99ce4c2801341fc43c4290afb551bcae69e0747a6b98a633b284bce009cc18d978b75a23bf22dafb39c5020595159806d5627128577770be3aad72a022549a3
 DIST hypothesis-python-5.35.2.tar.gz 9082095 BLAKE2B 6d2d2f74519975455a6d73f5d006837f7f71d162c5fe84c33afe81c7a110ecd93d2643db5b1ed8b00aec212c5c311254dcfbd66ae5bd08b077335a3754c9e9b4 SHA512 f17b7783d689986703bc6755a7dc30e8bfd4977a128954481067780d14b1b3f4bbfb21751a607a215357b5d300ad4e06ce951b81059ac8638c84005d682e2398
+DIST hypothesis-python-5.35.3.tar.gz 9084707 BLAKE2B ff0638194067a1c52a0297254be572ba66d67afa49c1f2fbcc42bff694ab4fe545d408d9144118314a6decfdffdbe950e2b72e89b689ae99b82ad3d3321e72fd SHA512 d862cba17444b36fa05877419495b5e49e8686980e0203da388e2dc4e528ace928f0bcb244afc8512f97bf466f2e5a2a421a2c873053849af61de71421d5c61a
diff --git a/dev-python/hypothesis/hypothesis-5.35.0.ebuild b/dev-python/hypothesis/hypothesis-5.35.0.ebuild
index 74106e060fc5..f7a7e61736bf 100644
--- a/dev-python/hypothesis/hypothesis-5.35.0.ebuild
+++ b/dev-python/hypothesis/hypothesis-5.35.0.ebuild
@@ -7,7 +7,7 @@ DISTUTILS_USE_SETUPTOOLS=rdepend
 PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
 PYTHON_REQ_USE="threads(+),sqlite"
 
-inherit distutils-r1 eutils multiprocessing
+inherit distutils-r1 eutils multiprocessing optfeature
 
 DESCRIPTION="A library for property based testing"
 HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
diff --git a/dev-python/hypothesis/hypothesis-5.35.3.ebuild b/dev-python/hypothesis/hypothesis-5.35.3.ebuild
new file mode 100644
index 000000000000..f7a7e61736bf
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-5.35.3.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 eutils multiprocessing optfeature
+
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
+SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
+S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="cli test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' python3_{6..9})
+	)
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/pytest-5.3.5[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/typing-3.7.4.1
+	)
+"
+
+python_prepare() {
+	if ! use cli || [[ ${EPYTHON} != python* ]]; then
+		sed -i -e '/console_scripts/d' setup.py || die
+	fi
+}
+
+python_test() {
+	pytest -vv tests/cover tests/pytest tests/quality \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/matplotlib/Manifest b/dev-python/matplotlib/Manifest
index ea54fac553d1..7b781c250ccf 100644
--- a/dev-python/matplotlib/Manifest
+++ b/dev-python/matplotlib/Manifest
@@ -2,3 +2,4 @@ DIST freetype-2.6.1.tar.gz 2302080 BLAKE2B 6a5fb98e5fa6cf4b7d7533ad44e364227d8c2
 DIST matplotlib-3.2.2.tar.gz 40295831 BLAKE2B 32fb34b95d1df928f949fd7b04909da2494b56efbe543f75bffedf1d9d85a0089a50cd27b82a28ac75361b56fe3f2a6c95b7d9e777778ce46f1d2805e5dae9df SHA512 4b8080fddc717f311a87b6ef1a279304da2931ef2d6de85688c153f14da5009351f42d9533c44695ca43ce1496bb642927aca822a7946a2d50d40a7d25224b31
 DIST matplotlib-3.3.0.tar.gz 38782487 BLAKE2B 97330d93b8d8a64a1296ccb173e44ebcc54c61e22aacdd73cc38a46fb2d22fbfe7334fb3c6993be001c475724c47f530243affddd71ec647232ac093db6e3135 SHA512 2ffd9e79e300a37092ab4b5a7156c2f57e408975818abd413c74477ad622030c7636695467aab821c9996564cddec57e26ba6a8004f6639070964fcb7a510a75
 DIST matplotlib-3.3.1.tar.gz 38780756 BLAKE2B b67388408da5ca6c36333705f0c19db6a1dc815819f01a5b0a7fe4ebd990f3e0df8def90971494e308ba8731f305db80dbe367f64c4fbf1294fd0f884cbb2d64 SHA512 cb3c61b7c96dde226f978980ebc960edc1329655efdeb974c8b6d8fd0cd3b660a8dfa3c98c1b140128b2ba13b134c81b000f6e87fa049d77512c81b1138b2b35
+DIST matplotlib-3.3.2.tar.gz 37939974 BLAKE2B f28e184a0fccd4192ba8135b70569bf463d08cae0f4eb8e7f997f417cb947500a9fe46eb5f979473b4d7d22c0ad03ab55aba4067082c86f63eacbf837b8606ad SHA512 cae68e63d879bcfb41b25df4de48472461f7987403d42d34c7205a65ed3ef567660309c04d2a55e155fbe1ef708fd9de0b0d66e71578f34c3ee93379c4ea1e1a
diff --git a/dev-python/matplotlib/files/matplotlib-3.3.2-test-extra.patch b/dev-python/matplotlib/files/matplotlib-3.3.2-test-extra.patch
new file mode 100644
index 000000000000..1fff166295b2
--- /dev/null
+++ b/dev-python/matplotlib/files/matplotlib-3.3.2-test-extra.patch
@@ -0,0 +1,25 @@
+From 5d2f40b312966c08436b4495980313f2dacd9750 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
+Date: Tue, 15 Sep 2020 23:48:05 +0200
+Subject: [PATCH] Increase tolerance for test_transparent_markers
+
+---
+ lib/matplotlib/tests/test_axes.py | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/lib/matplotlib/tests/test_axes.py b/lib/matplotlib/tests/test_axes.py
+index 412dd2471..52a32f9f1 100644
+--- a/lib/matplotlib/tests/test_axes.py
++++ b/lib/matplotlib/tests/test_axes.py
+@@ -3500,7 +3500,7 @@ def test_hist_labels():
+     assert l[2][0].get_label() == '00'
+ 
+ 
+-@image_comparison(['transparent_markers'], remove_text=True)
++@image_comparison(['transparent_markers'], remove_text=True, tol=5)
+ def test_transparent_markers():
+     np.random.seed(0)
+     data = np.random.random(50)
+-- 
+2.28.0
+
diff --git a/dev-python/matplotlib/matplotlib-3.3.2.ebuild b/dev-python/matplotlib/matplotlib-3.3.2.ebuild
new file mode 100644
index 000000000000..d61638774dab
--- /dev/null
+++ b/dev-python/matplotlib/matplotlib-3.3.2.ebuild
@@ -0,0 +1,277 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+PYTHON_REQ_USE='tk?,threads(+)'
+
+DISTUTILS_USE_SETUPTOOLS=bdepend
+inherit distutils-r1 flag-o-matic virtualx toolchain-funcs prefix
+
+FT_PV=2.6.1
+DESCRIPTION="Pure python plotting library with matlab like syntax"
+HOMEPAGE="https://matplotlib.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+	test? (
+		https://downloads.sourceforge.net/project/freetype/freetype2/${FT_PV}/freetype-${FT_PV}.tar.gz
+	)"
+
+# Main license: matplotlib
+# Some modules: BSD
+# matplotlib/backends/qt4_editor: MIT
+# Fonts: BitstreamVera, OFL-1.1
+LICENSE="BitstreamVera BSD matplotlib MIT OFL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="cairo doc excel examples gtk3 latex qt5 tk wxwidgets"
+
+# internal copy of pycxx highly patched
+#	dev-python/pycxx
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/cycler-0.10.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/kiwisolver-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.18.2[${PYTHON_USEDEP}]
+	>=dev-python/pillow-7.1.1[jpeg,${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-1.5.6[${PYTHON_USEDEP}]
+	dev-python/python-dateutil:0[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2019.3[${PYTHON_USEDEP}]
+	>=dev-python/six-1.14.0[${PYTHON_USEDEP}]
+	dev-python/versioneer[${PYTHON_USEDEP}]
+	media-fonts/dejavu
+	media-fonts/stix-fonts
+	media-libs/freetype:2
+	media-libs/libpng:0
+	>=media-libs/qhull-2013
+	>=www-servers/tornado-6.0.4[${PYTHON_USEDEP}]
+	cairo? (
+		dev-python/cairocffi[${PYTHON_USEDEP}]
+	)
+	excel? (
+		dev-python/xlwt[${PYTHON_USEDEP}]
+	)
+	gtk3? (
+		dev-python/pygobject:3[cairo?,${PYTHON_USEDEP}]
+		x11-libs/gtk+:3[introspection]
+	)
+	latex? (
+		virtual/latex-base
+		app-text/dvipng
+		app-text/ghostscript-gpl
+		app-text/poppler[utils]
+		dev-texlive/texlive-fontsrecommended
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-xetex
+	)
+	qt5? (
+		dev-python/PyQt5[gui,widgets,${PYTHON_USEDEP}]
+	)
+	wxwidgets? (
+		$(python_gen_cond_dep '
+			dev-python/wxpython:*[${PYTHON_USEDEP}]
+		' python3_{6,7,8})
+	)
+"
+
+BDEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	doc? (
+		>=app-text/dvipng-1.15-r1
+		>=dev-python/colorspacious-1.1.2[${PYTHON_USEDEP}]
+		>=dev-python/ipython-1.18.2[${PYTHON_USEDEP}]
+		>=dev-python/numpydoc-0.9.2[${PYTHON_USEDEP}]
+		>=sci-libs/scipy-1.4.1[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.3.1[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-gallery-0.3.1-r1[${PYTHON_USEDEP}]
+		>=dev-python/xlwt-1.3.0-r1[${PYTHON_USEDEP}]
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-fontsrecommended
+		dev-texlive/texlive-latexrecommended
+		>=media-gfx/graphviz-2.42.3[cairo]
+	)
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[cairo?,${PYTHON_USEDEP}]
+		x11-libs/gtk+:3[introspection]
+	)
+"
+
+# A few C++ source files are written to srcdir.
+# Other than that, the ebuild shall be fit for out-of-source build.
+DISTUTILS_IN_SOURCE_BUILD=1
+
+distutils_enable_tests pytest
+
+pkg_setup() {
+	unset DISPLAY # bug #278524
+}
+
+use_supported() {
+	case ${1} in
+		wxwidgets)
+			[[ ${EPYTHON} == python3.[678] ]]
+			;;
+	esac
+
+	return 0
+}
+
+use_setup() {
+	local uword="${2:-${1}}"
+	if use_supported "${1}" && use "${1}"; then
+		echo "${uword} = True"
+		echo "${uword}agg = True"
+	else
+		echo "${uword} = False"
+		echo "${uword}agg = False"
+	fi
+}
+
+python_prepare_all() {
+# Generates test failures, but fedora does it
+#	local PATCHES=(
+#		"${FILESDIR}"/${P}-unbundle-pycxx.patch
+#		"${FILESDIR}"/${P}-unbundle-agg.patch
+#	)
+#	rm -r agg24 CXX || die
+#	rm -r agg24 || die
+
+#	cat > lib/${PN}/externals/six.py <<-EOF
+#	from __future__ import absolute_import
+#	from six import *
+#	EOF
+
+	local PATCHES=(
+		"${FILESDIR}"/matplotlib-3.3.0-test.patch
+		"${FILESDIR}"/matplotlib-3.3.2-test-extra.patch
+	)
+
+	# requires jupyter-nbconvert
+	rm lib/matplotlib/tests/test_backend_nbagg.py || die
+
+	sed \
+		-e 's/matplotlib.pyparsing_py[23]/pyparsing/g' \
+		-i lib/matplotlib/{mathtext,fontconfig_pattern}.py \
+		|| die "sed pyparsing failed"
+
+	sed -e 's:\(@pytest.mark.flaky\)(reruns=3):\1:' \
+		-i lib/matplotlib/tests/test_*.py || die
+
+	hprefixify setupext.py
+
+	rm -rf libqhull || die
+
+	export XDG_RUNTIME_DIR="${T}/runtime-dir"
+	mkdir "${XDG_RUNTIME_DIR}" || die
+	chmod 0700 "${XDG_RUNTIME_DIR}" || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	append-flags -fno-strict-aliasing
+	append-cppflags -DNDEBUG  # or get old trying to do triangulation
+	tc-export PKG_CONFIG
+}
+
+python_configure() {
+	mkdir -p "${BUILD_DIR}" || die
+
+	# create setup.cfg (see setup.cfg.template for any changes).
+
+	# common switches.
+	cat > "${BUILD_DIR}"/setup.cfg <<- EOF || die
+		[directories]
+		basedirlist = ${EPREFIX}/usr
+		[provide_packages]
+		pytz = False
+		dateutil = False
+		[libs]
+		system_freetype = True
+		system_qhull = True
+		[packages]
+		tests = $(usex test True False)
+		[gui_support]
+		agg = True
+		gtk = False
+		gtkagg = False
+		pyside = False
+		pysideagg = False
+		qt4 = False
+		qt4agg = False
+		$(use_setup cairo)
+		$(use_setup gtk3)
+		$(use_setup qt5)
+		$(use_setup tk)
+		$(use_setup wxwidgets wx)
+	EOF
+
+	if use gtk3 && use cairo; then
+		echo "gtk3cairo = True" >> "${BUILD_DIR}"/setup.cfg || die
+	else
+		echo "gtk3cairo = False" >> "${BUILD_DIR}"/setup.cfg || die
+	fi
+}
+
+wrap_setup() {
+	local MAKEOPTS=-j1
+	local -x MPLSETUPCFG="${BUILD_DIR}"/setup.cfg
+	"$@"
+}
+
+python_compile() {
+	wrap_setup distutils-r1_python_compile --build-lib="${BUILD_DIR}"/lib
+}
+
+python_compile_all() {
+	if use doc; then
+		cd doc || die
+
+		# necessary for in-source build
+		local -x PYTHONPATH="${BUILD_DIR}"/build/lib:${PYTHONPATH}
+
+		VARTEXFONTS="${T}"/fonts \
+		emake SPHINXOPTS= O=-Dplot_formats=png:100 html
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	# we need to rebuild mpl against bundled freetype, otherwise
+	# over 1000 tests will fail because of mismatched font rendering
+	grep -v system_freetype "${BUILD_DIR}"/setup.cfg \
+		> "${BUILD_DIR}"/test-setup.cfg || die
+	local -x MPLSETUPCFG="${BUILD_DIR}"/test-setup.cfg
+	ln -s "${WORKDIR}/freetype-${FT_PV}" "${BUILD_DIR}" || die
+	distutils-r1_python_compile -j1 --build-lib="${BUILD_DIR}"/test-lib
+	local -x PYTHONPATH=${BUILD_DIR}/test-lib:${PYTHONPATH}
+
+	"${EPYTHON}" -c "import sys, matplotlib as m; sys.exit(m.test(argv=['-m', 'not network'], verbosity=2))" || die
+}
+
+python_install() {
+	wrap_setup distutils-r1_python_install
+
+	# mpl_toolkits namespace
+	python_moduleinto mpl_toolkits
+	python_domodule lib/mpl_toolkits/__init__.py
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	find "${D}" -name '*.pth' -delete || die
+}
diff --git a/dev-python/mss/mss-6.0.0.ebuild b/dev-python/mss/mss-6.0.0.ebuild
index b010f45a9639..28a7a6fe0acc 100644
--- a/dev-python/mss/mss-6.0.0.ebuild
+++ b/dev-python/mss/mss-6.0.0.ebuild
@@ -21,6 +21,7 @@ S="${WORKDIR}/python-${PN}-${PV}"
 BDEPEND="test? (
 	dev-python/flaky[${PYTHON_USEDEP}]
 	dev-python/wheel[${PYTHON_USEDEP}]
+	sys-process/lsof
 )"
 
 distutils_enable_tests pytest
diff --git a/dev-python/protobuf-python/Manifest b/dev-python/protobuf-python/Manifest
index 91e20f9553ba..579b5e38b3fd 100644
--- a/dev-python/protobuf-python/Manifest
+++ b/dev-python/protobuf-python/Manifest
@@ -1,2 +1,4 @@
 DIST protobuf-3.11.4.tar.gz 5140799 BLAKE2B 97b450c0623593efe6a42b66582ff183344b8831689e6a5b4d36096dbd57c33da9569bbf26578536aaf73ecd866ac0588b6cb7d55a6a9b9a6e840d4c57099001 SHA512 777bbb0e9e2375eaebe6b8c87abd660bac70ee469c9ad00dd25917b82d7fb5bbe33cf87f0d69c90e19d55c07a7285ec20974ba4768623ce9ccfadf147fd5e261
 DIST protobuf-3.12.2.tar.gz 5309688 BLAKE2B 6f04ab75a165d8135b4c1de210f8698f56f309f73d664192209de10580e0ef850bf56f6f394b860f21912e341141f7bbb1f63198eaee55fd7ad74d86b00c3b1f SHA512 84a349a1dcb5bce6a6a892cf11264390b557ed1e7b05883b71fa9cfb7460d9f73119da1f2861066869e33c752246ea438d5ce2c2b3ff7a4b07696d9450b7916b
+DIST protobuf-3.12.4.tar.gz 5310348 BLAKE2B 2630941672963165467221843c10079a0ed966f2fdfcbc970b0b41e1ed3c7f78734496c1fbd3ec509c68999a14f637fff267b309cf82a8acf2bb5a948484f79b SHA512 c5d24502b9a6be0a606a19213186fe462e0de6830547003636f0897781f36d0bd7e4e7d9689d96390a0399ce04b6438cda3a0fe6f97f0feb700a110e90beef0c
+DIST protobuf-3.13.0.tar.gz 5277913 BLAKE2B 168aaa5beef83be675cd2543ca8efeaf5174f5e7fd861a056b04b01c8c781dc7b1fcbd05068ae89f051dfacfdc47c34b19cc33c8d09dd3212d3827746e3408f2 SHA512 514efa65fc8a36bc0791e6d39bdfb07b2689e9c2a4b82536c657859b800e7bc1e1a0ae86a7ee33f30c43a473a49b5c346ce830ac0057b6da104ed37f90b8b0fd
diff --git a/dev-python/protobuf-python/protobuf-python-3.12.4.ebuild b/dev-python/protobuf-python/protobuf-python-3.12.4.ebuild
new file mode 100644
index 000000000000..4b2d3c1527db
--- /dev/null
+++ b/dev-python/protobuf-python/protobuf-python-3.12.4.ebuild
@@ -0,0 +1,63 @@
+# Copyright 2008-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=( python2_7 python3_{5,6,7,8,9} )
+DISTUTILS_USE_SETUPTOOLS="manual"
+
+inherit distutils-r1
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/protocolbuffers/protobuf"
+	EGIT_SUBMODULES=()
+fi
+
+DESCRIPTION="Google's Protocol Buffers - Python bindings"
+HOMEPAGE="https://developers.google.com/protocol-buffers/ https://github.com/protocolbuffers/protobuf"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/protocolbuffers/protobuf/archive/v${PV}.tar.gz -> protobuf-${PV}.tar.gz"
+fi
+
+LICENSE="BSD"
+SLOT="0/23"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE=""
+
+BDEPEND="${PYTHON_DEPS}
+	~dev-libs/protobuf-${PV}
+	dev-python/namespace-google[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="${PYTHON_DEPS}
+	~dev-libs/protobuf-${PV}"
+RDEPEND="${BDEPEND}
+	!<dev-libs/protobuf-3[python(-)]"
+
+S="${WORKDIR}/protobuf-${PV}/python"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_CHECKOUT_DIR="${WORKDIR}/protobuf-${PV}"
+fi
+
+python_configure_all() {
+	mydistutilsargs=(--cpp_implementation)
+}
+
+python_compile() {
+	python_is_python3 || local -x CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	find "${D}" -name "*.pth" -type f -delete || die
+}
diff --git a/dev-python/protobuf-python/protobuf-python-3.13.0.ebuild b/dev-python/protobuf-python/protobuf-python-3.13.0.ebuild
new file mode 100644
index 000000000000..4870905f496f
--- /dev/null
+++ b/dev-python/protobuf-python/protobuf-python-3.13.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2008-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=( python2_7 python3_{5,6,7,8,9} )
+DISTUTILS_USE_SETUPTOOLS="manual"
+
+inherit distutils-r1
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/protocolbuffers/protobuf"
+	EGIT_SUBMODULES=()
+fi
+
+DESCRIPTION="Google's Protocol Buffers - Python bindings"
+HOMEPAGE="https://developers.google.com/protocol-buffers/ https://github.com/protocolbuffers/protobuf"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/protocolbuffers/protobuf/archive/v${PV}.tar.gz -> protobuf-${PV}.tar.gz"
+fi
+
+LICENSE="BSD"
+SLOT="0/24"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE=""
+
+BDEPEND="${PYTHON_DEPS}
+	~dev-libs/protobuf-${PV}
+	dev-python/namespace-google[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="${PYTHON_DEPS}
+	~dev-libs/protobuf-${PV}"
+RDEPEND="${BDEPEND}
+	!<dev-libs/protobuf-3[python(-)]"
+
+S="${WORKDIR}/protobuf-${PV}/python"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_CHECKOUT_DIR="${WORKDIR}/protobuf-${PV}"
+fi
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	sed -e "/^[[:space:]]*setup_requires = \['wheel'\],$/d" -i setup.py || die
+}
+
+python_configure_all() {
+	mydistutilsargs=(--cpp_implementation)
+}
+
+python_compile() {
+	python_is_python3 || local -x CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	find "${D}" -name "*.pth" -type f -delete || die
+}
diff --git a/dev-python/protobuf-python/protobuf-python-9999.ebuild b/dev-python/protobuf-python/protobuf-python-9999.ebuild
index f03027b829ac..b9b5dab0d541 100644
--- a/dev-python/protobuf-python/protobuf-python-9999.ebuild
+++ b/dev-python/protobuf-python/protobuf-python-9999.ebuild
@@ -23,7 +23,7 @@ else
 fi
 
 LICENSE="BSD"
-SLOT="0/23"
+SLOT="0/24"
 KEYWORDS=""
 IUSE=""
 
@@ -43,6 +43,12 @@ if [[ "${PV}" == "9999" ]]; then
 	EGIT_CHECKOUT_DIR="${WORKDIR}/protobuf-${PV}"
 fi
 
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	sed -e "/^[[:space:]]*setup_requires = \['wheel'\],$/d" -i setup.py || die
+}
+
 python_configure_all() {
 	mydistutilsargs=(--cpp_implementation)
 }
diff --git a/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.4.0.ebuild b/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.4.0.ebuild
index 7f758ae3eeea..eea00e94a460 100644
--- a/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.4.0.ebuild
+++ b/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.4.0.ebuild
@@ -16,8 +16,10 @@ LICENSE="BSD-with-disclosure"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
 
-BDEPEND="dev-python/pytest-regressions[${PYTHON_USEDEP}]
-	test? ( dev-python/beautifulsoup[${PYTHON_USEDEP}] )"
+BDEPEND="test? (
+	dev-python/beautifulsoup[${PYTHON_USEDEP}]
+	dev-python/pytest-regressions[${PYTHON_USEDEP}]
+)"
 
 RDEPEND="dev-python/sphinx[${PYTHON_USEDEP}]"
 
diff --git a/dev-python/sentry-sdk/Manifest b/dev-python/sentry-sdk/Manifest
index 6d0255ea3205..65f6efc9d30a 100644
--- a/dev-python/sentry-sdk/Manifest
+++ b/dev-python/sentry-sdk/Manifest
@@ -1,2 +1,3 @@
 DIST sentry-sdk-0.16.3.tar.gz 170145 BLAKE2B bf619313fb3f49800f5384f0dfec3aa34ef4bb030c5e038a485a8861a733a537ee7c834c8c200a2244335c3c61e7d564005b81d4e5c5f603d2864b2a943a5384 SHA512 e8589f7bd433d4aff068099e860c0cf012fc88dc63806873573a338bb91848d73e0a2af76dad0a5e023a1b25b0be85507346b77dec5c5a265942005219541699
 DIST sentry-sdk-0.17.5.tar.gz 183114 BLAKE2B a2fdd5fb0ffb18f7987eae9f3837a4bf4df20df9757d89bcc3ec18f7022d20de083c905f6edbb854bcc7f074f6d158cbf30f69d953a75048e7d9d0d98e859477 SHA512 5f0d6679832fed346d00b27bac9f680909a7ede38e46b1c05c583fcc574edc193d855dba2f11a629e2919da5e13cc2e89f6c0b231e47bc7b0a67138ff7905d9f
+DIST sentry-sdk-0.17.6.tar.gz 183157 BLAKE2B ea0f6af54c31abc785274fc75238a02b8c9f7a978881a01203e0928e100c18df2257ec4a3cef608141b6846c616566388134a4ec31364f26d0bc2b0fadbb0dac SHA512 1af433b5c2311612ad650ea196ddfedb444e9ccb424df72422759f8647fe6cc22bb81a15933f2716cf40313ce3b2e262c077168aa831758d057a1f2e5e1499ff
diff --git a/dev-python/sentry-sdk/sentry-sdk-0.17.6.ebuild b/dev-python/sentry-sdk/sentry-sdk-0.17.6.ebuild
new file mode 100644
index 000000000000..483a5b3f6a82
--- /dev/null
+++ b/dev-python/sentry-sdk/sentry-sdk-0.17.6.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python client for Sentry"
+HOMEPAGE="https://getsentry.com https://pypi.org/project/sentry-sdk/"
+SRC_URI="https://github.com/getsentry/sentry-python/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/sentry-python-${PV}"
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+RDEPEND="
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/asttokens[${PYTHON_USEDEP}]
+		<dev-python/dnspython-2[${PYTHON_USEDEP}]
+		dev-python/executing[${PYTHON_USEDEP}]
+		dev-python/eventlet[${PYTHON_USEDEP}]
+		dev-python/fakeredis[${PYTHON_USEDEP}]
+		dev-python/flask-login[${PYTHON_USEDEP}]
+		dev-python/gevent[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pyrsistent[${PYTHON_USEDEP}]
+		dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+		dev-python/pytest-forked[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/werkzeug[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/aiocontextvars[${PYTHON_USEDEP}]
+			dev-python/contextvars[${PYTHON_USEDEP}]
+		' python3_6)
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local deselect=(
+		# tests require Internet access
+		--deselect tests/integrations/stdlib/test_httplib.py
+		--deselect tests/integrations/requests/test_requests.py
+		# wtf is it supposed to do?!
+		--deselect tests/integrations/gcp/test_gcp.py
+		# fails on py3.6, hangs on py3.7+
+		--deselect
+		'tests/test_transport.py::test_transport_works[eventlet'
+		# TODO
+		--deselect
+		'tests/test_basics.py::test_auto_enabling_integrations_catches_import_error'
+		--deselect
+		tests/test_client.py::test_databag_depth_stripping
+		--deselect
+		tests/test_client.py::test_databag_string_stripping
+		--deselect
+		tests/test_client.py::test_databag_breadth_stripping
+		# test_filename: apparently unhappy about pytest being called pytest
+		--deselect 'tests/utils/test_general.py::test_filename'
+		# test_circular_references: apparently fragile
+		--deselect
+		'tests/integrations/threading/test_threading.py::test_circular_references'
+	)
+	[[ ${EPYTHON} == python3.6 ]] && deselect+=(
+		# broken with contextvars on py3.6
+		--deselect
+		'tests/utils/test_contextvars.py::test_leaks[greenlet]'
+		--deselect
+		'tests/test_transport.py::test_transport_works[greenlet'
+	)
+
+	# Prevent tests/integrations/modules/test_modules.py:test_basic failure
+	# Needs to detect sentry-sdk in the installed modules
+	distutils_install_for_testing
+
+	pytest -vv "${deselect[@]}" || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/tenacity/Manifest b/dev-python/tenacity/Manifest
index 033f120522b4..2b5f687809a9 100644
--- a/dev-python/tenacity/Manifest
+++ b/dev-python/tenacity/Manifest
@@ -1 +1,2 @@
 DIST tenacity-6.1.0.tar.gz 33438 BLAKE2B e3f7c0ef19f98c0ac5b2a9a1be53241292d895547e5c10810ff94c27f34e8bbca7ef3aea79ce6e4042c84109e209b4be2913e6231233a3b050c18ed52f8af087 SHA512 a8f52f77e066a35c4a35cdd80fe01922613d9f4ca07975aece4a35bc743475f7540bf419e5095eacf94cb248ce33bdd89b46c5e3c5bd5a93bd99a601cf580732
+DIST tenacity-6.2.0.tar.gz 35213 BLAKE2B 830953463ef9d7ee9e99fc0c9d3f55910754f4c2c777110ad8af65b0af186b2aada25ec3d9ae80f266ad9200080db1af70b80bb77f1edc51148001ca49e0bd08 SHA512 3753ab44390810458c559d243bdc5e3c0092a0c2af7eb4e6fa43d5e6e215a58d4bf3ff6e81800db2f517796b501fff038964b424e364ac417ddd3e70b57bc6c8
diff --git a/dev-python/tenacity/tenacity-6.2.0.ebuild b/dev-python/tenacity/tenacity-6.2.0.ebuild
new file mode 100644
index 000000000000..aeb25ace9f87
--- /dev/null
+++ b/dev-python/tenacity/tenacity-6.2.0.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="General-purpose retrying library"
+HOMEPAGE="https://github.com/jd/tenacity"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE=""
+
+DEPEND="
+	dev-python/pbr[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/monotonic-0.6[${PYTHON_USEDEP}]
+"
+
+python_prepare_all() {
+	sed -i '/typing/d' setup.cfg || die
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/xapp/metadata.xml b/dev-python/xapp/metadata.xml
index 28b44f3a6899..a2fa205b61a3 100644
--- a/dev-python/xapp/metadata.xml
+++ b/dev-python/xapp/metadata.xml
@@ -5,18 +5,14 @@
 		<email>olivier.laurantin@laposte.net</email>
 		<name>Olivier Laurantin</name>
 	</maintainer>
-	<maintainer type="project">
-		<email>cinnamon@gentoo.org</email>
-		<name>Cinnamon Project</name>
+	<maintainer type="person">
+		<email>sparky@bluefang-logic.com</email>
+		<name>Matthew Turnbull</name>
 	</maintainer>
 	<maintainer type="project">
 		<email>proxy-maint@gentoo.org</email>
 		<name>Proxy Maintainers</name>
 	</maintainer>
-	<maintainer type="person">
-		<email>sparky@bluefang-logic.com</email>
-		<name>Matthew Turnbull</name>
-	</maintainer>
 	<upstream>
 		<remote-id type="github">linuxmint/python3-xapp</remote-id>
 	</upstream>