Adding metadata

17 files changed, 398 insertions, 136 deletions

diff --git a/dev-python/Pyro4/Pyro4-4.82-r1.ebuild b/dev-python/Pyro4/Pyro4-4.82-r1.ebuild
new file mode 100644
index 000000000000..13608ae4c3e3
--- /dev/null
+++ b/dev-python/Pyro4/Pyro4-4.82-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Distributed object middleware for Python (RPC)"
+HOMEPAGE="
+	https://github.com/irmen/Pyro4/
+	https://pypi.org/project/Pyro4/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 ppc x86"
+IUSE="doc examples"
+
+RDEPEND="
+	>=dev-python/serpent-1.27[${PYTHON_USEDEP}]
+"
+DEPEND="
+	test? (
+		>=dev-python/cloudpickle-1.2.1[${PYTHON_USEDEP}]
+		>=dev-python/dill-0.2.6[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.5.2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# network
+		tests/PyroTests/test_naming.py
+		tests/PyroTests/test_naming2.py::OfflineNameServerTests::testStartNSfunc
+		tests/PyroTests/test_naming2.py::OfflineNameServerTestsDbmStorage::testStartNSfunc
+		tests/PyroTests/test_naming2.py::OfflineNameServerTestsSqlStorage::testStartNSfunc
+		tests/PyroTests/test_serialize.py::SerializeTests_dill::testSerCoreOffline
+		tests/PyroTests/test_serialize.py::SerializeTests_dill::testSerializeDumpsAndDumpsCall
+		tests/PyroTests/test_socket.py::TestSocketutil::testBroadcast
+		tests/PyroTests/test_socket.py::TestSocketutil::testGetIP
+	)
+
+	cd tests/PyroTests || die
+	epytest
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/. )
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/Pyro4/Pyro4-4.82.ebuild b/dev-python/Pyro4/Pyro4-4.82.ebuild
deleted file mode 100644
index 595364ed6d30..000000000000
--- a/dev-python/Pyro4/Pyro4-4.82.ebuild
+++ /dev/null
@@ -1,55 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{7,8,9,10} )
-inherit distutils-r1
-
-DESCRIPTION="Distributed object middleware for Python (RPC)"
-HOMEPAGE="https://pypi.org/project/Pyro4/
-	https://github.com/irmen/Pyro4"
-SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 ~arm64 ppc x86"
-IUSE="doc examples test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	>=dev-python/serpent-1.27[${PYTHON_USEDEP}]"
-DEPEND="${RDEPEND}
-	test? (
-		>=dev-python/cloudpickle-1.2.1[${PYTHON_USEDEP}]
-		>=dev-python/dill-0.2.6[${PYTHON_USEDEP}]
-		>=dev-python/msgpack-0.5.2[${PYTHON_USEDEP}]
-	)"
-
-python_prepare_all() {
-	# Disable tests requiring network connection.
-	rm tests/PyroTests/test_naming.py || die
-	sed \
-		-e "s/testStartNSfunc/_&/" \
-		-i tests/PyroTests/test_naming2.py || die
-
-	sed \
-		-e "s/testBroadcast/_&/" \
-		-e "s/testGetIP/_&/" \
-		-i tests/PyroTests/test_socket.py || die
-
-	distutils-r1_python_prepare_all
-}
-
-python_test() {
-	esetup.py test
-}
-
-python_install_all() {
-	use doc && HTML_DOCS=( docs/. )
-	if use examples; then
-		dodoc -r examples
-		docompress -x /usr/share/doc/${PF}/examples
-	fi
-	distutils-r1_python_install_all
-}
diff --git a/dev-python/jschema_to_python/jschema_to_python-1.2.3-r1.ebuild b/dev-python/jschema_to_python/jschema_to_python-1.2.3-r1.ebuild
new file mode 100644
index 000000000000..fff04ef62e9d
--- /dev/null
+++ b/dev-python/jschema_to_python/jschema_to_python-1.2.3-r1.ebuild
@@ -0,0 +1,27 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+DESCRIPTION="Generate source code for Python classes from a JSON schema"
+HOMEPAGE="
+	https://pypi.org/project/jschema-to-python/
+	https://github.com/microsoft/jschema-to-python/"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/attrs[${PYTHON_USEDEP}]
+	dev-python/jsonpickle[${PYTHON_USEDEP}]
+	dev-python/pbr[${PYTHON_USEDEP}]"
+BDEPEND="
+	dev-python/pbr[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
diff --git a/dev-python/jsondiff/Manifest b/dev-python/jsondiff/Manifest
index 925d9e5191c4..342d8e6c22e1 100644
--- a/dev-python/jsondiff/Manifest
+++ b/dev-python/jsondiff/Manifest
@@ -1 +1,2 @@
+DIST jsondiff-2.0.0-nose2pytest.diff 11525 BLAKE2B e1e9f6996448c5f8454a74dbe5782684d68cbb00eae1793fd010bccd80b682e6f3869082df9546603ce87bee82a99148a948db675b1da8f2815e5290eb632763 SHA512 791e4f8473459e374892067cf90099df23d981857b81cc164e2d0c35c51cbbede160de1b46474b6cb817b8811e2481172807eff31847a7847fc847948cf402f7
 DIST jsondiff-2.0.0.gh.tar.gz 15405 BLAKE2B d69e5a9316e8ce32c6fd3e62162b609a471ff57bacb77f47a192b85352e77135a37c964d0ade5df4b4e37fe7d996eab13649dd4c6a3bc3fc0479294f840c82f9 SHA512 ca266040294c064b499763174613628125a9d426f37eddb8f63806d5774ce8828d514ca30ea4b42f6e2529aa34344c601ece05b6c1b42dcedd71c7b62ed0afba
diff --git a/dev-python/jsondiff/jsondiff-2.0.0-r1.ebuild b/dev-python/jsondiff/jsondiff-2.0.0-r1.ebuild
new file mode 100644
index 000000000000..252f98ed8df3
--- /dev/null
+++ b/dev-python/jsondiff/jsondiff-2.0.0-r1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Diff JSON and JSON-like structures in Python"
+HOMEPAGE="
+	https://github.com/xlwings/jsondiff/
+	https://pypi.org/project/jsondiff/
+"
+SRC_URI="
+	https://github.com/xlwings/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	https://dev.gentoo.org/~andrewammerlaan/${P}-nose2pytest.diff
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+PATCHES=(
+	# https://github.com/xlwings/jsondiff/pull/51
+	"${DISTDIR}/${P}-nose2pytest.diff"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Avoid file collision with jsonpatch's jsondiff cli.
+	sed -e "/'jsondiff=jsondiff.cli/ d" -i setup.py || die
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/jsonpickle/files/jsonpickle-2.2.0-python3.11.patch b/dev-python/jsonpickle/files/jsonpickle-2.2.0-python3.11.patch
new file mode 100644
index 000000000000..10c266a2a696
--- /dev/null
+++ b/dev-python/jsonpickle/files/jsonpickle-2.2.0-python3.11.patch
@@ -0,0 +1,46 @@
+diff --git a/jsonpickle/pickler.py b/jsonpickle/pickler.py
+index 3d391cb..2103e46 100644
+--- a/jsonpickle/pickler.py
++++ b/jsonpickle/pickler.py
+@@ -476,8 +476,12 @@ def _flatten_obj_instance(self, obj):
+ 
+         # Support objects with __getstate__(); this ensures that
+         # both __setstate__() and __getstate__() are implemented
+-        has_getstate = hasattr(obj, '__getstate__')
++        has_own_getstate = (
++            hasattr(type(obj), '__getstate__')
++            and type(obj).__getstate__ is not getattr(object, '__getstate__', None)
++        )
+         # not using has_method since __getstate__() is handled separately below
++        # Note: on Python 3.11+, all objects have __getstate__.
+ 
+         if has_class:
+             cls = obj.__class__
+@@ -549,7 +553,7 @@ def _flatten_obj_instance(self, obj):
+                 # check that getstate/setstate is sane
+                 if not (
+                     state
+-                    and hasattr(obj, '__getstate__')
++                    and has_own_getstate
+                     and not hasattr(obj, '__setstate__')
+                     and not isinstance(obj, dict)
+                 ):
+@@ -581,7 +585,7 @@ def _flatten_obj_instance(self, obj):
+             if has_getinitargs:
+                 data[tags.INITARGS] = self._flatten(obj.__getinitargs__())
+ 
+-        if has_getstate:
++        if has_own_getstate:
+             try:
+                 state = obj.__getstate__()
+             except TypeError:
+@@ -590,7 +594,8 @@ def _flatten_obj_instance(self, obj):
+                 self._pickle_warning(obj)
+                 return None
+             else:
+-                return self._getstate(state, data)
++                if state:
++                    return self._getstate(state, data)
+ 
+         if util.is_module(obj):
+             if self.unpicklable:
diff --git a/dev-python/jsonpickle/jsonpickle-2.2.0-r1.ebuild b/dev-python/jsonpickle/jsonpickle-2.2.0-r1.ebuild
new file mode 100644
index 000000000000..e35facdd8a6a
--- /dev/null
+++ b/dev-python/jsonpickle/jsonpickle-2.2.0-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for serializing any arbitrary object graph into JSON"
+HOMEPAGE="
+	https://github.com/jsonpickle/jsonpickle/
+	https://pypi.org/project/jsonpickle/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/feedparser[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/simplejson[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/ujson[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	# https://github.com/jsonpickle/jsonpickle/pull/396
+	"${FILESDIR}/${P}-python3.11.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -i -e 's:--flake8 --cov::' pytest.ini || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# unpackaged bson dependency
+		tests/bson_test.py
+		# broken when gmpy is installed
+		# https://github.com/jsonpickle/jsonpickle/issues/328
+		# https://github.com/jsonpickle/jsonpickle/issues/316
+		tests/ecdsa_test.py
+	)
+	epytest
+}
+
+pkg_postinst() {
+	# Unpackaged optional backends: yajl, demjson
+	optfeature "encoding numpy-based data" dev-python/numpy
+	optfeature "encoding pandas objects" dev-python/pandas
+	optfeature "fast JSON backend" dev-python/simplejson
+}
diff --git a/dev-python/kombu/kombu-5.2.4.ebuild b/dev-python/kombu/kombu-5.2.4.ebuild
index 983103758caa..2429ca455367 100644
--- a/dev-python/kombu/kombu-5.2.4.ebuild
+++ b/dev-python/kombu/kombu-5.2.4.ebuild
@@ -29,7 +29,6 @@ BDEPEND="
 	test? (
 		app-arch/brotli[python,${PYTHON_USEDEP}]
 		>=dev-python/boto3-1.4.4[${PYTHON_USEDEP}]
-		>=dev-python/case-1.5.2[${PYTHON_USEDEP}]
 		>=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
 		dev-python/pycurl[${PYTHON_USEDEP}]
 		>=dev-python/pymongo-3.3.0[${PYTHON_USEDEP}]
diff --git a/dev-python/moto/moto-4.0.7-r1.ebuild b/dev-python/moto/moto-4.0.7-r1.ebuild
new file mode 100644
index 000000000000..151a958de4bc
--- /dev/null
+++ b/dev-python/moto/moto-4.0.7-r1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="https://github.com/spulec/moto"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-python-0.93[${PYTHON_USEDEP}]
+	dev-python/cfn-lint[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.3.1[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	>=dev-python/docker-py-2.5.1[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/jsondiff-1.1.2[${PYTHON_USEDEP}]
+	dev-python/boto3[${PYTHON_USEDEP}]
+	dev-python/botocore[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3.0.7[${PYTHON_USEDEP}]
+	>=dev-python/openapi-spec-validator-0.2.8[${PYTHON_USEDEP}]
+	dev-python/pretty-yaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	dev-python/python-sshpubkeys[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		>=dev-python/sure-1.4.11[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_firehose/test_firehose_put.py::test_put_record_http_destination
+		tests/test_firehose/test_firehose_put.py::test_put_record_batch_http_destination
+		tests/test_swf/responses/test_decision_tasks.py::test_respond_decision_task_completed_with_schedule_activity_task_boto3
+		tests/test_swf/responses/test_timeouts.py::test_activity_task_heartbeat_timeout_boto3
+		tests/test_swf/responses/test_timeouts.py::test_decision_task_start_to_close_timeout_boto3
+		tests/test_swf/responses/test_timeouts.py::test_workflow_execution_start_to_close_timeout_boto3
+		# broken code (local variable used referenced before definition)
+		tests/test_appsync/test_appsync_schema.py
+		tests/test_appsync/test_server.py::test_appsync_list_tags_for_resource
+		# Needs network (or docker?) but not marked as such, bug #807031
+		# TODO: report upstream
+		tests/test_batch/test_batch_jobs.py::test_terminate_job
+		tests/test_batch/test_batch_jobs.py::test_cancel_pending_job
+		tests/test_batch/test_batch_jobs.py::test_cancel_running_job
+		tests/test_batch/test_batch_jobs.py::test_dependencies
+		tests/test_batch/test_batch_jobs.py::test_container_overrides
+		tests/test_cloudformation/test_cloudformation_custom_resources.py::test_create_custom_lambda_resource__verify_cfnresponse_failed
+		tests/test_cloudformation/test_cloudformation_stack_integration.py::test_lambda_function
+		tests/test_events/test_events_lambdatriggers_integration.py::test_creating_bucket__invokes_lambda
+		tests/test_sqs/test_integration.py::test_invoke_function_from_sqs_exception
+		tests/test_sqs/test_sqs_integration.py::test_invoke_function_from_sqs_exception
+		tests/test_s3/test_server.py::test_s3_server_post_to_bucket_redirect
+		tests/test_s3/test_multiple_accounts_server.py::TestAccountIdResolution::test_with_custom_request_header
+		"tests/test_s3/test_s3_lambda_integration.py::test_objectcreated_put__invokes_lambda[match_events0-ObjectCreated:Put]"
+		"tests/test_s3/test_s3_lambda_integration.py::test_objectcreated_put__invokes_lambda[match_events1-ObjectCreated:Put]"
+		"tests/test_s3/test_s3_lambda_integration.py::test_objectcreated_put__invokes_lambda[match_events3-ObjectCreated:Put]"
+	)
+
+	# pytest-django causes freezegun try to mangle stuff inside django
+	# which fails when django is not really used
+	epytest -p no:django -m 'not network'
+}
diff --git a/dev-python/py-amqp/Manifest b/dev-python/py-amqp/Manifest
index 61804329b6fa..413eb5b7b2d1 100644
--- a/dev-python/py-amqp/Manifest
+++ b/dev-python/py-amqp/Manifest
@@ -1,2 +1 @@
-DIST amqp-5.1.0.tar.gz 128629 BLAKE2B 8fe0b07233fce04b84b46e0ab4da1badf2de8a2ac53494dbb33b246d149ccec728de42c4f9f7d40752701a8e02851805456d8d54c2e519bbbfdbbb1274edf124 SHA512 9f4f3fd4cea6c214ff03a80a9aec7c5bff65a964ff1e77fbc937f1b6daf45f7b06be0b0873b2998afc3de22b4693a3327f0b439f70a4496060997b9f1aa73331
 DIST amqp-5.1.1.tar.gz 127869 BLAKE2B 3ba95874a45f6fce163cf95b0b1fae57e636bc2bec8311f64fc9597025ba36f35daf8d0457af3bc10fa1f1dae604b262ebf205d7b89d4f1745bf3480b542278d SHA512 f549a85e4f04543dd8e844edb68350ca185de9259aa896af31ae5ee5dfdfe73f904d95821c403dc797c7f3ada17ce6bff4e0fd9fcdf2abc1b33a94d079f99179
diff --git a/dev-python/py-amqp/py-amqp-5.1.0.ebuild b/dev-python/py-amqp/py-amqp-5.1.1-r1.ebuild
index 816cd17d8c42..434b4ccc9e84 100644
--- a/dev-python/py-amqp/py-amqp-5.1.0.ebuild
+++ b/dev-python/py-amqp/py-amqp-5.1.1-r1.ebuild
@@ -19,11 +19,11 @@ SLOT="0"
 KEYWORDS="amd64 ~arm64 x86"
 IUSE="extras"
 
-BDEPEND="
+RDEPEND="
 	>=dev-python/vine-5.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
 	test? (
-		>=dev-python/case-1.3.1[${PYTHON_USEDEP}]
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
 		>=dev-python/pytest-rerunfailures-6.0[${PYTHON_USEDEP}]
 	)
 "
diff --git a/dev-python/py-amqp/py-amqp-5.1.1.ebuild b/dev-python/py-amqp/py-amqp-5.1.1.ebuild
deleted file mode 100644
index 816cd17d8c42..000000000000
--- a/dev-python/py-amqp/py-amqp-5.1.1.ebuild
+++ /dev/null
@@ -1,51 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{7,8,9,10} )
-
-inherit distutils-r1
-
-MY_P="amqp-${PV}"
-DESCRIPTION="Low-level AMQP client for Python (fork of amqplib)"
-HOMEPAGE="https://github.com/celery/py-amqp https://pypi.org/project/amqp/"
-SRC_URI="mirror://pypi/${MY_P:0:1}/amqp/${MY_P}.tar.gz"
-S="${WORKDIR}/${MY_P}"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="amd64 ~arm64 x86"
-IUSE="extras"
-
-BDEPEND="
-	>=dev-python/vine-5.0.0[${PYTHON_USEDEP}]
-	test? (
-		>=dev-python/case-1.3.1[${PYTHON_USEDEP}]
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		>=dev-python/pytest-rerunfailures-6.0[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_sphinx docs \
-	dev-python/sphinx_celery
-distutils_enable_tests pytest
-
-EPYTEST_IGNORE=(
-	# rmq tests require a rabbitmq instance
-	t/integration/test_rmq.py
-)
-
-EPYTEST_DESELECT=(
-	# fails when gssapi is installed (how does that test make sense?!)
-	t/unit/test_sasl.py::test_SASL::test_gssapi_missing
-)
-
-python_install_all() {
-	if use extras; then
-		insinto /usr/share/${PF}/extras
-		doins -r extra
-	fi
-	distutils-r1_python_install_all
-}
diff --git a/dev-python/sarif_om/sarif_om-1.0.4-r1.ebuild b/dev-python/sarif_om/sarif_om-1.0.4-r1.ebuild
new file mode 100644
index 000000000000..26e631845dfc
--- /dev/null
+++ b/dev-python/sarif_om/sarif_om-1.0.4-r1.ebuild
@@ -0,0 +1,25 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+DESCRIPTION="Classes implementing the SARIF 2.1.0 object model"
+HOMEPAGE="
+	https://pypi.org/project/sarif-om/
+	https://github.com/microsoft/sarif-python-om/"
+SRC_URI="
+	mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/attrs[${PYTHON_USEDEP}]
+	dev-python/pbr[${PYTHON_USEDEP}]"
+BDEPEND="
+	dev-python/pbr[${PYTHON_USEDEP}]"
diff --git a/dev-python/serpent/serpent-1.41.ebuild b/dev-python/serpent/serpent-1.41.ebuild
index f52783343b38..1a0af5e6acf1 100644
--- a/dev-python/serpent/serpent-1.41.ebuild
+++ b/dev-python/serpent/serpent-1.41.ebuild
@@ -5,11 +5,14 @@ EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
 PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
 inherit distutils-r1
 
 DESCRIPTION="A simple serialization library based on ast.literal_eval"
-HOMEPAGE="https://pypi.org/project/serpent/
-	https://github.com/irmen/Serpent"
+HOMEPAGE="
+	https://github.com/irmen/Serpent/
+	https://pypi.org/project/serpent/
+"
 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="MIT"
diff --git a/dev-python/versioneer/versioneer-0.26.ebuild b/dev-python/versioneer/versioneer-0.26.ebuild
index 35c361ff0c88..bf9a2e70fd49 100644
--- a/dev-python/versioneer/versioneer-0.26.ebuild
+++ b/dev-python/versioneer/versioneer-0.26.ebuild
@@ -35,6 +35,14 @@ BDEPEND="
 	)
 "
 
+python_compile() {
+	cat > "${T}"/versioneer.py <<-EOF || die
+		raise ImportError("Please pretend I'm not here!")
+	EOF
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	distutils-r1_python_compile
+}
+
 python_test() {
 	esetup.py make_versioneer
 
diff --git a/dev-python/vine/vine-5.0.0-r1.ebuild b/dev-python/vine/vine-5.0.0-r1.ebuild
new file mode 100644
index 000000000000..d731b7d4b0e2
--- /dev/null
+++ b/dev-python/vine/vine-5.0.0-r1.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python Promises"
+HOMEPAGE="
+	https://github.com/celery/vine/
+	https://pypi.org/project/vine/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 x86"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# remove the dep on dead dev-python/case package
+	sed -i -e 's:from case:from unittest.mock:' t/unit/*.py || die
+	# also removed upstream
+	rm t/unit/conftest.py || die
+
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/vine/vine-5.0.0.ebuild b/dev-python/vine/vine-5.0.0.ebuild
deleted file mode 100644
index b11e7dade81c..000000000000
--- a/dev-python/vine/vine-5.0.0.ebuild
+++ /dev/null
@@ -1,23 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
-DISTUTILS_USE_SETUPTOOLS=bdepend
-
-inherit distutils-r1
-
-DESCRIPTION="Python Promises"
-HOMEPAGE="https://pypi.org/project/vine/ https://github.com/celery/vine"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="amd64 ~arm64 x86"
-
-DEPEND="
-	test? (
-		>=dev-python/case-1.3.1[${PYTHON_USEDEP}]
-	)"
-
-distutils_enable_tests pytest