Adding metadata

14 files changed, 525 insertions, 0 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index f65f37251ae7..5a16f6bee894 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -3,3 +3,4 @@ DIST boto3-1.34.144.gh.tar.gz 840506 BLAKE2B 7fccc6ae45dec6411995795dc7dd180cec5
 DIST boto3-1.34.145.gh.tar.gz 841776 BLAKE2B e93a6c4d634c2df22ed27e58c2abe0a6cc835364b4a93c73c8c221ba39b63b89c5f3ddbf210eb90a451c9b6650061f08a173395f1fb3cd4abe8fde90347b4c63 SHA512 ebd85e3068d1ad332b2ed4c2ad45c022fadb090f8aacdcd72c0d515f91b218201afd69750281b68c909dbf2ab35bef3a39412a616f5b134780f15c0cc9854123
 DIST boto3-1.34.146.gh.tar.gz 842332 BLAKE2B 1e718ca3ae9c59f8528a8e944d1a1e596a595c6ae0d1c7ec83aa47a429f03fe14f9a173772590dc1134fe64bfa471a2cfcf729db107bb19a80fa15b8d13f804a SHA512 ec1fc0bc4aa528a9f93e5ec9ce2b582b6c7c79967097f39c4eb9895486569f2953235867b7f88a593040fd614a37e05fd9d91db107e28106b6d6ff0ea1b5a0c9
 DIST boto3-1.34.147.gh.tar.gz 842874 BLAKE2B 22363cdc4acce00cce16a78a30c0121b0046f309ea9bda21a45880bf5abd19a8177ee7376393b85b3283a8a6ea27931bea21a2f97a4c59d087a4a2aff45dfc6f SHA512 90eda840237b3e968913800de4978ce6bafe3393d7076af4eacfd0851d09358859d5025daacf789b47f984a29d1036af9620f6cac9f12639a041a964ad840aee
+DIST boto3-1.34.148.gh.tar.gz 843651 BLAKE2B 78bc66b075d5df39b6f800a25d00c7c98e2f1c1c31a756453843b4809cc1dbd5fa7714e081d7533bf4671dde9eb69f82c8ed35183e9656613b9bfc3abe4c5eb8 SHA512 dfa5b1eaf9dc510fe03ae855604ed0d1ab5f7aa1df1c57b6ff088a6eb2dcdc62ad855156e13ec7f427700b04105753f907fe1ce0e43d4957ca0cc810c1bbc33a
diff --git a/dev-python/boto3/boto3-1.34.148.ebuild b/dev-python/boto3/boto3-1.34.148.ebuild
new file mode 100644
index 000000000000..509842b2699d
--- /dev/null
+++ b/dev-python/boto3/boto3-1.34.148.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+SRC_URI="
+	https://github.com/boto/boto3/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.10.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 9af5fc75d6fd..e066c64ae76e 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -3,3 +3,4 @@ DIST botocore-1.34.144.gh.tar.gz 13221134 BLAKE2B 9b688a781ad80f294c147ce4aacc31
 DIST botocore-1.34.145.gh.tar.gz 13230154 BLAKE2B ebcf6acdd7ab01bca4032eaa9bc94fd72807edb3b0ce7cdc7addc4bed9a3500627b95d95e69c3027ecb384e65d95c0955e71a0e3262d89e3e8d49eefc37e9aaf SHA512 96042253f2f5ec74b258327c3c4eb322a8ed534ac8ed78f38a5aafb3a97ce832bfe5184090a2dadd41e30b75bf35c463d8d80c3de72a46410656d62076469650
 DIST botocore-1.34.146.gh.tar.gz 13225796 BLAKE2B e59b6192e4fe3e7d0305b43f869049a864909211a3a507a64bca662988c5d982c98f911e272f7928032c7a5b313b7538bd4eaac5f4a43071b5add58c07252c49 SHA512 3032c453bcaac696dfae811880a5ff036ef0f0cd47450d6509aa9f7cd45e6fab043819f73544c4de1b44e59c5e0e8d388c3e99ff9b180912a209d6c1903d737f
 DIST botocore-1.34.147.gh.tar.gz 13233174 BLAKE2B dfb8ad5f0f98bb69805cd9d229545125e0da0b7f57cea070d9c2c10ef7afdfb47deb2c9477fb0e97459b2eff31f959f57137ef210230291ea6b2d5c5b08e0252 SHA512 f0ffd3b350333cf62a1eacce0ea2c3e2a96f1d497b57cb419a539867709aceae6af615af24245659b186a8ad5c18a4f57708241b78ff077258768d8b72562ea0
