Adding metadata

13 files changed, 301 insertions, 28 deletions

diff --git a/dev-python/genshi/genshi-0.7.7.ebuild b/dev-python/genshi/genshi-0.7.7.ebuild
index 70a91e1f5f12..6b7c44d2e6b6 100644
--- a/dev-python/genshi/genshi-0.7.7.ebuild
+++ b/dev-python/genshi/genshi-0.7.7.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -20,9 +20,12 @@ KEYWORDS="amd64 ~arm arm64 ppc ~ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux
 IUSE="doc examples test"
 RESTRICT="!test? ( test )"
 
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+"
 BDEPEND="
 	test? (
-		dev-python/six[${PYTHON_USEDEP}]
+		${RDEPEND}
 	)
 "
 
diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index a11d7c268c91..e9da2ac43cac 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1 +1,3 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
+EBUILD langdetect-1.0.9.ebuild 493 BLAKE2B 0df8bce19bc80f79f8e76bcef5a4c2caf333365fe0cb9a3c076b7858bceded5a3e58921474f866a2709dd657b7ed330c1ec4a7f9d7bab0fcf1bc92d77cabc32d SHA512 ea2a1adcb133ac5fc951ba1aa90ef1ce3dfcc424e59727591763d4875aa044a74188be2d15fd89c6b2e83ed6ea04ec3d9851ed584ae79d2c2c127bde7d994b48
+MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch b/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
deleted file mode 100644
index 637368d2f237..000000000000
--- a/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
+++ /dev/null
@@ -1,13 +0,0 @@
-Fix "Package 'langdetect.profiles' is absent from the `packages` configuration."
-
---- a/setup.py
-+++ b/setup.py
-@@ -18,7 +18,7 @@ setup(
-     author_email='michal.danilak@gmail.com',
-     url='https://github.com/Mimino666/langdetect',
-     keywords='language detection library',
--    packages=['langdetect', 'langdetect.utils', 'langdetect.tests'],
-+    packages=['langdetect', 'langdetect.utils', 'langdetect.tests', 'langdetect.profiles'],
-     include_package_data=True,
-     install_requires=['six'],
-     license='MIT',
diff --git a/dev-python/langdetect/langdetect-1.0.9.ebuild b/dev-python/langdetect/langdetect-1.0.9.ebuild
index 630fe63c6f53..c09b7356f549 100644
--- a/dev-python/langdetect/langdetect-1.0.9.ebuild
+++ b/dev-python/langdetect/langdetect-1.0.9.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2022-2024 Gentoo Authors
+# Copyright 2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -19,6 +19,4 @@ KEYWORDS="~amd64"
 
 RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
 
-PATCHES=( "${FILESDIR}/${P}-explicit-config.patch" )
-
 distutils_enable_tests unittest
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index 736a1167c898..020e07f2a3dd 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -1,6 +1,12 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- 
- <origin>gentoo-guru-overlay</origin>
+ <maintainer type="person">
+  <email>marcin.deranek@slonko.net</email>
+  <name>Marcin Deranek</name>
+ </maintainer>
+ <upstream>
+  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
+ </upstream>
+ <origin>slonko-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/mechanize/files/mechanize-0.4.9-test.patch b/dev-python/mechanize/files/mechanize-0.4.9-test.patch
new file mode 100644
index 000000000000..369cbe9495e1
--- /dev/null
+++ b/dev-python/mechanize/files/mechanize-0.4.9-test.patch
@@ -0,0 +1,23 @@
+From 1324b09b661aaac7d4cdc7e1e9d49e1c3851db2c Mon Sep 17 00:00:00 2001
+From: Martin Weinelt <hexa@darmstadt.ccc.de>
+Date: Sun, 21 Apr 2024 13:05:45 +0200
+Subject: [PATCH] Fix test_ftp mime type expectation on 3.11+
+
+Closes: #94
+---
+ test/test_urllib2.py | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/test/test_urllib2.py b/test/test_urllib2.py
+index e9b96fd..c46a2fc 100644
+--- a/test/test_urllib2.py
++++ b/test/test_urllib2.py
+@@ -864,7 +864,7 @@ def connect_ftp(self, user, passwd, host, port, dirs, timeout):
+              ["foo", "bar"], _sockettimeout._GLOBAL_DEFAULT_TIMEOUT, "", None),
+             ("ftp://localhost/baz.gif;type=a", "localhost", ftplib.FTP_PORT,
+              "A", [], _sockettimeout._GLOBAL_DEFAULT_TIMEOUT, "baz.gif",
+-             None),  # TODO: really this should guess image/gif
++             "image/gif" if sys.version_info >= (3, 11) else None),
+         ]:
+             req = Request(url, timeout=timeout)
+             r = h.ftp_open(req)
diff --git a/dev-python/mechanize/mechanize-0.4.9.ebuild b/dev-python/mechanize/mechanize-0.4.9.ebuild
index ab8b93af7c1c..1453c1acef8b 100644
--- a/dev-python/mechanize/mechanize-0.4.9.ebuild
+++ b/dev-python/mechanize/mechanize-0.4.9.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -29,6 +29,11 @@ BDEPEND="
 	)
 "
 
