Adding metadata

19 files changed, 716 insertions, 32 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index f99ec54dd9c4..60678dd3b5c5 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -4,3 +4,4 @@ DIST boto3-1.20.46.tar.gz 464857 BLAKE2B 40eb0f2c298821530028c84f90d8acd9757a4b6
 DIST boto3-1.20.47.tar.gz 465774 BLAKE2B ab615d29d79b209671808770968c38c2ef26b83ae48d1e18c3129c2886a274ae8a9fc7680fa851f205c28161bd16b20eef075c1a6cdbc5cfaf835c7ead974313 SHA512 c3a84ba9df6670879605e9085ea7aa15077d9f1c30117de6e9cd9cbb427a6a06097a388feb80a0ebc7ad1f422a40df402986d3dc9b004abf5252dab16524c761
 DIST boto3-1.20.48.tar.gz 466063 BLAKE2B 7ba92d1cfbd576d4262e0f99a9e9aa118747fbbe60caa703c14f24559d4c2312b3e7695c40b6555bd58f7beb248e7ecfcedd64bc84badb44cb96812c9537cabe SHA512 e80f2e54909a3a54e5eba9c9a75c0ccbb2ba3f8907dfec9563f50bef1be56b82b593ae0bc0ee0bfab1a7c993d4bbf0c624486822ef3cd93ef425f39205b628f0
 DIST boto3-1.20.49.tar.gz 466426 BLAKE2B 82f2ed7f14576afd5a4d2dab91b99986904fef97b98460dce152e0806cb20e39b14975e4c3362c9d208c4dce9de3e7a4fa9fa60559aa0007ff735ce9e43995e4 SHA512 6ea92236726b9200a8b06f773483b0d6803585480cfad1f68eab227598ca86c3aa93cbeccec5338febc52eb48691f003c5983d52be56dd91e97735ddbfac7053
+DIST boto3-1.20.50.tar.gz 466795 BLAKE2B 662284de4654781391605fba93f401ec24300abab696c02146739598e9206598e92539ff9468f99b108d3ac00f72555945986e04e2b6625baace11b8f9b746ef SHA512 103a75edc907ea9a7ed5d08bb8a2f31b1360495a130d0492461956c0ec5c1e1b839187d9d9feaebf7eb06e2d367f9fcdc1c522c234be3314fceca7884651d54e
diff --git a/dev-python/boto3/boto3-1.20.50.ebuild b/dev-python/boto3/boto3-1.20.50.ebuild
new file mode 100644
index 000000000000..ed44d35fedd6
--- /dev/null
+++ b/dev-python/boto3/boto3-1.20.50.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index e77cc073d796..dd2a0116f4f8 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -4,3 +4,4 @@ DIST botocore-1.23.46.tar.gz 8743469 BLAKE2B 804e4ea772bbc74a12645fa5b5e1056115a
 DIST botocore-1.23.47.tar.gz 8757185 BLAKE2B 7d80ec4a869ed9c86b47a1fe8a7e9913381d56164827c9ffd8911c3c4f715867a6200c4a6cea5d8941e747ab72dbd61bfc4282aa5109a9f28679b47a9563c0ea SHA512 c69b4e4192e5acd85bb0664762e2d9eee7d317b48bb7071047dcbf58efdea7f96cc6915f71e83c134df795e810a4e507ff35702434785c92f9eadf6509b9e9a2
 DIST botocore-1.23.48.tar.gz 8757876 BLAKE2B e70a1aa1fdbeab5246640d9e5fc26ac6853491e32cdd0a29ef98d4dda441f4b61ae16011298cf2da0434d5668260010cd2a70c2cc760fc2c282b236b278158f3 SHA512 ad2d8e632ff7da1a1b677876b9d4345a9ba60a407f77deb8fe9df7108495853ff9a915b8e5956f6cf226501d6fe34d8328fdb7446c4a8db5b3f219ca2fbe1cb6
 DIST botocore-1.23.49.tar.gz 8758361 BLAKE2B 5e53366fdd705e81af6752665f3078e26d55460bc2e3644fa030f6b3a4485bd504c445ac15d6b6abcdb164d6c93f33fe8a596d5eb8e7f85c10363cd93a3d3e58 SHA512 2450752613a815a67f007a23371e0349a2ebaa991f3b48062bab5ed5736fa11255e206a20cc71a2477b65673f689c5447229a9e0c14358ffcd322e1f55971a86