+DIST botocore-1.34.148.gh.tar.gz 13237574 BLAKE2B 5f0ba1e3c2979a24ef326913367700b5172407714cb0d07b35944a167ad8d0c21e23c41fd3b78faa1aa283633738ea6d2271cec31e3bbb1547fa60a166252f0e SHA512 2caae5680f65fc7750d48ed42c71a8522f7d1555dd0d3d2b6041d47037286c8ed1bb0c1a08b7ee0504fccedffd7568ef27b6d8ee6d1da1425d73d4db13ad7437
diff --git a/dev-python/botocore/botocore-1.34.148.ebuild b/dev-python/botocore/botocore-1.34.148.ebuild
new file mode 100644
index 000000000000..64a61a30c80b
--- /dev/null
+++ b/dev-python/botocore/botocore-1.34.148.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+SRC_URI="
+	https://github.com/boto/botocore/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+# unbundled packages
+RDEPEND+="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	case ${EPYTHON} in
+		python3.13)
+			EPYTEST_DESELECT+=(
+				# memory use tests, probably fragile
+				tests/functional/leak/test_resource_leaks.py::TestDoesNotLeakMemory
+			)
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/importlib-metadata/Manifest b/dev-python/importlib-metadata/Manifest
index 05309042f261..2a04c2d6c864 100644
--- a/dev-python/importlib-metadata/Manifest
+++ b/dev-python/importlib-metadata/Manifest
@@ -1,3 +1,4 @@
 DIST importlib_metadata-7.1.0.tar.gz 52120 BLAKE2B a43a1f0724b3197f51c055d36d31700d67b3bcae849fd648c7cd1ac158a410fdf05a27f2c7003a30e566f86ec5dcbf7cf386ebe4e0ed0a1ce2e89e280ab9e1d3 SHA512 e75db6da03c251acc690ceef6ab2b668acfcf5499032cff370a574b31a5fd7afcbf9756bc20e44e6e649767c1609c7ebb40203aa6406ec5341f27fba886d208e
 DIST importlib_metadata-8.0.0.tar.gz 52667 BLAKE2B 5ca77157938dcced0c32a526e760a2d29bae5c34fa5a8f5711f3746278a9843ca85d82405eafe18821b5f7956bf75cdb2b619db903be8de96d60462b4af7fb62 SHA512 07245e6ba3f47ecc7ff4201b2dd24e6970317fe7ef0a39d74a66de180269f480c09e12601738c7c11e720a2e7c78347871ff83700c7f796a01fb1a12c8e46ff6
 DIST importlib_metadata-8.1.0.tar.gz 53881 BLAKE2B b441a78e12b1f2f360deeed5d54d2694d97994881ee18a5e7c2790c96d25b433385fe20b38b70b075ced138853ac242792e098105f53c40d7f749864d06c511f SHA512 98a5f72eab0871b55a394de5e18ab74c225515620eed62ee0273de2c23607566af7a449ffc4b3900f8d0fd8e6eb7bd2a893666c1b459f9f07b700319a7236ac0
