Adding metadata

31 files changed, 691 insertions, 2 deletions

diff --git a/dev-python/attrs/Manifest b/dev-python/attrs/Manifest
index 34e7f1b2225f..968692af20b1 100644
--- a/dev-python/attrs/Manifest
+++ b/dev-python/attrs/Manifest
@@ -1,2 +1,3 @@
 DIST attrs-21.2.0.tar.gz 184694 BLAKE2B 5c960f7c1a4623186c7a0cec8a9096df8df8e7d3022b67b281dcdd3a512ce6f105dfdd5ec10dc85a2b9971564f44e7b4474d760667e53cd2cf0f0543153eb6e2 SHA512 35863f599076357e40f72a62968f4a2f9bc2af9f59f484fef051be4f9730ce9e28e11568915d690ade7980df8998af22e2ff8b9568a205d7745e246ba5f3a7e1
 DIST attrs-21.3.0.tar.gz 204413 BLAKE2B 1aac1198196aa3438eb1ec9dac0a4971362caea655e27a2b7811e48d500a40fe8f2daf43ce86d3b381892763fdfecf9adbda16a29dda57155ec5a588732b423d SHA512 23b2ba52af809581e9907ad7c6d18ed050d415645a249ae912af3f1398276ea5bf67f11991d7958f3eeafe759d8d62a65009555ae8f75580cfa464c5b4a37742
+DIST attrs-21.4.0.tar.gz 201839 BLAKE2B f8e9ca1385efe6f5b9bf468f622f0bf5390830c5f3c3526821446113146a61460b17e8750ea763f6da50221a8aa65f5f1ff98a6ddf69b1a87344508ca6495560 SHA512 5a52776eb505c8a354912fa037a9710e49830fa6ad37272cb6d8c3298f4179a5b237e36cd7db3b1c9af19fbf0194ad6b83c3db9a473f9349769180073273ba65
diff --git a/dev-python/attrs/attrs-21.4.0.ebuild b/dev-python/attrs/attrs-21.4.0.ebuild
new file mode 100644
index 000000000000..c93798b21eb6
--- /dev/null
+++ b/dev-python/attrs/attrs-21.4.0.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Attributes without boilerplate"
+HOMEPAGE="
+	https://github.com/python-attrs/attrs/
+	https://attrs.readthedocs.io/
+	https://pypi.org/project/attrs/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/zope-interface[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		$(python_gen_cond_dep '
+			dev-python/cloudpickle[${PYTHON_USEDEP}]
+		' 'python*')
+		>=dev-python/hypothesis-3.6.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-4.3.0[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
diff --git a/dev-python/dns-lexicon/Manifest b/dev-python/dns-lexicon/Manifest
index 3d984d62690c..bed68b5cb48b 100644
--- a/dev-python/dns-lexicon/Manifest
+++ b/dev-python/dns-lexicon/Manifest
@@ -1,2 +1,3 @@
 DIST dns-lexicon-3.8.3.tar.gz 7834913 BLAKE2B a72b356d10d0af8367ce9d51d2c4d4a3a1cc8aa26d5edfa2cb1aca4b2eb67acdcadc46f46d5457430708f94fda9654a87ded76fa796c44a4b4e2a0d4f3accd13 SHA512 3035e9c5d073feb0dd910b79d8de02f2e9bfc81f922bce34ad33c22b583896a781e50f85104799a13133121ab5e88a372667cf0014399df50c5a829747d98073
 DIST dns-lexicon-3.8.4.tar.gz 7850337 BLAKE2B f72a338c00346091df2cf53fa01cbc34e81b235cb5100b4993ccf46f738e2588b08b7a57316c07c7eff1c039437e49371193c9952b6fd870f30a2c6b538d3e1e SHA512 7a598b38a847e384fda243b76af523701d80d84a2338ef5745ca9f82284675ace5f84bf93cccfeda101584194c15fdbd0d4d8f69fdd0db60ec42d4c063a7916c
+DIST dns-lexicon-3.8.5.tar.gz 7850115 BLAKE2B 27dfb837385e370142d82bc682627fa96efc8a4868f9a5532ace608e2739afbecee82dcb531e9a4e0cdf9b2c68e639ae5c7ad1f4774e80f989c13eaa86c93d7a SHA512 e50fdb5c0b0d250babaff0a2d485f9112732a9e975cb853329dbcec33fe592e80a28c469b17cc0a5544909285805c1c20578b5e5f4b22ff6259b624be8c6acde
diff --git a/dev-python/dns-lexicon/dns-lexicon-3.8.5.ebuild b/dev-python/dns-lexicon/dns-lexicon-3.8.5.ebuild
new file mode 100644
index 000000000000..223666b993ee
--- /dev/null
+++ b/dev-python/dns-lexicon/dns-lexicon-3.8.5.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_SETUPTOOLS=pyproject.toml
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Manipulate DNS records on various DNS providers in a standardized/agnostic way"
+HOMEPAGE="https://pypi.org/project/dns-lexicon/"
+SRC_URI="https://github.com/AnalogJ/lexicon/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/lexicon-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/tldextract[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/boto3[${PYTHON_USEDEP}]
+		dev-python/zeep[${PYTHON_USEDEP}]
+		dev-python/vcrpy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# Requires the "localzone" module
+	lexicon/tests/providers/test_localzone.py
+	# Requires the "softlayer" module
+	lexicon/tests/providers/test_softlayer.py
+	# Requires the "transip" module
+	lexicon/tests/providers/test_transip.py
+	# Requires the "oci" module
+	lexicon/tests/providers/test_oci.py
+	# Uses tldextract which needs Internet access to download its database
+	lexicon/tests/providers/test_auto.py
+)
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		optfeature_header \
+			"Install the following packages to enable support for additional DNS providers:"
+		optfeature Gransy dev-python/zeep
+		optfeature Route53 dev-python/boto3
+		optfeature DDNS dev-python/dnspython
+	fi
+}
diff --git a/dev-python/dnspython/dnspython-1.16.0-r2.ebuild b/dev-python/dnspython/dnspython-1.16.0-r2.ebuild
index 41d141d4cf6a..cabc7cedd213 100644
--- a/dev-python/dnspython/dnspython-1.16.0-r2.ebuild
+++ b/dev-python/dnspython/dnspython-1.16.0-r2.ebuild
@@ -8,7 +8,7 @@ PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
 inherit distutils-r1
 
 DESCRIPTION="DNS toolkit for Python"
