Adding metadata

27 files changed, 608 insertions, 80 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 197184c77142..616059cae3b8 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -7,3 +7,4 @@ DIST boto3-1.24.50.gh.tar.gz 526501 BLAKE2B 4ff77e527a990be760296471f6695eac1604
 DIST boto3-1.24.51.gh.tar.gz 526840 BLAKE2B e796ee5c68260b1b125e658b80b74e2f76e611b4e317abf716a9b42da74ede88a17032d7035585bc92e029a1a8236443faf9aa2c52c541e421ee98fdf78e9769 SHA512 2f05f422dbe347940ce2fef0d2a55b79f26077237b6171a17f77dc5e97af4b9d796748ef854020e06a7f8e895b462eb55a4b1f9f1f02b20a68fb3ee4bbb76bb3
 DIST boto3-1.24.52.gh.tar.gz 527776 BLAKE2B 301c8c8fe2a5b75af1aa34d72df8e16ecf9f547428f42dfda9c25d19f29fb6f955ea457cf5b61cced45f36e008073bab02a93e955dea2749a2dcaa881e1f2b79 SHA512 1a7fb5aa77f7bccc1a9f58c3d4149ff653b0e4cb22dd2a47bf255d09ba09ccba2dabba32d444c85b78762d1b140b538da5b274546e2883a00f849d6fca0a1a91
 DIST boto3-1.24.53.gh.tar.gz 527969 BLAKE2B f0075c531876176c11a874398f2935a7ced0e42b233941825e1d926d8ad0ab76f594edc14eaafc80a47c9f6b030df5ea04a555d57de101b28096d67eda693409 SHA512 b1186ef0f1d9c3f1f7b0bd651882c0f771c2de280a66ba2b2d03f4ef0cb8e9c2d0c7544fad2cb72706d0576a3871bc26b42ea4a711647fac3837a6f1e1fc3d9f
+DIST boto3-1.24.54.gh.tar.gz 528596 BLAKE2B a34f5bdd4a72aecaa40b9235696b502702c39a14fc4dc23fc03d4abfc2fe763c278e00b20f04b1167a5acedb77c6c149cdd053eb7ed2dd4ed4333790b4fc0ab7 SHA512 82f77416f0ae1bfadfe59764ec2e956e1533359c4cd28ea82d955c1b909d8057e5cfb2588ad14d8edf54ad44b623ce17fe7bdbd976e1928bcd8f8cdf6d7a9489
diff --git a/dev-python/boto3/boto3-1.24.54.ebuild b/dev-python/boto3/boto3-1.24.54.ebuild
new file mode 100644
index 000000000000..e4a98e2e28f5
--- /dev/null
+++ b/dev-python/boto3/boto3-1.24.54.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index e3861cb7b856..12205598ea5d 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -7,3 +7,4 @@ DIST botocore-1.27.50.gh.tar.gz 9519905 BLAKE2B 2a44bcc5c66a4306884683f9da022750
 DIST botocore-1.27.51.gh.tar.gz 9525092 BLAKE2B c38085ca15f4dfef1853ef40cc7fe09ab1e19efe8f680e7bf5a1d586c3519ca48c43432ac534fc24c7ff9d4630136cda7782af82b3b7d4a4bab5f726419def7a SHA512 67b2bccfc2fc92edd8397b02b5e5bf896ec09b6b826c9bab6a1dcdc523de78900b0204443a862728384bf0596e2c79f6fc27ba3a95c3556e7e10c6ace941afe1
 DIST botocore-1.27.52.gh.tar.gz 9525783 BLAKE2B 272b7b36f51b4048bbf75b426826ce5c60fb7fd2b9fbd714b1aaf02fdb99da6b522ae5cecea0468755a9edb2cd4d82a8fc6794b9f4a6e64d3c129a436f6a8397 SHA512 cb231a0dff10c55212ce013daa686b96da59b226ef545911a6dc535ce29565aca317e300d6a8dbcf2de1e3c97f761a6ad46f66d17aad2980be7e7f45166e3365
 DIST botocore-1.27.53.gh.tar.gz 9527747 BLAKE2B 9b5d2c01af6692bac0e105fbb2283741aba21894a28270d6f3d57fd59b9f72cb6552361ed2a07392980a3921cdccd151aa62f378099028e8ae25c3a4cbd32e0d SHA512 78602aea42ce262f5e8552708a4e93a5a49dc2de61e83e6d2ad63627cc6aa0dd236992adaa22613098346f0d042ee572ee40de01794518cb7db443a92b5c3d58