+DIST importlib_metadata-8.2.0.tar.gz 53907 BLAKE2B 3864e1fcea4f0c30134c401f787b83500b8c13860a69784f769a67d1db1d4345c8a289fec2a21812f29dc3f07c522836dc1271f33eaf4592bcb709561f0adbe6 SHA512 cc0467f5ac95503b4fcbce6bf0b4211a5bf9ba8389a714c6d0cb3f35756b7c5bcb6359873cfeb1dbd068b0a41ddf57b27a564aeaad9bc17cb8a5e4d71fa12e8a
diff --git a/dev-python/importlib-metadata/importlib-metadata-8.2.0.ebuild b/dev-python/importlib-metadata/importlib-metadata-8.2.0.ebuild
new file mode 100644
index 000000000000..ce9e2dc50049
--- /dev/null
+++ b/dev-python/importlib-metadata/importlib-metadata-8.2.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+# NB: this package extends beyond built-in importlib stuff in py3.8+
+# new entry_point API not yet included in cpython release
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Read metadata from Python packages"
+HOMEPAGE="
+	https://github.com/python/importlib_metadata/
+	https://pypi.org/project/importlib-metadata/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+
+RDEPEND="
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/jaraco-test-5.4[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pyfakefs[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_configure() {
+	grep -q 'build-backend = "setuptools' pyproject.toml ||
+		die "Upstream changed build-backend, recheck"
+	# write a custom pyproject.toml to ease setuptools bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "importlib_metadata"
+		version = "${PV}"
+		description = "Read metadata from Python packages"
+	EOF
+}
diff --git a/dev-python/numpydoc/Manifest b/dev-python/numpydoc/Manifest
index 151561e8acfc..2a55279af042 100644
--- a/dev-python/numpydoc/Manifest
+++ b/dev-python/numpydoc/Manifest
@@ -1 +1,2 @@
 DIST numpydoc-1.7.0.gh.tar.gz 87818 BLAKE2B b31e9478324bc45d78904c16330c9ed1513eca5668f20472faf9e2a36c0ed7eb03b18cf1c314180ec35716a26bd05357d5ef93025efbb8fb09c885a614ac7ea9 SHA512 0858d7eaafdd93d5a0894bb107b8238f75bd7cd34afa64fee38effcf4bebf9b4db957768143a46eec46023e69b53599a79b07a39640887f3a0471b5996022247
+DIST numpydoc-1.8.0rc2.gh.tar.gz 90642 BLAKE2B cf47c0a2865ab5579c7f095607a58fe3db4e64ccf521e052797e4286d74351017ebe9c300b968f3f2f799fc0fc07f3d8eebbef59e1f1aab269ededf6d0a8bd12 SHA512 f323ca5fc62ba37af10a8d892b22a348ca3b2ecd9faa3bd885f0b233f51e169e8d86eb364bd0155bb8c9daee9185866f962e586123758555dae03ef46f437450
diff --git a/dev-python/numpydoc/numpydoc-1.8.0_rc2.ebuild b/dev-python/numpydoc/numpydoc-1.8.0_rc2.ebuild
new file mode 100644
index 000000000000..1346548324a1
--- /dev/null
+++ b/dev-python/numpydoc/numpydoc-1.8.0_rc2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="Sphinx extension to support docstrings in Numpy format"
+HOMEPAGE="
+	https://numpydoc.readthedocs.io/en/latest/
+	https://github.com/numpy/numpydoc/
+	https://pypi.org/project/numpydoc/
+"
+SRC_URI="
+	https://github.com/numpy/numpydoc/archive/v${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/sphinx-6[${PYTHON_USEDEP}]
+	>=dev-python/tabulate-0.8.10[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	test? (
+		>=dev-python/matplotlib-3.2.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# these require Internet (intersphinx)
+		numpydoc/tests/test_full.py::test_MyClass
+		numpydoc/tests/test_full.py::test_my_function
+		# TODO
+		numpydoc/tests/test_validate.py::test_extract_ignore_validation_comments
+	)
+	epytest -o addopts= --pyargs numpydoc
+}
diff --git a/dev-python/regex/Manifest b/dev-python/regex/Manifest
index 71d89549d628..71e4affdaf42 100644
--- a/dev-python/regex/Manifest
+++ b/dev-python/regex/Manifest
@@ -1 +1,2 @@
 DIST regex-2024.5.15.tar.gz 394856 BLAKE2B 8990bbc78f7f9c6a4dc07d913ec5557a4cd1bac022bc71093e3d8083b5d547182e08f2e8189c3808d8e368ed42530578df9951367b59dc3450bb09458b57f496 SHA512 7e465987bff529a6895cd6606b5a188c0fb2cdf333de108a4e3e37c7badeea146fd23d1d757f47b65d4facdc30cbdb0ca3c0df2395124c8e3e6946a98f52f413
+DIST regex-2024.7.24.tar.gz 393485 BLAKE2B d2a46fe2039f78fc3f1e8cda1b7b1808b160018d8e0c1b880bb1a573b36a3e1e7c7ccfa238f99719b5a484fa3b7457109f9e8668fbf16cbaef52006e0e6f6f89 SHA512 7b9efc5bdefa6610862be06831404380939dfffad6e2a488d362f4a247356eb0739c2b9078f41e554eca21d64fd4b1b145291ca8140f18d1586328f7d19cefc9
diff --git a/dev-python/regex/regex-2024.7.24.ebuild b/dev-python/regex/regex-2024.7.24.ebuild
new file mode 100644
index 000000000000..141086a0dd4b
--- /dev/null
+++ b/dev-python/regex/regex-2024.7.24.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+# pypy isn't supported upstream because of its UTF8 representation for strings
+# See https://github.com/mrabarnett/mrab-regex/issues/521#issuecomment-1936260187.
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Alternative regular expression module to replace re"
+HOMEPAGE="
+	https://github.com/mrabarnett/mrab-regex/
+	https://pypi.org/project/regex/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+IUSE="doc"
+
+distutils_enable_tests unittest
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/Features.html )
+	local DOCS=( README.rst docs/*.rst )
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index 1d6e00a9df4d..da36c871619f 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -2,3 +2,4 @@ DIST sphinx-7.2.6.gh.tar.gz 7067425 BLAKE2B 4da1cb5ccebea4df0dc134c552311d7b70ce
 DIST sphinx-7.3.7.gh.tar.gz 7165383 BLAKE2B bcc68f26937e6aefe60cedea533a5c8e245c76b59ab4913fb6516f285e3afc32be60b336c662ac8305fb88e82fcc2b477128f2d8b9bf92f037b124f4c855df2a SHA512 540553ecddc55b3e673c79bc776a899d2c660f1e93ef819711be52174accf5b70465883a46bed81d163534e56718caf0765b4bae153e9307a3792387d8228df5
 DIST sphinx-7.4.6.gh.tar.gz 8187130 BLAKE2B 69cf73dc3644ac0fbb4e2d26ee07652b4a16bb2d87fba1a6f5a3dba74533af470d2449658eb7029479618d47ea34d6dc896126cfe330d31b343c0a3300ba90b3 SHA512 7015aa5b926856e1e3ed35b559a78dbeb8a1746028f4a488a3237c65ea5eb786a9feff05649b8126395c6f8277802a093c704ca13e941d3aab561b2fca8b0de8
 DIST sphinx-7.4.7.gh.tar.gz 8135111 BLAKE2B b5a511355b16edfbcf32f9a20855466251c592a7fbffa33a84d84369f2a9de7767cd9529cce3f350cdf25bfbb53534ddea70d9482c1d6d78e9ab160d2c9821e8 SHA512 bfb48d4dc09f108986c5b7737710c7495fbdd83eb18f2a1c77bc9d324c499bffb5103f65ebf7396260f10c0f89eddb1ae5eb8d037bd33fffd748483f4391a7e1
+DIST sphinx-8.0.0rc1.gh.tar.gz 8139326 BLAKE2B 3cb69ece3d6f85ceebd494abe9ae11a76b3473eca52611b197cd3a34985e37bc0275c9c194d87ca529a63d46976c9624ff9270734b638f8cbfb81c25f5fee0be SHA512 cd7e1b01a2a6dcc3106aef6f110bbd1c4cc06865e7c20c85e65b191128c4a28c836c5401f02e6a812317033b97ff4f683948b78d3edd56fbb8d12d6a7ada52f6
diff --git a/dev-python/sphinx/sphinx-8.0.0_rc1.ebuild b/dev-python/sphinx/sphinx-8.0.0_rc1.ebuild
new file mode 100644
index 000000000000..e1702504343d
--- /dev/null
+++ b/dev-python/sphinx/sphinx-8.0.0_rc1.ebuild
@@ -0,0 +1,144 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="
+	https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinx/
+	https://pypi.org/project/Sphinx/
+"
+SRC_URI="
+	https://github.com/sphinx-doc/sphinx/archive/v${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc latex"
+
+RDEPEND="
+	>=dev-python/alabaster-0.7.14[${PYTHON_USEDEP}]
+	>=dev-python/Babel-2.13[${PYTHON_USEDEP}]
+	<dev-python/docutils-0.22[${PYTHON_USEDEP}]
+	>=dev-python/docutils-0.20[${PYTHON_USEDEP}]
+	>=dev-python/imagesize-1.3[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-23.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.14[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.30.0[${PYTHON_USEDEP}]
+	>=dev-python/snowballstemmer-2.2[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-htmlhelp-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-serializinghtml-1.1.9[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2[${PYTHON_USEDEP}]
+	' 3.10)
+	latex? (
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)
+"
+BDEPEND="
+	doc? (
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)
+	test? (
+		app-text/dvipng
+		>=dev-python/cython-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/defusedxml-0.7.1[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		>=dev-python/setuptools-67.0[${PYTHON_USEDEP}]
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		virtual/imagemagick-tools[jpeg,png,svg]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/sphinx-3.2.1-doc-link.patch"
+	#"${FILESDIR}/sphinx-4.3.2-doc-link.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# disable internet access
+	sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+		doc/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# we can't use distutils_enable_sphinx because it would
+	# introduce a dep on itself
+	use doc && build_sphinx doc
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+	local EPYTEST_DESELECT=(
+		# less interesting failures
+		tests/test_builders/test_build_latex.py::test_build_latex_doc
+		tests/test_extensions/test_ext_math.py::test_imgmath_png
+		tests/test_extensions/test_ext_math.py::test_imgmath_numfig_html
+	)
+	case ${EPYTHON} in
+		python3.13x)
+			EPYTEST_DESELECT+=(
+				tests/test_extensions/test_ext_autodoc.py::test_autodoc_special_members
+				tests/test_extensions/test_ext_autodoc_configs.py::test_autodoc_type_aliases
+				tests/test_extensions/test_ext_autodoc_configs.py::test_autodoc_typehints_format_fully_qualified
+				tests/test_extensions/test_ext_autodoc_configs.py::test_autodoc_typehints_none
+				tests/test_extensions/test_ext_autodoc_configs.py::test_autodoc_typehints_signature
+			)
+			;;
+		pypy3)
+			EPYTEST_DESELECT+=(
+				tests/test_extensions/test_ext_autodoc.py::test_autodoc_exception
+				tests/test_extensions/test_ext_autodoc.py::test_autodoc_ignore_module_all
+				tests/test_extensions/test_ext_autodoc.py::test_autodoc_inherited_members_None
+				tests/test_extensions/test_ext_autodoc.py::test_autodoc_subclass_of_builtin_class
+				tests/test_extensions/test_ext_autodoc.py::test_automethod_for_builtin
+				tests/test_extensions/test_ext_autodoc.py::test_cython
+				tests/test_extensions/test_ext_autodoc.py::test_format_signature
+				tests/test_extensions/test_ext_autodoc.py::test_partialfunction
+				tests/test_extensions/test_ext_autodoc_autoclass.py::test_autodoc_process_bases
+				tests/test_extensions/test_ext_autodoc_autoclass.py::test_show_inheritance_for_decendants_of_generic_type
+				tests/test_extensions/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
+				tests/test_extensions/test_ext_autodoc_autofunction.py::test_builtin_function
+				tests/test_extensions/test_ext_autodoc_autofunction.py::test_methoddescriptor
+				tests/test_extensions/test_ext_autodoc_automodule.py::test_automodule_inherited_members
+				tests/test_extensions/test_ext_autodoc_preserve_defaults.py::test_preserve_defaults_special_constructs
+				tests/test_extensions/test_ext_autosummary.py::test_autosummary_generate_content_for_module
+				tests/test_extensions/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
+				tests/test_util/test_util_inspect.py::test_isattributedescriptor
+				tests/test_util/test_util_inspect.py::test_signature
+				tests/test_util/test_util_typing.py::test_is_invalid_builtin_class
+			)
+			;;
+	esac
+
+	# note: pytest-xdist causes random test failures
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p rerunfailures --reruns=5
+}
diff --git a/dev-python/uv/Manifest b/dev-python/uv/Manifest
index a01568fbdaa4..5119709a5943 100644
--- a/dev-python/uv/Manifest
+++ b/dev-python/uv/Manifest
@@ -10,3 +10,5 @@ DIST uv-0.2.26.gh.tar.gz 1401835 BLAKE2B 24d4fdb7f332635293235602ba117167432aa9d
 DIST uv-0.2.27.gh.tar.gz 1421504 BLAKE2B 18bbc260d57a12c9265da8bf9d566678cba95374db22a6aca0d66550eb23d09490814111763876cf8db97671899d9ccbe121df9d7cadd357d2275199569e33a7 SHA512 86fdc58c6a0fa93c77c8dd08a58385702ed16a6421658d3d97fcf1011bf6bc562161e4e0ad8d021417e2e0cd3860bfc0384aa9550b1c5bce52aa3cb32b1f8539
 DIST uv-0.2.28-crates.tar.xz 56802104 BLAKE2B c0eed0eb3405a9a06918091926864731b35060e1a67e28a8916090c5f61c76633ca78584270003212efe892727f0e53951385a1bb0df337044aa3996492d6e82 SHA512 10e233add9062ec4a9ca73bc13bb8dc85ffa109a432d7001d009a882c0edc1ed6a5a31c53dba012bc825bec855290d085ea17e797e9bc3335c8f5268a17d0a56
 DIST uv-0.2.28.gh.tar.gz 1448749 BLAKE2B 162f07ff36f1e4edb036fe10ab2f17b8aeefb0e11fbd2a6b15d48f1d77c9986bf24930c8f9e111d470f1d0344d97f970aeb50bfa8e0362974c06f21b4723f8ad SHA512 ca2e25e0e3edd15d033516aa2f1ad799e6008bd96045443d011c2da8c29813192152e2b60d242cd13491b2248f9bb9c2d793c93c379e73e2249190ae9b180615
+DIST uv-0.2.29-crates.tar.xz 48592012 BLAKE2B 57492ede8b970171fc00c4f07ff3e9cb39dcd8bbf52433ed966963838bb9af14bfc9fc52ef5ec7e7a01af74598f066bfb5461d683a69390256fab3b69f08360a SHA512 aef3ee357dfc66a2b04967cd4526a5f07ce09e6ea949641ef1934fb774133b93b106c8e5f255bba92fd375b3f1996b7b016682e9e8f1c9afa871781af163e095
+DIST uv-0.2.29.gh.tar.gz 1468793 BLAKE2B b69397a9fa0fb855a876d5c0322c53c01c400f023bae681e9347a5dde13e5d844da06b9016af5aab7ccc1e3482f2a2004f5efcad4887291ee28c455f6198ac31 SHA512 83b34496868cdd903122140ed28d8cf4e503f7be1848ce711aa98e9019a62ce82607b9a7eba189194024f21e376f61805e42d6b8c4544ff7d1a14212e99f5bc1
diff --git a/dev-python/uv/uv-0.2.29.ebuild b/dev-python/uv/uv-0.2.29.ebuild
new file mode 100644
index 000000000000..f3cf0860cc38
--- /dev/null
+++ b/dev-python/uv/uv-0.2.29.ebuild
@@ -0,0 +1,109 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES="
+"
+
+declare -A GIT_CRATES=(
+	[async_zip]='https://github.com/charliermarsh/rs-async-zip;1dcb40cfe1bf5325a6fd4bfcf9894db40241f585;rs-async-zip-%commit%'
+	[pubgrub]='https://github.com/astral-sh/pubgrub;3f0ba760951ab0deeac874b98bb18fc90103fcf7;pubgrub-%commit%'
+	[reqwest-middleware]='https://github.com/astral-sh/reqwest-middleware;21ceec9a5fd2e8d6f71c3ea2999078fecbd13cbe;reqwest-middleware-%commit%/reqwest-middleware'
+	[reqwest-retry]='https://github.com/astral-sh/reqwest-middleware;21ceec9a5fd2e8d6f71c3ea2999078fecbd13cbe;reqwest-middleware-%commit%/reqwest-retry'
+)
+
+inherit cargo check-reqs
+
+CRATE_PV=0.2.29
+DESCRIPTION="A Python package installer and resolver, written in Rust"
+HOMEPAGE="
+	https://github.com/astral-sh/uv/
+	https://pypi.org/project/uv/
+"
+# pypi sdist misses scripts/, needed for tests
+SRC_URI="
+	https://github.com/astral-sh/uv/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	${CARGO_CRATE_URIS}
+"
+if [[ ${PKGBUMPING} != ${PVR} ]]; then
+	SRC_URI+="
+		https://dev.gentoo.org/~mgorny/dist/uv-${CRATE_PV}-crates.tar.xz
+	"
+fi
+
+# most of the code
+LICENSE="|| ( Apache-2.0 MIT )"
+# crates/pep508-rs is || ( Apache-2.0 BSD-2 ) which is covered below
+# Dependent crate licenses
+LICENSE+="
+	0BSD Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD ISC MIT
+	MPL-2.0 Unicode-DFS-2016
+"
+# ring crate
+LICENSE+=" openssl"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="test"
+PROPERTIES="test_network"
+
+BDEPEND="
+	>=virtual/rust-1.77
+	test? (
+		dev-lang/python:3.8
+		dev-lang/python:3.9
+		dev-lang/python:3.10
+		dev-lang/python:3.11
+		dev-lang/python:3.12
+	)
+"
+
+QA_FLAGS_IGNORED="usr/bin/.*"
+
+check_space() {
+	local CHECKREQS_DISK_BUILD=3G
+	use debug && CHECKREQS_DISK_BUILD=9G
+	check-reqs_pkg_setup
+}
+
+pkg_pretend() {
+	check_space
+}
+
+pkg_setup() {
+	check_space
+}
+
+src_prepare() {
+	default
+
+	# remove patch.* that breaks GIT_CRATES
+	sed -i -e "/^\[patch/,\$s@^\(reqwest-middleware = \).*@\1 { path = \"${WORKDIR}/reqwest-middleware-21ceec9a5fd2e8d6f71c3ea2999078fecbd13cbe/reqwest-middleware\" }@" Cargo.toml || die
+
+	# https://github.com/vorot93/tokio-tar/pull/23
+	# (fortunately uv already depends on portable-atomic, so we don't
+	# have to fight Cargo.lock)
+	cd "${ECARGO_VENDOR}/tokio-tar-0.3.1" || die
+	eapply "${FILESDIR}/tokio-tar-0.3.1-ppc.patch"
+}
+
+src_compile() {
+	cd crates/uv || die
+	cargo_src_compile
+}
+
+src_test() {
+	# work around https://github.com/astral-sh/uv/issues/4376
+	local -x PATH=${BROOT}/usr/lib/python-exec/python3.12:${PATH}
+	local -x COLUMNS=100
+
+	cd crates/uv || die
+	cargo_src_test --no-fail-fast
+}
+
+src_install() {
+	cd crates/uv || die
+	cargo_src_install
+}