+PATCHES=(
+	# https://github.com/python-mechanize/mechanize/pull/95
+	"${FILESDIR}/${P}-test.patch"
+)
+
 python_test() {
-	"${EPYTHON}" run_tests.py || die
+	"${EPYTHON}" run_tests.py -v || die
 }
diff --git a/dev-python/myst-parser/Manifest b/dev-python/myst-parser/Manifest
index f62ab3c5d2ac..850540c12b8c 100644
--- a/dev-python/myst-parser/Manifest
+++ b/dev-python/myst-parser/Manifest
@@ -1 +1,2 @@
 DIST MyST-Parser-2.0.0.gh.tar.gz 815453 BLAKE2B 8f5dd823c3c79d843b45a7a4819d5677b51a12f78db2c1ce9700eb6faa8c4f0bc167fb1d8cd947e89ffab85aec947ab527b67dc73ef4db97a393f700a4331738 SHA512 c47bdd773565e93c4714d318a70f9a8adab1be6e2a63c23175667fc4afb5da4d66b84e11176782c8202e9fd68883e74d444911ddfb0b91356c2ba07fa65f7ea4
+DIST myst-parser-2.0.0-sphinx-7.2.patch 22443 BLAKE2B 994f0b2c419832e61cb006b1b45c01274970900bdcfcef3422d5331e88962a46884afbf5b27b5cb98ed349a426444ca4ff21810526cc34eae4cf074102f7b3de SHA512 707b2a69c81352d2900c91088ca137f6455e0006b0e7c798b6f03b9f0cac85489c27db662f5e6ab6e2cd52e10f1594aa54d5c6821c07c110ad138d0cf129ac65
diff --git a/dev-python/myst-parser/myst-parser-2.0.0.ebuild b/dev-python/myst-parser/myst-parser-2.0.0-r1.ebuild
index a1218d6d28a8..adcab8ba839f 100644
--- a/dev-python/myst-parser/myst-parser-2.0.0.ebuild
+++ b/dev-python/myst-parser/myst-parser-2.0.0-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2022-2023 Gentoo Authors
+# Copyright 2022-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -17,6 +17,8 @@ HOMEPAGE="
 SRC_URI="
 	https://github.com/executablebooks/MyST-Parser/archive/v${PV}.tar.gz
 		-> ${MY_P}.gh.tar.gz
+	https://github.com/executablebooks/MyST-Parser/pull/811.patch
+		-> ${P}-sphinx-7.2.patch
 "
 S=${WORKDIR}/${MY_P}
 
@@ -25,7 +27,7 @@ SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
 
 RDEPEND="
-	<dev-python/docutils-0.21[${PYTHON_USEDEP}]
+	dev-python/docutils[${PYTHON_USEDEP}]
 	dev-python/jinja[${PYTHON_USEDEP}]
 	<dev-python/markdown-it-py-4[${PYTHON_USEDEP}]
 	>=dev-python/markdown-it-py-3.0[${PYTHON_USEDEP}]
@@ -42,19 +44,38 @@ BDEPEND="
 		>=dev-python/linkify-it-py-2.0.0[${PYTHON_USEDEP}]
 		dev-python/pytest-regressions[${PYTHON_USEDEP}]
 		dev-python/pytest-param-files[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-7.2.6[${PYTHON_USEDEP}]
 		dev-python/sphinx-pytest[${PYTHON_USEDEP}]
 	)
 "
 
 distutils_enable_tests pytest
 
