Adding metadata

30 files changed, 623 insertions, 61 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index d246b9b2970a..afc514be528d 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -3,3 +3,4 @@ DIST boto3-1.34.149.gh.tar.gz 845064 BLAKE2B 25e77483b8ac8a52e7f5586794839dcab69
 DIST boto3-1.34.153.gh.tar.gz 847038 BLAKE2B f29aec887fd57d2bc4b6be125787384438e0dba65dd01effcc91016b9301be2fdde315a2fbdc8f122350ae52f904ba1c281aee9a5dc52994ddd11b45ead3f8a3 SHA512 a8d8f75ef48ad8418aafddbdea4fb021f64b041e7beabf68a0c2f6c461c3aa0b3f2f20c33122ac87d57296fd0d14ee8834b96257085c522b556f6aa1d99ea0d1
 DIST boto3-1.34.154.gh.tar.gz 847586 BLAKE2B 6ae763f1e112f865f8711951ac52f4ff28976928470ac3d8c468278e0abde23750457b8f92a9346b1468f94da4282b5b71eba09f7b442fd448ab8c1501e79914 SHA512 22eb130dbeaf9dfc87d2e01dddd00d3bd10a2fa91c8c7994add2ad3d739769dbd56717d9d034a0edb8e02ad15b8b956a31737269b303a3ec3508d8cfc00482ed
 DIST boto3-1.34.155.gh.tar.gz 847949 BLAKE2B 922377411d5535ff98b81f96cdb15dfd98de23bda40acabb172c889b221936083ad91403f59926fb29ca480f6d0056fb0441371dcfbd2b94d05158c34503bb8c SHA512 c8d7764c10a81fa8fb32eecdd242a36032db451bf4afe1bbc1974de422e0dc387d18e9ef78dcbdb41b19a05db4da8d66131d246b074463a33ae072a61141c362
+DIST boto3-1.34.156.gh.tar.gz 848245 BLAKE2B ee690925f3e3866f0b843bebdfd48bf4bf2f63232c5207f2e3c5823f7b5142c8990b65d5cdfb14a2d14b2460c463efec6444c50733ac920b3a28188dc814adff SHA512 f42ddc6eab3cd07b80021fc3fa99c2fdeae85d70249a369d8a8d5c1e0fc7d692e78989489de8976ac66ce91327352f9df2b70574a8067bf44c1f09b4476ef0ca
diff --git a/dev-python/boto3/boto3-1.34.156.ebuild b/dev-python/boto3/boto3-1.34.156.ebuild
new file mode 100644
index 000000000000..509842b2699d
--- /dev/null
+++ b/dev-python/boto3/boto3-1.34.156.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+SRC_URI="
+	https://github.com/boto/boto3/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.10.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 850625a13c7d..e27916f7ed60 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -3,3 +3,4 @@ DIST botocore-1.34.149.gh.tar.gz 13245965 BLAKE2B 6bc05c1d93eaa62fa9acb3c0e42acd
 DIST botocore-1.34.153.gh.tar.gz 13269606 BLAKE2B 1b2ec1af3b699c18c5761fe72b8488361f843e1b2abc5f311736e7c93a52574738a8e72708791657d0d86586d64ee3c85804514779c6dc75c6c2e37035517be1 SHA512 9a7b3359f4304bcb4d3605e2516514360e8898d7b8b1fdee8fab5dc6026a7d8197b09199da4e9aefcf1ab0b094a2e0e336ad13942ce0364f7b5ac87d86fdc4fd
 DIST botocore-1.34.154.gh.tar.gz 13272973 BLAKE2B ce1616749d9baddf6fbbf08be1dc0c5343b3b9ec3bf2b357690ca31076d52f814e7a7d4f61f2a2e2629d35c55894bd56e6fa4ada8834e1df1b072638ec6dd874 SHA512 5b5d8efb5834ddfac08216a9919f2e1d3ac92823b635530a429e45b90f16fbf426dabec7da98e965f5e540fb471eba49d3ccbf55e771d956fa200f6196612837
 DIST botocore-1.34.155.gh.tar.gz 13274262 BLAKE2B ec3602e31e2091877faa07841494e63b169624992c88a7eb9fa0315c2dcb205b7903e1eba101291caeadc89f078365e1fb605ffd1dc096cbb748e206d9bc5df1 SHA512 6582c286304cb667048325c7b2710fc040f41a822497732919e7982791d686af21e9f7851239b736e0b2f7e463f00fdb9e0e2793004d04c3fce7831d10f46e60
