Adding metadata

8 files changed, 273 insertions, 0 deletions

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index f04a82b89536..dc9a75ee3939 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -6,3 +6,5 @@ DIST Django-4.0.4.checksum.txt 2545 BLAKE2B d82f7b01f49f2b37de3cfd9eb8738e4af69c
 DIST Django-4.0.4.tar.gz 10388499 BLAKE2B f839b343bf5c2f83810f2bb22e93a91b18ccc30754589fef2931ebdf29d4600a3bf5493f9e977a3b647097c3a379ea1ef4e0e25366efb54082bc0f43ed00485f SHA512 75ecf5991763237297b458f546d245a25f62272f7013364783aea19469586fa54ce94a16323ac9a6d6b81097f8e962ea7a20f26c7afd8acda842812409215bb1
 DIST Django-4.0.5.checksum.txt 2549 BLAKE2B e0aae25d6e9b15eddc9f6be566d611d03b3cd2aa97020b99372eebbc5183e2f04f27bfc9c1faa9f4b5ec0e4da453a5812a8c8afd7dbb61c10424c458c81bf453 SHA512 45c628253a530df210c94b7c2e8493faaa5eecd68c1f84c4d61936f0f85d590ddc96d64be0313a6353435bed884fde6f6cf0bd54dc04d361dac093f259c5927b
 DIST Django-4.0.5.tar.gz 10410720 BLAKE2B 43c8000a54829d639a63a7a17067368b3c6fbda483eae374d4e7f561a3bd3490b754de888e597514f706b1843c8dae2f78453f0efc8eb9a335874993eac44e8f SHA512 915dd5f853544dcd9f85e7d11f50d3f8c34eaf4a6819ec76178bec9466feaf2b386f044fdeebec6bd88366917b8feb6e2512d45b8996c8906326205d4f449f90