+src_prepare() {
+	local PATCHES=(
+		# https://github.com/executablebooks/MyST-Parser/pull/811
+		"${DISTDIR}/${P}-sphinx-7.2.patch"
+	)
+
+	default
+
+	# unpin docutils
+	sed -i -e '/docutils/s:,<[0-9.]*::' pyproject.toml || die
+}
+
 python_test() {
 	local EPYTEST_DESELECT=()
 
-	false && [[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
-		# bad test relying on exact exception messages
-		"tests/test_renderers/test_include_directive.py::test_errors[9-Non-existent path:]"
-	)
+	if has_version ">=dev-python/sphinx-7.3"; then
+		EPYTEST_DESELECT+=(
+			# https://github.com/executablebooks/MyST-Parser/issues/913
+			'tests/test_renderers/test_fixtures_sphinx.py::test_syntax_elements[298-Sphinx Role containing backtick:]'
+			'tests/test_renderers/test_fixtures_sphinx.py::test_sphinx_directives[341-versionadded (`sphinx.domains.changeset.VersionChange`):]'
+			tests/test_sphinx/test_sphinx_builds.py::test_references_singlehtml
+			tests/test_sphinx/test_sphinx_builds.py::test_heading_slug_func
+			tests/test_sphinx/test_sphinx_builds.py::test_gettext_html
+		)
+	fi
 
 	epytest
 }
diff --git a/dev-python/pyarrow/Manifest b/dev-python/pyarrow/Manifest
index bbcab56c3705..3b44275b17cd 100644
--- a/dev-python/pyarrow/Manifest
+++ b/dev-python/pyarrow/Manifest
@@ -1 +1,2 @@
 DIST apache-arrow-15.0.2.tar.gz 21503812 BLAKE2B 5a42b3409515d7a09daff33d30e72e828e1df2e009ed746f101f4d8e6dcadb2e9c305a6cb9799d4003e1421ba666d2a2e9ba182c11b0c538fbd1aee4b3ba10ff SHA512 6c83e3be1e5840c30387f088315b74aca8e7c2d060793af70a156effb496a71e3e6af0693188c0f46f8a4a061a263a47095912ef04a5dc8141abd59075b14c78
+DIST apache-arrow-16.0.0.tar.gz 21695067 BLAKE2B aa5dfef3d8d46a53242075c165473635051d51ff28587ea8b80751232d5f75ee3ef89e0a027aa39bdc9dc03fa46ddb68e46ae2c7f40605258e47ff194f1d3979 SHA512 773f4f3eef603032c8ba0cfdc023bfd2a24bb5e41c82da354a22d7854ab153294ede1f4782cc32b27451cf1b58303f105bac61ceeb3568faea747b93e21d79e4
diff --git a/dev-python/pyarrow/pyarrow-16.0.0.ebuild b/dev-python/pyarrow/pyarrow-16.0.0.ebuild
new file mode 100644
index 000000000000..a980e74a3f09
--- /dev/null
+++ b/dev-python/pyarrow/pyarrow-16.0.0.ebuild
@@ -0,0 +1,96 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Python library for Apache Arrow"
+HOMEPAGE="
+	https://arrow.apache.org/
+	https://github.com/apache/arrow/
+	https://pypi.org/project/pyarrow/
+"
+SRC_URI="mirror://apache/arrow/arrow-${PV}/apache-arrow-${PV}.tar.gz"
+S="${WORKDIR}/apache-arrow-${PV}/python"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~hppa ~riscv ~x86"
+IUSE="+parquet +snappy ssl"
+
+RDEPEND="
+	~dev-libs/apache-arrow-${PV}[compute,dataset,json,parquet?,re2,snappy?,ssl?]
+	>=dev-python/numpy-1.16.6:=[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-libs/apache-arrow[lz4,zlib]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# cython's -Werror
+	sed -i -e '/--warning-errors/d' CMakeLists.txt || die
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	export PYARROW_PARALLEL="$(makeopts_jobs)"
+	export PYARROW_BUILD_VERBOSE=1
+	export PYARROW_CXXFLAGS="${CXXFLAGS}"
+	export PYARROW_BUNDLE_ARROW_CPP_HEADERS=0
+	export PYARROW_CMAKE_GENERATOR=Ninja
+	export PYARROW_WITH_HDFS=1
+	if use parquet; then
+		export PYARROW_WITH_DATASET=1
+		export PYARROW_WITH_PARQUET=1
+		use ssl && export PYARROW_WITH_PARQUET_ENCRYPTION=1
+	fi
+	if use snappy; then
+		export PYARROW_WITH_SNAPPY=1
+	fi
+
+	distutils-r1_src_compile
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# wtf?
+		tests/test_fs.py::test_localfs_errors
+		# these require apache-arrow with jemalloc that doesn't seem
+		# to be supported by the Gentoo package
+		tests/test_memory.py::test_env_var
+		tests/test_memory.py::test_specific_memory_pools
+		tests/test_memory.py::test_supported_memory_backends
+		# pandas changed, i guess
+		tests/test_pandas.py::test_array_protocol_pandas_extension_types
+		tests/test_table.py::test_table_factory_function_args_pandas
+		# hypothesis health check failures
+		# https://github.com/apache/arrow/issues/41318
+		tests/interchange/test_interchange_spec.py::test_dtypes
+		tests/test_convert_builtin.py::test_array_to_pylist_roundtrip
+		tests/test_feather.py::test_roundtrip
+	)
+
+	if has_version ">=dev-python/numpy-2"; then
+		EPYTEST_DESELECT+=(
+			# https://github.com/apache/arrow/issues/41319
+			tests/test_array.py::test_numpy_array_protocol
+			tests/test_table.py::test_numpy_array_protocol
+		)
+	fi
+
+	cd "${T}" || die
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest --pyargs pyarrow
+}
diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index aa8c8615a5e3..8d26b2d8487b 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -1 +1,2 @@
 DIST sphinx-7.2.6.gh.tar.gz 7067425 BLAKE2B 4da1cb5ccebea4df0dc134c552311d7b70ce9b76424ea4355ad67b1ece60c9b445e56c96b838832d4df2f50940832b3fa9555b596390464a4017a573bcf514c3 SHA512 204e859318ad5044639f2e682098b07c7cc675b54ba801feeb3322290bfd15316cc15a2cae8fa6a55e6ec6d1e9690790e5402652eb04720bfe96e172f4c8bdbc