+DIST botocore-1.27.54.gh.tar.gz 9535763 BLAKE2B e1797243102043564a369c519397a609a4b8b6dcc9b8362f2b05961279b4b858e4f1d81ba6f4898039812a87729e0c9e9b880abe6cb509ba0fce442933aaf563 SHA512 714d70cd2d86add4c34a8ffbba3e89305928a614013bc56214dad25eeb1a7766805e737d9fb54ee96e8df81892d2faebeaa6639adea6d1f4cd50c5ac9b589c6b
diff --git a/dev-python/botocore/botocore-1.27.54.ebuild b/dev-python/botocore/botocore-1.27.54.ebuild
new file mode 100644
index 000000000000..6a8e7e93c947
--- /dev/null
+++ b/dev-python/botocore/botocore-1.27.54.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/ensurepip-setuptools/Manifest b/dev-python/ensurepip-setuptools/Manifest
index c86590636a50..deb7cbedb88f 100644
--- a/dev-python/ensurepip-setuptools/Manifest
+++ b/dev-python/ensurepip-setuptools/Manifest
@@ -1 +1,2 @@
 DIST setuptools-65.0.2-py3-none-any.whl 1233332 BLAKE2B 0c0d0db73452d15947097f3d453f01bb42ef150b50122b7a1f39212f663064284bc313a04c3dbe99e8da7e614d72a963d6c9f0c8f486f5d84131a06718b288c8 SHA512 11d9975468166bf7db9a9da44d893a67daacc5f309da1b521278a95a33fa2b3574cae10840c9943de54bf5d411e54697f91b62a3bfb5a6a3bc69b804af2a1365
+DIST setuptools-65.1.0-py3-none-any.whl 1232689 BLAKE2B db8f85b99b1d47af55d484d77ecafe5122abe9ab8dcec565659bb91c16aa26513c00d8684ca3b7b57e629d512b42273188a00ee0a0958bba5097ce150869609f SHA512 1072a826964ec3413c5bcd3f930a2f314b87b0b77714ddc948573841fbb871a898843211beaff0bcc5e003fcaab678de5d2b9a3a9fa864beced1bf2af282d048
diff --git a/dev-python/ensurepip-setuptools/ensurepip-setuptools-65.1.0.ebuild b/dev-python/ensurepip-setuptools/ensurepip-setuptools-65.1.0.ebuild
new file mode 100644
index 000000000000..96c75c915768
--- /dev/null
+++ b/dev-python/ensurepip-setuptools/ensurepip-setuptools-65.1.0.ebuild
@@ -0,0 +1,27 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN=${PN#ensurepip-}
+WHL=${MY_PN}-${PV}-py3-none-any.whl
+
+DESCRIPTION="Shared setuptools wheel for ensurepip Python module"
+HOMEPAGE="https://pypi.org/project/setuptools/"
+SRC_URI="
+	https://files.pythonhosted.org/packages/py3/${MY_PN::1}/${MY_PN}/${WHL}
+"
+S=${DISTDIR}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	!<dev-python/ensurepip-wheels-100
+"
+
+src_install() {
+	insinto /usr/lib/python/ensurepip
+	doins "${WHL}"
+}
diff --git a/dev-python/hatch-fancy-pypi-readme/Manifest b/dev-python/hatch-fancy-pypi-readme/Manifest
new file mode 100644
index 000000000000..172765ae3b7b
--- /dev/null
+++ b/dev-python/hatch-fancy-pypi-readme/Manifest
@@ -0,0 +1 @@
+DIST hatch-fancy-pypi-readme-22.3.0.gh.tar.gz 22107 BLAKE2B 7358a35ed9176d5107d406c1f99cfcf17ce409224dcad55ac845087e2fd6cc9ab88e5ea929e3b1304bbff6464cbbbd0b0d9716bcfe199dcd887c809cd6a9356a SHA512 93fe293ddce6dde450bc427d8fa492cf2b1f7d4a0e2d754873f765f588a962ca2c7c48b515ba613503bed6100b302ed91bbedb4d6a9f8d7bc10ab4b1418164e8
diff --git a/dev-python/hatch-fancy-pypi-readme/hatch-fancy-pypi-readme-22.3.0.ebuild b/dev-python/hatch-fancy-pypi-readme/hatch-fancy-pypi-readme-22.3.0.ebuild
new file mode 100644
index 000000000000..40b7c813be57
--- /dev/null
+++ b/dev-python/hatch-fancy-pypi-readme/hatch-fancy-pypi-readme-22.3.0.ebuild
@@ -0,0 +1,36 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Fancy PyPI READMEs with Hatch"
+HOMEPAGE="
+	https://pypi.org/project/hatch-fancy-pypi-readme/
+	https://github.com/hynek/hatch-fancy-pypi-readme
+"
+SRC_URI="
+	https://github.com/hynek/hatch-fancy-pypi-readme/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/hatchling[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# tests for self build a wheel? No need for that and fails.
+	tests/test_end_to_end.py
+)
diff --git a/dev-python/hatch-fancy-pypi-readme/metadata.xml b/dev-python/hatch-fancy-pypi-readme/metadata.xml
new file mode 100644
index 000000000000..ea8988e8af6a
--- /dev/null
+++ b/dev-python/hatch-fancy-pypi-readme/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+  <email>python@gentoo.org</email>
+  <name>Python</name>
+ </maintainer>
+ 
+ <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/ipywidgets/Manifest b/dev-python/ipywidgets/Manifest
index 26c03187d5c5..818851ad02b9 100644
--- a/dev-python/ipywidgets/Manifest
+++ b/dev-python/ipywidgets/Manifest
@@ -1 +1,2 @@
 DIST ipywidgets-7.7.1.tar.gz 4075672 BLAKE2B 1e52d3b3b9380f42f67ad658f6e8579a61220e7160c10b1569437c1fd74ce962fbe746f3a6a3e302b5417812f69807deddc0ae3fe255b8e2f213d65103d55362 SHA512 ed6bf1a59a511714a3af96cc66e7665b9b264f56862ca4ea02d943137fcc6018da8fcb8dff4a8f9157bfb46cc19b7d58ceaff028e84f2f8d18ee16e57ce7fb96