+DIST botocore-1.34.156.gh.tar.gz 13279124 BLAKE2B 022551a3247c467a4ec81ec257b50887ea9626b966df42b3f175a1ff3fa3daab73be9c17d0fdf8b2d0a69797f26575c84b11aac8e39ca26b624e4f3228de92e6 SHA512 ae4dbde1624b410b26c2e514582470ece7d841faad72d8288da09e980314170e60594095d86aeb3cba0878687832cf1e971277f943f935ecee2625eaefd4faab
diff --git a/dev-python/botocore/botocore-1.34.156.ebuild b/dev-python/botocore/botocore-1.34.156.ebuild
new file mode 100644
index 000000000000..64a61a30c80b
--- /dev/null
+++ b/dev-python/botocore/botocore-1.34.156.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+SRC_URI="
+	https://github.com/boto/botocore/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+# unbundled packages
+RDEPEND+="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	case ${EPYTHON} in
+		python3.13)
+			EPYTEST_DESELECT+=(
+				# memory use tests, probably fragile
+				tests/functional/leak/test_resource_leaks.py::TestDoesNotLeakMemory
+			)
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/crc32c/Manifest b/dev-python/crc32c/Manifest
index 760df9c9fcc6..326fbd5bbccd 100644
--- a/dev-python/crc32c/Manifest
+++ b/dev-python/crc32c/Manifest
@@ -1,2 +1,2 @@
 DIST crc32c-2.4.1.tar.gz 38277 BLAKE2B 3d4a0eeb5811e8bc46df30b8890ab409de92dc3cfe2c5c3ab355df3394e56812c19ac26523be2cf9c33bb5825fb6e080b6f27ea77bed5c38d98fbe6c247653fb SHA512 005f95f66e97f552a83b5c94b706224f44280895d70c348fee86943bf1589a94b57eeddde5e18499fea9c77cbcbcfd5691d9d4b33ed788dc885a1333b6db476b
-DIST crc32c-2.4.tar.gz 38272 BLAKE2B 1273f62794bd646e983737d922c4e1320a4519856b1cedf2d1d1f9b1e47fc767e248b6e00ada48e8f245e47fc18619327e9a8cfa5d88a0569c467ca6147a1974 SHA512 d747dee42184ff025dd6fd7334b65e5caba4066a055943a783b951d09e09339694072ea552aa95579f03a85a7bdb2eb4a8d12dc9a17f0f83d84c0fde534b36cb
+DIST crc32c-2.5.tar.gz 41514 BLAKE2B a9424ef917f3c89f3b8b3881ccd5d59cb8a634d6177260ce9e7300e151e68e97e55b74448dd4cd545d2d66d2e2d8e70a085578719f768662542e43f06e914d20 SHA512 446f2290706eae8a625590c6b314d8422938dd9b8bffcf5e4dd6d3d260932548dbc5d9a9b6e7e5eaaaaac8dce424876f4e4acc9b0b1ea2b7cdc6ddd101228cfd
diff --git a/dev-python/crc32c/crc32c-2.4.ebuild b/dev-python/crc32c/crc32c-2.5.ebuild
index 1fbac4912349..5a5ea87c360b 100644
--- a/dev-python/crc32c/crc32c-2.4.ebuild
+++ b/dev-python/crc32c/crc32c-2.5.ebuild
@@ -23,11 +23,6 @@ IUSE="cpu_flags_arm_crc32 cpu_flags_x86_sse4_2"
 
 distutils_enable_tests pytest
 
