Adding metadata

30 files changed, 732 insertions, 38 deletions

diff --git a/dev-python/bitarray/Manifest b/dev-python/bitarray/Manifest
index d5fe7a27b746..9622d1249e44 100644
--- a/dev-python/bitarray/Manifest
+++ b/dev-python/bitarray/Manifest
@@ -1,2 +1,2 @@
-DIST bitarray-2.3.7.tar.gz 89721 BLAKE2B 8c56e82862a4314d199fa8021fbe4d0fefa5172f6c3c93573cc1d6a06d7965788d65e0b193f199f86d685c7edd0f0faf878db65243625427d4b6be6d2fb8c807 SHA512 4484f93001a74105bdb85155ee9975f7f399652634e6173a4502e2a8eae83dc4d331e638f6b2dc2a94e89aa695208586a502bc41583539271ae3869576de41c9
 DIST bitarray-2.4.0.tar.gz 95151 BLAKE2B 04b76ac59042b6b318f75944b84f1927844e7858b2559a81809fc905bfd080ac52fcc2ba89caa30b0329b74997b9547bd7a6bfeec22c7257c12b5435f178f5a5 SHA512 c668c378fe66bcc6579e2b687e272481c43285875924660cb1b5796e441d7f815580fde24d38d94f950d25dba043a85b2466768bc5dc6f2efa10836088d5eff2
+DIST bitarray-2.4.1.tar.gz 95300 BLAKE2B feee2339f66d0941719fca7bb9a43d3234d1043f894bb52346f89318e586397078d84afd386b027338b5186d609f0197d656288ac9f7f4bbd631e41056d7f24b SHA512 ba623e783bae879833ac7759599c085e86c2acb3c81780ce0df95e2b23764e494a33f1e27e52db8b634b6b04d02ebee693ce0186e7a2bb9bd73906856c19bade
diff --git a/dev-python/bitarray/bitarray-2.3.7.ebuild b/dev-python/bitarray/bitarray-2.4.1.ebuild
index c63a993b4278..241cdbcbca63 100644
--- a/dev-python/bitarray/bitarray-2.3.7.ebuild
+++ b/dev-python/bitarray/bitarray-2.4.1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 2020-2022 Liguros Authors
 # Distributed under the terms of the GNU General Public License v2
-EAPI=7
+EAPI=8
 
 PYTHON_COMPAT=( python3_{7,8,9,10} )
 
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 34e9f105039d..a65744d752a7 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -4,4 +4,5 @@ DIST boto3-1.21.25.tar.gz 482117 BLAKE2B 7f4823fa6045addb4b4ed01e83d1095e9f56dac
 DIST boto3-1.21.26.tar.gz 482624 BLAKE2B 19f38b86eab6363ff86febc9f7623def010314a70e3d88c405bf641a4cd0b2de390fb69f5205c5df2e7d71c80a31989efbc64c442bd02d3d2a5efb7ee937596d SHA512 85848df7f5863df5ddc97be29f734bbdff54d195d5d1e465b35f3693b8196c03422b9a8024a2ecdaead40a4ddd1742c06e9d2e5b90fd4de28dffd6609f209dfb
 DIST boto3-1.21.27.tar.gz 482968 BLAKE2B f8dbabe73377a861cf1d3d2e9388f7ba91f2047d8ce792b44a10693e5b0575924b3abbd8ec2b72d0c3b9a553bb088fc17dc4cd23b571f375db45737376931a46 SHA512 54bb43022ba12fc7b5c54872632cd46c07c6f167246917b5413cdd30de6c327bc625410cdfe62f4ff257ad7c42da762d2bcec5515367e214131259ddc69a9061
 DIST boto3-1.21.28.tar.gz 483052 BLAKE2B 89afa5ff7d9b8c256b525ef2d67a17de45fda8b63a3640513d9a786b2bcd77c0b8a5a572deb4bf3fb264fcc9c317c510b27fd836cba958816514bc1ac32bc327 SHA512 af6a8d11371b3616b15a5bf996b165808590d0074ead1bb54ee1b7a8357cd076648700838aba84f7d370120981db36096a6060c8b00ea7bdd9a4da5cb5ddcb8c
+DIST boto3-1.21.29.tar.gz 483137 BLAKE2B fa753a52923d013a3c5b3981fb32614bc5cb7be1b7696d2b60df877b33814553c22eccaf8d66e4719922b4289181c2e8356a3b377b25e81c8bdf8496cd49d0a9 SHA512 6c916fce1097d226b865cebf2d8791bc40506d9dd5b2db49b61e038872fb2f51d9de727ab8c9da3accced2563e81314dbe87788af57d6366fb90c446d3b79555
 DIST boto3-1.21.8.tar.gz 473069 BLAKE2B f08f76fb9c4e56e6ba5624c885973599505769d7f9eea6e20a06e1a641768b1f7b108fc7293282a55bf4c7d2b62eb34853f46b8c3ada9afb8fc25624daa60c12 SHA512 23ed88dcaefe3224db05959251befaae4f03859bf00daf649db1e838e5fb92e01a6da4bee8083366d804404aac358df19d7e4552d6aaf39f9c4b371ccc7f9088