+DIST sphinx-7.3.7.gh.tar.gz 7165383 BLAKE2B bcc68f26937e6aefe60cedea533a5c8e245c76b59ab4913fb6516f285e3afc32be60b336c662ac8305fb88e82fcc2b477128f2d8b9bf92f037b124f4c855df2a SHA512 540553ecddc55b3e673c79bc776a899d2c660f1e93ef819711be52174accf5b70465883a46bed81d163534e56718caf0765b4bae153e9307a3792387d8228df5
diff --git a/dev-python/sphinx/sphinx-7.3.7.ebuild b/dev-python/sphinx/sphinx-7.3.7.ebuild
new file mode 100644
index 000000000000..8a1b64d1f393
--- /dev/null
+++ b/dev-python/sphinx/sphinx-7.3.7.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="
+	https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinx/
+	https://pypi.org/project/Sphinx/
+"
+SRC_URI="
+	https://github.com/sphinx-doc/sphinx/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc latex"
+
+RDEPEND="
+	>=dev-python/alabaster-0.7.14[${PYTHON_USEDEP}]
+	>=dev-python/Babel-2.9[${PYTHON_USEDEP}]
+	<dev-python/docutils-0.22[${PYTHON_USEDEP}]
+	>=dev-python/docutils-0.18.1[${PYTHON_USEDEP}]
+	>=dev-python/imagesize-1.3[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.14[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.25.0[${PYTHON_USEDEP}]
+	>=dev-python/snowballstemmer-2.0[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-htmlhelp-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-serializinghtml-1.1.9[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2[${PYTHON_USEDEP}]
+	' 3.10)
+	latex? (
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)
+	!dev-python/namespace-sphinxcontrib
+"
+BDEPEND="
+	doc? (
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)
+	test? (
+		app-text/dvipng
+		>=dev-python/cython-3.0.0[${PYTHON_USEDEP}]
+		dev-python/filelock[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		>=dev-python/setuptools-67.0[${PYTHON_USEDEP}]
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		virtual/imagemagick-tools[jpeg,png,svg]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/sphinx-3.2.1-doc-link.patch"
+	"${FILESDIR}/sphinx-4.3.2-doc-link.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# disable internet access
+	sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+		doc/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# we can't use distutils_enable_sphinx because it would
+	# introduce a dep on itself
+	use doc && build_sphinx doc
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				tests/test_extensions/test_ext_autodoc.py::test_autodoc_exception
+				tests/test_extensions/test_ext_autodoc.py::test_autodoc_ignore_module_all
+				tests/test_extensions/test_ext_autodoc.py::test_autodoc_inherited_members_None
+				tests/test_extensions/test_ext_autodoc.py::test_autodoc_subclass_of_builtin_class
+				tests/test_extensions/test_ext_autodoc.py::test_automethod_for_builtin
+				tests/test_extensions/test_ext_autodoc.py::test_cython
+				tests/test_extensions/test_ext_autodoc.py::test_format_signature
+				tests/test_extensions/test_ext_autodoc.py::test_partialfunction
+				tests/test_extensions/test_ext_autodoc_autoclass.py::test_autodoc_process_bases
+				tests/test_extensions/test_ext_autodoc_autoclass.py::test_show_inheritance_for_decendants_of_generic_type
+				tests/test_extensions/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
+				tests/test_extensions/test_ext_autodoc_autofunction.py::test_builtin_function
+				tests/test_extensions/test_ext_autodoc_autofunction.py::test_methoddescriptor
+				tests/test_extensions/test_ext_autodoc_automodule.py::test_automodule_inherited_members
+				tests/test_extensions/test_ext_autodoc_preserve_defaults.py::test_preserve_defaults_special_constructs
+				tests/test_extensions/test_ext_autosummary.py::test_autosummary_generate_content_for_module
+				tests/test_extensions/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
+				tests/test_util/test_util_inspect.py::test_isattributedescriptor
+				tests/test_util/test_util_inspect.py::test_signature
+				tests/test_util/test_util_typing.py::test_is_invalid_builtin_class
+			)
+			;;
+	esac
+
+	# note: pytest-xdist causes random test failures
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}