-PATCHES=(
-	# https://github.com/ICRAR/crc32c/pull/44
-	"${FILESDIR}/${P}-sparc.patch"
-)
-
 python_test() {
 	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
 	local -x CRC32C_SW_MODE
diff --git a/dev-python/crc32c/files/crc32c-2.4-sparc.patch b/dev-python/crc32c/files/crc32c-2.4-sparc.patch
deleted file mode 100644
index f2e96638d51b..000000000000
--- a/dev-python/crc32c/files/crc32c-2.4-sparc.patch
+++ /dev/null
@@ -1,34 +0,0 @@
-From 9d94ecbfe2363c7adf49bddbf31871764faf4f41 Mon Sep 17 00:00:00 2001
-From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
-Date: Sun, 30 Jun 2024 16:00:34 +0200
-Subject: [PATCH] Fix char signedness issue in _crc32c_sw_slicing_by_8()
-
-Fix `_crc32c_sw_slicing_by_8()` to use `unsigned char` for `p_buf`,
-to fix incorrect results on platforms with signed `char` such as SPARC.
-The code has been casting `unsigned char *` to `char *` for no apparent
-reason, and this broke the bitshifts in the big endian blocks.
-
-Particularly,
-
-    crc ^= *(p_buf++) << 16
-
-would be XOR-ed against `0xffee0000` rather than `0x00ee0000`.
-
-Fixes #43
----
- crc32c_sw.c | 4 ++--
- 1 file changed, 2 insertions(+), 2 deletions(-)
-
-diff --git a/crc32c_sw.c b/crc32c_sw.c
-index 8382749..67409c9 100644
---- a/crc32c_sw.c
-+++ b/crc32c_sw.c
-@@ -490,7 +490,7 @@ const uint32_t crc_tableil8_o88[256] =
- 
- uint32_t _crc32c_sw_slicing_by_8(uint32_t crc, unsigned const char* data, unsigned long length)
- {
--	const char* p_buf = (const char*) data;
-+	unsigned const char* p_buf = data;
- 	size_t initial_bytes = (sizeof(uint32_t) - (intptr_t)p_buf) & (sizeof(uint32_t) - 1);
- 	size_t li;
- 	size_t running_length;
diff --git a/dev-python/dict2xml/Manifest b/dev-python/dict2xml/Manifest
index 5339c8fbe34b..5011bac1eb4a 100644
--- a/dev-python/dict2xml/Manifest
+++ b/dev-python/dict2xml/Manifest
@@ -1 +1,2 @@
 DIST dict2xml-1.7.5.tar.gz 14958 BLAKE2B 1907003e3a27a8e1c1a0e7ab1d5c72b310c46e7af7d51f6a1743ca018fb6a070b0b54b4b24afd8c78dd18f83f9f6950031c0076eae83ccc309a341a0df153708 SHA512 88a77fcdc2ec320ba1668b27da4aacfcfc817090aebabc01fce76bff51b316166a0cc1f053884e8012a28e7118449f901465703869245dc662f29cee9665157e
+DIST dict2xml-1.7.6.tar.gz 15210 BLAKE2B 86ed48b2dc857efd58294c23f0708102ac66dab50e7f50ae149185f3fb707f72ef67008921ea641ed1bd96a91b25b39a92ddc796eadb64560ff29b82cd1ef07e SHA512 54e8330a556e7576d100fbbc036e8c9627872c4c1cbebcaedf137f2b8ad8e197e49b2e699c284f9c8a3d9874fea83eac80d129f67ea426e807e5699f8811b933
diff --git a/dev-python/dict2xml/dict2xml-1.7.6.ebuild b/dev-python/dict2xml/dict2xml-1.7.6.ebuild
new file mode 100644
index 000000000000..0630a43d91fb
--- /dev/null
+++ b/dev-python/dict2xml/dict2xml-1.7.6.ebuild
@@ -0,0 +1,25 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Small utility to convert a python dictionary into an XML string"
+HOMEPAGE="
+	https://github.com/delfick/python-dict2xml/
+	https://pypi.org/project/dict2xml/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="
+	dev-python/noseofyeti[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 15e8bd1f8c46..3e1b4e225a62 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -2,6 +2,7 @@ DIST Django-4.2.15.checksum.txt 2418 BLAKE2B 06338f990952736d1368c11bc0a14df4fcb
 DIST Django-4.2.15.tar.gz 10418066 BLAKE2B 4abf7205995fbc8dd90ca43aadfdd6737c5f731fea4054f987ae851e0b6f0a5f0f799441f94ca322e31c07c2a810903a00b4432b71a7517b2a261c4844ddba90 SHA512 8f334dcaa36b3bce5184ddf1a1508bf42614be6ab486c9e0d87e9bfd212511c43081ad5fb02d2dd7b54f8236fc1f7ee9cd7b7f6f94ac8edc1cb52d1c0c698880
 DIST Django-5.0.8.checksum.txt 2408 BLAKE2B 18751733d7abaa4e98039bf0cfa3773a999df4351371939803ec77850c25d75392abc7e4136e8c4a79620017c224bafcd8552c2446ee0817249abebcc3b0e1bb SHA512 c05027bdec0928dd51239ba5c72b97b737ad73dbbdbdc1c4bef2b9faf8afc188cd854e1dcd3b5ffbdc9c3a30dea5a27e4b899f9d257bcee6f80fbfdfd30e7a20
 DIST Django-5.0.8.tar.gz 10630791 BLAKE2B 0a5408b46b69b701f3ff88717b41b22cd4abd776a0b46f46025febd423e4b9c5f395da50a5be9e479bc0047405330231da400f3f2324bbb69ca5ab07966bc168 SHA512 b835d01f76f0e0082f299c2b15483aa3a8aef79f873b09dac546d3b4ecfa8a6fb84d9377e06e18a858bd24bcdd2db89c4cf05811b3af133b7da6609f6c2d917c
-DIST Django-5.1rc1.tar.gz 10747906 BLAKE2B a254c19d3e1713962e42736a99f2775c79ed7ad9b337280688402e7f564bc21c4b190f4887eb8aefee8ed17ab11cc51b490eb99bad967f2ad2e1321f70de9e80 SHA512 52d07fbfa031962a12109aa79ff44e93de3cba40c410be0707b46d1c47e352f066e5b58495f3aec5e60bd0b3844c667014b959965a248c4b6d997b8ced953622
+DIST Django-5.1.checksum.txt 2551 BLAKE2B bec3fb2608b4152667420951ea7ba34cdbf416b30c0d03508917c0f41b914d6f55b69b209da308407659d93c1a23ecac33272969ad042c7bb8c1e8ac1c19527f SHA512 70f9dce04687c01b641b5c07ce8476db15231a82262015fb18a97b90b3caac11cb7d50cd7a749a80321af9a04bfce212ed9400be0fd114cb8d37f82193396161
+DIST Django-5.1.tar.gz 10681050 BLAKE2B 1cded54e573d7a75ff246523235a1e17b6900000ef428f02ddf1f17fb0146449cef28da9207cfb3a0a888def86620a755cb62dba033c15501dc9125d6164f462 SHA512 4c34df7adf2a151488d8595551fe6e8eb90fdef9d7592ce1d8c8b0663fe4d876614f5dde4df1dd648153d4df6246ae39dbb33a66b1c3d2f60bd46595e0efb396
 DIST django-4.2.8-pypy3.patch.xz 5900 BLAKE2B b7dc5c5fc162817a218ee6d025ed8a65559b80e4506e49ac393428c26e2621f9e7c5010b36f2412dea8194a9f1086ab21f97286eabd696c6a786285eb07393cf SHA512 f953b5adbd1364f1d84dde55087ccb493256b1327701275fd2fe99f3cd41751d18e002b6e21afc96892e1671428a6b8f3c2e4b88252c3c278f1a79e286bb73e3
 DIST django-5.0-pypy3.patch.xz 6124 BLAKE2B 7eba7cc70b30743cf4e186a2c5b0f27c13f49114a7a80bcaa2b25fdd7a959583c115a302c9bc6da97c32f6401cf8f3616818ba759190d317c5b033a0f0088766 SHA512 c550e2b2c1243d13cd1f4908f4b6df606355d1491e3bf72042e4b4777a4474306ff0f67b1c2eb4ab4d137cc85bde52dcdbd54bec245d2ba2e092545be8a2993b
diff --git a/dev-python/django/django-5.1_rc1.ebuild b/dev-python/django/django-5.1.ebuild
index 9b16c9a95a0d..0b53a7c5d8d6 100644
--- a/dev-python/django/django-5.1_rc1.ebuild
+++ b/dev-python/django/django-5.1.ebuild
@@ -4,12 +4,10 @@
 EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
-PYPI_NO_NORMALIZE=1
-PYPI_PN=${PN^}
 PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
 PYTHON_REQ_USE='sqlite?,threads(+)'
 
-inherit bash-completion-r1 distutils-r1 multiprocessing optfeature pypi
+inherit bash-completion-r1 distutils-r1 multiprocessing optfeature verify-sig
 
 DESCRIPTION="High-level Python web framework"
 HOMEPAGE="
@@ -17,6 +15,12 @@ HOMEPAGE="
 	https://github.com/django/django/
 	https://pypi.org/project/Django/
 "
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+	https://dev.gentoo.org/~mgorny/dist/python/django-5.0-pypy3.patch.xz
+	verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
 
 LICENSE="BSD"
 # admin fonts: Roboto (media-fonts/roboto)
@@ -24,6 +28,7 @@ LICENSE+=" Apache-2.0"
 # admin icons, jquery, xregexp.js
 LICENSE+=" MIT"
 SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
 IUSE="doc sqlite test"
 RESTRICT="!test? ( test )"
 
@@ -46,6 +51,7 @@ BDEPEND="
 		>=dev-python/tblib-1.5.0[${PYTHON_USEDEP}]
 		sys-devel/gettext
 	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20240807 )
 "
 
 PATCHES=(
@@ -56,6 +62,17 @@ distutils_enable_sphinx docs --no-autodoc
 
 VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/django.asc
 
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
 python_test() {
 	# Tests have non-standard assumptions about PYTHONPATH,
 	# and don't work with ${BUILD_DIR}/lib.
diff --git a/dev-python/http-ece/Manifest b/dev-python/http-ece/Manifest
index eb6b778bee52..607aadc4b0c6 100644
--- a/dev-python/http-ece/Manifest
+++ b/dev-python/http-ece/Manifest
@@ -1,2 +1,2 @@
-DIST http-ece-1.1.0.gh.tar.gz 19406 BLAKE2B 3347d318ac30c14d6d0b6149746c6dd8ad1681664c165a1dd89858cc50b04452db1576841280f44fe701ca0cb662dad6cbf4c44188b24dad9863185f76e0839d SHA512 22e5d23258c8a4216d63ee0c0e2765dfc742a1887baddca337cce090213e78c8849de01e3bd83c92628eb85ecdbcd6ad4e0462a47fde741028b83cb972865908
+DIST http-ece-1.2.1.gh.tar.gz 19876 BLAKE2B 71955d47e68dca11b1b4b5bd73f5808369a2e3a95c71b250561ce0ab109ecf4b57dce6a80f750ab23c580ee855e95bf6798f612975c6b4fb8632ae392e34255b SHA512 362ffc15a5cd320c01b49ca6ffbe3e23abb12996b689750052d2fa77f6d17bcb0a736c9dccd08983d39daef487879e13ec874d4fa6b266aa57edccadfeb2565a
 DIST http_ece-1.2.0.tar.gz 8771 BLAKE2B 378c82356b4cc754485a830b44e4dd67e7bc3ccab0b1d6ab786b35c7c9529cf621c3a285cdcee9750803367567cb0387a9c7318296e1b401fee317b0ccf057a5 SHA512 84173c190798c1706eda826b49efbe5db394d4216a236df9265c7995cf7baf151d653c6ff34d4fd981513303808062bdebf7cc1d98bc7543bc352a11631f3180
diff --git a/dev-python/http-ece/http-ece-1.1.0.ebuild b/dev-python/http-ece/http-ece-1.2.1.ebuild
index 76551a8812c2..d6a7dd33a241 100644
--- a/dev-python/http-ece/http-ece-1.1.0.ebuild
+++ b/dev-python/http-ece/http-ece-1.2.1.ebuild
@@ -1,10 +1,12 @@
-# Copyright 2022-2023 Gentoo Authors
+# Copyright 2022-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
 PYTHON_COMPAT=( python3_{8,9,10,11,12} )
 DISTUTILS_USE_PEP517=setuptools
+# TODO re-enable pypi when it is available on there
+# <https://github.com/web-push-libs/encrypted-content-encoding/issues/79>
 inherit distutils-r1
 
 MY_PN="encrypted-content-encoding"
@@ -13,16 +15,15 @@ HOMEPAGE="
 	https://pypi.org/project/http-ece/
 	https://github.com/web-push-libs/encrypted-content-encoding
 "
-SRC_URI="https://github.com/martinthomson/${MY_PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
-S="${WORKDIR}/${MY_PN}-${PV}/python"
+SRC_URI="https://github.com/web-push-libs/encrypted-content-encoding/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/encrypted-content-encoding-${PV}/python"
 
 LICENSE="MIT"
 SLOT="0"
 KEYWORDS="~amd64"
 
-# v1.1.0 is incompatible with latest 'cryptography'
-RESTRICT="test"
-
 RDEPEND="dev-python/cryptography[${PYTHON_USEDEP}]"
 
+RESTRICT="test" # tests seem to be broken, further investigation advised
+
 distutils_enable_tests pytest
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index c03130161f08..6860396ab89d 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -4,3 +4,4 @@ DIST hypothesis-6.108.5.gh.tar.gz 9473125 BLAKE2B fa72dd3958970308bbd656643343d5
 DIST hypothesis-6.108.8.gh.tar.gz 9474435 BLAKE2B fd199019fdbc945c3fec0d9349f443ede307ee155cbb6f01e30f8ce888805b4f37754af9c675112b0f0ca30146d4a5dd45915be66194c677a72a7b2f71979605 SHA512 62090fc72e8f563c59a93b27a2febf0e68e30e2ef322f85ef6abca9a21d182105ea2210b47e4590a752a365d79328d758d0077d50f5857cbeb336ca6ce1e1c1b
 DIST hypothesis-6.108.9.gh.tar.gz 9474517 BLAKE2B c5f10dcc096e7c410444bc609ef8d2c05177f38b4fba79205913db014839da44f25b0ad76758bb31a4ba3c6d6fed25ebb80d66d833842044644b0638feb19afa SHA512 ae0e4963d304cf41900c3ad23f4839d49cfb74edb4d27aae7317e3a8ecd23ca965bd002766228012407b8297828e1d1304719875b4ffd04c6a21d0249cdf2fe2
 DIST hypothesis-6.109.0.gh.tar.gz 9475581 BLAKE2B 2e523b35745b7d1062c17093cf8b80da746574b985653f8f3e83880e5e2f3a3671a7b264b071c8c45394ce190154cc6f6b5f8ae508a9eb6c5911a836753497a4 SHA512 da8ff55e3661bc7f4cb9e5378ae37284af8b246d9fc5162363ba67c8ab4147f3c6d0feff7afa9d7deaeab3ab4cde6ba972c6b1d6464602eb78dcd33f67094113
+DIST hypothesis-6.110.0.gh.tar.gz 9476232 BLAKE2B 69ba7c4872608a69ae18e35fa895cec6fc4fa2dc426a0f876d41d5e85eec061962d98edeaaefeddd5244423923231316dc29ce4eba3a639e533bd61a52d6425c SHA512 45fa3bcb59e9e7f173b153b56888d69df2650f5382226c92f1f67ae9c9ad7e3fff383cb27c9862c7ea103c1b059c8de9d04c66cbaaf7a2a5b529044b3a31ed41
diff --git a/dev-python/hypothesis/hypothesis-6.110.0.ebuild b/dev-python/hypothesis/hypothesis-6.110.0.ebuild
new file mode 100644
index 000000000000..6ba8058fdf38
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.110.0.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( pypy3 python3_{10..13} )
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/pytest-8[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/requests-toolbelt-0.10.1
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,_hypothesis_pytestplugin
+	local -x HYPOTHESIS_NO_PLUGINS=1
+
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# failing due to warnings from numpy/cython
+				hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+			)
+			;;
+	esac
+
+	epytest -o filterwarnings= tests/cover tests/pytest tests/quality
+}
+
+src_install() {
+	local HAD_CLI=
+
+	distutils-r1_src_install
+
+	if [[ ! ${HAD_CLI} ]]; then
+		rm -r "${ED}/usr/bin" || die
+	fi
+}
+
+python_install() {
+	distutils-r1_python_install
+	if use cli && has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		HAD_CLI=1
+	else
+		rm -r "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index 37a64204a00a..a11d7c268c91 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1,3 +1 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
-EBUILD langdetect-1.0.9.ebuild 494 BLAKE2B 9b3521c5721afa49a58e0c35267f7d82bb56bd7e1d6d3152be0d36cd220180a526cb20b90b1113fbf0fff4a512137570f0b3bcf864498b7b7cc00403cb61ca27 SHA512 16d311400bf84a5f04e15f3da4b68b2810e4b005009f4d03dc8a487176dfc294403c976c412c83dcfa8084a49ef7b7d5389b43fb2ba446ce107ce4595e3558c6
-MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch b/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
new file mode 100644
index 000000000000..637368d2f237
--- /dev/null
+++ b/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
@@ -0,0 +1,13 @@
+Fix "Package 'langdetect.profiles' is absent from the `packages` configuration."
+
+--- a/setup.py
++++ b/setup.py
+@@ -18,7 +18,7 @@ setup(
+     author_email='michal.danilak@gmail.com',
+     url='https://github.com/Mimino666/langdetect',
+     keywords='language detection library',
+-    packages=['langdetect', 'langdetect.utils', 'langdetect.tests'],
++    packages=['langdetect', 'langdetect.utils', 'langdetect.tests', 'langdetect.profiles'],
+     include_package_data=True,
+     install_requires=['six'],
+     license='MIT',
diff --git a/dev-python/langdetect/langdetect-1.0.9.ebuild b/dev-python/langdetect/langdetect-1.0.9.ebuild
index c09b7356f549..630fe63c6f53 100644
--- a/dev-python/langdetect/langdetect-1.0.9.ebuild
+++ b/dev-python/langdetect/langdetect-1.0.9.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2022 Gentoo Authors
+# Copyright 2022-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -19,4 +19,6 @@ KEYWORDS="~amd64"
 
 RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
 
+PATCHES=( "${FILESDIR}/${P}-explicit-config.patch" )
+
 distutils_enable_tests unittest
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index 020e07f2a3dd..c0f74ac187e2 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -2,11 +2,9 @@
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
  <maintainer type="person">
-  <email>marcin.deranek@slonko.net</email>
-  <name>Marcin Deranek</name>
+  <email>pastalian46@gmail.com</email>
+  <name>Takuya Wakazono</name>
  </maintainer>
- <upstream>
-  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
- </upstream>
- <origin>slonko-overlay</origin>
+ 
+ <origin>gentoo-guru-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/more-itertools/Manifest b/dev-python/more-itertools/Manifest
index e3e759cdd461..f6fa4c97d9c7 100644
--- a/dev-python/more-itertools/Manifest
+++ b/dev-python/more-itertools/Manifest
@@ -1 +1,2 @@
 DIST more-itertools-10.3.0.tar.gz 118147 BLAKE2B 7205050f4cb3e705e3ad7f477baba0e3976b7b48fae44622014efb56fbae85efc1abfee5f6c3075326b53ffbae2bf1e626a524d2cb9241e033a75525e8b747d4 SHA512 fed7c1b085aafd5c50bbc5304f29a098d4ba96e4b253c2e5ab7fd995e895f5cdf63edada93f039b1a71e0f913c0902d8836f73de270bd1048a5fd8ed4f3d45a4
+DIST more-itertools-10.4.0.tar.gz 120755 BLAKE2B 26950158c03c3d05cf5e6983941bf087e7799c90aff2928b20cfa9efc80a890f85a9616e95e363c4151d2233fa49b0dfaa381ab6e27d188573162887226ccdff SHA512 03f1a2390cac259138c96b4bd53712f14b8ee09dc83fe32f237835e7cac59ed22d48f6bc97d1734e06fb0fb44511abf72bf5d30b72e757ab2c62ee0b0f02ffb1
diff --git a/dev-python/more-itertools/more-itertools-10.4.0.ebuild b/dev-python/more-itertools/more-itertools-10.4.0.ebuild
new file mode 100644
index 000000000000..8068c1213f82
--- /dev/null
+++ b/dev-python/more-itertools/more-itertools-10.4.0.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="More routines for operating on iterables, beyond itertools"
+HOMEPAGE="
+	https://github.com/more-itertools/more-itertools/
+	https://pypi.org/project/more-itertools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme
+distutils_enable_tests unittest
diff --git a/dev-python/pytest-import-check/pytest-import-check-0.0.4.ebuild b/dev-python/pytest-import-check/pytest-import-check-0.0.4.ebuild
index 44902770b8c7..749b264325bc 100644
--- a/dev-python/pytest-import-check/pytest-import-check-0.0.4.ebuild
+++ b/dev-python/pytest-import-check/pytest-import-check-0.0.4.ebuild
@@ -16,7 +16,7 @@ HOMEPAGE="
 
 LICENSE="GPL-2+"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 
 RDEPEND="
 	>=dev-python/pytest-8.1[${PYTHON_USEDEP}]
diff --git a/dev-python/sphinx-prompt/Manifest b/dev-python/sphinx-prompt/Manifest
index 666a3bee910b..0199b5855a29 100644
--- a/dev-python/sphinx-prompt/Manifest
+++ b/dev-python/sphinx-prompt/Manifest
@@ -1 +1,2 @@
 DIST sphinx-prompt-1.8.0.gh.tar.gz 38424 BLAKE2B c469e2acfdad076afd472c30380a59aae4d719edce653794fd4d09a2c8008b7f67642ce2a740fb1408987243ba5d520e28b3dc4d7ec34899de6fcf57f2171456 SHA512 1acaa18066537adaab71eb900f0b0fb8041f8f25a9079e171b98b98106d5b7d1885e23bae2c1fd278bbf22c66d17238fbf386cb61fc5725475862aaf86d5701e
+DIST sphinx-prompt-1.9.0.gh.tar.gz 39458 BLAKE2B 16b646bd0e288da3d2f401650c3131c7c6b9fb27023617717821927c7bd8b8d031f14d82b7dd02c6603f3ece084e766a28022cc418867646d770886cdce538ce SHA512 f9ee34b86ead0eda791ba7d648ae54785c09ca276279197c4632963892a03080e547d1930743d81ddb3b327c912c70a58dea968b1da763c4875ec84014b207f8
diff --git a/dev-python/sphinx-prompt/sphinx-prompt-1.9.0.ebuild b/dev-python/sphinx-prompt/sphinx-prompt-1.9.0.ebuild
new file mode 100644
index 000000000000..07723359bcac
--- /dev/null
+++ b/dev-python/sphinx-prompt/sphinx-prompt-1.9.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Sphinx directive to add unselectable prompt"
+HOMEPAGE="
+	https://github.com/sbrunner/sphinx-prompt/
+	https://pypi.org/project/sphinx-prompt/
+"
+SRC_URI="
+	https://github.com/sbrunner/sphinx-prompt/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/sphinx[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# version number relies on git repo, sigh
+	# also all dependencies are pinned to exact versions, sigh
+	# also huge hack to install package as "sphinx-prompt", sigh
+	sed -i \
+		-e "/^version =/s:[0-9.]\+:${PV}:" \
+		-e '/^\[tool\.poetry\.dependencies\]$/,$s:"[0-9.]\+:"*:' \
+		-e '/include.*sphinx-prompt/d' \
+		pyproject.toml || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index d171d4e5a59e..64a8fe1e904d 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,2 +1,3 @@
 DIST tox-4.16.0.tar.gz 179738 BLAKE2B 24ab57b05504ca8d4ef39c164604e5cc8150d722d0d0258bac8fe35b0dcf7ee31625734c65cabb26b4c49f377fe9b2be65f8d84481f7aee7307f9499e6498929 SHA512 b3d65c5b4f086f1f0474d6cb08d3d4bcdf81735376a94e97997ab5dee5c726e71e8b9a1117eda59f9afd61be0bff38a9533faf16e76b78b504ff6de0f2ddfde0
 DIST tox-4.17.0.tar.gz 179927 BLAKE2B 07e98d42248482ba0bf77080ea32ab5ccca937f1a8788a80d3e8f24a62f71553669bbcaaab4570f8d0ec4c6eecef3b0f812c00e9a31f212cb13bc16568408993 SHA512 8debbd10beca8d54135b11e88fdf8189389ec883f201bb3ef3b8418cd07f3247332cda4e0a82ee79ec9eadd09068bfd6bf0880ab22c88d82507dbf1c1650cedd
+DIST tox-4.17.1.tar.gz 180242 BLAKE2B 7b0a9964b359500bac47547530edf4e62fb8f39a52e10987959945e993f55f62f5ffed4db0c482c881348af5366c723be431ad9ded2d3642806c71ce62de0799 SHA512 51041bc7f09de1fdf4cfdc9c25ed2a4add2984a8612d4d43ce4740e7920d8fa984c1c64d0d6a45947d1891de6fa35507b1ca14afa641bc5af184ad97ba6df640
diff --git a/dev-python/tox/tox-4.17.1.ebuild b/dev-python/tox/tox-4.17.1.ebuild
new file mode 100644
index 000000000000..c4c03e498202
--- /dev/null
+++ b/dev-python/tox/tox-4.17.1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/pyproject-api[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.{9..10})
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/distlib[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_run_installpkg_targz
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+			)
+			;;
+		python3.13)
+			EPYTEST_DESELECT+=(
+				# https://github.com/tox-dev/tox/issues/3290
+				'tests/config/loader/test_str_convert.py::test_str_convert_ok_py39[1,2-value1-Optional]'
+			)
+			;;
+	esac
+
+	epytest
+}
diff --git a/dev-python/trimesh/Manifest b/dev-python/trimesh/Manifest
index 847db99d3871..693cce107dfd 100644
--- a/dev-python/trimesh/Manifest
+++ b/dev-python/trimesh/Manifest
@@ -1 +1,2 @@
 DIST trimesh-4.4.3.gh.tar.gz 13606522 BLAKE2B d59c59e11b67c301c0171dc911cf1e518b57f9b3e9d0d4410130922eb0fc5b190ec5d8088e43d35fb7b09687a2698fe41342ce492fafc7bb050431cf43624c9b SHA512 b93ed203589a5467116c942b6d02db7eb4c130b7f110ea2612a2cf4d86d9f7943b949dd62d2229762a2a14f796041aa6a4294857a8fcc3b96d470a6925b9d568
+DIST trimesh-4.4.4.gh.tar.gz 13606701 BLAKE2B 52df2a318adbc1ef263734d1ecc55121c486a8d546a5e3452d38f6e580e89dabe72eb8f437e023391bf5ae10a145d453ef1b3309af8d7a8fd37d20aa14f92832 SHA512 afeeca5532208bacca9e5539d894f72c7e93975c9f932487a852033ed75d20fe29a66880c62d3daf1ff328c198e40464ad3751c69e190994fd0ccc19da5723cf
diff --git a/dev-python/trimesh/trimesh-4.4.4.ebuild b/dev-python/trimesh/trimesh-4.4.4.ebuild
new file mode 100644
index 000000000000..3a9c1843a308
--- /dev/null
+++ b/dev-python/trimesh/trimesh-4.4.4.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for loading and using triangular meshes"
+HOMEPAGE="
+	https://trimesh.org/
+	https://github.com/mikedh/trimesh/
+	https://pypi.org/project/trimesh/
+"
+SRC_URI="
+	https://github.com/mikedh/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorlog[${PYTHON_USEDEP}]
+	dev-python/httpx[${PYTHON_USEDEP}]
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.20[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycollada[${PYTHON_USEDEP}]
+	dev-python/pyglet[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/shapely-1.8.2[${PYTHON_USEDEP}]
+	dev-python/svg-path[${PYTHON_USEDEP}]
+	dev-python/sympy[${PYTHON_USEDEP}]
+	dev-python/xxhash[${PYTHON_USEDEP}]
+	dev-python/rtree[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mapbox-earcut[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_TIMEOUT=1800
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# require pyinstrument
+		tests/test_sweep.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+pkg_postinst() {
+	optfeature_header "${PN} functionality can be extended by installing the following packages:"
+	optfeature "making GUI applications with 3D stuff" dev-python/glooey
+	optfeature "2D triangulations of polygons" dev-python/mapbox-earcut
+	optfeature "loading a number of additional mesh formats" dev-python/meshio
+	optfeature "figuring out how much memory we have" dev-python/psutil
+	optfeature "marching cubes and other nice stuff" dev-python/scikit-image
+}
diff --git a/dev-python/trio/Manifest b/dev-python/trio/Manifest
index fd17fe90c3b1..03b2f5e1bac7 100644
--- a/dev-python/trio/Manifest
+++ b/dev-python/trio/Manifest
@@ -1,2 +1,3 @@
 DIST trio-0.26.0.gh.tar.gz 609710 BLAKE2B ec263e5db731760472111b8eb6a7d6ebdc476f8dc0976787692289caa5d5361a1a3db03d4713f14ee3198ad45dcec19c6c672af4af3860c3cd7ad5ff3e13bc8a SHA512 9a51f4e71795083ffd4a606e989583b1a93e45dc32f93d2d03bccaf32ca62a82daaf964676636363711b7ea1675dddd3eac1acae1be73b0fc570baef3c37c748
 DIST trio-0.26.1.gh.tar.gz 610304 BLAKE2B 3bd9cd09cef7fe5484025ff2532c45a4a38f1c19b64ae833ecac5eda61463184a18020215dc569e40d1ec9950a860cf371ea461ac4d5b2dfc0f611d093c1ae7d SHA512 415bb701183e1a38574770e94c30fe4893a5f0be80291decf4524fc27677c12455124b3f7a03c37be89d42cb67b75e3315322f0cbf23264947d51ae251b3204e
+DIST trio-0.26.2.gh.tar.gz 610516 BLAKE2B dfb62a4024f2e42243dff6bea97ee3657c1975ff8d081010efe1b0fd3962a3b1c4847341df1028e2c902a043d0b43b6190ccdd72d5bfdb6e650912034ee56c28 SHA512 0b6fda127937de5c13eb12aea4ad5f95b4bfcb839c1a65c25a563aef6450bfb35c24af3509043eb389472e414549fbc9d40e64c8aff068cb34ffaf8b29fe9c67
diff --git a/dev-python/trio/trio-0.26.2.ebuild b/dev-python/trio/trio-0.26.2.ebuild
new file mode 100644
index 000000000000..552d9a0e3267
--- /dev/null
+++ b/dev-python/trio/trio-0.26.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for async concurrency and I/O"
+HOMEPAGE="
+	https://github.com/python-trio/trio/
+	https://pypi.org/project/trio/
+"
+SRC_URI="
+	https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/attrs-23.2.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.2.1[${PYTHON_USEDEP}]
+	' 3.10)
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/outcome[${PYTHON_USEDEP}]
+	>=dev-python/sniffio-1.3.0[${PYTHON_USEDEP}]
+	dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/astor-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/immutables-0.6[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+# Bug https://bugs.gentoo.org/916756
+# distutils_enable_sphinx docs/source \
+# 	dev-python/immutables \
+# 	dev-python/sphinxcontrib-trio \
+# 	dev-python/sphinx-rtd-theme \
+# 	dev-python/towncrier
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Times out on slower arches (ia64 in this case)
+		# https://github.com/python-trio/trio/issues/1753
+		tests/test_unix_pipes.py::test_close_at_bad_time_for_send_all
+		# requires ruff
+		_tests/tools/test_gen_exports.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	rm -rf trio || die
+	epytest -p trio._tests.pytest_plugin \
+		-m "not redistributors_should_skip" \
+		--pyargs trio \
+		--skip-optional-imports
+}