diff --git a/dev-python/boto3/boto3-1.21.29.ebuild b/dev-python/boto3/boto3-1.21.29.ebuild
new file mode 100644
index 000000000000..80278b309f54
--- /dev/null
+++ b/dev-python/boto3/boto3-1.21.29.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index d8eba447cc10..d2c2196fff37 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -4,4 +4,5 @@ DIST botocore-1.24.25.tar.gz 8852839 BLAKE2B feb0f5de1d34b9f5a1b20f76480f432059c
 DIST botocore-1.24.26.tar.gz 8855676 BLAKE2B ad8e82872429043a9a80d6584a5a8af623ce91b516c045284b8ea618629c7cf65195433691db7eced91969ccb14fc8c7f57956897b528c6861fe84175d46286b SHA512 2f08bcd1db6b9a5ede68be204d68f8fa0f1c906ca8d7dccb69d5775a66f86c990788970194058973a90ada928914ec92cf02d4cba30a85c7619bb38d3b117268
 DIST botocore-1.24.27.tar.gz 8856607 BLAKE2B aa149a79106bc6e9460d2b69b032b20d0fcd9b0a4d7dda04ac656e0681aff378267f5c6bde4e64432f309ad4ed89ff8cae50b0dc92f01086f8fbe433e5347ad3 SHA512 1cdeb2926bfdd54eb6805295982891cb02005c01ee74e3394d8680e486fd924f73322fb9ae56730deaf360b0e60c9fd482759d597eadb3dc180cb099beff487c
 DIST botocore-1.24.28.tar.gz 8856916 BLAKE2B d662fec904cdfb048582252cfa77dadfcb1fcb58bb61e4b273bda34120825a27bc630d2c7fffd215f8733cdba97534da643da6d5b094f3e2ee3c6bb0a86bb27f SHA512 3f10d5ccd2b8051598adc37e452b057a3b53bc267f9cc3fb71caa18f406e515f008f22d2394a37b194ff4c63477f93791e6bdc09657df5ba59377379227c106b
+DIST botocore-1.24.29.tar.gz 8857387 BLAKE2B b873c369a6a9fe2d44124385f618f1caac2986cdbad2ea53cf9ce481692431ff389de44b055b0128eefbd1e26d8cf205d49cfb22decfa11bf6cba8c00aa5df3f SHA512 dcc836ebe25a510aa13f4ba54be99c0d2d086e6a54d446bd303ecd13f3528f004be92ff6408690ebda84b8c13f83ef19cc4026422c2ad15e3c32abfdbf923e9d
 DIST botocore-1.24.8.tar.gz 8798121 BLAKE2B 4ca37ed7be0af62901bf154f75739cc7e07505a809e551884c72d5b5eed334fff1111fc6db016df522564a1f3d9b6f258e8eca96161a734711340bf880b553b5 SHA512 6ac2139694ab199313a0fb9a2f783b12de7f3915d10cba739f4758356a3b84a917c3c394954b6d82d7a62de907c6fe57a3559e2b9a625bb0479e7bacd31d21cc
diff --git a/dev-python/botocore/botocore-1.24.29.ebuild b/dev-python/botocore/botocore-1.24.29.ebuild
new file mode 100644
index 000000000000..5fe8ae8c2f96
--- /dev/null
+++ b/dev-python/botocore/botocore-1.24.29.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	epytest tests/{functional,unit} \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
diff --git a/dev-python/fastimport/fastimport-0.9.11.ebuild b/dev-python/fastimport/fastimport-0.9.11.ebuild
index 3841a2af41d7..dd2bbb83b70a 100644
--- a/dev-python/fastimport/fastimport-0.9.11.ebuild
+++ b/dev-python/fastimport/fastimport-0.9.11.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -13,7 +13,7 @@ SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
 
 LICENSE="GPL-2+"
 SLOT="0"