+DIST ipywidgets-8.0.1.tar.gz 111771 BLAKE2B 78217eaf6386f18a634c016562925213233ed6fc3b35266fede83f66e831f761766be0db3e23ef694edd9bc6089ff987df97f6addf2a17bc5ef1d4b6d59585b7 SHA512 cb443734897f786a86a34ab6177d84e32d00155513c835756dc53a76b7201144e0cb34c3701c06b07df22de78f6d43973f4b9be456c3b4a22db39c16de4a4dc6
diff --git a/dev-python/ipywidgets/ipywidgets-8.0.1.ebuild b/dev-python/ipywidgets/ipywidgets-8.0.1.ebuild
new file mode 100644
index 000000000000..734f7f7a3d08
--- /dev/null
+++ b/dev-python/ipywidgets/ipywidgets-8.0.1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="IPython HTML widgets for Jupyter"
+HOMEPAGE="
+	https://ipywidgets.readthedocs.io/
+	https://github.com/jupyter-widgets/ipywidgets/
+	https://pypi.org/project/ipywidgets/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/ipykernel-4.5.1[${PYTHON_USEDEP}]
+	>=dev-python/ipython_genutils-0.2.0[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/widgetsnbextension-3.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# upstream hack to autoconfigure ipywidgets in jupyter
+	# we don't have jupyterlab_widgets packaged
+	sed -i -e '/jupyterlab_widgets/d' setup.py || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/jsonschema/Manifest b/dev-python/jsonschema/Manifest
index c519c3f20b36..137925b5450e 100644
--- a/dev-python/jsonschema/Manifest
+++ b/dev-python/jsonschema/Manifest
@@ -1,5 +1,6 @@
 DIST jsonschema-4.10.0.tar.gz 286110 BLAKE2B b59e425df6a8d747424ff938de6cbd0eceaa16a1b16b795847f86662a5cbc7953f052f7aaac10109a4c75e69e227d29f3dbfdcd50197be0436f6e36ea02df29a SHA512 765ed96fe086feda9604d3079e78f62e35ab883e8826be57112bd8f7c4fedc385c4e2436b5224a171b3a7c0d18b22162ff0973448b339a8f13043532e52eb06d
 DIST jsonschema-4.10.2.tar.gz 285395 BLAKE2B 2e40fc5e8b93922c12110f1983f933a07455d9f5d1388fc2c1ee8f07e042f3840573553f709ab7f373c8f5be0651996ffd203696bd0ec1356e90163dad8f4eb4 SHA512 1328af7b4bc70ce43aec6e27b75c9ebe1c2745eceb3b794aeb41eb430362123f9b40dda26e90e62f23d5733ff4fd21407b05569603ee1e2a4941c2009e1855e7
+DIST jsonschema-4.12.1.tar.gz 287475 BLAKE2B 78f4e6fa120eef9ac3fead84fa28b16a8f4c212c570785f0f6f08fcec1a58c51f7cc756ba9a7272e71e3877e80e5e17e2e4d8fbcf503a20c27232dcb4b918085 SHA512 ae95bf3dccb7365af1814255a5aecc11044c3ee579921e935e7c3f955596fdf8d32bbdd0fa2693ea701792a8a29053cf25ef3ab9b08ffb66a6859059a877888f
 DIST jsonschema-4.7.2.tar.gz 278495 BLAKE2B 55c25847e210e0bdd3bec672b4b6a4eb1a2e2ec5167c115c34a2d0b2de079a00eaff8d901386b475fc26660887090896e78e3a38c1805f5b767fa1eece740e3b SHA512 c624d7bf317ca20fd8cdd248ec7d7679fde907ab304f1a092fc7a172464f43e41904d3f88df57e1351043b978448f51166a09af3625f00a9ad4d7353033b80af
 DIST jsonschema-4.8.0.tar.gz 279424 BLAKE2B 9e8936bde13841f9edf42ffe214ce8d1aaae8b9be4c3040871f228399a31b4292e8cfbf4bf4261822ca1b88622cb69cdf0d55bd2cc51bf191f6e364e9bfb94f8 SHA512 75a7593eb8b0163ba428f507ed4fd9fa6d51567f284776af96f4d79cb507a69666cc048034bfa3a401f960295779e935562dde4e97cf3f7b3b4571bc28b9dde7
 DIST jsonschema-4.9.0.tar.gz 281100 BLAKE2B 5a1c387fc33735ffd39342f3e62600aea721a51be0995d10aa1726e8e4c3bf93694a7844410c0b245c699880d6642a6903525b3637883f5e662086b53deb0948 SHA512 73fc9958f37802c4558ea6893386810784d2b577c04423b7090fce4cd052e3af078f0b0c46b2b16f96bb49820047f1ec5d96cf6c6cb822fca1d988cf1d70209f
diff --git a/dev-python/jsonschema/jsonschema-4.12.1.ebuild b/dev-python/jsonschema/jsonschema-4.12.1.ebuild
new file mode 100644
index 000000000000..c22d365a1b6d
--- /dev/null
+++ b/dev-python/jsonschema/jsonschema-4.12.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="An implementation of JSON-Schema validation for Python"
+HOMEPAGE="
+	https://pypi.org/project/jsonschema/
+	https://github.com/python-jsonschema/jsonschema/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/attrs-17.4.0[${PYTHON_USEDEP}]
+	>=dev-python/pyrsistent-0.18.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_resources-1.4.0[${PYTHON_USEDEP}]
+		dev-python/pkgutil_resolve_name[${PYTHON_USEDEP}]
+	' 3.8)
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+"
+
+# formatter deps
+RDEPEND+="
+	dev-python/fqdn[${PYTHON_USEDEP}]
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/isoduration[${PYTHON_USEDEP}]
+	>=dev-python/jsonpointer-1.13[${PYTHON_USEDEP}]
+	dev-python/rfc3339-validator[${PYTHON_USEDEP}]
+	dev-python/rfc3986-validator[${PYTHON_USEDEP}]
+	dev-python/rfc3987[${PYTHON_USEDEP}]
+	dev-python/uri_template[${PYTHON_USEDEP}]
+	>=dev-python/webcolors-1.11[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# requires pip, does not make much sense for the users
+	jsonschema/tests/test_cli.py::TestCLIIntegration::test_license
+	# wtf?
+	jsonschema/tests/test_deprecations.py::TestDeprecations::test_version
+	jsonschema/tests/test_jsonschema_test_suite.py::test_suite_bug
+)
diff --git a/dev-python/matplotlib-inline/Manifest b/dev-python/matplotlib-inline/Manifest
index 09cb11b0ea01..f70f50f7a419 100644
--- a/dev-python/matplotlib-inline/Manifest
+++ b/dev-python/matplotlib-inline/Manifest
@@ -1,2 +1,3 @@
 DIST matplotlib-inline-0.1.3.gh.tar.gz 7337 BLAKE2B 995b6e5ce9068760e701e3b429d2187bdc7e7c5b989d54a9fb1f8b5f385f91c6a3621a54d5a1e62c9000737f5f42d9ceae5be7f36b664b7e06ff9c712e6d76ac SHA512 684821204faa3cb35c46663b8c8cb8f0ba5d4f761d15bc708de69c98753685c89da1d330087bcfa970792de592188768dc068accc471d55360f551e44cf4a79a
 DIST matplotlib-inline-0.1.5.gh.tar.gz 7520 BLAKE2B 90fe7ed66b6d0ef7fd2b2a9478847adaa37af281ea383b60a1d01091d1be338411ccb2480e4bf34f0722e29cf6564a58ab358718c7704ac0c1c09375ba043627 SHA512 2a12d675ae6db1657f7202450ef3d889618c896d3571fd1a6c43b75fba1d72e80e49a06d55f7c333381b1afd2cd4a9ef282b5bcbadd2b53a19e02bd3f8bc9301
+DIST matplotlib-inline-0.1.6.gh.tar.gz 7526 BLAKE2B fd8fde8e218e19fdf7a09bd7f36abd2e4422ed7de8ed8e2d6e52d995e76b62d8e60223fc43a243f2a0ca545037b44ead9520b67cf54b173d95389eb401b17e9a SHA512 7d34f5a86d65d7a2017cf924dc363d7578d1eb14943c3de56e5a0ac79d92d674b387c5528ea76e9e11e0193e71d8cd1315ceb517e9c9678c41ed412e8fd42c04
diff --git a/dev-python/matplotlib-inline/matplotlib-inline-0.1.6.ebuild b/dev-python/matplotlib-inline/matplotlib-inline-0.1.6.ebuild
new file mode 100644
index 000000000000..af1b14d708c1
--- /dev/null
+++ b/dev-python/matplotlib-inline/matplotlib-inline-0.1.6.ebuild
@@ -0,0 +1,25 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Inline Matplotlib backend for Jupyter"
+HOMEPAGE="https://github.com/ipython/matplotlib-inline/"
+SRC_URI="
+	https://github.com/ipython/matplotlib-inline/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+"
diff --git a/dev-python/pyspnego/Manifest b/dev-python/pyspnego/Manifest
index 10cbd4c3d354..acc06ac62b4d 100644
--- a/dev-python/pyspnego/Manifest
+++ b/dev-python/pyspnego/Manifest
@@ -1,2 +1,3 @@
 DIST pyspnego-0.5.3.tar.gz 389939 BLAKE2B 236151d9d9f37137d46b06a99f037922563b4d43931288129492aa7173f166d24c3086297e30a0f05158773101df9868f88efffe00864b1bd5deb0a99a496b61 SHA512 41ca9f785a7dcc99818da351e0a020ffaed72d65cd67b0f19ad4a462a6a1fe739d040acec85052133a19aed06066dae9a9e8f0b469713b331f6ddc52cd3b4c0a
 DIST pyspnego-0.5.4.tar.gz 390427 BLAKE2B dcd9a58b2ecdab8d0ef89c6d321cdc75b8711d613afc7fdc2d3986768397b8c097cd2dd86383da7072f8e85686ea02afbe4c738d603d20590c67f8560df5e790 SHA512 5f49ba1a2f86880ded9f09f81969eecdfefc468c72c770846e3af6520bb186c585bf8d74e8fc16bcba24d9220f88d6f5d9b59af203efe499866d6335d13b96b5
+DIST pyspnego-0.6.0.tar.gz 200621 BLAKE2B cb6b44ccfb87600c480f67ddae686a424ad75a7f16c8f78d3539159c523069b71c534a3dfb8ec06ee26b75261d87d54e8b96aaa2d0f477f2488438075d6212a5 SHA512 65f877a2fcff4671606063223d1499be19368040a0f70d0d9363dd84c0b09a195a5e6bc7da1d3745fbf81af822f20f3d903ca2a9372898a2973ba93b6661a708
diff --git a/dev-python/pyspnego/pyspnego-0.6.0.ebuild b/dev-python/pyspnego/pyspnego-0.6.0.ebuild
new file mode 100644
index 000000000000..06a15d6a9b10
--- /dev/null
+++ b/dev-python/pyspnego/pyspnego-0.6.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Library to handle SPNEGO and CredSSP authentication"
+HOMEPAGE="
+	https://github.com/jborean93/pyspnego/
+	https://pypi.org/project/pyspnego/
+"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/cryptography[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/gssapi[${PYTHON_USEDEP}]
+		>=dev-python/krb5-0.3.0[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+pkg_postinst() {
+	optfeature "Kerberos authentication" "dev-python/gssapi >=dev-python/krb5-0.3.0"
+	optfeature "YAML output support" "dev-python/ruamel-yaml"
+}
diff --git a/dev-python/python-openstackclient/Manifest b/dev-python/python-openstackclient/Manifest
index ad27cb506f1b..0ddbeb38fbcd 100644
--- a/dev-python/python-openstackclient/Manifest
+++ b/dev-python/python-openstackclient/Manifest
@@ -1 +1,2 @@
 DIST python-openstackclient-5.8.0.tar.gz 827602 BLAKE2B 07893ae405532614605560d4d3423e501e2d86da5ad5a529fdc62113d55ad7a010407d45143a4d7ae8adc731804e6698a5cd527089ff9de809ac117f08e4e959 SHA512 ebd288fbdcd18245bed4262ab191ba06dbe6fb54ad4247c332f9c11b1439c3158e557bf20a7a7205e7913becb6c59126121521a32bce1f70092dc2d7f648b808
+DIST python-openstackclient-6.0.0.tar.gz 838447 BLAKE2B c6b213b022e8c75d3a94752b29cebda4d9ca1d329dc1cb0b470f6e787dd930b379d16bec6c4a0047e63110e01dbf48bee72ed6ccbf54036fa3d1d5de55487e8b SHA512 20bd8da025ee3c69a5e491089edcb42f961c5109563718198ddd22fab8d6928fa08afd6a7db608c70386bd2b61c571c2fadb1c76f84c3d7f1a60c65d4520dfa6
diff --git a/dev-python/python-openstackclient/python-openstackclient-6.0.0.ebuild b/dev-python/python-openstackclient/python-openstackclient-6.0.0.ebuild
new file mode 100644
index 000000000000..a3c24ca4a475
--- /dev/null
+++ b/dev-python/python-openstackclient/python-openstackclient-6.0.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A client for the OpenStack APIs"
+HOMEPAGE="https://github.com/openstack/python-openstackclient"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/cliff-3.5.0[${PYTHON_USEDEP}]
+	>=dev-python/openstacksdk-0.56.0[${PYTHON_USEDEP}]
+	>=dev-python/osc-lib-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-3.22.0[${PYTHON_USEDEP}]
+	>=dev-python/python-novaclient-17.0.0[${PYTHON_USEDEP}]
+	>=dev-python/python-cinderclient-3.3.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-2.0.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/tempest-17.1.0[${PYTHON_USEDEP}]
+		>=dev-python/wrapt-1.7.0[${PYTHON_USEDEP}]
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Depends on specific runner
+	sed -e 's/test_command_has_logger/_&/' -i openstackclient/tests/unit/common/test_command.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b openstackclient/tests/unit
+}
diff --git a/dev-python/pyzmq/pyzmq-23.2.0-r1.ebuild b/dev-python/pyzmq/pyzmq-23.2.0-r1.ebuild
index bfa7514a1e75..86c71d3522d8 100644
--- a/dev-python/pyzmq/pyzmq-23.2.0-r1.ebuild
+++ b/dev-python/pyzmq/pyzmq-23.2.0-r1.ebuild
@@ -22,7 +22,7 @@ SRC_URI="
 
 LICENSE="LGPL-3"
 SLOT="0"
-KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ~m68k ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"
+KEYWORDS="amd64 arm arm64 hppa ~ia64 ~m68k ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"
 IUSE="+draft"
 
 DEPEND="
diff --git a/dev-python/pyzmq/pyzmq-23.2.0.ebuild b/dev-python/pyzmq/pyzmq-23.2.0.ebuild
deleted file mode 100644
index 69c56fe85bcc..000000000000
--- a/dev-python/pyzmq/pyzmq-23.2.0.ebuild
+++ /dev/null
@@ -1,77 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{7,8,9,10} )
-# TODO: Find out exactly where this error comes from
-# error: '<' not supported between instances of 'str' and 'int'
-#DISTUTILS_USE_PEP517=setuptools
-PYTHON_REQ_USE="threads(+)"
-
-inherit flag-o-matic distutils-r1 toolchain-funcs
-
-DESCRIPTION="Lightweight and super-fast messaging library built on top of the ZeroMQ library"
-HOMEPAGE="
-	https://zeromq.org/languages/python/
-	https://pypi.org/project/pyzmq/
-	https://github.com/zeromq/pyzmq/"
-SRC_URI="
-	https://github.com/zeromq/pyzmq/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz"
-
-LICENSE="LGPL-3"
-SLOT="0"
-KEYWORDS="amd64 arm arm64 hppa ~ia64 ~m68k ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"
-IUSE="+draft"
-
-DEPEND="
-	>=net-libs/zeromq-4.2.2-r2:=[drafts]
-"
-# it uses cffi backend for pypy, cython backend for cpython
-RDEPEND="${DEPEND}
-	$(python_gen_cond_dep '
-		dev-python/py[${PYTHON_USEDEP}]
-		dev-python/cffi:=[${PYTHON_USEDEP}]
-	' pypy3)
-"
-BDEPEND="
-	$(python_gen_cond_dep '
-		dev-python/cython[${PYTHON_USEDEP}]
-	' 'python*')
-	test? (
-		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
-		>=www-servers/tornado-5.0.2[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-distutils_enable_sphinx docs \
-	"dev-python/numpydoc"
-
-python_configure_all() {
-	tc-export CC
-	append-cppflags -DZMQ_BUILD_DRAFT_API=$(usex draft '1' '0')
-}
-
-python_compile() {
-	esetup.py cython --force
-	ZMQ_PREFIX="${EPREFIX}/usr" distutils-r1_python_compile
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# TODO
-		zmq/tests/test_constants.py::TestConstants::test_draft
-		zmq/tests/test_cython.py::test_cython
-
-		# hangs often
-		zmq/tests/test_log.py::TestPubLog::test_blank_root_topic
-	)
-	local EPYTEST_IGNORE=(
-		zmq/tests/test_mypy.py
-	)
-
-	cd "${BUILD_DIR}/lib" || die
-	epytest -p no:flaky
-}
diff --git a/dev-python/regex/Manifest b/dev-python/regex/Manifest
index 0501cc9cc0d5..0b783f6c52d4 100644
--- a/dev-python/regex/Manifest
+++ b/dev-python/regex/Manifest
@@ -1,2 +1,3 @@
 DIST regex-2022.7.25.tar.gz 385022 BLAKE2B 64c2ff2e9a41d6d559ed199e978b7eb453ffe872d3cbe3d14f31ed6f7df546aa33079ce1d8279b815a35a18d9ea75da6f0beb38e4df576037995518a38db688a SHA512 1179239e8e2a1ff55150b6c2e483f2d2b795a7f5cb400310c315a59aad19590d410cc9c1a862c66be2ca93b24b387a4c4fa0a5467d497a9bc5ffc79dac7cb0ff
 DIST regex-2022.7.9.tar.gz 383431 BLAKE2B 9773b3e5c516d79ec6b37d288addb0638016716093ec49d8cdc4a2132fc16ea76c4a21fd02cc6bc6547fd0dd76bb0ec9984bb7f41eb88e4f89623a8d4a5be40d SHA512 0c8b78fc10e5ba4e95a3603a4958efb610168b63a490715c2556243af7bab4d04e6eab6cad6bc98816cfa94209404806ede28cf48643d7e92c9b8323c2b0c5e2
+DIST regex-2022.8.17.tar.gz 385777 BLAKE2B c4425e01fea5c25b9ad77e645d3671d65e747a6ee9bd7b8c1870396b4bd989c3a3ec73c33b72eb5e00f24b8e9fff2cef8c229280d2b98a13df7dd8a07bd1b2c9 SHA512 6a305c00a6355dfb9293876292e7d22de58cc00f15d7beadfaf49b49b5ef512404ad5d689f4b90f6302c5246610cb08ebd8ad6a4739818a43c6eb84fc5bc6421
diff --git a/dev-python/regex/regex-2022.8.17.ebuild b/dev-python/regex/regex-2022.8.17.ebuild
new file mode 100644
index 000000000000..d2f1386cd89a
--- /dev/null
+++ b/dev-python/regex/regex-2022.8.17.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Alternative regular expression module to replace re"
+HOMEPAGE="
+	https://bitbucket.org/mrabarnett/mrab-regex/
+	https://pypi.org/project/regex/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="doc"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2021.4.4-pypy3-fix-test_empty_array.patch"
+	"${FILESDIR}/${PN}-2021.4.4-pypy3-fix-test_issue_18468.patch"
+)
+
+distutils_enable_tests unittest
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/Features.html )
+	local DOCS=( README.rst docs/*.rst )
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index 135486ef7eb1..d91442163573 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -5,3 +5,4 @@ DIST setuptools-63.4.2.tar.gz 2600520 BLAKE2B e5cedf9f5e58044ec74e45b7232ef64680
 DIST setuptools-63.4.3.tar.gz 2600453 BLAKE2B 927be74bdc11271589134aca26849e61c5ae23d5780a57c96b9c4a9fe5f93e57fa8a80787c8db1c555f32fab1e007a956e91a374ed285db393e26d9486805ef9 SHA512 f19478921ffcf5441ec60a2af17c695456fee064f287e2130c4ff14d471a1124bd37104ad43adc7623ea0cba4ed170ed4aa37c6883aff8fd811ab960e6d12453
 DIST setuptools-64.0.3.tar.gz 2631478 BLAKE2B ff21a4cf81aed36561ac5a0da7d44c1cbe714bbd39de30041c48134c8e1204ad9edcb74540c392e4f4cf01ea161ae0ca4bdc55319e015748069986f30aa2d337 SHA512 0333322479d40b9d30187bcbb3ceadc5dd5ef8a5dcbcebc75f451b9fea06a5b7ca5d5db44c39278d62e932df7f563578c86fcd2cab9a41000caf15374a5cf182
 DIST setuptools-65.0.2.tar.gz 2619562 BLAKE2B e00e6ff7fd18c77c3924151bdbb40b36243b48eb389b67cee3279a82abd41943e08b4f8b7422edcce67b90e4c989fc170d96b140a18c78918ca7970039af8b29 SHA512 ccaf438b78a0d33ec4ec606f0fe64dcaf306dfe8935076b7534b984d0c0bfdf023d37a2b50e94572d54a5c8150e1458baabe811a4236410aedb75ee2a9215862
+DIST setuptools-65.1.0.tar.gz 2614949 BLAKE2B 89f4556b292afa7b46e558ff059647798a720647287419515cd3717ac37c6511f6ce2976967ceed98d1a34946116ad2fd366ce509b86a8153dc581171ab9c129 SHA512 6b18647b7a8a4c22e3115f233eaf97f7f564badcc31b2e5ee762630bbff3ef7f59397ca05cc4dbce65191f480be43f5e92de79eeaf8de6d32f0a79d88814e7e5
diff --git a/dev-python/setuptools/setuptools-65.1.0.ebuild b/dev-python/setuptools/setuptools-65.1.0.ebuild
new file mode 100644
index 000000000000..7460575c4f20
--- /dev/null
+++ b/dev-python/setuptools/setuptools-65.1.0.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+# please bump dev-python/ensurepip-setuptools along with this package!
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{7,8,9,10} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="
+	https://github.com/pypa/setuptools/
+	https://pypi.org/project/setuptools/
+"
+SRC_URI="
+	mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/appdirs-1.4.4-r2[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/nspektr-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/ordered-set-4.0.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3-r2[${PYTHON_USEDEP}]
+	>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-4.11.1[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_resources-5.4.0-r3[${PYTHON_USEDEP}]
+	' 3.8)
+"
+BDEPEND="
+	${RDEPEND}
+	>=dev-python/wheel-0.37.1-r1[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/build[${PYTHON_USEDEP}]
+			>=dev-python/ini2toml-0.9[${PYTHON_USEDEP}]
+			>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/pip-run[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+PDEPEND="
+	>=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+
+DOCS=( {CHANGES,README}.rst )
+
+src_prepare() {
+	local PATCHES=(
+		# TODO: remove this when we're 100% PEP517 mode
+		"${FILESDIR}"/setuptools-62.4.0-py-compile.patch
+	)
+
+	# remove bundled dependencies, setuptools will switch to system deps
+	# automatically
+	rm -r */_vendor || die
+
+	# remove the ugly */extern hack that breaks on unvendored deps
+	rm -r */extern || die
+	find -name '*.py' -exec sed \
+		-e 's:from \w*[.]\+extern ::' -e 's:\w*[.]\+extern[.]::' \
+		-i {} + || die
+
+	distutils-r1_src_prepare
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local -x SETUPTOOLS_USE_DISTUTILS=stdlib
+
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		return
+	fi
+
+	local EPYTEST_DESELECT=(
+		# network
+		# TODO: see if PRE_BUILT_SETUPTOOLS_* helps
+		setuptools/tests/config/test_apply_pyprojecttoml.py::test_apply_pyproject_equivalent_to_setupcfg
+		setuptools/tests/integration/test_pip_install_sdist.py::test_install_sdist
+		setuptools/tests/test_build_meta.py::test_legacy_editable_install
+		setuptools/tests/test_distutils_adoption.py
+		setuptools/tests/test_editable_install.py
+		setuptools/tests/test_setuptools.py::test_its_own_wheel_does_not_contain_tests
+		setuptools/tests/test_virtualenv.py::test_clean_env_install
+		setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+		setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+		# TODO
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
+		setuptools/tests/test_extern.py::test_distribution_picklable
+		# expects bundled deps in virtualenv
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
+		setuptools/tests/test_editable_install.py::test_editable_with_pyproject
+	)
+
+	epytest -n "$(makeopts_jobs)" setuptools
+}
diff --git a/dev-python/sphinxcontrib-apidoc/sphinxcontrib-apidoc-0.3.0-r1.ebuild b/dev-python/sphinxcontrib-apidoc/sphinxcontrib-apidoc-0.3.0-r1.ebuild
index 1a750ec3b12a..d1993e5247ec 100644
--- a/dev-python/sphinxcontrib-apidoc/sphinxcontrib-apidoc-0.3.0-r1.ebuild
+++ b/dev-python/sphinxcontrib-apidoc/sphinxcontrib-apidoc-0.3.0-r1.ebuild
@@ -17,7 +17,7 @@ SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
 
 BDEPEND="
 	dev-python/pbr[${PYTHON_USEDEP}]
diff --git a/dev-python/versioningit/versioningit-2.0.1.ebuild b/dev-python/versioningit/versioningit-2.0.1.ebuild
index 2e7f072bd8d8..d90755252de4 100644
--- a/dev-python/versioningit/versioningit-2.0.1.ebuild
+++ b/dev-python/versioningit/versioningit-2.0.1.ebuild
@@ -17,7 +17,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
 
 RDEPEND="
 	>=dev-python/packaging-17.1[${PYTHON_USEDEP}]