+DIST botocore-1.23.50.tar.gz 8758107 BLAKE2B ac43af21c46168bc0c14f3afe6afb06e1e33e09af9c0f62bc6331f6bb2240563e137dcf23381ec0e4ed97f79e3475a70ae73ded969b0c9f954f01361504134ee SHA512 64230e9d6d4b4916fcbe8d2fdbba2ee0575a85de56160518e8ad48f2f1566f7cec0667cd9bd53f2afa514f5f6e341cc681b2830a43ac82e3356c1e82a49e2c7a
diff --git a/dev-python/botocore/botocore-1.23.50.ebuild b/dev-python/botocore/botocore-1.23.50.ebuild
new file mode 100644
index 000000000000..c44cf37adbf0
--- /dev/null
+++ b/dev-python/botocore/botocore-1.23.50.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/jellyfish/Manifest b/dev-python/jellyfish/Manifest
index 3ffcce5fa058..fa2d2b3cc630 100644
--- a/dev-python/jellyfish/Manifest
+++ b/dev-python/jellyfish/Manifest
@@ -1,2 +1 @@
-DIST jellyfish-0.8.9.tar.gz 137296 BLAKE2B 7f71f6e683021f3062c0ca529f3cd0488ab52cb9aea0d87766aa6b08d19d6b480f482a7385758ceba1a203247431d0362814f388f6a242f1ea928c32a385325f SHA512 d7d30573ebe552370a191eb755b4d27417e31eb66e7f57c2abb414e3d4075854a51f231c1d76001b7c0ff8b112a82dbe5e72be224425bd7a569a6b12455113d8
 DIST jellyfish-0.9.0.tar.gz 132588 BLAKE2B e7490da91d1a53b775ef145151c6dba5b16c938f59773e205b5cf01e1a262d36bb07a49d8c5d823fa722e2d244fc8af1bf9a603911411461a97b155cfdd0ce83 SHA512 1faa3ea03ec8b26085b5db34339f0aea061d3e4897f29235eca56995bea36ae8c152ae0ab0c67279dab4844d92d89293e2de2126c1d449407652b77da258e9f0