+DIST Django-4.0.6.checksum.txt 2543 BLAKE2B 4d38a86dc468f1cf9553557073fa6d5aad6875739c5cd3e50dd79954254dc25a0345b32fc771f4db3d566858c58b48d4f0fba434903eae0e0709666627b5e38c SHA512 b701e13371bdc00b61e7ff7f5a2b2d39a9d703616ce79640700e53a252f8aefd8bbf5560b082420bd4ff921110a44ac6a353c61db664b0ee899905d5cf65de59
+DIST Django-4.0.6.tar.gz 10389543 BLAKE2B c458b2b2a782d95771df00ed529d4b0ef0f42720f19258d32ea955e90806b61aabf03a5eb39a7a36c5d220af32dd35e78244db4d17a3f074601952905fd5e0fa SHA512 1050511bd9345519d8382a58e4e6ccc39cd41a6777c9575540dcc655f11dd36316cfc2431f94da9ac4a0fa6e41640a9131c8d49df4188a2ffc26f7ff56d40a6a
diff --git a/dev-python/django/django-4.0.6.ebuild b/dev-python/django/django-4.0.6.ebuild
new file mode 100644
index 000000000000..e28079b64571
--- /dev/null
+++ b/dev-python/django/django-4.0.6.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+MY_P=${P^}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/asgiref-3.4.1[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/backports-zoneinfo[${PYTHON_USEDEP}]
+	' 3.8)
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+		!!<dev-python/ipython-7.21.0-r1
+		!!=dev-python/ipython-7.22.0-r0
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.0-bashcomp.patch
+	"${FILESDIR}"/django-4.0.5-py311.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+src_prepare() {
+	# TODO: this suddenly started failing
+	sed -i -e 's:test_custom_fields:_&:' tests/inspectdb/tests.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}
diff --git a/dev-python/libvirt-python/Manifest b/dev-python/libvirt-python/Manifest
index bc4ae5f19b75..95cd7e51cc42 100644
--- a/dev-python/libvirt-python/Manifest
+++ b/dev-python/libvirt-python/Manifest
@@ -12,3 +12,5 @@ DIST libvirt-python-8.3.0.tar.gz 231579 BLAKE2B 0bd169b66f490e100eab95f94f412d27
 DIST libvirt-python-8.3.0.tar.gz.asc 833 BLAKE2B bb19bef914e39d04b6580dcce1813bc21c5213a2b4c88d44686eeecc9ffc9383db3bab62d46840138a9a9e80d6429662aec43d586dddc041bca4543ff49c465b SHA512 65d417a6849614f94a59dca94cb258b7de487fbc409cd2cfc8c3e9cbdc76ae83c6c2c40a0cf4c12877d2fa78bbcf371512ca6f71973466d2151be690a8b4422c
 DIST libvirt-python-8.4.0.tar.gz 231985 BLAKE2B 64d37074e04cdb02332987dc46e6dd7b38dbc8fa4de0e6e1cbde1caba370f5eed650c4a135f6101c355f189a91fbba82dcac3d50f8c0d0678ce4def448a4b168 SHA512 6c831ae45549ab0c4d720826e2f5cb219eaab0943b8c71fe70c02fd49097fb5565ee6f651b19e34f72d6b0133bf3b4bb8bfe56b37723b24eaf336f65ab0a5865
 DIST libvirt-python-8.4.0.tar.gz.asc 833 BLAKE2B fa6f5e10ca3e06c017e9988e676dd2beca2bcb88f4d55d7a1740d42b4ea56ff0cdb4fd7698392ce1eead7a81fafcc1475eb6270329f56e191a4a4551120e982b SHA512 855869856ff41338c4ed1b707db4a0ace97a60e51d19183a0c1f904695b8a367249ae6266a45d79449443325cc85485db89dc73b09ac318c206cc03ab36ef179
+DIST libvirt-python-8.5.0.tar.gz 235414 BLAKE2B 616c8415f94a6c53b9bcd6ff7433993a3d40eb49ff13eaf81eee52c52806fb1d281216e8bd591deeee6058e2cb5161310d0ae1217467cd1f0525c00d7252214d SHA512 0e922301243200229c01659e57b4abad69a85931ea3ffcb70b117f313971d266d036dc6c1dbe42d48380d5ad9ed72326603101eb33d6a68dd6b7253a6e197aff
+DIST libvirt-python-8.5.0.tar.gz.asc 833 BLAKE2B 5b3c37ee02d6a5cefcc81945b9f4c67f19d297f03ad16e2666e87c3ea54ac609d774d3bb90a47e4098914460fd0928f66641f52185fe367cad9794636a809836 SHA512 4fae1d23f7ef2fccb38dee397173f3571b64969672cbe297e3622b9a0194e4a434329de543e886a4a20a9e1e0e3f1fec10a08d924ec0e728b9e29a44877c7e24
diff --git a/dev-python/libvirt-python/libvirt-python-8.5.0.ebuild b/dev-python/libvirt-python/libvirt-python-8.5.0.ebuild
new file mode 100644
index 000000000000..1e4b92098d8b
--- /dev/null
+++ b/dev-python/libvirt-python/libvirt-python-8.5.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Packages which get releases together:
+# app-emacs/nxml-libvirt-schemas
+# dev-python/libvirt-python
+# dev-perl/Sys-Virt
+# app-emulation/libvirt
+# Please bump them together!
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+DISTUTILS_USE_PEP517=setuptools
+MY_P="${P/_rc/-rc}"
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/libvirt.org.asc
+inherit distutils-r1 verify-sig
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/libvirt/libvirt-python.git"
+	RDEPEND="app-emulation/libvirt:=[-python(-)]"
+else
+	SRC_URI="https://libvirt.org/sources/python/${MY_P}.tar.gz
+		verify-sig? ( https://libvirt.org/sources/python/${MY_P}.tar.gz.asc )"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+	RDEPEND="app-emulation/libvirt:0/${PV}"
+fi
+S="${WORKDIR}/${P%_rc*}"
+
+DESCRIPTION="libvirt Python bindings"
+HOMEPAGE="https://www.libvirt.org"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		dev-python/lxml[${PYTHON_USEDEP}]
+	)
+	verify-sig? ( sec-keys/openpgp-keys-libvirt )
+"
+
+distutils_enable_tests pytest
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/mkdocs-material/Manifest b/dev-python/mkdocs-material/Manifest
index afe1aeb752ac..2a864d357a15 100644
--- a/dev-python/mkdocs-material/Manifest
+++ b/dev-python/mkdocs-material/Manifest
@@ -4,3 +4,4 @@ DIST mkdocs-material-8.3.4.gh.tar.gz 8311720 BLAKE2B df2b01fa36b49e33be95d67935b
 DIST mkdocs-material-8.3.6.gh.tar.gz 8312956 BLAKE2B c4a6603a23adb882c404356234b10f9a41159424534f1eed4d407381ae8bad0c50adc2d92670e33a52e0e946fdcf0a5a02ae74b25e6ef7439cdb57f178eab313 SHA512 94ec949c133d09b166326490ee8da4c539ded266aeabdd46970596df7da5607dc06866e618cdbe1694a8e1cd1ba0202a3fbb9da90cc5862f4324551c3a4e4154
 DIST mkdocs-material-8.3.7.gh.tar.gz 8202111 BLAKE2B 1a30a3d4de788adb3b0129458d9c3ad14f16f40c8109f8b31cf15cb285cd5ad58e8eea529a8bc74ba8ef9342589ae2e22a561e01e1d0940ac77e673232557caf SHA512 766bb25d4f6a0332bd7ebb473b846b45a006e44335cf0b5b57024ef1f77f5ca173ad3fea5041ce9bfb777d2da2249907f3c4b921d41686fe430ed43c158e8780
 DIST mkdocs-material-8.3.8.gh.tar.gz 8318363 BLAKE2B 5b97026e96e28058e7d7081db9da92bc4457e8e7e022e4201c558c1193c5ff293f85ec576cb46db40de24c301f73a614217062a6bee2835fedab71c362e89a96 SHA512 216ae887463e67251285b788ff298db504ce65043337707a2f54dc3ce31f3461c90126a86c506c709592b3e3876934685a97e68a9c58ac0a4b6be480bb3b65b8
+DIST mkdocs-material-8.3.9.gh.tar.gz 8347276 BLAKE2B 51c953aad234a177d6b74bc8ef5e836ea6ee9f3c9e53b843efe25214069bfd94c3695fbe0dde0d3daec54c030bc35f5c4be668592afda45fa7ba7bbeb63a0475 SHA512 e7012a6f7db41b2bc4a43d0463f08fb3f7102ca3d7957ecdb2c88343a96ea774c8f724e498b2254a6bc6464d88681a605e52e4632c56cf0c60c6bf4269ac01a9
diff --git a/dev-python/mkdocs-material/mkdocs-material-8.3.9.ebuild b/dev-python/mkdocs-material/mkdocs-material-8.3.9.ebuild
new file mode 100644
index 000000000000..c6c3069f44ba
--- /dev/null
+++ b/dev-python/mkdocs-material/mkdocs-material-8.3.9.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="
+	dev-python/mkdocs-material-extensions
+	dev-python/mkdocs-minify-plugin
+	dev-python/mkdocs-redirects
+"
+
+inherit distutils-r1 docs
+
+DESCRIPTION="A Material Design theme for MkDocs"
+HOMEPAGE="
+	https://github.com/squidfunk/mkdocs-material/
+	https://pypi.org/project/mkdocs-material/
+"
+SRC_URI="
+	https://github.com/squidfunk/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/jinja-2.11.1[${PYTHON_USEDEP}]
+	>=dev-python/markdown-3.2[${PYTHON_USEDEP}]
+	>=dev-python/mkdocs-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.12[${PYTHON_USEDEP}]
+	>=dev-python/pymdown-extensions-9.4[${PYTHON_USEDEP}]
+"
+
+# mkdocs-material-extensions depends on mkdocs-material creating a circular dep
+PDEPEND=">=dev-python/mkdocs-material-extensions-1.0.3[${PYTHON_USEDEP}]"
diff --git a/dev-python/pikepdf/Manifest b/dev-python/pikepdf/Manifest
index 08ee820e3f37..ed686d74ff79 100644
--- a/dev-python/pikepdf/Manifest
+++ b/dev-python/pikepdf/Manifest
@@ -2,3 +2,4 @@ DIST pikepdf-5.1.3.tar.gz 2356111 BLAKE2B 5a9ec1d06f91be44b4eacc68d7d9449a2bb74b
 DIST pikepdf-5.1.4.gh.tar.gz 2356865 BLAKE2B 7ebeedd7a2bb29371325b0cd6cb89cd56843eee1847cb26f0487d0114a3268e9a15171769abc16502c48684bb1bbe59050a2c692e17857f161ccd10a4663eeb0 SHA512 390c8f07bb5602715a061bf26b272cc8301dbb610ea06b8e5e5560282b7256c03e87717ab62a657c662ef51f549f5d52f0133f3806ff536451664ac93add625a
 DIST pikepdf-5.1.5.gh.tar.gz 2356890 BLAKE2B e08f311ad2714f856eb29510e847ca2ddf2b3919cc372d4bedb59c7449be69574a32ea6cd23f51c34d56096bb8d2936f70c52a6a948d513277ff2a5d13e35725 SHA512 e6da0471abdd2a8133fb5789f72eb948e32eae24ee61956fb71f5e279151bc6df5d18ac9b6d73987fd9b891739892111df8c5f93c90ba8ae022dbb2821858350
 DIST pikepdf-5.2.0.gh.tar.gz 2359546 BLAKE2B 953a5268eb7dc52934967b593237bb3006ee35e7a1657c0721ef4cdc874c9c51d7920fbdb7e38f67e221b01536166b8811a95021668491e8c783f51a08f49144 SHA512 f36ec09017aeac547c2b4ef17de7513293e8bf243707cb9c0c03826973be266847d8514002be546ac958a735e29765df94efdaecde6ad5f901c329dadc3e9451
+DIST pikepdf-5.3.0.gh.tar.gz 2360722 BLAKE2B 1be449661deb3e57f097e0a95fcd099c1652e0700077077e299c88ae131487e6f2bb89cc07ffc06bdf15f46bc6aa613ed823b9dcc6ef55f100f37451be7c2488 SHA512 ef82703447d20edc497fcac287b4eddb48f1901aa060dc5f57301469741bb15ce367d0eac4ec27431740707f0e56975dc36d8e7eb3897c879663d56134c14fb1
diff --git a/dev-python/pikepdf/pikepdf-5.3.0.ebuild b/dev-python/pikepdf/pikepdf-5.3.0.ebuild
new file mode 100644
index 000000000000..1422766e810c
--- /dev/null
+++ b/dev-python/pikepdf/pikepdf-5.3.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="Python library to work with pdf files based on qpdf"
+HOMEPAGE="
+	https://github.com/pikepdf/pikepdf/
+	https://pypi.org/project/pikepdf/
+"
+SRC_URI="
+	https://github.com/${PN}/${PN}/archive/v${PV/_p/.post}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	>=app-text/qpdf-10.6.2:0=
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/deprecation[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pillow-9[${PYTHON_USEDEP}]
+	>=dev-python/pybind11-2.9.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pybind11-2.9.1[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-6.4[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm_git_archive[${PYTHON_USEDEP}]
+	dev-python/tomli[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-5[${PYTHON_USEDEP}]
+		>=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
+		>=dev-python/psutil-5[${PYTHON_USEDEP}]
+		>=dev-python/pytest-6[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-1.4.2[${PYTHON_USEDEP}]
+		>=dev-python/python-dateutil-2.8.0[${PYTHON_USEDEP}]
+		>=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/-n auto/d' pyproject.toml || die
+	distutils-r1_src_prepare
+}