-HOMEPAGE="http://www.dnspython.org/ https://pypi.org/project/dnspython/"
+HOMEPAGE="https://www.dnspython.org/ https://pypi.org/project/dnspython/"
 SRC_URI="https://github.com/rthalley/dnspython/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="ISC"
diff --git a/dev-python/git-review/git-review-2.2.0.ebuild b/dev-python/git-review/git-review-2.2.0.ebuild
index a9471b4b7ee6..9a8a0698ca32 100644
--- a/dev-python/git-review/git-review-2.2.0.ebuild
+++ b/dev-python/git-review/git-review-2.2.0.ebuild
@@ -14,7 +14,7 @@ if [[ ${PV} == 9999* ]]; then
 	EGIT_REPO_URI="https://opendev.org/opendev/${PN}.git"
 else
 	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-	KEYWORDS="~amd64 ~x86 ~x64-cygwin ~amd64-linux ~x86-linux"
+	KEYWORDS="amd64 x86 ~x64-cygwin ~amd64-linux ~x86-linux"
 fi
 
 LICENSE="Apache-2.0"
diff --git a/dev-python/huawei-lte-api/Manifest b/dev-python/huawei-lte-api/Manifest
index 427075993def..a59d2f9b5958 100644
--- a/dev-python/huawei-lte-api/Manifest
+++ b/dev-python/huawei-lte-api/Manifest
@@ -1 +1,2 @@
 DIST huawei-lte-api-1.5.2.tar.gz 31969 BLAKE2B ced0afc9c1b878d30ac4d3fb731cdebd6c2a658a7ace7d74f5e3641c049d5eaeab5fe1edd4678b791da0ebd22c78c4c7b10f56e2bb4f224788d1f1cdd8f31c6a SHA512 7d7b8b0248ef6080aa990ce06e196653f315605d771c312c490976cd950dfa962affe47f8df3366a645e0d499606514618e1e24976f434258ca22bd9ccf34237