-KEYWORDS="~alpha amd64 ~arm arm64 ~ia64 ppc ~ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+KEYWORDS="~alpha amd64 ~arm arm64 ~ia64 ppc ~ppc64 ~riscv x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
 
 python_test() {
 	"${EPYTHON}" -m unittest -v fastimport.tests.test_suite ||
diff --git a/dev-python/flask-login/Manifest b/dev-python/flask-login/Manifest
index 992cbf9700bb..866e813dab6b 100644
--- a/dev-python/flask-login/Manifest
+++ b/dev-python/flask-login/Manifest
@@ -1 +1,2 @@
 DIST flask-login-0.5.0.tar.gz 44961 BLAKE2B a780a3ca1ced7f01cbc1f99e3d92f57819c73982a4098330be7b9b4dce88e5fac577d15b2989b99971c4b2f7e6c9f02a54aeab9f7fa1c101f409cbdcfa3c6942 SHA512 8ffecd2a512738f81ec3901ad30d356b1d63355268f7cf1b427e463d0a271a4623723255e139bbd0f88845d73fa4aab051418b5f68aef0b4576c30294f6207b3
+DIST flask-login-0.6.0.gh.tar.gz 47368 BLAKE2B 799591ec0bd538e6cc467a80b3a8891a97ee60bbfcf01eb6ba7be1ab48e7ea9be22e8777801621b39bf089c00d7914f7b045e4e6617e45d623354276ba7e245b SHA512 0766ef5702105bc2cea7082b2b2a9bebed282a9166757adbc91a02c4adcc291d41a3217e8b9566b6bb4778db4a1d2453edb0b7a727c9bff2673833d27b69148e
diff --git a/dev-python/flask-login/flask-login-0.6.0.ebuild b/dev-python/flask-login/flask-login-0.6.0.ebuild
new file mode 100644
index 000000000000..ef3de160a860
--- /dev/null
+++ b/dev-python/flask-login/flask-login-0.6.0.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Login session support for Flask"
+HOMEPAGE="https://pypi.org/project/Flask-Login/"
+SRC_URI="
+	https://github.com/maxcountryman/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/flask-1.0.4[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-1.0.1[${PYTHON_USEDEP}]
+"
+DEPEND="
+	test? (
+		dev-python/asgiref[${PYTHON_USEDEP}]
+		dev-python/blinker[${PYTHON_USEDEP}]
+		dev-python/semantic_version[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -p no:httpbin
+}
diff --git a/dev-python/geventhttpclient/geventhttpclient-1.5.3.ebuild b/dev-python/geventhttpclient/geventhttpclient-1.5.3.ebuild
index 9249193c25a5..ef95df65f053 100644
--- a/dev-python/geventhttpclient/geventhttpclient-1.5.3.ebuild
+++ b/dev-python/geventhttpclient/geventhttpclient-1.5.3.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -13,7 +13,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha amd64 ~arm arm64 ppc ~ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+KEYWORDS="~alpha amd64 ~arm arm64 ppc ~ppc64 ~riscv x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
 
 RDEPEND="
 	app-arch/brotli[python,${PYTHON_USEDEP}]
diff --git a/dev-python/iminuit/Manifest b/dev-python/iminuit/Manifest
index 34c10091136f..4a552fa9c765 100644
--- a/dev-python/iminuit/Manifest
+++ b/dev-python/iminuit/Manifest
@@ -1,2 +1,3 @@
 DIST iminuit-2.10.0.tar.gz 408625 BLAKE2B 8876f4e94958a9154d517b91859d0c3a58ea919d53271f372eb4f648157567cf39e6639f5cdee7e137bb5a3011eadcfc28b52e3ba87333b2d7dafb0f8b58a7f1 SHA512 0f40a7f775ff814004d6fd5b331887eef2c9d389462b2c3585eca7568cd4babe5f83c85a002c6b47f047008a3ffc0a9e2c6f29cdc4acaf3d4c7208637a16d1e8
+DIST iminuit-2.11.2.tar.gz 411984 BLAKE2B 8fa47b24890f26718ebb8f053c2f908d982a7b6cc7f71f6523f387128ab0bd894bb851f18e2f8611ff5ab1c113651f526893445f465fbbfa10d487dc15effcbd SHA512 b60755f21ae38bd19860e0d711bab9c6e37dd361cc8cf43bdd1a583e8c06abca38e42ae0a6c4631be05c5082c9ab169bddb51e4d84397ce8f81833fd4c46cdd7
 DIST iminuit-2.9.0.tar.gz 408294 BLAKE2B d924d5ca5bef0e5b2dbc1fcfc12daab196c6937feff1badd73f9f8f20601989b21673165e758df7dabe072cb4a14cbda12823cfaf30fa5687de4184238465c50 SHA512 55d1d855b23862a4205b6c12ff53ddc088739945523670f3959edfe859abdbd3600da78cc219af6ed792156e2da7d8ae844e76e49ac759af433af875eab26714
diff --git a/dev-python/iminuit/iminuit-2.11.2.ebuild b/dev-python/iminuit/iminuit-2.11.2.ebuild
new file mode 100644
index 000000000000..aeaeffc6c6f4
--- /dev/null
+++ b/dev-python/iminuit/iminuit-2.11.2.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+# forced implicitly
+CMAKE_MAKEFILE_GENERATOR=emake
+inherit cmake distutils-r1 virtualx
+
+DESCRIPTION="Minuit numerical function minimization in Python"
+HOMEPAGE="https://github.com/scikit-hep/iminuit/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT LGPL-2.1"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	epytest -p no:pytest-describe || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/jellyfish/jellyfish-0.9.0-r1.ebuild b/dev-python/jellyfish/jellyfish-0.9.0-r1.ebuild
index 643ce8678efa..888a5f3f5b29 100644
--- a/dev-python/jellyfish/jellyfish-0.9.0-r1.ebuild
+++ b/dev-python/jellyfish/jellyfish-0.9.0-r1.ebuild
@@ -14,7 +14,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="BSD-2"
 SLOT="0"
-KEYWORDS="amd64 ~x86"
+KEYWORDS="amd64 x86"
 
 BDEPEND="
 	test? (
diff --git a/dev-python/jellyfish/jellyfish-0.9.0.ebuild b/dev-python/jellyfish/jellyfish-0.9.0.ebuild
deleted file mode 100644
index 91972ec8fb03..000000000000
--- a/dev-python/jellyfish/jellyfish-0.9.0.ebuild
+++ /dev/null
@@ -1,29 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{7,8,9,10} )
-inherit distutils-r1
-
-DESCRIPTION="Python module for doing approximate and phonetic matching of strings"
-HOMEPAGE="https://github.com/jamesturk/jellyfish https://pypi.org/project/jellyfish/"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="BSD-2"
-SLOT="0"
-KEYWORDS="amd64 x86"
-
-BDEPEND="
-	test? (
-		dev-python/unicodecsv[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-
-python_test() {
-	cp -r testdata "${BUILD_DIR}" || die
-	cd "${BUILD_DIR}" || die
-	epytest lib/jellyfish/test.py
-}
diff --git a/dev-python/oauthlib/oauthlib-3.2.0.ebuild b/dev-python/oauthlib/oauthlib-3.2.0.ebuild
index c37fca87ef8e..bd4384996ee9 100644
--- a/dev-python/oauthlib/oauthlib-3.2.0.ebuild
+++ b/dev-python/oauthlib/oauthlib-3.2.0.ebuild
@@ -14,7 +14,7 @@ SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="amd64 ~arm arm64 x86"
+KEYWORDS="amd64 ~arm arm64 ~riscv x86"
 
 # optional extras hard set as RDEPs. See setup.py
 RDEPEND="
diff --git a/dev-python/pikepdf/Manifest b/dev-python/pikepdf/Manifest
index a29793b60666..7fa33da066a8 100644
--- a/dev-python/pikepdf/Manifest
+++ b/dev-python/pikepdf/Manifest
@@ -1,2 +1,3 @@
 DIST pikepdf-5.0.1.tar.gz 2354060 BLAKE2B 0aafaa27642dc2ee5994e670cbc7c7f828027111ce6a7aeb0ff71db8a07a271a1335c60ee9cbbbdbaaf9f8403e206df2c3083cc735cf5bc7f8810b4b113d1634 SHA512 d259806303a3faed861b91cc838efb1317b0d865220708f379d9a674e4ffc0a2752be9b09bcad9950edff7fe8a1c1511c56d9348cfd8ce7c0ca8893316a3ce78
 DIST pikepdf-5.1.0.tar.gz 2354197 BLAKE2B dd6fdfac9a5050ed0f935f4a17a4ce6561f5e67b02b8f651d3d9944aee329086827eda06c6fba95d4371147ab148394cde7040d003efcdad14dcf0fbe89690c5 SHA512 2b7aeb5156e296957c6f7a0c9c1e46e75368b6683f0c79d11a6e01c04c7cb58839d831990c8203f2d6ad5759b95e7766cf2e6fd831e582744eb830d3483fac68
+DIST pikepdf-5.1.1.tar.gz 2354977 BLAKE2B e9cdeac42fe49fd4497931ee1a45dea43b36059b485fd81bef0a7c73fda018c60db55d686a4016c6c10d39b85730da72cb064a3dec0619e8ad5f9ea72a451b5a SHA512 63e44381404a15d29a81d1b6ec0d547ada93f43cfea8ef5bd9310b9ffc60bc17a55f32fcfd3c5f92e8818817f167ff549cf88df0c95ef960c353bc3d7efd2f25
diff --git a/dev-python/pikepdf/pikepdf-5.1.1.ebuild b/dev-python/pikepdf/pikepdf-5.1.1.ebuild
new file mode 100644
index 000000000000..9b67efc0592c
--- /dev/null
+++ b/dev-python/pikepdf/pikepdf-5.1.1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="Python library to work with pdf files based on qpdf"
+HOMEPAGE="https://pypi.org/project/pikepdf/ https://github.com/pikepdf/pikepdf"
+SRC_URI="
+	https://github.com/${PN}/${PN}/archive/v${PV/_p/.post}.tar.gz
+		-> ${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND=">=app-text/qpdf-10.6.2:0="
+RDEPEND="${DEPEND}
+	<dev-python/pillow-10[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20[${PYTHON_USEDEP}]
+	>=dev-python/pybind11-2.9.1[${PYTHON_USEDEP}]"
+BDEPEND="
+	>=dev-python/pybind11-2.9.1[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-6.4[${PYTHON_USEDEP}]
+	dev-python/tomli[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm_git_archive[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-5[${PYTHON_USEDEP}]
+		>=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
+		>=dev-python/psutil-5[${PYTHON_USEDEP}]
+		>=dev-python/pytest-6[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-1.4.2[${PYTHON_USEDEP}]
+		>=dev-python/python-dateutil-2.8.0[${PYTHON_USEDEP}]
+		>=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+	)"
+
+#distutils_enable_sphinx docs \
+#	dev-python/ipython \
+#	dev-python/matplotlib \
+#	dev-python/sphinx_rtd_theme
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/-n auto/d' pyproject.toml || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/pylint/Manifest b/dev-python/pylint/Manifest
index 56af8334ed1b..0a577317d728 100644
--- a/dev-python/pylint/Manifest
+++ b/dev-python/pylint/Manifest
@@ -2,3 +2,4 @@ DIST pylint-2.12.2.gh.tar.gz 1032702 BLAKE2B de7dce04159b332baa5c23f4034ee249e49
 DIST pylint-2.13.0.gh.tar.gz 1114326 BLAKE2B 2d99ae38474a13ecf0b306b2de445b93ef39c4ed286abdbc62e08580b34ea22615983bded024f87eb4ad5e9cfdd12edbab6e7bf841d4e7827c945e798f31771f SHA512 7ca5fdf6d5835886ae01937fad56319cc9b71248d7a8aa6c6d92ba4bf5d35340ec0a16c1b2029d1ca5170f8c3abd29b1d6915a415d5df3c0949f4f9c0d6a690c
 DIST pylint-2.13.1.gh.tar.gz 1116054 BLAKE2B 633636f97e284a8a93c598261b90019ea359fd61cf2e833936749a6a650098772c46008f465b118634cfa3cc8d873d9bbdd7d4b0e54621e47b7c33a33938b01d SHA512 9e5f6f2578d240a4984e00fd9e9a33a39bac4855060054f96c4414d8e1c6c16cd6a27d4d5e82fde52f91b2d25595d638e66e928c82aa3eb72a37c61f7aa6e038
 DIST pylint-2.13.2.gh.tar.gz 1116482 BLAKE2B da35c9f39781bbd796e2ec055b41c44211588d7da360fd27f81eef57a3f5c65e27931ca927b41692627c9914f5c28e3262c0f34a45c38b20aa1b83710ab1d1f1 SHA512 15274658cf3067ffa6635a94f2c75d8854b3843be45ea5dc5896bc12583b156428858baeed19eed4bfab35489326d70d0cce1375354d9ec97d00cfd895fc4a47
+DIST pylint-2.13.3.gh.tar.gz 1116747 BLAKE2B 9ab6ff4746f78472de9c248754d102e55e8cb60d3ead8c5079cfe851b2b7c8e16afc9b0be02041cf24e789784200b90751ad0bcf172eb6d4edd88463863d18ac SHA512 0bda6d89219ad6f7f64f1361f95b85a34e3bc70f9f18f71eaa3d69deb47ab6fc056000c13a11c8c5644f0a9789eac2a5c262ddcf96302aeebfa16aa2e3b3086c
diff --git a/dev-python/pylint/pylint-2.13.3.ebuild b/dev-python/pylint/pylint-2.13.3.ebuild
new file mode 100644
index 000000000000..971a6044db64
--- /dev/null
+++ b/dev-python/pylint/pylint-2.13.3.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python code static checker"
+HOMEPAGE="
+	https://www.logilab.org/project/pylint
+	https://pypi.org/project/pylint/
+	https://github.com/pycqa/pylint/
+"
+SRC_URI="
+	https://github.com/pycqa/pylint/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~m68k ~ppc ~riscv ~x86"
+IUSE="examples"
+
+# Make sure to check https://github.com/PyCQA/pylint/blob/main/setup.cfg#L43 on bumps
+# Adjust dep bounds!
+RDEPEND="
+	<dev-python/astroid-2.12[${PYTHON_USEDEP}]
+	>=dev-python/astroid-2.11.0[${PYTHON_USEDEP}]
+	>=dev-python/dill-0.2[${PYTHON_USEDEP}]
+	>=dev-python/isort-4.2.5[${PYTHON_USEDEP}]
+	<dev-python/isort-6[${PYTHON_USEDEP}]
+	>=dev-python/mccabe-0.6[${PYTHON_USEDEP}]
+	<dev-python/mccabe-0.8[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+"
+BDEPEND="
+	test? (
+		>=dev-python/GitPython-3[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.4.4-sphinx-theme.patch"
+)
+
+distutils_enable_sphinx doc --no-autodoc
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# No need to run the benchmarks
+		tests/benchmark/test_baseline_benchmarks.py
+
+		# TODO
+		'tests/test_functional.py::test_functional[forgotten_debug_statement_py37]'
+		'tests/test_functional.py::test_functional[dataclass_with_field]'
+		tests/checkers/unittest_typecheck.py::TestTypeChecker::test_nomember_on_c_extension_error_msg
+		tests/checkers/unittest_typecheck.py::TestTypeChecker::test_nomember_on_c_extension_info_msg
+	)
+	# Specify the test directory explicitly to avoid import file mismatches
+	epytest tests
+}
+
+python_install_all() {
+	if use examples ; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/pypy-exe/Manifest b/dev-python/pypy-exe/Manifest
index b22b36917ccc..c5323d318202 100644
--- a/dev-python/pypy-exe/Manifest
+++ b/dev-python/pypy-exe/Manifest
@@ -1,2 +1,4 @@
 DIST pypy2.7-gentoo-patches-7.3.8.tar.xz 7428 BLAKE2B 5362c34929e2053fc9a806e9894f35cce02ba1ebfad66cc64acc200ade4317934ee50dbc072194d19e201dea2a678abd609001ffe7e39bd6890a3b26c9d6d00e SHA512 6a7bfadac8f638e69419a6a1536af595a63bb2b4e3028da6423bd164d3df5399901b217468b1b374a5162ca8d2e5a61c4a19996f9e63109ed414a1aedcaac5d6
+DIST pypy2.7-gentoo-patches-7.3.9.tar.xz 7428 BLAKE2B 0a42e3c04ac0e560d56ce7218db81fa55f74ad45a4a033ccda8c5fba34e3a0b1f06587b5b18e947170cc635bd44e5a7799daeec9319c6a09165a73b32554a4b6 SHA512 3a52d40ccf8d77f3493a763b51e4bf86a808f6478191ed4eeaa4f2c2ce8b75769c3880d07cbc7614d8af5573f3e8edfe694be41626b947f3d06c321cf4f59abd
 DIST pypy2.7-v7.3.8-src.tar.bz2 23279006 BLAKE2B 7b2f5bfaffb99d3444f355039f743a21016dea22cc78cd5feca05eb12ce0e5ed39dafd22a8726994d0aff789e68b506197680e7181087313d2c5cd17b674ae4d SHA512 6ff90fad998c25aec5823e61d65266c169e89cba2ee2e3b6d0864d34d69a6b9fe7ad4d591bc8b38a48c5c22ea3dd468d3188cd34e03746c258752eaa24ac3ae2
+DIST pypy2.7-v7.3.9-src.tar.bz2 23328628 BLAKE2B 50d015439b6a6f15dd24eb4524726a2054f0d8e7ef209b54dc4eb9365b41b333f3dad525422316af3ff19e6ffb5866859db4455e05fc1529a81ce3b6e7c621db SHA512 8d7513d4efe924f2456dd65a45a82dd16171f7962c81ba90f2a168c332cdad78ceffa3ed1af379c09e61082b39d5c2a8385cd77c89b698c47cc75e9df1bb4d2a
diff --git a/dev-python/pypy-exe/pypy-exe-7.3.9.ebuild b/dev-python/pypy-exe/pypy-exe-7.3.9.ebuild
new file mode 100644
index 000000000000..e0c13c3fc05a
--- /dev/null
+++ b/dev-python/pypy-exe/pypy-exe-7.3.9.ebuild
@@ -0,0 +1,185 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+inherit check-reqs pax-utils python-any-r1 toolchain-funcs
+
+PYPY_PV=${PV%_p*}
+MY_P=pypy2.7-v${PYPY_PV/_}
+PATCHSET="pypy2.7-gentoo-patches-${PV/_}"
+
+DESCRIPTION="PyPy executable (build from source)"
+HOMEPAGE="https://www.pypy.org/"
+SRC_URI="
+	https://buildbot.pypy.org/pypy/${MY_P}-src.tar.bz2
+	https://dev.gentoo.org/~mgorny/dist/python/${PATCHSET}.tar.xz
+"
+S="${WORKDIR}/${MY_P}-src"
+
+LICENSE="MIT"
+SLOT="${PYPY_PV}"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="bzip2 +jit low-memory ncurses cpu_flags_x86_sse2"
+
+RDEPEND="
+	>=sys-libs/zlib-1.1.3:0=
+	dev-libs/libffi:0=
+	virtual/libintl:0=
+	dev-libs/expat:0=
+	bzip2? ( app-arch/bzip2:0= )
+	ncurses? ( sys-libs/ncurses:0= )
+	!dev-python/pypy-exe-bin:${PYPY_PV}
+"
+# don't enforce the dep on pypy with USE=low-memory since it's going
+# to cause either collisions or circular dep on itself
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	!low-memory? (
+		|| (
+			dev-python/pypy
+			dev-lang/python:2.7
+		)
+	)
+"
+
+check_env() {
+	if use low-memory; then
+		if ! has_version -b dev-python/pypy &&
+				! has_version -b dev-python/pypy-bin
+		then
+			eerror "USE=low-memory requires a (possibly old) version of dev-python/pypy"
+			eerror "being installed. Please install it using e.g.:"
+			eerror
+			eerror "  $ emerge -1v dev-python/pypy dev-python/pypy-exe-bin"
+			eerror
+			eerror "before attempting to build dev-python/pypy-exe[low-memory]."
+			die "dev-python/pypy needs to be installed for USE=low-memory"
+		fi
+
+		CHECKREQS_MEMORY="1750M"
+		use amd64 && CHECKREQS_MEMORY="3500M"
+	else
+		CHECKREQS_MEMORY="3G"
+		use amd64 && CHECKREQS_MEMORY="6G"
+	fi
+
+	check-reqs_pkg_pretend
+}
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && check_env
+}
+
+pkg_setup() {
+	if [[ ${MERGE_TYPE} != binary ]]; then
+		check_env
+
+		use low-memory && EPYTHON=
+		if [[ ! ${EPYTHON} || ${EPYTHON} == pypy ]] &&
+				{ has_version -b dev-python/pypy ||
+				has_version -b dev-python/pypy-bin; }
+		then
+			einfo "Using already-installed PyPy to perform the translation."
+			EPYTHON=pypy
+		else
+			einfo "Using ${EPYTHON} to perform the translation. Please note that upstream"
+			einfo "recommends using PyPy for that. If you wish to do so, please unset"
+			einfo "the EPYTHON variable."
+			python-any-r1_pkg_setup
+		fi
+	fi
+}
+
+src_prepare() {
+	local PATCHES=(
+		"${WORKDIR}/${PATCHSET}"
+	)
+	default
+}
+
+src_configure() {
+	tc-export CC
+
+	local jit_backend
+	if use jit; then
+		jit_backend='--jit-backend='
+
+		# We only need the explicit sse2 switch for x86.
+		# On other arches we can rely on autodetection which uses
+		# compiler macros. Plus, --jit-backend= doesn't accept all
+		# the modern values...
+
+		if use x86; then
+			if use cpu_flags_x86_sse2; then
+				jit_backend+=x86
+			else
+				jit_backend+=x86-without-sse2
+			fi
+		else
+			jit_backend+=auto
+		fi
+	fi
+
+	local args=(
+		--no-shared
+		$(usex jit -Ojit -O2)
+
+		${jit_backend}
+
+		pypy/goal/targetpypystandalone
+	)
+
+	# Avoid linking against libraries disabled by use flags
+	local opts=(
+		bzip2:bz2
+		ncurses:_minimal_curses
+	)
+
+	local opt
+	for opt in "${opts[@]}"; do
+		local flag=${opt%:*}
+		local mod=${opt#*:}
+
+		args+=(
+			$(usex ${flag} --withmod --withoutmod)-${mod}
+		)
+	done
+
+	local interp=( "${EPYTHON}" )
+	if use low-memory; then
+		interp=( env PYPY_GC_MAX_DELTA=200MB
+			"${EPYTHON}" --jit loop_longevity=300 )
+	fi
+
+	if [[ ${EPYTHON} != pypy ]]; then
+		# reuse bundled pycparser to avoid external dep
+		mkdir -p "${T}"/pymod/cffi || die
+		: > "${T}"/pymod/cffi/__init__.py || die
+		cp -r lib_pypy/cffi/_pycparser "${T}"/pymod/cffi/ || die
+		local -x PYTHONPATH=${T}/pymod:${PYTHONPATH}
+	fi
+
+	# translate into the C sources
+	# we're going to build them ourselves since otherwise pypy does not
+	# free up the unneeded memory before spawning the compiler
+	set -- "${interp[@]}" rpython/bin/rpython --batch --source "${args[@]}"
+	echo -e "\033[1m${@}\033[0m"
+	"${@}" || die "translation failed"
+}
+
+src_compile() {
+	emake -C "${T}"/usession*-0/testing_1
+}
+
+src_install() {
+	local dest=/usr/lib/pypy2.7
+	exeinto "${dest}"
+	newexe "${T}"/usession*-0/testing_1/pypy-c pypy-c-${PYPY_PV}
+	insinto "${dest}"/include/${PYPY_PV}
+	doins include/pypy_*
+	pax-mark m "${ED}${dest}/pypy-c-${PYPY_PV}"
+}
diff --git a/dev-python/pypy3-exe-bin/Manifest b/dev-python/pypy3-exe-bin/Manifest
index a6e72860e85d..91eade7e4e7e 100644
--- a/dev-python/pypy3-exe-bin/Manifest
+++ b/dev-python/pypy3-exe-bin/Manifest
@@ -2,3 +2,5 @@ DIST pypy3-exe-7.3.7-1.amd64.xpak 12149428 BLAKE2B 468fe50d8b607793438bc59179acb
 DIST pypy3-exe-7.3.7-1.x86.xpak 9221421 BLAKE2B fc24f93533127f48ffc5974dfd3eb4611442489aee6318ccb911a2f3e3d234bc44c659309006ffe55eb6de3a00915fa3aaf6dc50e4efb1adb668d0d38281cf3c SHA512 9322a25ad230615cc96b81448a0591f730a5d09b57c02259412d427290934074baeb48f58f3829d393137252d5cf1b3f0fdd3b50d9194d69ea3ab38fbe83abac
 DIST pypy3-exe-7.3.8-1.amd64.xpak 12480863 BLAKE2B 4db76687e1662a9674dcf2ac863cf837b27551874613ee94281cd0d2e701214fc65181ae54a52246d8d0cd01631e0a35fe0c044ea916a488e53aa6e8850c95c4 SHA512 dee849a1e066ef28ab1bedd37cc3a89a087f5cf44d2144862df7825880a1b6bd3238dbe94e4ca47a2009945cb716b8720bec42e32228afeaebd69d5ac6c1e077
 DIST pypy3-exe-7.3.8-1.x86.xpak 9211472 BLAKE2B d0fd9fc64fb29367dfa017ac9654c699f11386f4a661cfad12cbb2b543f6ab4bf74a9f5131da3ae1307d03fce1d801d4b04c9bdd43c2ee42592e8658c91fae39 SHA512 5311a7aa24b8ea24ee408f3f0ff1efb14ca9875d36991f3e842819841d304a3df000679712b6e2d00095590bc684c262c44a4f9ad8e41fadaf0b0e0ffb0fc220
+DIST pypy3-exe-7.3.9-1.amd64.xpak 12455132 BLAKE2B 09ad89ca1d7ba84ff1b5c0d925c02617567d8d6c659774e980dc9e56fd1bd5eef9b612631d64ace8218bdd2c5723cad174d49ac3c5ef442d244f2ba21ebb6d0d SHA512 078f57a0027680ff061f137a47fa5349254a086e1c28eb81fd9d89079bd3894902b532cde39c5214b0a686fd1a1dba2589f1fb0f9c5e6ff43cc7f4db97b3c181
+DIST pypy3-exe-7.3.9-1.x86.xpak 9239282 BLAKE2B d44b9f3410a94ad41c1f49abe641460464ae6266478e7c38a994ded97fd70f50a041977fc72fe11a1c7fcfc9aeae4782564c2cbaaf8477a0eef60e443ec837e1 SHA512 1a073254e0c6bef089169a138a84ff6efe377374b9f263f58f856bba937f8e6249d835e3bdc9a68792e7178105e03a67dee3a3e5307089b6ed3b846ae8ee73ed
diff --git a/dev-python/pypy3-exe-bin/pypy3-exe-bin-7.3.9.ebuild b/dev-python/pypy3-exe-bin/pypy3-exe-bin-7.3.9.ebuild
new file mode 100644
index 000000000000..d8bcb20900a9
--- /dev/null
+++ b/dev-python/pypy3-exe-bin/pypy3-exe-bin-7.3.9.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit pax-utils
+
+MY_P=pypy3-exe-${PV}-1
+DESCRIPTION="PyPy3 executable (pre-built version)"
+HOMEPAGE="https://www.pypy.org/"
+SRC_URI="
+	amd64? (
+		https://dev.gentoo.org/~mgorny/binpkg/amd64/pypy/dev-python/pypy3-exe/${MY_P}.xpak
+			-> ${MY_P}.amd64.xpak
+	)
+	x86? (
+		https://dev.gentoo.org/~mgorny/binpkg/x86/pypy/dev-python/pypy3-exe/${MY_P}.xpak
+			-> ${MY_P}.x86.xpak
+	)
+"
+S="${WORKDIR}"
+
+LICENSE="MIT"
+SLOT="3.9-${PV%_p*}"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=sys-libs/zlib-1.1.3:0/1
+	|| (
+		dev-libs/libffi-compat:7
+		dev-libs/libffi:0/7
+	)
+	virtual/libintl:0/0
+	dev-libs/expat:0/0
+	app-arch/bzip2:0/1
+	sys-libs/ncurses:0/6
+	!dev-python/pypy-exe:${SLOT}
+"
+
+PYPY_PV=${PV%_p*}
+QA_PREBUILT="
+	usr/bin/pypy3.9-c-${PYPY_PV}
+"
+
+src_unpack() {
+	ebegin "Unpacking ${MY_P}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${MY_P}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${MY_P} failed"
+}
+
+src_install() {
+	insinto /
+	doins -r usr
+	fperms +x "/usr/bin/pypy3.9-c-${PYPY_PV}"
+	pax-mark m "${ED}/usr/bin/pypy3.9-c-${PYPY_PV}"
+}
diff --git a/dev-python/pywinrm/pywinrm-0.4.2-r1.ebuild b/dev-python/pywinrm/pywinrm-0.4.2-r1.ebuild
index f715e6c0ad1e..6def4f563d4c 100644
--- a/dev-python/pywinrm/pywinrm-0.4.2-r1.ebuild
+++ b/dev-python/pywinrm/pywinrm-0.4.2-r1.ebuild
@@ -14,7 +14,7 @@ SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64"
+KEYWORDS="~amd64 ~riscv"
 IUSE="kerberos"
 
 RDEPEND="
diff --git a/dev-python/stripe/Manifest b/dev-python/stripe/Manifest
index 9509b61905aa..39a672a23a21 100644
--- a/dev-python/stripe/Manifest
+++ b/dev-python/stripe/Manifest
@@ -1,2 +1,3 @@
 DIST stripe-2.66.0.tar.gz 234929 BLAKE2B 289c3464c3aa9ef5ebeccaffde383271ca23e704303d5b5499d1f5f1f197483088781d16878749bca03c8ea56209a22173c376ef00510f53d81c733f0a626af8 SHA512 d716e82580757ec0b187a74de1f8ef7bbe2f32468f13c551886bcbadf631eef001df9f4d249f091856b009545ca8b6d60f16c07e79345fee33651e7d27fb31c0
 DIST stripe-2.67.0.tar.gz 235426 BLAKE2B ee396b0b7d3991afdd81e6b051fad0168a7b3dcfaddccc7700292878fc437788dcc40480fea2131dd52e3b787dc6e7b420d6023079f55d9365f76076cc51070d SHA512 099208259c6ca8d69fd6f39f72b9f12f41eace2f0a2a08b017f6141ad06882df742749941326fb8d9898db7c59e32ed74a464ad372d6f7f0a929c9ae4e4d2475
+DIST stripe-2.70.0.tar.gz 239653 BLAKE2B d59d7b452e91169e83e4d4bc10b544fc94c48aa3a967c899136b1b9ea60e835d998c1a5a0c5e131989d9628c36b77e3fe133952dddbede69d0bcfa11dc9fc640 SHA512 62f40d82e4a5d37ce070a2457b8372d903993e209f6a042ab97a93f5ee98eb994c0cac070451e2b130df9a72f4a9ece65600266735b438aff3cc5cf09e217b27
diff --git a/dev-python/stripe/stripe-2.70.0.ebuild b/dev-python/stripe/stripe-2.70.0.ebuild
new file mode 100644
index 000000000000..eefd4e50929a
--- /dev/null
+++ b/dev-python/stripe/stripe-2.70.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Stripe python bindings"
+HOMEPAGE="https://github.com/stripe/stripe-python"
+SRC_URI="mirror://pypi/s/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/requests-2.20[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-util/stripe-mock-0.122.0
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		net-misc/curl
+	)
+"
+
+distutils_enable_tests pytest
+
+DOCS=( LONG_DESCRIPTION.rst CHANGELOG.md README.md )
+
+python_test() {
+	epytest tests
+}
+
+src_test() {
+	local stripe_mock_port=12111
+	local stripe_mock_max_port=12121
+	local stripe_mock_logfile="${T}/stripe_mock_${EPYTHON}.log"
+	# Try to start stripe-mock until we find a free port
+	while [[ "${stripe_mock_port}" -le "${stripe_mock_max_port}" ]]; do
+		ebegin "Trying to start stripe-mock on port ${stripe_mock_port}"
+		stripe-mock --http-port ${stripe_mock_port} &> "${stripe_mock_logfile}" &
+		local stripe_mock_pid=$!
+		sleep 2
+		# Did stripe-mock start?
+		curl --fail -u "sk_test_123:" \
+			http://127.0.0.1:${stripe_mock_port}/v1/customers &> /dev/null
+		eend $? "Port ${stripe_mock_port} unavailable"
+		if [[ $? -eq 0 ]]; then
+			einfo "stripe-mock running on port ${stripe_mock_port}"
+			break
+		fi
+		(( stripe_mock_port++ ))
+	done
+	if [[ "${stripe_mock_port}" -gt "${stripe_mock_max_port}" ]]; then
+		eerror "Unable to start stripe-mock for tests"
+		die "Please see the logfile located at: ${stripe_mock_logfile}"
+	fi
+
+	local -x STRIPE_MOCK_PORT=${stripe_mock_port}
+	distutils-r1_src_test
+
+	# Tear down stripe-mock
+	kill "${stripe_mock_pid}" || die "Unable to stop stripe-mock"
+}
diff --git a/dev-python/voluptuous/Manifest b/dev-python/voluptuous/Manifest
index 3a2ee0654ac5..8e9bfccc528f 100644
--- a/dev-python/voluptuous/Manifest
+++ b/dev-python/voluptuous/Manifest
@@ -1 +1,2 @@
 DIST voluptuous-0.12.2.tar.gz 48477 BLAKE2B c1cc26b3ac87bcd357d522c8a5210397f1a16e68f812727f2e8ab18c6731d12a04c2e9a96735e25926854eb378feaaeb8bafc083f394b7e9c2dfa2a503abeeb9 SHA512 86193294c1c6a593f6556f23a9a2c093690a06cbdabb7e268db135e36af6a15c113e78f3e05d000276b6ff54b8e17a0a01d589e9232da9eb5320500fdb5757e1
+DIST voluptuous-0.13.0.tar.gz 47117 BLAKE2B 101cb8bb2e06cde87e1f19306188a9b7df9fa93cf940f69443b6730b678db09c93d2999b22cb22ad108b9f08c1096e4f9055330d77d31dded9bda1ae99a158d0 SHA512 a4b76a7d7e3f1f2697c09b025c2386b77c48e7f9d001e05ab0b93c91167e438352ac682d52527e2cc01d009787fedd4674cf7c926ed908022fe381c09d488f29
diff --git a/dev-python/voluptuous/voluptuous-0.13.0.ebuild b/dev-python/voluptuous/voluptuous-0.13.0.ebuild
new file mode 100644
index 000000000000..3714e7ffd554
--- /dev/null
+++ b/dev-python/voluptuous/voluptuous-0.13.0.ebuild
@@ -0,0 +1,21 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A Python data validation library"
+HOMEPAGE="https://github.com/alecthomas/voluptuous/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.11.5-fix-doctest.patch )
+
+distutils_enable_tests nose
diff --git a/dev-python/websocket-client/Manifest b/dev-python/websocket-client/Manifest
index 97e441652afe..eed7fe040ac6 100644
--- a/dev-python/websocket-client/Manifest
+++ b/dev-python/websocket-client/Manifest
@@ -1,2 +1,3 @@
 DIST websocket-client-1.2.3.tar.gz 46434 BLAKE2B e1e294938b41e6d82fa5cf8cd58fd9653e5170e11e546a04bce6dc0c8a9752cc25a21dbc1352fc614651f9fee43410a269a35e4c8dbacffec14f1ed8e8526f89 SHA512 5e5e00d43b7b4da5e2cb0d00d1e743e420791856e51e2b3d28d78219edcd7a2eace834ae4d7ee2faf89ab27c2b65f063e508f0e470a47ff9d88c36748b3dd113
 DIST websocket-client-1.3.1.tar.gz 47672 BLAKE2B c28af7684750e5d678a2e3bb5440eee2ff96effdc6f08a7312b7f596e39b29fd96936f04735b737fe00426869a3d8bb9eaf51c2aac32cbc845e7386d0a653780 SHA512 d60c5e755944ed0b2d426c75da9650a6624ee5718061a0cfb71b9a700e5bd3db9143702657175d7988b57e81117bad9cbb58636fb14ca55ad6addd90ff02ce0f
+DIST websocket-client-1.3.2.tar.gz 47821 BLAKE2B bdd398885f1c76646e094f6e2efa3c886bfddb0d5f1a2961ad2586444c9bff7272f61d880567e7826aa49c36ac48d6cad1583d0cc4bdb73d0f1702e9b4bf2e2b SHA512 c2a38aa3fff0e7f94433cec1939ce75074d9f89d403c0627f34e3a0486dc35fe00230ba7c05f9172a89d3ee49f0ef53ae367eca864f34ec95932966b31d6c3a8
diff --git a/dev-python/websocket-client/websocket-client-1.3.2.ebuild b/dev-python/websocket-client/websocket-client-1.3.2.ebuild
new file mode 100644
index 000000000000..5968d1c40f2f
--- /dev/null
+++ b/dev-python/websocket-client/websocket-client-1.3.2.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="WebSocket client for python with hybi13 support"
+HOMEPAGE="https://github.com/websocket-client/websocket-client"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="examples"
+
+BDEPEND="
+	test? (
+		dev-python/python-socks[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}