Updating liguros repo

12 files changed, 273 insertions, 1 deletions

diff --git a/dev-python/beautifulsoup/Manifest b/dev-python/beautifulsoup/Manifest
index 6b9e2318704e..620425abfaea 100644
--- a/dev-python/beautifulsoup/Manifest
+++ b/dev-python/beautifulsoup/Manifest
@@ -1,2 +1,3 @@
 DIST beautifulsoup4-4.9.1.tar.gz 374759 BLAKE2B 43f5dc296bd0c4967036fcb70889f988c0dfc9d8713f8bbab423c9089e87960323392458b3abb9b2332acff286efbbb308a5c77058462c15f8dfe9056f0304c3 SHA512 a1fe9cbfe8616d2ff25cc836769ff02d51ed86b06ca9a37366867b145440b7f64b866346600ed74820f0407c8e70eaac3d58700766a99b5ff7433cb736a57b3c
 DIST beautifulsoup4-4.9.2.tar.gz 375880 BLAKE2B 99137530e3b95aa4dde80b64dd42f0614c6429aca421208eab98764f7929c30a725e9df3625afa4a2c2e8bd4be56144cb9077e8e260741b6b306cfa696e6a076 SHA512 3bac5d57404e0be1e77a1bd560750e831c8636fc5f9b3c05b375c0cf44d6846ed73127a2a7d1d8ca657c21ec33854b8194f76b62820fb627d80a5906229a7454