+DIST huawei-lte-api-1.5.4.tar.gz 32433 BLAKE2B 36ba5729f7016c07955f87b85745314f683345e06e174efa90e2fdfd59a8a68c8425b549f8e25293dc2d65d0681a588feb062c3067b275d4e0ed2b56dc3ebbb6 SHA512 549373bf6d00aa1fb3f9f6443446520e068ec2c5412c84472b687102b2590cd22a742805f8c7fab67b7a4482e37cb3b03900aaf078ed777c3b1c111194e69da6
diff --git a/dev-python/huawei-lte-api/huawei-lte-api-1.5.4.ebuild b/dev-python/huawei-lte-api/huawei-lte-api-1.5.4.ebuild
new file mode 100644
index 000000000000..748b4d515860
--- /dev/null
+++ b/dev-python/huawei-lte-api/huawei-lte-api-1.5.4.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="API For huawei LAN/WAN LTE Modems"
+HOMEPAGE="https://github.com/Salamek/huawei-lte-api"
+SRC_URI="https://github.com/Salamek/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+RDEPEND="dev-python/pycryptodome[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	# make cryptodome-friendly
+	find -name '*.py' -exec \
+		sed -i -e 's:Cryptodome:Crypto:g' {} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+distutils_enable_tests pytest
diff --git a/dev-python/jupyter-lsp/Manifest b/dev-python/jupyter-lsp/Manifest
index b7dd34a43a25..8968ce2934fe 100644
--- a/dev-python/jupyter-lsp/Manifest
+++ b/dev-python/jupyter-lsp/Manifest
@@ -1 +1,2 @@
 DIST jupyter-lsp-1.5.0.tar.gz 35747 BLAKE2B 110840905b929c5aab420493e1535fbe5329dc5cc7204d48c59fd656b6b98ca5830887fa5eb513299cfd1ed63cda2f133652c85fe8a285ac304212598be2afbf SHA512 868b16236d02aaf055431f88f1680df9f8b8f5bf9de0feee3f378d23a653c5e7555602717bf30b7e48089e287dc595f8674f9431296a24e788c54f085e50bc79
+DIST jupyter-lsp-1.5.1.tar.gz 35907 BLAKE2B bc69791253bfcf40188fe2bae24a2681ce17835f5eb1d2640edf93a69285b33d426bffdf09c66308e6f79e33c4778e539fc2a7ed056fe64758e82acc6374b4cf SHA512 585c7b3b7ea87fd9d3ad27e3e4473f3bce56ad41d3b028173e2fcad4b0d2db5b1c0c89cd8c976c3f8b4d30ae7a63018dc1e19d4527b56eafe21ec0b5e89a538b
diff --git a/dev-python/jupyter-lsp/jupyter-lsp-1.5.1.ebuild b/dev-python/jupyter-lsp/jupyter-lsp-1.5.1.ebuild
new file mode 100644
index 000000000000..93b502cdfe40
--- /dev/null
+++ b/dev-python/jupyter-lsp/jupyter-lsp-1.5.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Multi-Language Server WebSocket proxy for Jupyter Notebook/Lab"
+HOMEPAGE="https://github.com/krassowski/jupyterlab-lsp"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# TODO: Find out what is going on here
+# asyncio.exceptions.TimeoutError
+RESTRICT="test"
+
+RDEPEND="
+	dev-python/entrypoints[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_server-1.1.2[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Do not depend on pytest-cov or flake8
+	sed -i -e '/--cov/d' -e '/--flake8/d' setup.cfg || die
+	# R lsp server not packaged
+	sed -i -e 's:test_r_package_detection:_&:' \
+		jupyter_lsp/tests/test_detect.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
+
+pkg_postinst() {
+	optfeature "Language server for Python" dev-python/python-lsp-server
+}
diff --git a/dev-python/jupyter-server-proxy/Manifest b/dev-python/jupyter-server-proxy/Manifest
index 356c8ee07181..52e9f88897a0 100644
--- a/dev-python/jupyter-server-proxy/Manifest
+++ b/dev-python/jupyter-server-proxy/Manifest
@@ -1 +1,2 @@
 DIST jupyter-server-proxy-3.1.0.tar.gz 84326 BLAKE2B 8de532ba67ea3759e5997d93839b47cc962ddd1f58bb4b594e9949cd1d933147d01f3747b992aec192b84861cb64aeb214eae2ce649978a0faef66c54f9a96de SHA512 6914a322f37f383bc5276cc34607bdd53e2c754564e214cf5fd7295ba6e8e8c89f2f25b23e673e66f575f4cb5ffa757b64cbfd008bc69dffa0480b46be603e66
+DIST jupyter-server-proxy-3.2.0.tar.gz 122240 BLAKE2B 9638db24a6a1fafba361f6ba67f31f6e76735428506b10684f7f6b42675250abe2affae63efec1dad2b0ebd52db680f736e2dadcd736263c62e70d4d0d1bc728 SHA512 6c804300644a84edcde334fa254a4a4f6292f3b077e69e70400a14480bd44b0fb9e186952d0f69fc53e7eed1fb694b0d239a9e77d3dd051a9224df5e3de2544b
diff --git a/dev-python/jupyter-server-proxy/jupyter-server-proxy-3.2.0.ebuild b/dev-python/jupyter-server-proxy/jupyter-server-proxy-3.2.0.ebuild
new file mode 100644
index 000000000000..9ee46ce2b8d3
--- /dev/null
+++ b/dev-python/jupyter-server-proxy/jupyter-server-proxy-3.2.0.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Jupyter notebook server extension to proxy web services"
+HOMEPAGE="https://github.com/jupyterhub/jupyter-server-proxy"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+# The GitHub tarball includes the tests, but does not have the js stuff we need
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_server-1.0[${PYTHON_USEDEP}]
+	>=dev-python/simpervisor-0.4[${PYTHON_USEDEP}]
+"
+BDEPEND="dev-python/jupyter_packaging[${PYTHON_USEDEP}]"
+
+src_install() {
+	distutils-r1_src_install
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
diff --git a/dev-python/jupyter_core/Manifest b/dev-python/jupyter_core/Manifest
index 215774878a84..1a4ad534107b 100644
--- a/dev-python/jupyter_core/Manifest
+++ b/dev-python/jupyter_core/Manifest
@@ -1 +1,2 @@
 DIST jupyter_core-4.8.1.tar.gz 73579 BLAKE2B d5dcc89d948fa52f4a1b7c210585e9e5657004a431a4d177d7393d8283a9be86117e2c2452e4381399d1f479ae7b9ec4c5f891d09dd99c81768a64b69d8b182a SHA512 774612652537f46f486c0ae4157053463debcdc079d5e732865c729ef7fbab5f0d1b8da5d4e7cc1eda3a80250b43877d8f75889fa86330f951c61e3f8a7a29e2
+DIST jupyter_core-4.9.1.tar.gz 74787 BLAKE2B 3c902063c4d2819c8254eca87a64d922c3d1e408fc22e96d03765a8bb0fe644a9aafaccf3db106841becf307ffe47c9fcb723cad611833b5fcbe79e812ea2445 SHA512 3a176271e073448e3a15a69d51558486775abebec051e141594fe0d2859d9a0fc5cadbf6857764de6d1ec746f03d9d22419c91f97015d4ff6694626f455df773
diff --git a/dev-python/jupyter_core/jupyter_core-4.9.1.ebuild b/dev-python/jupyter_core/jupyter_core-4.9.1.ebuild
new file mode 100644
index 000000000000..5187c99fb838
--- /dev/null
+++ b/dev-python/jupyter_core/jupyter_core-4.9.1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Core common functionality of Jupyter projects"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="dev-python/traitlets[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		>=dev-python/ipython-4.0.1[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinxcontrib-github-alt
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# fails if jupyter is not in system sitedir
+	# (PYTHONPATH is insufficient)
+	jupyter_core/tests/test_command.py::test_not_on_path
+	jupyter_core/tests/test_command.py::test_path_priority
+	# assert '/usr/local/share/jupyter' == '/usr/share/jupyter'
+	jupyter_core/tests/test_paths.py::test_jupyter_path_user_site
+	jupyter_core/tests/test_paths.py::test_jupyter_path_no_user_site
+	# TODO
+	jupyter_core/tests/test_paths.py::test_jupyter_path_prefer_env
+)
diff --git a/dev-python/jupyter_server/Manifest b/dev-python/jupyter_server/Manifest
index 1c0509554a96..139fa6df49c3 100644
--- a/dev-python/jupyter_server/Manifest
+++ b/dev-python/jupyter_server/Manifest
@@ -1,3 +1,4 @@
 DIST jupyter_server-1.11.1.tar.gz 420035 BLAKE2B 0676b0e126752ebeaa45e2325c34fe787756265f5ad35e356660485e5e7fd98a9ecaa029badf4c45815f25425e5a8a44133b6595698dca212f871b898c6ef76c SHA512 537bb9dbacabe396761a17be3280ecc0d28d63116a72386a7ff69bd8467f38909b7c2491eeb1f6b8bb7618b7fe661cd583d9efb8597ecbe88941c35096e0b1a8
 DIST jupyter_server-1.12.0.tar.gz 422318 BLAKE2B 9aa4843d02bfd918b0df13d94fc0058e6a6dee74f634dac359f7f6b4ca85e6cd4f91e8ddafb873647cd672284fb3eff087e05c3fcb6eff1621c7beb4b99030ee SHA512 28de049051852ae5d2bc10f2a0643a1441c2df3c229348e8d45e7031cc1c85a118124bc0b3bf7f101fd912ee25cd9cbf3e9b1b633fee20d70f43152e1e03e12c
 DIST jupyter_server-1.12.1.tar.gz 422410 BLAKE2B 611f17fe9804b0279c60ecc4fc1c23e6548643e4f7aa8e120580e167dc58a1f2d98ed7f07b90927bf07a71a89829d5701bd296a8f5ad3e954e4e8ee20c95bd5f SHA512 b199be8b0590c4bd14e995e6c9933f6da4d33e1796203cc157fd42b111db5ec6e860ef321d8311c30995d8aba6f1803dd0fec9148ae9a1cf427b7e38924f5357
+DIST jupyter_server-1.13.1.tar.gz 423717 BLAKE2B 9524e6648365e9c4158a8af4a4b277b4673ca320fc8e2c101ef2797ad89ebe8f93d25b1e74193ed88b06d151621a2ab9d9622cd06d67d5bea3a9ba96a95eb8e0 SHA512 e42a93930d16adb3952a0f98e3ae399a50881c32ef78205922511ea702dc24ffbeae30058fb1445897c4cf52873af0c03be16276398581a3eff52b58739ed2ba
diff --git a/dev-python/jupyter_server/jupyter_server-1.13.1.ebuild b/dev-python/jupyter_server/jupyter_server-1.13.1.ebuild
new file mode 100644
index 000000000000..275cb03b7636
--- /dev/null
+++ b/dev-python/jupyter_server/jupyter_server-1.13.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Core services, APIs, and REST endpoints to Jupyter web applications"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=www-servers/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	dev-python/argon2-cffi[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.2.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_core-4.6.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-6.1.1[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	dev-python/nbconvert[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	>=dev-python/terminado-0.8.3[${PYTHON_USEDEP}]
+	dev-python/prometheus_client[${PYTHON_USEDEP}]
+	>=dev-python/anyio-3.1.0[${PYTHON_USEDEP}]
+	<dev-python/anyio-4[${PYTHON_USEDEP}]
+	dev-python/websocket-client[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+		dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+	)"
+
+# TODO: Package 'myst_parser'
+# distutils_enable_sphinx docs/source
+# 	dev-python/pydata-sphinx-theme
+distutils_enable_tests --install pytest
+
+python_prepare_all() {
+	# Defining 'pytest_plugins' in a non-top-level conftest is no longer supported:
+	mv jupyter_server/conftest.py . || die
+
+	# This fails if your terminal is zsh (and maybe other non-bash as well?)
+	sed -i \
+		-e 's:est_terminal_create_with_cwd:_&:' \
+		-e 's:test_culling:_&:' \
+		jupyter_server/tests/test_terminal.py || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/jupyterlab-lsp/Manifest b/dev-python/jupyterlab-lsp/Manifest
index d5438107a1fc..f570093e2000 100644
--- a/dev-python/jupyterlab-lsp/Manifest
+++ b/dev-python/jupyterlab-lsp/Manifest
@@ -1,2 +1,3 @@
 DIST jupyterlab-lsp-3.9.1.tar.gz 262645 BLAKE2B cd3377ea3abbb3f877b257140d5ac6b162aa9d4229cb58f67fa60a9b7f5db43de6873af381bac5bbf6103a47a53863ae322ad200550d73e5c19baa5eb2866aa2 SHA512 0289dc666a3ec3d93d276c67e95c19b0427e45a4f1e001180df4af9a72f7e81dddc8bdd175684f857dfc8e02935dbd31b454bfd0ee1431a8e702f662365c747e
 DIST jupyterlab-lsp-3.9.2.tar.gz 263499 BLAKE2B 2ece934e68b27e28161ee3218af2d11bd5b286b4c517ff8feb4f9ec10c261e51a95fb4d52de7717d896a7c4dbca9be168aa75ed8ab7728dd4844640417f31365 SHA512 c41045736cbf511f72668dc03c0fd1265c2b2e2f60a4e987fecd8e23be0a6af1ae7b341f6b0c47fb4f5956f00cbb982f8cd9f31ebca8098ce01cc21a8f0df357
+DIST jupyterlab-lsp-3.9.3.tar.gz 263515 BLAKE2B 0e2c4c13d6959d24357d140c0484494d1e2922864cf7c4ab58dff886560b627f2648f6cd2ac9f7fe64e3d86f0d26dfc76f413b376c6d2663df3f1396bcaf7fcf SHA512 4009ddd1754a74d031f91b29743c9a9ad21bb5260af066390e9987bca211a34d4a6f96ff863b4ab408133cea3df9464ea17bc3ff5cb5306b3ddfcba937843897
diff --git a/dev-python/jupyterlab-lsp/jupyterlab-lsp-3.9.3.ebuild b/dev-python/jupyterlab-lsp/jupyterlab-lsp-3.9.3.ebuild
new file mode 100644
index 000000000000..3b84dfe8eb34
--- /dev/null
+++ b/dev-python/jupyterlab-lsp/jupyterlab-lsp-3.9.3.ebuild
@@ -0,0 +1,21 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Coding assistance for JupyterLab with Language Server Protocol"
+HOMEPAGE="https://github.com/jupyter-lsp/jupyterlab-lsp"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/jupyterlab-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/jupyterlab-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-lsp-1.4.0[${PYTHON_USEDEP}]
+"
diff --git a/dev-python/jupyterlab_server/Manifest b/dev-python/jupyterlab_server/Manifest
index 58274e2e0a09..68146451b87b 100644
--- a/dev-python/jupyterlab_server/Manifest
+++ b/dev-python/jupyterlab_server/Manifest
@@ -1 +1,2 @@
+DIST jupyterlab_server-2.10.2.tar.gz 59380 BLAKE2B 9c4e29409d255192be18d891940cb499fe8949f1734ab2fb85c5656b2498d2ca999a0e10cc0e8aee796493882774ac78b2d1b57020ba6b4013959b49f0d03a38 SHA512 1c8779d587233503ae63e54197b66c0ff21abc158ef04370db09e587a168d380948a9711676bacc88c043a8f66e0c20e0d77b26519f998583775b8dfac7c88f4
 DIST jupyterlab_server-2.8.2.tar.gz 56188 BLAKE2B 8aadb2a01659151e0b2ada1fb235f4a3eee9fa1a1d6b046cbd1096c67971b1dab7d52c517f8b57b2b43c5c59b4fd37ed0a99ec75640fed6ebe3829812539fc7d SHA512 d35b8dad009f21aac6c0790e881ee4b7cc442b0762afcd10ab5fabccf417a6a4cd9ed1f54be5c3ad631823064a7c1a25112fe829b59e28ca8fc706b46c1b5603
diff --git a/dev-python/jupyterlab_server/jupyterlab_server-2.10.2.ebuild b/dev-python/jupyterlab_server/jupyterlab_server-2.10.2.ebuild
new file mode 100644
index 000000000000..8ac6578dedb6
--- /dev/null
+++ b/dev-python/jupyterlab_server/jupyterlab_server-2.10.2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Server components for JupyterLab and JupyterLab like applications"
+HOMEPAGE="https://jupyter.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# TODO: package openapi et al
+RESTRICT="test"
+
+RDEPEND="
+	dev-python/Babel[${PYTHON_USEDEP}]
+	>=dev-python/entrypoints-0.2.2[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10[${PYTHON_USEDEP}]
+	dev-python/json5[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.0.1[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/jupyter_server[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+# TODO: package myst_parser
+#distutils_enable_sphinx docs/source dev-python/pydata-sphinx-theme
+
+python_prepare_all() {
+	# Do not depend on pytest-cov
+	sed -i -e '/addopts/d' pyproject.toml || die
+
+	# Defining 'pytest_plugins' in a non-top-level conftest is no longer supported:
+	mv ${PN}/tests/conftest.py . || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/metakernel/Manifest b/dev-python/metakernel/Manifest
index 8664a6942e32..de02e35291ae 100644
--- a/dev-python/metakernel/Manifest
+++ b/dev-python/metakernel/Manifest
@@ -1 +1,2 @@
 DIST metakernel-0.27.5.tar.gz 186405 BLAKE2B 096d003639d54202aaa233460cd46a2b18984722d89ad3f6ff630802c8eda9080172610a788cac801da8aef6e9298b0d2a538b210a480653382c1e538f751585 SHA512 bce9b9dac82b68b6040ba73e2def08804d31114f21037eda3c845a4dc3b3e27e3895116c7c0227219452bf873cd0baf85b3c6492e6da64dba8541575e2800390
+DIST metakernel-0.28.2.tar.gz 197302 BLAKE2B 86d4464a8d796273aa831665fa7ecfcf7ed180fdb7d40448d9f3c84b96aa0baf36d8dd5771f702520b44786a1f3b031531430fb3c4687fbf498851817bfeb33e SHA512 5e41dbf5b3bc1121e2d2ba4a60cf3e2bd52c6c19f0965442115e241b1a261f441b01b29e5771539a9ef53a4fd421c58e8ac45296112e58c3a71e93a1e918cb17
diff --git a/dev-python/metakernel/metakernel-0.28.2.ebuild b/dev-python/metakernel/metakernel-0.28.2.ebuild
new file mode 100644
index 000000000000..08cbc232299d
--- /dev/null
+++ b/dev-python/metakernel/metakernel-0.28.2.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Metakernel for Jupyter"
+HOMEPAGE="https://github.com/Calysto/metakernel"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.2[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+PATCHES=( "${FILESDIR}"/${PN}-0.25.0-disable-brittle-tests.patch )
+
+python_prepare_all() {
+	# cannot import name 'MetaKernelPython' from 'metakernel_python' (unknown location)
+	rm generate_help.py || die
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/nbclassic/Manifest b/dev-python/nbclassic/Manifest
index 6c6ccb6b0124..0baa70ee5d41 100644
--- a/dev-python/nbclassic/Manifest
+++ b/dev-python/nbclassic/Manifest
@@ -1 +1,2 @@
 DIST nbclassic-0.3.3.tar.gz 21924 BLAKE2B 382d41c2eeb6ffc9588b80c0bc84e7e8b581fc36f2628d46577ca0a6956c50086a7b9a3bccb1c318fc60169a0367c8c5e1c6bba56b0a35fa063768f8fa580d52 SHA512 74b765c842351b2a93e92850193db7d3ef1a0b11c0c25a9adb2d1b8f7a6f88ae083cc700cda004d874340443632e738a24d26349d661613a707ad6cc42abd709
+DIST nbclassic-0.3.4.tar.gz 22308 BLAKE2B e5adddbd89f22ea1391149d97484f34c3f4d1a7601e471859834a06f5294868bbb23e96a536e792599f5743b68cb72bb91c88ba1e79d4fb4dc0f1ad6ee78041f SHA512 fe18a3523f7cf6bb411fe2e78f6bd0313e18a8a63a51649c99bdfc11365e2d775b8e6b879da1326c5389ab1a69e52a267cafa905348fead74b24a1d5d65e8646
diff --git a/dev-python/nbclassic/nbclassic-0.3.4.ebuild b/dev-python/nbclassic/nbclassic-0.3.4.ebuild
new file mode 100644
index 000000000000..6d2067f76821
--- /dev/null
+++ b/dev-python/nbclassic/nbclassic-0.3.4.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Jupyter Notebook as a Jupyter Server Extension"
+HOMEPAGE="https://jupyter.org/"
+SRC_URI="https://github.com/jupyterlab/nbclassic/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/jupyter_server[${PYTHON_USEDEP}]
+	<dev-python/notebook-7[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Defining 'pytest_plugins' in a non-top-level conftest is no longer supported:
+	mv ${PN}/conftest.py . || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	# move /usr/etc stuff to /etc
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
diff --git a/dev-python/numpy/metadata.xml b/dev-python/numpy/metadata.xml
index c93628f601f2..6ce213a34056 100644
--- a/dev-python/numpy/metadata.xml
+++ b/dev-python/numpy/metadata.xml
@@ -19,6 +19,7 @@
 </longdescription>
  <upstream>
   <remote-id type="pypi">numpy</remote-id>
+  <remote-id type="cpe">cpe:/a:numpy:numpy</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/psycopg/Manifest b/dev-python/psycopg/Manifest
index 5d8ac5309f1d..0b468d4b76a3 100644
--- a/dev-python/psycopg/Manifest
+++ b/dev-python/psycopg/Manifest
@@ -1,2 +1,3 @@
 DIST psycopg2-2.8.6.tar.gz 383797 BLAKE2B da0e3f1e143c51c940ba1f51d3e457b492d880ab71267dacd4747444bc767711ccd6c2f54d9e10ce5ad8fae0c3206fb4b6199f267e9bbaf12eb654227f59c2b0 SHA512 1e1d5d8755c6d1a153d84210bf29902afafe853659d709e13abc6bc5772def13779d2394690af1c544384c9c607edc0fe5cf2763244fb346febf9a9e0032b45f
 DIST psycopg2-2.9.2.tar.gz 380253 BLAKE2B f3b649986f8bec56df33858373e510ea69623fc38416f6344c7b63e4c82b412d24edd1b0cadcbf391e8920626ac86e81388e916711ab4d5c6dfc3f88070f5d8f SHA512 96b15db1a8c597dc7b6a725aa67952bcbac8e0e3d4f1cea97c7ffa14b272d21b4c16fd567edbbb4a01aa2c4b01c0bba562cdeea1f678aebf2139aa171dacd0a8
+DIST psycopg2-2.9.3.tar.gz 380611 BLAKE2B 78099da7378dcfa8b7f28aae4d533a7e890cdb7ae4c0cc718a9411e630fd07b56f074760fc29de8fe08fe727328cca39414a5f297fb92ed2f7471a24e633d18d SHA512 048184d1d162a371fc0fba711448a6fa8a6aac193421f4484c7f7b91c39065d5b632fa34fc15a901eca055d597302b1f9e38330b248ed0e4653dcdc544b0d660
diff --git a/dev-python/psycopg/psycopg-2.9.3.ebuild b/dev-python/psycopg/psycopg-2.9.3.ebuild
new file mode 100644
index 000000000000..6349f1cf0623
--- /dev/null
+++ b/dev-python/psycopg/psycopg-2.9.3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+MY_PN="${PN}2"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="PostgreSQL database adapter for Python"
+HOMEPAGE="https://www.psycopg.org https://pypi.org/project/psycopg2/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="LGPL-3+"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
+IUSE="debug test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=dev-db/postgresql-8.1:*"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	test? ( >=dev-db/postgresql-8.1[server] )"
+
+python_prepare_all() {
+	if use debug; then
+		sed -i 's/^\(define=\)/\1PSYCOPG_DEBUG,/' setup.cfg || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	initdb -D "${T}"/pgsql || die
+	# TODO: random port
+	pg_ctl -w -D "${T}"/pgsql start \
+		-o "-h '' -k '${T}'" || die
+	createdb -h "${T}" psycopg2_test || die
+
+	local -x PSYCOPG2_TESTDB_HOST="${T}"
+	distutils-r1_src_test
+
+	pg_ctl -w -D "${T}"/pgsql stop || die
+}
+
+python_test() {
+	"${EPYTHON}" -c "
+import tests
+tests.unittest.main(defaultTest='tests.test_suite')
+" --verbose || die "Tests fail with ${EPYTHON}"
+}
diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index d17acb7a3d51..4d6803fa2612 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -8,3 +8,4 @@ DIST setuptools-59.6.0.tar.gz 2281973 BLAKE2B 1e7ffc94626684f7e82a1bbba14889af05
 DIST setuptools-59.8.0.tar.gz 2282358 BLAKE2B 2f1b49285fc70420e24f958c4955200ef0407a7f3aa52fd581a165fd47c7bbde8366c26963f1bbb36f0f77797c12cbb9016fdc69e1a5cc696bb67aacca16d140 SHA512 d906558b498bda8abf28831224502c6f0290a4cdbf087fe07af8321dba3dfd1e19fa5b4a820033e54c4561b82ea8ec54c287b4fd657892ed28c2a7de91a9107e
 DIST setuptools-60.1.0.tar.gz 2281751 BLAKE2B d6302564ccb841232561c479959d2ed412888b49c07f774f194214ded659d7d45c5328570318ded9ff7eb81fc08e20b8be576f7a38099cfb855833955bbdb3a6 SHA512 9dba9022be345f5e0c9a915cfd8a24b441e813e703c817f40cd36236d1de1af8a5227acd886ca5910f1900e0c6ed5836f181117c11486009588a9777d6855032
 DIST setuptools-60.1.1.tar.gz 2282219 BLAKE2B 0e24774592fc10cccccd5b4be24ca11d7d2831962f7ca41e92c859488aeee6c133657a2971258d1954f8f1c6092459ea5e0fd7be549b0d74e5e2689b36f10571 SHA512 94804f82d1debbeefce0fc4101b9e9854425fd85ba59eec221c8f596826af8a44b03d80c367ff7948fd121f84573426c704140d6fdfc8c022040cc32ba14f634
+DIST setuptools-60.2.0.tar.gz 2282807 BLAKE2B 97d54353050d4e8a009e617a112c23d70726ad00625994d78639665f41245cee6f92544d5d5fc9962841ac0b2db3302ebbf0b5c6ee8f544f003fa05358c7ccf2 SHA512 9c7185843ead283ef97311018f1bb683c2e969f0333d5b246c7f1687c5ec6a9d6a2dafc39540ea7354e969d5a3f84e74c07dbce010970dd0ed46ebb48300a0bf
diff --git a/dev-python/setuptools/setuptools-60.2.0.ebuild b/dev-python/setuptools/setuptools-60.2.0.ebuild
new file mode 100644
index 000000000000..d386091769f9
--- /dev/null
+++ b/dev-python/setuptools/setuptools-60.2.0.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+# Set to 'manual' to avoid triggering install QA check
+DISTUTILS_USE_SETUPTOOLS=manual
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 multiprocessing
+
+CPY_PATCHSET="python-gentoo-patches-3.10.0_p1"
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="https://github.com/pypa/setuptools https://pypi.org/project/setuptools/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+	https://dev.gentoo.org/~floppym/python/${CPY_PATCHSET}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/jaraco-envs[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+		' python3_{8..10} pypy3)
+	)
+"
+PDEPEND="
+	>=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]"
+
+# Force in-source build because build system modifies sources.
+DISTUTILS_IN_SOURCE_BUILD=1
+
+DOCS=( {CHANGES,README}.rst )
+
+src_prepare() {
+	# apply distutils patches to the bundled distutils
+	pushd setuptools/_distutils >/dev/null || die
+	# TODO: distutils C++ patch?
+	eapply -p3 "${WORKDIR}/${CPY_PATCHSET}/0006-distutils-make-OO-enable-both-opt-1-and-opt-2-optimi.patch"
+	popd >/dev/null || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x SETUPTOOLS_USE_DISTUTILS=stdlib
+
+	# keep in sync with python_gen_cond_dep above!
+	has "${EPYTHON}" python3.{8..10} pypy3 || continue
+
+	distutils_install_for_testing
+	local EPYTEST_DESELECT=(
+		# network
+		setuptools/tests/test_distutils_adoption.py
+		'setuptools/tests/test_virtualenv.py::test_pip_upgrade_from_source[None]'
+		# unhappy with pytest-xdist?
+		setuptools/tests/test_easy_install.py::TestUserInstallTest::test_local_index
+		# TODO
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+		setuptools/tests/test_test.py::test_tests_are_run_once
+	)
+
+	# test_easy_install raises a SandboxViolation due to ${HOME}/.pydistutils.cfg
+	# It tries to sandbox the test in a tempdir
+	HOME="${PWD}" epytest \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" setuptools
+}
+
+python_install() {
+	export DISTRIBUTE_DISABLE_VERSIONED_EASY_INSTALL_SCRIPT=1
+	distutils-r1_python_install
+}
diff --git a/dev-python/virtualenv/Manifest b/dev-python/virtualenv/Manifest
index c571b96f5701..1899cf67a8c6 100644
--- a/dev-python/virtualenv/Manifest
+++ b/dev-python/virtualenv/Manifest
@@ -1,2 +1,3 @@
 DIST virtualenv-20.10.0.tar.gz 9007218 BLAKE2B 1fd37b38679b7375c1eb6e9644418b1653cb6a8dab194c8553fa113cf4a801a7c1d5e6490067767cfb198a0ef2b5ab9cf166783b9c6fac0b2c8b538949c11804 SHA512 df940aa29801a39d39be46d3518a99e93efb2113650abf81d00b4545183ec6806823ce8b754c5a3c951cb64e941944421046c709ed3de6a925489e5ac1988d48
 DIST virtualenv-20.11.1.tar.gz 9952979 BLAKE2B d8e44f5a8fedfca4eed79798be74ccfca86af2cacc076d797832028363c2d5269194e711d4511a415420285bc408373a641248a5a96cfaea326f60e023129d65 SHA512 c378bd088d9f2f6a07128d6d04b71554ad7c4de6227baea68ea486c8e10c99c40818eb9bf98cb4c950e64d0aeed4d2be40c101fbd6005d48d2eccaea0382d581
+DIST virtualenv-20.11.2.tar.gz 9953645 BLAKE2B 8bd0e5bee4fad2cdb13b1ce3e018191ef69993c9d1c66332c74908483802b2d1aff1ea1ef9acd4d94b17cacc9ae4c4014ded6ac0e7df4ea807d050d1243d5464 SHA512 18f9c6e50aa6d7b7060163b23332d7e9140199e525f7fb4efe99e84dfb298413889f4516b6e942d3e05a667774093ed521cc757a67a1698138cb793b9798a46f
diff --git a/dev-python/virtualenv/virtualenv-20.11.2.ebuild b/dev-python/virtualenv/virtualenv-20.11.2.ebuild
new file mode 100644
index 000000000000..be2cf623ac94
--- /dev/null
+++ b/dev-python/virtualenv/virtualenv-20.11.2.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+DISTUTILS_USE_SETUPTOOLS=manual
+
+inherit distutils-r1
+
+DESCRIPTION="Virtual Python Environment builder"
+HOMEPAGE="
+	https://virtualenv.pypa.io/en/stable/
+	https://pypi.org/project/virtualenv/
+	https://github.com/pypa/virtualenv/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/backports-entry_points_selectable-1.0.4[${PYTHON_USEDEP}]
+	>=dev-python/distlib-0.3.1[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-41[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]"
+# coverage is used somehow magically in virtualenv, maybe it actually
+# tests something useful
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		>=dev-python/pip-20.0.2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-freezegun-0.4.1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-1.3.4[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+		>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+	)"
+
+# (unpackaged deps)
+#distutils_enable_sphinx docs \
+#	dev-python/sphinx-argparse \
+#	dev-python/sphinx_rtd_theme \
+#	dev-python/towncrier
+distutils_enable_tests pytest
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		tests/unit/activation/test_xonsh.py
+		tests/unit/seed/embed/test_bootstrap_link_via_app_data.py::test_seed_link_via_app_data
+		tests/unit/create/test_creator.py::test_cross_major
+	)
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-pypy3-posix-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-pypy3-posix-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-pypy3-posix-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-pypy3-posix-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-venv-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-venv-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-venv-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-venv-copies-global]'
+		'tests/unit/create/test_creator.py::test_zip_importer_can_import_setuptools'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.9-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.9--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.10-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.10--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.9-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.9--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.10-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.10--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3--bin-]'
+	)
+
+	distutils_install_for_testing
+	epytest
+}
+
+pkg_postinst() {
+	elog "Please note that while virtualenv package no longer supports"
+	elog "Python 2.7, you can still create py2.7 virtualenvs via:"
+	elog "  $ virtualenv -p 2.7 ..."
+}