diff --git a/dev-python/jellyfish/jellyfish-0.8.9.ebuild b/dev-python/jellyfish/jellyfish-0.8.9.ebuild
deleted file mode 100644
index d0eae3c81277..000000000000
--- a/dev-python/jellyfish/jellyfish-0.8.9.ebuild
+++ /dev/null
@@ -1,30 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{6,7,8,9,10} )
-inherit distutils-r1
-
-DESCRIPTION="Python module for doing approximate and phonetic matching of strings"
-HOMEPAGE="https://github.com/jamesturk/jellyfish https://pypi.org/project/jellyfish/"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="BSD-2"
-SLOT="0"
-KEYWORDS="amd64 x86"
-
-BDEPEND="
-	test? (
-		dev-python/unicodecsv[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_sphinx docs --no-autodoc
-distutils_enable_tests pytest
-
-python_test() {
-	cp -r testdata "${BUILD_DIR}" || die
-	cd "${BUILD_DIR}" || die
-	epytest lib/jellyfish/test.py
-}
diff --git a/dev-python/jellyfish/jellyfish-0.9.0.ebuild b/dev-python/jellyfish/jellyfish-0.9.0.ebuild
index 933ce0d77da9..8aa5aa7026d9 100644
--- a/dev-python/jellyfish/jellyfish-0.9.0.ebuild
+++ b/dev-python/jellyfish/jellyfish-0.9.0.ebuild
@@ -12,7 +12,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="BSD-2"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="amd64 x86"
 
 BDEPEND="
 	test? (
diff --git a/dev-python/nagiosplugin/Manifest b/dev-python/nagiosplugin/Manifest
index 37c503c200d6..9e3193b8720e 100644
--- a/dev-python/nagiosplugin/Manifest
+++ b/dev-python/nagiosplugin/Manifest
@@ -1 +1,2 @@
 DIST nagiosplugin-1.3.2.tar.gz 54262 BLAKE2B af2a8a876105a1ea26671b39d611beaa46303998544adadee3370c6d1b5096fa93160121f89412f3778a2bbc1c3e95606a49413b8f3f0880c9c9ca4e946fb1b8 SHA512 899650852397bffb66ad53843233adec2c91e96656674a9b21c5a02ed97ce4db69c1440d1b88c5799a54745e69b8c05f52188403b5a2fe9050acbd0067806d50
+DIST nagiosplugin-1.3.3.tar.gz 3119586 BLAKE2B e1aecd6f69fc7afe5cbba259191d2ae540efa513ea8f61a263a453ac2b1f6a5d91bbb209d01fc83c72080b54540f7661c04b3485b5cc6c1f9aab44ee2e8fba67 SHA512 edff09b689fd767b9c8ee2ffab30fc63cb740234c830f2f8fef5054e5bc44e945c69858e2374257433b758fb33943a8b148c023a8fde75edbc188da7424a00b6
diff --git a/dev-python/nagiosplugin/nagiosplugin-1.3.3.ebuild b/dev-python/nagiosplugin/nagiosplugin-1.3.3.ebuild
new file mode 100644
index 000000000000..3b44f1dede85
--- /dev/null
+++ b/dev-python/nagiosplugin/nagiosplugin-1.3.3.ebuild
@@ -0,0 +1,20 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A class library for writing nagios-compatible plugins"
+HOMEPAGE="https://github.com/mpounsett/nagiosplugin https://nagiosplugin.readthedocs.io"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="ZPL"
+SLOT="0"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc dev-python/sphinx_rtd_theme
diff --git a/dev-python/proto-plus/Manifest b/dev-python/proto-plus/Manifest
index 01fdad8c9c9c..49d7eb3da03d 100644
--- a/dev-python/proto-plus/Manifest
+++ b/dev-python/proto-plus/Manifest
@@ -2,3 +2,4 @@ DIST proto-plus-1.19.2.gh.tar.gz 61183 BLAKE2B 8c1c0a70ae573fc8c64004e4bd923f403
 DIST proto-plus-1.19.7.gh.tar.gz 64614 BLAKE2B 918bb04a084cff8a2188a68c31f08aebd25443fd399d69ba9734d002f773df2769904e4aa551cd1d93586ee4710f2b7160e6a8eb4160fe1bb846be18155a7b29 SHA512 118187a852a998deba3b5d7e700cd084eab966b549c7dba6150f318e9602f950a9533e27d775f9f0bca2fedaed6375b592bae42c55cf5aee8b52708fcc4691c8
 DIST proto-plus-1.19.8.gh.tar.gz 64668 BLAKE2B d90ba4bd2404a0b05325e08e9ec39de0b819af00e9229ca54a7173364a99e0cedb584696093f3df7720d96f8291fad4f26b9963171de8ebd44396550dc932e17 SHA512 e9bd790ec7d2cc7fa54e5c8be374e4a7bc5c92899c5259e6985024fe1c9e25768c1355b808a9a4c38b132026412b2e7d91c5fe0098af661b1dac604b84aaf2ee
 DIST proto-plus-1.19.9.gh.tar.gz 64845 BLAKE2B 82f6021b912140c49e8625c51050a384f8375a3619a78537f6aadded03ce7524687e8f118cd4081c9a8376b3756c608ed781cac9808fb2c8d0bad9e32d2063ec SHA512 671dad31faf33a81bc90d98ffac599b51930f1f4f17c10c9a1dd5f242b3c55d04b9e59080197cdd42c1c430a72e1e812aadafbcf20cfb5da2fcd17c20e5a69e3
+DIST proto-plus-1.20.0.gh.tar.gz 65648 BLAKE2B 19cfcfde913896de83d17c36bacd7799a9f28ea20c4681266b2194c6521aef116f6a594df8be8912bdf55558d84a0ab09d283ec444ba114592ebb7017db257fe SHA512 1e399bc0ac686f33242c1d15c15255ec1815e94eaf87de03e5145cc6ed249048c3b8af081b70964cb7b6baf8286f6be2f461c3638331a2269a5b2d89976ffa6a
diff --git a/dev-python/proto-plus/proto-plus-1.20.0.ebuild b/dev-python/proto-plus/proto-plus-1.20.0.ebuild
new file mode 100644
index 000000000000..691f5eb9793f
--- /dev/null
+++ b/dev-python/proto-plus/proto-plus-1.20.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Beautiful, Pythonic protocol buffers"
+HOMEPAGE="https://pypi.org/project/proto-plus/ https://github.com/googleapis/proto-plus-python"
+SRC_URI="
+	https://github.com/googleapis/proto-plus-python/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${PN}-python-${PV}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/protobuf-python[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/google-api-core[${PYTHON_USEDEP}]
+		dev-python/grpcio[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme
+
+src_prepare() {
+	# https://github.com/pytest-dev/pytest/issues/9637#issuecomment-1031997415
+	sed -i -e '/staticmethod/d' tests/test_datetime_helpers.py || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/redis-py/Manifest b/dev-python/redis-py/Manifest
index 216f67127eae..ff2d0e2bb226 100644
--- a/dev-python/redis-py/Manifest
+++ b/dev-python/redis-py/Manifest
@@ -1,3 +1,4 @@
 DIST redis-py-4.1.0.tar.gz 2346542 BLAKE2B 3d59f904f376df7bca14dcd7bc8547d7a7b41b8d934a50ade6dbf5e74f3da8deef59b3b7cf683fe3c7389859f76fe1d3307f91b52250da945f91b90c629640ab SHA512 85cd09570f4faf34a735befd0677aa8ca2cb0d62b0285c4c040380c2440f2774e47762ec4219381294465343353a15804b96f06b4d6eefa7159a224eb9e72001
 DIST redis-py-4.1.1.tar.gz 2349319 BLAKE2B adebda19239e1fd4cf685c0de7a9b2c2fc4e8f23df0e80f2ecdf5f4b9b8b2698fbab613975bd380ea74dc275710d8ed58ee0720486c079bf554612cb7d8b392e SHA512 a974a910dcbaf75516e311badbe6e019cdce668a6d8cd918503934bb92bf97f7ea373fae32139f89a9eecdb360184ae42d24d742ef8b008e95eae648bd992e64
 DIST redis-py-4.1.2.tar.gz 2349862 BLAKE2B 3e68918654e63c3403f2408350b2a877027a3c3990b623818332e0e77e1fbaa413e85912ea586a90788a87e0206ebe408ab55df522864dc534907c31a690c0c1 SHA512 beb6e50051eae61e84e7cf37f9f3e3efbc404d49e506b0b3bdae0d0c45fd940f12c801434a6394505519bf327b5933c076ad4f8c66ad812441bc08b3aa682542
+DIST redis-py-4.1.3.tar.gz 2349885 BLAKE2B d1c16a88e7ec70cf2b954fa9cf841f971c02023b7c9387e3e680e16972d546347ee454febf096e54f7bfcd4dabf163e22e1a0ba3186cbb9417cdd7a613d5a992 SHA512 797c1ee4ff4f0e32b52add5bc1cc81fd36cb1eb4d6f9328b38dca46c79a01bc105bc172f56d3bea20d802ee7a6eb934c2ee3ab5f611a49d77f9c4c50d7a4b0d8
diff --git a/dev-python/redis-py/redis-py-4.1.3.ebuild b/dev-python/redis-py/redis-py-4.1.3.ebuild
new file mode 100644
index 000000000000..1d93bb961afc
--- /dev/null
+++ b/dev-python/redis-py/redis-py-4.1.3.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+MY_PN="redis"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python client for Redis key-value store"
+HOMEPAGE="https://github.com/redis/redis-py"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/deprecated[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-db/redis
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Flaky test
+		tests/test_pubsub.py::TestPubSubDeadlock::test_pubsub_deadlock
+
+		# Needs a second Redis running
+		tests/test_commands.py::TestRedisCommands::test_sync
+		tests/test_commands.py::TestRedisCommands::test_psync
+	)
+
+	local EPYTEST_IGNORE=(
+		# SSL tests need Docker/stunnel:
+		# https://github.com/redis/redis-py/commit/18c6809b761bc6755349e1d7e08e74e857ec2c65
+		tests/test_ssl.py
+
+		# Needs multiple Redises running
+		tests/test_cluster.py
+	)
+
+	epytest -k "not redismod and not ssl"
+}
+
+src_test() {
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+
+	# Spawn Redis itself for testing purposes
+	# NOTE: On sam@'s machine, spawning Redis can hang in the sandbox.
+	# I'm not restricting tests yet because this doesn't happen for anyone else AFAICT.
+	einfo "Spawning Redis"
+	einfo "NOTE: Port ${redis_port} must be free"
+	# "${EPREFIX}"/usr/sbin/redis-server - <<< "${redis_test_config}" || die
+	"${EPREFIX}"/usr/sbin/redis-server - <<- EOF || die "Unable to start redis server"
+		daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1
+	EOF
+
+	# Run the tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}
diff --git a/dev-python/twisted/Manifest b/dev-python/twisted/Manifest
index 3c5453df8fdc..06f514275b6a 100644
--- a/dev-python/twisted/Manifest
+++ b/dev-python/twisted/Manifest
@@ -1,2 +1,3 @@
 DIST twisted-21.7.0.tar.gz 3895345 BLAKE2B 510165ad2933f07005e508df5a8bdf2863a7988c0f18fcc089e948d190c65aab32fc876d3120e311e91d6989f1ea2d8b3b5f5db4a9dfc63c38da56213f718728 SHA512 a946769a6bc6c72af26e7763b9e0675788f134b4d005ea89d935da1b1d5f60d92c84fdb2615e442e7da2b98291ee8a63d5236ec7ba72ef04ad3f847b092feecb
+DIST twisted-22.1.0.tar.gz 3883519 BLAKE2B 0b438481af94fbfe08c7470a71421e176ca4994efaf7144b2bd3bc7e69c774295e04831d5356af104d087d970856c1c153b30331cb1598226f83e761b624a53c SHA512 1db52865d00e07044bc755b25bef2fa260cf269a8b51512bec97a015fa484d0b331b41154b52f97b5e8c477d3e5ad1d003f5ac15c7361988d073d097c6e7355d
 DIST twisted-regen-cache.gz 911 BLAKE2B ffd3fcda6c67ffe6fd3ef581c8d507548396b66ed0708e9a5c790095e579c0d5f0f71596acf05712989da2ddef2b8d437eca973bc4d80ef8a9fa852915f38305 SHA512 95a9b931c73017d16d1b5e6b41345dddffe62b6af1a8e93b5e40d06d3d15be17b0dd0181c767ffeeb791534d463764ef9e066fa6c2ee2ac4b53c86d1da8fce03
diff --git a/dev-python/twisted/files/twisted-22.1.0-force-gtk3.patch b/dev-python/twisted/files/twisted-22.1.0-force-gtk3.patch
new file mode 100644
index 000000000000..7c9f2d558d65
--- /dev/null
+++ b/dev-python/twisted/files/twisted-22.1.0-force-gtk3.patch
@@ -0,0 +1,67 @@
+From 9344f8cd80ecb2907dbfddfeeb8cc9ffdb50bc94 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
+Date: Sat, 22 May 2021 01:11:48 +0200
+Subject: [PATCH] Force using GTK+3 in twisted.internet.gireactor
+
+Modify twisted.internet.gireactor to explicitly request GTK+ version 3.
+Otherwise it uses the newest version installed which could be GTK+4
+that gireactor is currently incompatible with.
+---
+ src/twisted/internet/gireactor.py           | 3 +++
+ src/twisted/internet/test/test_gireactor.py | 3 +++
+ src/twisted/newsfragments/10200.bugfix      | 1 +
+ 3 files changed, 7 insertions(+)
+ create mode 100644 src/twisted/newsfragments/10200.bugfix
+
+diff --git a/src/twisted/internet/gireactor.py b/src/twisted/internet/gireactor.py
+index e2d24b599..838fa982e 100644
+--- a/src/twisted/internet/gireactor.py
++++ b/src/twisted/internet/gireactor.py
+@@ -21,6 +21,7 @@ On Python 3, pygobject v3.4 or later is required.
+ """
+ 
+ 
++import gi  # type: ignore[import]
+ import gi.pygtkcompat  # type: ignore[import]
+ from gi.repository import GLib  # type: ignore[import]
+ 
+@@ -69,6 +70,7 @@ class GIReactor(_glibbase.GlibReactorBase):
+     def __init__(self, useGtk=False):
+         _gtk = None
+         if useGtk is True:
++            gi.require_version("Gtk", "3.0")
+             from gi.repository import Gtk as _gtk
+ 
+         _glibbase.GlibReactorBase.__init__(self, GLib, _gtk, useGtk=useGtk)
+@@ -113,6 +115,7 @@ class PortableGIReactor(_glibbase.PortableGlibReactorBase):
+     def __init__(self, useGtk=False):
+         _gtk = None
+         if useGtk is True:
++            gi.require_version("Gtk", "3.0")
+             from gi.repository import Gtk as _gtk
+ 
+         _glibbase.PortableGlibReactorBase.__init__(self, GLib, _gtk, useGtk=useGtk)
+diff --git a/src/twisted/internet/test/test_gireactor.py b/src/twisted/internet/test/test_gireactor.py
+index c25ada63f..3bb88a07f 100644
+--- a/src/twisted/internet/test/test_gireactor.py
++++ b/src/twisted/internet/test/test_gireactor.py
+@@ -26,6 +26,9 @@ else:
+         gtk3reactor = None
+     else:
+         gtk3reactor = _gtk3reactor
++        import gi  # type: ignore[import]
++
++        gi.require_version("Gtk", "3.0")
+         from gi.repository import Gtk
+ 
+ from twisted.internet.error import ReactorAlreadyRunning
+diff --git a/src/twisted/newsfragments/10200.bugfix b/src/twisted/newsfragments/10200.bugfix
+new file mode 100644
+index 000000000..7afb343be
+--- /dev/null
++++ b/src/twisted/newsfragments/10200.bugfix
+@@ -0,0 +1 @@
++twisted.internet.gireactor was fixed to force GTK+3 in order to fix use of incompatible GTK+4 API when installed
+-- 
+2.35.1
+
diff --git a/dev-python/twisted/twisted-22.1.0-r1.ebuild b/dev-python/twisted/twisted-22.1.0-r1.ebuild
new file mode 100644
index 000000000000..2a5c658bb417
--- /dev/null
+++ b/dev-python/twisted/twisted-22.1.0-r1.ebuild
@@ -0,0 +1,160 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="An asynchronous networking framework written in Python"
+HOMEPAGE="https://www.twistedmatrix.com/trac/"
+SRC_URI="
+	https://github.com/twisted/twisted/archive/${P}.tar.gz
+	https://dev.gentoo.org/~mgorny/dist/twisted-regen-cache.gz"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="conch crypt http2 serial test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/automat-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
+	>=dev-python/hyperlink-17.1.1[${PYTHON_USEDEP}]
+	>=dev-python/incremental-21.3.0[${PYTHON_USEDEP}]
+	>=dev-python/pyhamcrest-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-3.6.5[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-4.4.2[${PYTHON_USEDEP}]
+	conch? (
+		>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+		dev-python/bcrypt[${PYTHON_USEDEP}]
+		>=dev-python/cryptography-1.5.0[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+	)
+	crypt? (
+		>=dev-python/pyopenssl-16.0.0[${PYTHON_USEDEP}]
+		dev-python/service_identity[${PYTHON_USEDEP}]
+		>=dev-python/idna-0.6[${PYTHON_USEDEP}]
+	)
+	serial? ( >=dev-python/pyserial-3.0[${PYTHON_USEDEP}] )
+	http2? (
+		>=dev-python/h2-3.0.0[${PYTHON_USEDEP}]
+		<dev-python/h2-4.0.0[${PYTHON_USEDEP}]
+		>=dev-python/priority-1.1.0[${PYTHON_USEDEP}]
+		<dev-python/priority-2.0[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	>=dev-python/incremental-21.3.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+		dev-python/bcrypt[${PYTHON_USEDEP}]
+		>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
+		dev-python/cython-test-exception-raiser[${PYTHON_USEDEP}]
+		dev-python/idna[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		dev-python/pyserial[${PYTHON_USEDEP}]
+		net-misc/openssh
+		$(python_gen_cond_dep '
+			dev-python/gmpy[${PYTHON_USEDEP}]
+		' 'python*')
+		!alpha? ( !hppa? ( !ia64? (
+			>=dev-python/cryptography-0.9.1[${PYTHON_USEDEP}]
+			>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
+			dev-python/service_identity[${PYTHON_USEDEP}]
+		) ) )
+	)
+"
+
+PATCHES=(
+	# https://twistedmatrix.com/trac/ticket/10200
+	"${FILESDIR}/${P}-force-gtk3.patch"
+)
+
+python_prepare_all() {
+	# upstream test for making releases; not very useful and requires
+	# sphinx (including on py2)
+	rm src/twisted/python/test/test_release.py || die
+
+	# puts system in EMFILE state, then the exception handler may fail
+	# trying to open more files due to some gi magic
+	sed -e '/SKIP_EMFILE/s:False:True:' \
+		-i src/twisted/internet/test/test_tcp.py || die
+
+	# multicast tests fail within network-sandbox
+	sed -e 's:test_joinLeave:_&:' \
+		-e 's:test_loopback:_&:' \
+		-e 's:test_multiListen:_&:' \
+		-e 's:test_multicast:_&:' \
+		-i src/twisted/test/test_udp.py || die
+
+	# These tests rely on warnings which seems work unreliably between python versions
+	sed -e 's:test_currentEUID:_&:' \
+		-e 's:test_currentUID:_&:' -i src/twisted/python/test/test_util.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	# the test suite handles missing file & failing ioctl()s gracefully
+	# but not permission errors from sandbox
+	addwrite /dev/net/tun
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	"${EPYTHON}" -m twisted.trial twisted ||
+		die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# own the dropin.cache so we don't leave orphans
+	> "${D}$(python_get_sitedir)"/twisted/plugins/dropin.cache || die
+
+	python_doscript "${WORKDIR}"/twisted-regen-cache
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newconfd "${FILESDIR}/twistd.conf" twistd
+	newinitd "${FILESDIR}/twistd.init" twistd
+}
+
+python_postinst() {
+	twisted-regen-cache || die
+}
+
+pkg_postinst() {
+	python_foreach_impl python_postinst
+
+	einfo "Install complete"
+	if use test ; then
+		einfo ""
+		einfo "Some tests have been disabled during testing due to"
+		einfo "known incompatibilities with the emerge sandboxes and/or"
+		einfo "not runnable as the root user."
+		einfo "For a complete test suite run on the code."
+		einfo "Run the tests as a normal user for each python it is installed to."
+		einfo "  ie:  $ python3.6 /usr/bin/trial twisted"
+	fi
+}
+
+python_postrm() {
+	rm -f "${ROOT}$(python_get_sitedir)/twisted/plugins/dropin.cache" || die
+}
+
+pkg_postrm() {
+	# if we're removing the last version, remove the cache file
+	if [[ ! ${REPLACING_VERSIONS} ]]; then
+		python_foreach_impl python_postrm
+	fi
+}
diff --git a/dev-python/twisted/twisted-22.1.0.ebuild b/dev-python/twisted/twisted-22.1.0.ebuild
new file mode 100644
index 000000000000..7a2e40b1a967
--- /dev/null
+++ b/dev-python/twisted/twisted-22.1.0.ebuild
@@ -0,0 +1,162 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="An asynchronous networking framework written in Python"
+HOMEPAGE="https://www.twistedmatrix.com/trac/"
+SRC_URI="
+	https://github.com/twisted/twisted/archive/${P}.tar.gz
+	https://dev.gentoo.org/~mgorny/dist/twisted-regen-cache.gz"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="conch crypt http2 serial test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/automat-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
+	>=dev-python/hyperlink-17.1.1[${PYTHON_USEDEP}]
+	>=dev-python/incremental-21.3.0[${PYTHON_USEDEP}]
+	>=dev-python/pyhamcrest-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-3.6.5[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-4.4.2[${PYTHON_USEDEP}]
+	conch? (
+		>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+		dev-python/bcrypt[${PYTHON_USEDEP}]
+		>=dev-python/cryptography-1.5.0[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+	)
+	crypt? (
+		>=dev-python/pyopenssl-16.0.0[${PYTHON_USEDEP}]
+		dev-python/service_identity[${PYTHON_USEDEP}]
+		>=dev-python/idna-0.6[${PYTHON_USEDEP}]
+	)
+	serial? ( >=dev-python/pyserial-3.0[${PYTHON_USEDEP}] )
+	http2? (
+		>=dev-python/h2-3.0.0[${PYTHON_USEDEP}]
+		<dev-python/h2-4.0.0[${PYTHON_USEDEP}]
+		>=dev-python/priority-1.1.0[${PYTHON_USEDEP}]
+		<dev-python/priority-2.0[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	>=dev-python/incremental-21.3.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+		dev-python/bcrypt[${PYTHON_USEDEP}]
+		>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
+		dev-python/cython-test-exception-raiser[${PYTHON_USEDEP}]
+		dev-python/idna[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		dev-python/pyserial[${PYTHON_USEDEP}]
+		net-misc/openssh
+		$(python_gen_cond_dep '
+			dev-python/gmpy[${PYTHON_USEDEP}]
+		' 'python*')
+		!alpha? ( !hppa? ( !ia64? (
+			>=dev-python/cryptography-0.9.1[${PYTHON_USEDEP}]
+			>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
+			dev-python/service_identity[${PYTHON_USEDEP}]
+		) ) )
+	)
+"
+
+PATCHES=(
+	# https://twistedmatrix.com/trac/ticket/10200
+	"${FILESDIR}/${P}-force-gtk3.patch"
+)
+
+python_prepare_all() {
+	# upstream test for making releases; not very useful and requires
+	# sphinx (including on py2)
+	rm src/twisted/python/test/test_release.py || die
+
+	# puts system in EMFILE state, then the exception handler may fail
+	# trying to open more files due to some gi magic
+	sed -e '/SKIP_EMFILE/s:False:True:' \
+		-i src/twisted/internet/test/test_tcp.py || die
+
+	# multicast tests fail within network-sandbox
+	sed -e 's:test_joinLeave:_&:' \
+		-e 's:test_loopback:_&:' \
+		-e 's:test_multiListen:_&:' \
+		-e 's:test_multicast:_&:' \
+		-i src/twisted/test/test_udp.py || die
+
+	# These tests rely on warnings which seems work unreliably between python versions
+	sed -e 's:test_currentEUID:_&:' \
+		-e 's:test_currentUID:_&:' -i src/twisted/python/test/test_util.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	# the test suite handles missing file & failing ioctl()s gracefully
+	# but not permission errors from sandbox
+	addwrite /dev/net/tun
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	# TODO: upstream seems to override our build paths
+	distutils_install_for_testing
+
+	"${EPYTHON}" -m twisted.trial twisted ||
+		die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# own the dropin.cache so we don't leave orphans
+	> "${D}$(python_get_sitedir)"/twisted/plugins/dropin.cache || die
+
+	python_doscript "${WORKDIR}"/twisted-regen-cache
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newconfd "${FILESDIR}/twistd.conf" twistd
+	newinitd "${FILESDIR}/twistd.init" twistd
+}
+
+python_postinst() {
+	twisted-regen-cache || die
+}
+
+pkg_postinst() {
+	python_foreach_impl python_postinst
+
+	einfo "Install complete"
+	if use test ; then
+		einfo ""
+		einfo "Some tests have been disabled during testing due to"
+		einfo "known incompatibilities with the emerge sandboxes and/or"
+		einfo "not runnable as the root user."
+		einfo "For a complete test suite run on the code."
+		einfo "Run the tests as a normal user for each python it is installed to."
+		einfo "  ie:  $ python3.6 /usr/bin/trial twisted"
+	fi
+}
+
+python_postrm() {
+	rm -f "${ROOT}$(python_get_sitedir)/twisted/plugins/dropin.cache" || die
+}
+
+pkg_postrm() {
+	# if we're removing the last version, remove the cache file
+	if [[ ! ${REPLACING_VERSIONS} ]]; then
+		python_foreach_impl python_postrm
+	fi
+}
diff --git a/dev-python/werkzeug/Manifest b/dev-python/werkzeug/Manifest
index 5d68236f74af..919d581150ae 100644
--- a/dev-python/werkzeug/Manifest
+++ b/dev-python/werkzeug/Manifest
@@ -1,2 +1,3 @@
 DIST werkzeug-1.0.1.gh.tar.gz 907482 BLAKE2B d2dcdce8b1bcbb177b52b0915f2c0ac17d235dee3c77b23e81e4b35412d1f53a194d3c7c7f2a5c065ade99797effe72cc464cf6980b12c761a8a919338021660 SHA512 ba82120fb3e96e3a1334c6452d5ba1950fc016d2d147d643bbc2168ccec496f1dea799982ae8c578167155082c0bdbda5d56a23f64b4b6865f97e90e22df022e
 DIST werkzeug-2.0.2.gh.tar.gz 896727 BLAKE2B 15506d57a8545eb45cb0f4efb78bcc4dfc1faa68910f09dfdd14f4bbb2404078247a7f61475c5fff9058a1557f7f6541eec262fb274e7ed82e1a82b9f644cf8b SHA512 789f210546c089e8a437a379e516147fd854806357938bd559a61855182143bdeca967c86a41d004e6adb119d31e4493e3c36e74aff989ee9cd08e48d1428dd9
+DIST werkzeug-2.0.3.gh.tar.gz 897523 BLAKE2B 1f97a2f7184e8e11bb85722becae7cc032ada38a642a2f925f7b81e89c881011889189999d50dab4591fc2e874aac4ab92b0f1531c211468cf352e31b0b8c8d0 SHA512 a205cd981b3e1b481436e483190427ff3808a5ea80abc616ca08d899d0e6a39893a5cb60adc65c99dcab3af47c24b321c71996d719cb7f224de7942b44b1fd69
diff --git a/dev-python/werkzeug/werkzeug-2.0.3.ebuild b/dev-python/werkzeug/werkzeug-2.0.3.ebuild
new file mode 100644
index 000000000000..59b199630087
--- /dev/null
+++ b/dev-python/werkzeug/werkzeug-2.0.3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of various utilities for WSGI applications"
+HOMEPAGE="
+	https://werkzeug.palletsprojects.com/
+	https://pypi.org/project/Werkzeug/
+	https://github.com/pallets/werkzeug/"
+SRC_URI="
+	https://github.com/pallets/werkzeug/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	test? (
+		!hppa? ( !ia64? (
+			$(python_gen_cond_dep '
+				dev-python/greenlet[${PYTHON_USEDEP}]
+			' 'python*')
+		) )
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/pytest-xprocess[${PYTHON_USEDEP}]
+		dev-python/watchdog[${PYTHON_USEDEP}]
+		!alpha? ( !hppa? ( !ia64? (
+			dev-python/cryptography[${PYTHON_USEDEP}]
+		) ) )
+	)"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=()
+	if ! has_version "dev-python/cryptography[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			"tests/test_serving.py::test_server[https]"
+			tests/test_serving.py::test_ssl_dev_cert
+			tests/test_serving.py::test_ssl_object
+		)
+	fi
+
+	# the default portage tempdir is too long for AF_UNIX sockets
+	local -x TMPDIR=/tmp
+	epytest -p no:django -p no:httpbin tests
+}