+DIST beautifulsoup4-4.9.3.tar.gz 376031 BLAKE2B fbe2139f288eee978c3f665c7640f66c6c51b857a186f6a8ace02b36effa1552f1cbea9e3744e0a46a65a06e6cdbd9203832e0ecd86b61406b933f9bd83d37b8 SHA512 e3cb6258bd7c51f12128fa8ee5948fb3566163ae233fac2dda21bab7772ab8dbb384d920b0ea138ef9921307b48f89cee3a9bf6111dfc8903d917ee7af365f34
diff --git a/dev-python/beautifulsoup/beautifulsoup-4.9.3.ebuild b/dev-python/beautifulsoup/beautifulsoup-4.9.3.ebuild
new file mode 100644
index 000000000000..c3a231b6ff60
--- /dev/null
+++ b/dev-python/beautifulsoup/beautifulsoup-4.9.3.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
+
+inherit distutils-r1
+
+MY_PN="${PN}4"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Pythonic idioms for iterating, searching, and modifying an HTML/XML parse tree"
+HOMEPAGE="https://www.crummy.com/software/BeautifulSoup/bs4/"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="4"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/soupsieve[${PYTHON_USEDEP}]
+	dev-python/html5lib[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests nose
+distutils_enable_sphinx doc/source
+
+python_test() {
+	nosetests --verbose -w "${BUILD_DIR}"/lib || die "Tests fail with ${EPYTHON}"
+}
diff --git a/dev-python/flake8/flake8-3.8.3.ebuild b/dev-python/flake8/flake8-3.8.3-r1.ebuild
index 799e3bd69640..7f86184cefa1 100644
--- a/dev-python/flake8/flake8-3.8.3.ebuild
+++ b/dev-python/flake8/flake8-3.8.3-r1.ebuild
@@ -22,7 +22,7 @@ RDEPEND="
 	<dev-python/pyflakes-2.3.0[${PYTHON_USEDEP}]
 	>=dev-python/pycodestyle-2.6.0[${PYTHON_USEDEP}]
 	<dev-python/pycodestyle-2.7.0[${PYTHON_USEDEP}]
-	dev-python/importlib_metadata[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/importlib_metadata[${PYTHON_USEDEP}]' pypy3 python3_{6,7})
 "
 PDEPEND="
 	>=dev-python/mccabe-0.6.0[${PYTHON_USEDEP}]
diff --git a/dev-python/loky/Manifest b/dev-python/loky/Manifest
index 917f78219b66..c1539e30bad3 100644
--- a/dev-python/loky/Manifest
+++ b/dev-python/loky/Manifest
@@ -1 +1,2 @@
 DIST loky-2.8.0.tar.gz 112383 BLAKE2B 5561d96c0e0d23951dff303bdb1789f200b88e74ca44ef75119112491693c5876a9a70ad3688b3af9eaf12c0000d891067c936ca984404146890fb131f8c261e SHA512 15fbdb56994e08f643b7bd5aa68d193f74ab61ef1230df9e2101fb4602a201a050e3ecf08229fc4ad61e478c893e0b34b81371ef9596733baa0e3d008125cd11
+DIST loky-2.9.0.tar.gz 115019 BLAKE2B 2aa2042e32821b67db8b8de12d4b380d22af93d308bb35878271a4859325d6740a3bdab70b464a2c0d0af143903c8af3da81b4b804605cdae88779fefd7971a6 SHA512 d49354b834251f6f05a689ac44464aafa5a7a5b4a8ef84a308ec3bda138e810fc3dc31aa628307984dc69386a210f442d4c202b9499ae3e3864837b47a5b0cd9
diff --git a/dev-python/loky/loky-2.9.0.ebuild b/dev-python/loky/loky-2.9.0.ebuild
new file mode 100644
index 000000000000..39d2300f1ede
--- /dev/null
+++ b/dev-python/loky/loky-2.9.0.ebuild
@@ -0,0 +1,34 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+inherit distutils-r1
+
+DESCRIPTION="Robust and reusable Executor for joblib"
+HOMEPAGE="https://github.com/joblib/loky"
+SRC_URI="
+	https://github.com/joblib/loky/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# docker, seriously?
+	sed -e 's:test_cpu_count_cfs_limit:_&:' \
+		-i tests/test_loky_module.py || die
+
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/mccabe/mccabe-0.6.1-r2.ebuild b/dev-python/mccabe/mccabe-0.6.1-r2.ebuild
new file mode 100644
index 000000000000..998f1d26fa1e
--- /dev/null
+++ b/dev-python/mccabe/mccabe-0.6.1-r2.ebuild
@@ -0,0 +1,25 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="flake8 plugin: McCabe complexity checker"
+HOMEPAGE="https://github.com/PyCQA/mccabe"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+KEYWORDS="amd64 arm hppa ~ia64 ~mips s390 sparc x86 ~amd64-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="dev-python/flake8[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -i -e '/pytest-runner/d' setup.py || die
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/nbconvert/Manifest b/dev-python/nbconvert/Manifest
index 3809b6a6622f..ecf7bbc3ada6 100644
--- a/dev-python/nbconvert/Manifest
+++ b/dev-python/nbconvert/Manifest
@@ -3,3 +3,4 @@ DIST nbconvert-6.0.3.tar.gz 848214 BLAKE2B 4265486536cfe0cf220b8080374726cc68be4
 DIST nbconvert-6.0.4.tar.gz 841651 BLAKE2B 080f60103709bd6ddb8258750a51e7bf8891adb1eb2921619cfbb0e774a585f3d3722758d8895f67a76e2705a15a0b35ffcb7c59842ec986a13315e5b10f4eca SHA512 46c2d250e25ad0e2fee0be0fefacc198687acd7ffcb4205bb8cf0ed263e90878cf659f352d551911b0025cb150302ea9ffd67b9453ec23fc5821908f7b56dd75
 DIST nbconvert-6.0.5.tar.gz 841650 BLAKE2B 7f8bb3849374284c90bd7b17c27a313c69694e42d4fd7b5913d3b210a15f17b89ffca8436ce31fa5bfc2b586feb536522106522f3d1741ad0fb6c2995a2e562e SHA512 79164546164eada6998bd6898833dfbada0a1476af8796bea40794f6caf121d0b9560f0f50e3d477357e977222a3b75f3de85ccfa03c4aec93be75801cf6f97c
 DIST nbconvert-6.0.6.tar.gz 888348 BLAKE2B 7662437e1436a4ee9694bc05b8472b64d0773c38cc5fda3372ce9009f5d6d20e2ffb28c4baf3442cbc88414ce97870cf15a102ee609f4aae2c951d3f7ac5202f SHA512 2be6a65ed86dd10fc4fd08536db304dc359da1af66c4f907753a419b8d9caec08274c07d110a060bdae5626bb48a4f6d209e423b8eacee420d3a4c6ef0f6bbf5
+DIST nbconvert-6.0.7.tar.gz 896833 BLAKE2B 1b5b39144509aa9f61dc1e9675b112d69ed2e2f9859f3ce7ccfac517d89fff0010062c03ded1c3db571c84dd8d4f8ba12e4851245f370d2e671d24921dd50ab6 SHA512 3c78fa4d777a79a08606a39bb31f6b329dc9d28c1ef2ea9f3253746dce853a295e8fe85b14c65b04762aa5acd5facc879232a375875a2ca6dc9477cc1ab88786
diff --git a/dev-python/nbconvert/nbconvert-6.0.7.ebuild b/dev-python/nbconvert/nbconvert-6.0.7.ebuild
new file mode 100644
index 000000000000..cfce79b23cdc
--- /dev/null
+++ b/dev-python/nbconvert/nbconvert-6.0.7.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Converting Jupyter Notebooks"
+HOMEPAGE="https://nbconvert.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/bleach[${PYTHON_USEDEP}]
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	>=dev-python/entrypoints-0.2.2[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	dev-python/jupyterlab_pygments[${PYTHON_USEDEP}]
+	>=dev-python/mistune-0.7.4[${PYTHON_USEDEP}]
+	dev-python/nbclient[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	>=dev-python/pandocfilters-1.4.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.2.1[${PYTHON_USEDEP}]
+	dev-python/testpath[${PYTHON_USEDEP}]
+	www-servers/tornado[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pebble[${PYTHON_USEDEP}]
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		>=dev-python/jupyter_client-4.2[${PYTHON_USEDEP}]
+		media-gfx/inkscape
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	mkdir -p "${HOME}/.local" || die
+	cp -r share "${HOME}/.local/" || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	local deselect=(
+		# Missing pyppeteer for now
+		# TODO: Doesn't skip?
+		--deselect exporters/tests/test_webpdf.py
+		# Needs pyppeteer too
+		--deselect 'tests/test_nbconvertapp.py::TestNbConvertApp::test_webpdf_with_chromium'
+	)
+
+	distutils_install_for_testing bdist_egg
+	cd "${TEST_DIR}"/lib || die
+	pytest -vv "${deselect[@]}" --pyargs nbconvert || die "Tests failed with ${EPYTHON}"
+}
+
+pkg_postinst() {
+	if ! has_version app-text/pandoc ; then
+		einfo "Pandoc is required for converting to formats other than Python,"
+		einfo "HTML, and Markdown. If you need this functionality, install"
+		einfo "app-text/pandoc."
+	fi
+}
diff --git a/dev-python/pytest/Manifest b/dev-python/pytest/Manifest
index c2e461607c24..5f2fe7057298 100644
--- a/dev-python/pytest/Manifest
+++ b/dev-python/pytest/Manifest
@@ -3,3 +3,4 @@ DIST pytest-5.4.3.tar.gz 1022353 BLAKE2B 70d4f23cbbfc4c4ce63c512ee0a01556973761a
 DIST pytest-6.0.1.tar.gz 1069631 BLAKE2B 89a78ebf8e8cf968ea767fe7244408ca79d247c1ca459815ac299ce773b44c375429935c8a25b4de26349969113c60e4b6812d5aa2d805691664af74796ea85b SHA512 bdd790c3860da2ed3a3ff47f04512c3bfae4fa1e31fc6b96fc19bd57d1804a6fec968ecf17a11c5b20d30dcf82d6391ef0d893ae57a3da9ad777a15c078c129f
 DIST pytest-6.0.2.tar.gz 1070533 BLAKE2B 54397bdf8255641e1cb0555a78b3687a49376d9cc603a98b6df3415159aef0331cbaa7d0883bafbceea1b2273fc0ba5c867f7b66eef5b2b4c24f3e5196786877 SHA512 478d28c30f4f990dcdd98edcd074051e32d9ab25941c21bdc9c4cc47b726da79b5b3a01572ff97f608598ef6bb9df075ebba49abb2f1420947e0c6d4fe0be9c8
 DIST pytest-6.1.0.tar.gz 1083563 BLAKE2B 79da2026ba6915b406a1b6a2c8d79e5f45695f32e8f9369ef3c27ebf9b3f80ced23b4832c75c47db552a084f03a68da04279fdc8c8ef526a41e42deed0a52b5e SHA512 a67571468315eea7ed5b56285f18b239b47992bfc7d4d891587f1c540f240159219be15a9a34852529ded7743bea82eb9cde4bcdd053f448a61a6c835b5405de
+DIST pytest-6.1.1.tar.gz 1084076 BLAKE2B 61eb5efcffbd5a623c7021e37bbe908522fcfbf42ac56cb45fb7e10e0cd30e845bb8a6c563e86bbff47fba1f0db72f1451eb0bf86862b7e150e29be6a2e80967 SHA512 fc61028a01187f6161061a0c2fc392dd719586780a49eec037a72878de00bc33a81c1bc0e2be01be52b30c7eeea2c590d1a4ec08cb14a955bc624478118889b0
diff --git a/dev-python/pytest/pytest-6.1.1.ebuild b/dev-python/pytest/pytest-6.1.1.ebuild
new file mode 100644
index 000000000000..18f35d4457aa
--- /dev/null
+++ b/dev-python/pytest/pytest-6.1.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Simple powerful testing with Python"
+HOMEPAGE="https://pytest.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/attrs-17.4.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/importlib_metadata[${PYTHON_USEDEP}]
+	' python3_{6,7} pypy3)
+	dev-python/iniconfig[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-4.0.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-0.12[${PYTHON_USEDEP}]
+	<dev-python/pluggy-1
+	>=dev-python/py-1.8.2[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+"
+# flake cause a number of tests to fail
+DEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/argcomplete[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-3.56[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/xmlschema[${PYTHON_USEDEP}]
+		!!dev-python/flaky
+	)"
+
+python_prepare_all() {
+	# fragile to warnings from other packages (setuptools)
+	# little value for us to run it
+	sed -i -e 's:test_no_warnings:_&:' \
+		testing/test_meta.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	distutils_install_for_testing
+
+	"${EPYTHON}" -m pytest -vv --lsof -rfsxX ||
+		die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/zipp/Manifest b/dev-python/zipp/Manifest
index b6230e3f3b68..b5608260e3d3 100644
--- a/dev-python/zipp/Manifest
+++ b/dev-python/zipp/Manifest
@@ -1,2 +1,3 @@
 DIST zipp-3.1.0.tar.gz 14808 BLAKE2B fb5524c2619e51c5f8c1b85fa819d1001e6296df6c9d5320c6ab3ec88fa5c932c139161e621d51b2827ef40402bb2492b8b08e470b7333e847495ec690024879 SHA512 bb8dea71eccc4f3b18fc816dae700582c3feb72f346e115bb2d1adc336f121304a285e4d5dad48d15b386b9e137c6e1d1793ef50d22b6bd697812a661817684e
 DIST zipp-3.2.0.tar.gz 16238 BLAKE2B d74781639c714342863a0532ac8bbfc4d8cdcd554b9ce2b0edf83dc26ac423231ac85323379b4923308f2319c828aca2e0bcd4bd136845e7026b09e1e16e108e SHA512 fc0c8a9f1fbbcdd0f70c536e7498605e0a338dd99abd65f16b360cb16f96c7860d422ce2b55f7b2c1bfd7e5c5b5ca3bf818a48bae19bfbf190d91d4778aed31a
+DIST zipp-3.3.0.tar.gz 16796 BLAKE2B 4d6acbca82e7da97f0634a47306d157fc3bc9cd37875c95fa449cd08ac7c9ad266c43cfeec373a6d866fc21ccb7ced9049552cc9cc816e471bbe5f7ffd43a4df SHA512 af43451d908dca5971625dade20fa8038713a2c4d2c3ddb1690199832d44b8515124276193bb514883cfba70b32360b450a64a2ed1d8537dc71f243ef57e9d92
diff --git a/dev-python/zipp/zipp-3.3.0.ebuild b/dev-python/zipp/zipp-3.3.0.ebuild
new file mode 100644
index 000000000000..52445b7f7362
--- /dev/null
+++ b/dev-python/zipp/zipp-3.3.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Backport of pathlib-compatible object wrapper for zip files"
+HOMEPAGE="https://github.com/jaraco/zipp"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	dev-python/toml[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-3.4.2[${PYTHON_USEDEP}]
+	test? ( dev-python/jaraco-itertools[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_sphinx docs \
+	">=dev-python/jaraco-packaging-3.2" \
+	">=dev-python/rst-linker-1.9"
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Skip a potentially flaky performance test
+	sed -i -e '/^import func_timeout\|^ *@func_timeout\.func_set_timeout/d' \
+		-e 's/test_implied_dirs_performance/_&/' test_zipp.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Ignoring zipp.py from ${S} avoids ImportPathMismatchError with Python < 3.8
+	# by ensuring only zipp from ${BUILD_DIR} is loaded
+	pytest --ignore zipp.py -vv || die "Tests fail with ${EPYTHON}"
+}