Adding metadata

23 files changed, 656 insertions, 0 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 9c71ae30e5d4..e468669eedfe 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -2,3 +2,4 @@ DIST boto3-1.26.155.gh.tar.gz 664838 BLAKE2B 35c78d4da5bcba6f218a854d67647b71b16
 DIST boto3-1.26.160.gh.tar.gz 667890 BLAKE2B 2d081604ea94a6fece2c6839c0be339fa2ff3f8c4eba5b882eb45597646ef8efc0294abb58f9233e3fe1ec445131a91701ddf8771220275c13c34af9813cd8e6 SHA512 2a427e63fc61581a873a75ea2b0fe4329cc55ea61e7c99049d8d24c3cb676490a66efa9d6236b90ba6d7c41208a90a60b04dac53ff8243952d64134abff4ba82
 DIST boto3-1.26.162.gh.tar.gz 669402 BLAKE2B 33b945dade4486c0f7069c2209d0877fd3e6886d963139aed7716321d26ed92573486465580161799be92ac427da0dbb8fbfdb604db841af505e7dffbbef1c6f SHA512 e0ad04b82a79ec028157f88e1a3c95a7156ecef8b5b869624637896ffc62aa93608d17436e931a8b240fb2f47574ae8de04e34eeb6270f821c95dfa0f62d8f1a
 DIST boto3-1.26.163.gh.tar.gz 670006 BLAKE2B c2bcd2a3a4aaf1f2f5b69a605971ee62a09c754894825acfb7fdfcb7b7114bcbbb5864fa7a5ab6fefd8adc6264746223bd801ed4d45553bb5823b19f4cb8ce60 SHA512 31fadc451df41030e88e51d2345d1b0e952ec88f2a381ca28679db8c0bce6fd97b928658216e1eec2e075ff3c98c512d732b93466e6f646bd44616b9ce2b1450
+DIST boto3-1.26.164.gh.tar.gz 670774 BLAKE2B d5a1f93ac403e738b754a915f6d64f16c083aa604cc535d33ca00c5484b3ff99a64b80173b0b1d60222e5cc797039d4135a767dab1284b0b16e913e2afcf00aa SHA512 165b779c667f7d6f53c4849e215425f9cd717923df582215a6966b0f30b81014c8e804d24072623c8210fae1c702c38c9331cc6d90903d2d270a9060318f3c08
diff --git a/dev-python/boto3/boto3-1.26.164.ebuild b/dev-python/boto3/boto3-1.26.164.ebuild
new file mode 100644
index 000000000000..03c610b184f7
--- /dev/null
+++ b/dev-python/boto3/boto3-1.26.164.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index ae8cfba3a64d..0f8f125779cd 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -2,3 +2,4 @@ DIST botocore-1.29.155.gh.tar.gz 11673165 BLAKE2B 653cc8b368d34502bcb16622677f11
 DIST botocore-1.29.160.gh.tar.gz 11695537 BLAKE2B e60b8ec0ea50fa13e61acd8f5cbc4f908c0d95916733e6ebdf11c2387e1a13efee611070fb72e37ca3e3058888d3acd6debdd67bfc973528c7674c760a3bd865 SHA512 42c6d02df87b12143248ecd314d5b9ebcf47900da975addc8343187c7bd35ec3c41118ba8c9482d9e152e5352a95111ccd93f425e215fdeeeee4ee991803bfa1
 DIST botocore-1.29.162.gh.tar.gz 11720182 BLAKE2B 38ab0a8e5c466417427d559a5646d8e2025c43f4554ca8380bd0a1d47faadddb6bc8feed297b02e3cc05f9cf9c079628b0c0a8dce4b8908dd28923de2f4e7273 SHA512 29a2882fedc63f5b59906e9648d3811c441e3901c546a8cf5a0c2079f44a82b3c1aeeaea2efbafb833748c046e749a6d1b127c2fe74d4748289228304782ef2c
 DIST botocore-1.29.163.gh.tar.gz 11722194 BLAKE2B 2519b70cf7e5cba4e0544d7d1e520a499f762a78354804bc70c97177fd91eae3ce60acbaac2c0a0fdad4e99f02b85660696826b378680bc35b80ce0c6d99e254 SHA512 8ddee4f7aea1479494b0a4763d044c75bf610d0a4b52ce4a224e36c325ecb418e3560489fee56eb51428e8f0156fb171cc6af87665112d7fb787967a3499a52c
+DIST botocore-1.29.164.gh.tar.gz 11728330 BLAKE2B 241747c505ae64941073de3b307829d443f79335ac2e8b756f00560b727e10d6b7ac65da92a4196ebc85fb2d266cf63a9e23fe89f3ecba8a90b13dd06a6f1a61 SHA512 181f715ea1357ed080e7bc6bfa5ea11a5a1d794721a38a32be834b703b503deae6b5bc2de25e9da541942347bbd53e4cd339eda7872e397fa90ecd0c5bdb72aa
diff --git a/dev-python/botocore/botocore-1.29.164.ebuild b/dev-python/botocore/botocore-1.29.164.ebuild
new file mode 100644
index 000000000000..509d06dedf97
--- /dev/null
+++ b/dev-python/botocore/botocore-1.29.164.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+		# fails on unrelated warnings
+		tests/unit/test_client.py::TestAutoGeneratedClient::test_BOTO_DISABLE_COMMONNAME
+		tests/unit/test_client.py::TestClientErrors::test_BOTO_DISABLE_COMMONNAME
+		# TODO
+		tests/functional/test_credentials.py::SSOSessionTest::test_token_chosen_from_provider
+		# urllib3-2 compatibility, mock relies on implementation details
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_expect_100_continue_no_response_from_server
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_expect_100_continue_returned
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_expect_100_continue_sends_307
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_expect_100_sends_connection_header
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_handles_expect_100_with_different_reason_phrase
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_state_reset_on_connection_close
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/google-api-python-client/Manifest b/dev-python/google-api-python-client/Manifest
index cf27e1408eb5..2b7b0dc6d4d1 100644
--- a/dev-python/google-api-python-client/Manifest
+++ b/dev-python/google-api-python-client/Manifest
@@ -1,2 +1,3 @@
 DIST google-api-python-client-2.89.0.tar.gz 10965040 BLAKE2B 819c9f0837b86acc693158830c54e48778a1c8ef1fb549a4fbbe100827d0a269b435c4c29d8683c674981ef7817a0489e1cd6639adb7c9b09951c05b8fcf3aef SHA512 e3541f7e6b151ade5feb6e50f22c26b63b85304c4254929be5776c44c6cd80a4c2660d62fc052777033705d3c6a7e8dcd1a69f7f5d3dd5dc49549237a2ce6a5f
 DIST google-api-python-client-2.90.0.tar.gz 10891311 BLAKE2B 0683e95e12e5f2faaa5ce5b3f4c82e65df00da0c884530917dd086d33dda74a66e62fd27c7edead205f9d330800d2c60929fce68ce7f82fc04f8787cae010cdf SHA512 331812b50c2816f407db25f703817bf0d20b9218de39bd91c67d40a1f113141c8b9af0210d9d10272ebf51b90485fa44f636e821de19add72eeb38fa04ffe449
+DIST google-api-python-client-2.91.0.tar.gz 10853485 BLAKE2B 3f31a18187701f833e06f514150acf5eec72d6dabdb8b3493efa8fff79f10848a2108c5c7114f0f467519bd2f943162cdc3cbe91c9805a65a74d80c6ca41b745 SHA512 638783176e9d98af621deb5ee10ad5418108910f0996e98653adfa252dee2edd8db712c8fc0fe73d7d83db14a770d297b34d3334c5b018ce800325ef2dd91e04
diff --git a/dev-python/google-api-python-client/google-api-python-client-2.91.0.ebuild b/dev-python/google-api-python-client/google-api-python-client-2.91.0.ebuild
new file mode 100644
index 000000000000..0c85e8ca1676
--- /dev/null
+++ b/dev-python/google-api-python-client/google-api-python-client-2.91.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Google API Client for Python"
+HOMEPAGE="
+	https://github.com/googleapis/google-api-python-client/
+	https://pypi.org/project/google-api-python-client/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/httplib2-0.15[${PYTHON_USEDEP}]
+	<dev-python/httplib2-1[${PYTHON_USEDEP}]
+	>=dev-python/google-api-core-2.3.1[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.35.0[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-httplib2-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/uritemplate-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/uritemplate-5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# require Internet access (and credentials)
+		tests/test_discovery.py::DiscoveryErrors::test_credentials_and_credentials_file_mutually_exclusive
+		tests/test_discovery.py::DiscoveryFromDocument::test_api_endpoint_override_from_client_options_mapping_object
+	)
+
+	epytest tests
+}
diff --git a/dev-python/hcloud-python/Manifest b/dev-python/hcloud-python/Manifest
index 3b84b411bba6..9775aa93c914 100644
--- a/dev-python/hcloud-python/Manifest
+++ b/dev-python/hcloud-python/Manifest
@@ -1,3 +1,4 @@
 DIST hcloud-python-1.20.0.gh.tar.gz 100107 BLAKE2B 584e1399ddb1c5d1e5ad0beaf795609bb63d37457afe33c663cf303f8b20e2c6f6b3ff294007e9f4ae2d9aa833794e59516ad167f1dd51d14e692f6eab887881 SHA512 b17abc716ae6f7c78803096f2fd887e47ee746fccbe299cc434b7f445abdd7818e445d186f5adacc715971e2ebe2e92551cdb08aa1891ed58d8f443ea3be61fb
 DIST hcloud-python-1.21.0.gh.tar.gz 102150 BLAKE2B 4ec6fb813f61f3c487d632e12a71f9105af5d45a307567fd2b22ff716e30c645bffebc5cd768846fc7d7892ab753d3e4487a1b72edfee62fb99dfefe188be41d SHA512 8226a79324f0097d576cc1336e813a28a562fb9c3f50dcac1debb3c32bb52f4f5e563e920e2bbb6ce8be407a65de321b734d30156fd066d74ed95f6e6bd94a35
 DIST hcloud-python-1.22.0.gh.tar.gz 103301 BLAKE2B 0280567bf75dfe1e684cc9a630cd9c517a9039add7b8937d6293fdddf55e593afa68c4ee7ffc73c186b3444d47fb5dcd385229bace3cf058a37497790d2abf46 SHA512 fca41cc61033c050981588633f9a9801a444db5782eafa35933dec5011f24542a103b1c900b9a830ea426418070d060e4ec407941d54cb9579291a7b467e6a22
+DIST hcloud-python-1.23.0.gh.tar.gz 101752 BLAKE2B 5a8746d7ea58e3ba89271efe541183c72792480b81307433a899278e0e6037e3b5d59519a9d1af4ffeaf391b20643cec33fdd8b82019faf29ed865c4563ff96b SHA512 94463080d0b0605efbbc5bc193c602ae207d45ca7accd5a370b8ba7663d867bf065f5cf154f51095f6ae8b4fb2470202512ba3f61df36d2f6e04bf7ad2a606a5
diff --git a/dev-python/hcloud-python/hcloud-python-1.23.0.ebuild b/dev-python/hcloud-python/hcloud-python-1.23.0.ebuild
new file mode 100644
index 000000000000..9b16db282211
--- /dev/null
+++ b/dev-python/hcloud-python/hcloud-python-1.23.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+MY_P=hcloud-python-${PV}
+DESCRIPTION="Official Hetzner Cloud python library"
+HOMEPAGE="
+	https://github.com/hetznercloud/hcloud-python/
+	https://pypi.org/project/hcloud/
+"
+# sdist is missing doc assets as of 1.19.0
+# https://github.com/hetznercloud/hcloud-python/pull/183
+SRC_URI="
+	https://github.com/hetznercloud/hcloud-python/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/requests-2.20[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# Integration tests need docker:
+	# https://github.com/hetznercloud/hcloud-python/blob/master/.travis.yml#L16
+	tests/integration
+)
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/joblib/Manifest b/dev-python/joblib/Manifest
index 39974800136e..9c426cd5ef4f 100644
--- a/dev-python/joblib/Manifest
+++ b/dev-python/joblib/Manifest
@@ -1,2 +1,3 @@
 DIST joblib-1.2.0.gh.tar.gz 345345 BLAKE2B e18be536054829057ff320eda320a7548434108b3fc6c92a03df73dc68e093d039c656c1d674ea26fb6419bdfc39d26cfc28236a6bfbf0dcbf3ace7e52b0c829 SHA512 de882f2ff8dd936b4f98352b9ee1cc56c3a734f215a74257cf90a25736afd9e6b93e6538929b7a29f5956e6fccbdfcbf8b39c8fd68035a8857721f7a76066133
 DIST joblib-1.3.0.gh.tar.gz 357076 BLAKE2B d14c71deba922fe9e9caabb35f60aeeac505e2b3fde1b87b12f998086aac91ef337af360320f5f5ac8e2e3c05a6b77d46e0b2f794932f8ecbcca2ecd907028b3 SHA512 3264f3fdf66095302c37c32cb43221c686c62646a01dbc14233c588d36e9dd13132e8b4cb0b48d2add6cdf5bb86e7c2e6dac6664a9bd22de2035ded28f61a06c
+DIST joblib-1.3.1.tar.gz 1986996 BLAKE2B fad0e61755b8d48595fcfcaeead7726242e8003acf0d50c4b0f810cb54c414fd25f6c3d420738b16d0667e06e05f5aaf8cd49e9abd693d620861acbb9eb0c16b SHA512 40aada55e64469887a323cad7049ad1fd7df815291c3e418544bce9b54af73bea67876de3469c3d0271aa4e2f6aa5f47c64c6be53730b1ba6b3e88814ddc0908
diff --git a/dev-python/joblib/joblib-1.3.1.ebuild b/dev-python/joblib/joblib-1.3.1.ebuild
new file mode 100644
index 000000000000..d10f9bd2b8f4
--- /dev/null
+++ b/dev-python/joblib/joblib-1.3.1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Tools to provide lightweight pipelining in Python"
+HOMEPAGE="
+	https://joblib.readthedocs.io/en/latest/
+	https://github.com/joblib/joblib/
+	https://pypi.org/project/joblib/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	dev-python/loky[${PYTHON_USEDEP}]
+"
+# joblib is imported by setup.py so we need ${RDEPEND}
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/threadpoolctl[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# https://github.com/joblib/joblib/issues/1115
+	joblib/test/test_memory.py::test_parallel_call_cached_function_defined_in_jupyter
+	# unexpectedly pickleable?
+	joblib/test/test_hashing.py::test_hashing_pickling_error
+)
+
+python_prepare_all() {
+	# unbundle
+	rm -r joblib/externals || die
+	sed -e "/joblib.externals/d" -i pyproject.toml || die
+	find -name '*.py' -exec \
+		sed -e 's:\(joblib\)\?\.externals\.::' \
+			-e 's:from \.externals ::' \
+			-i {} + || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/numpy/numpy-1.25.0.ebuild b/dev-python/numpy/numpy-1.25.0-r2.ebuild
index 8e6dbdbb4210..ee6716dea195 100644
--- a/dev-python/numpy/numpy-1.25.0.ebuild
+++ b/dev-python/numpy/numpy-1.25.0-r2.ebuild
@@ -62,6 +62,9 @@ python_prepare_all() {
 	append-flags -fno-strict-aliasing
 
 	distutils-r1_python_prepare_all
+
+	# TODO: Please drop once 1.25.0_rc1-meson-pyproject.toml.patch is gone
+	sed -i -e "s:version = \"2.0.0.dev0\":version = \"${PV}\":" pyproject.toml || die
 }
 
 python_configure_all() {
diff --git a/dev-python/openstacksdk/Manifest b/dev-python/openstacksdk/Manifest
index f4988e9e4e99..af7046e4de9a 100644
--- a/dev-python/openstacksdk/Manifest
+++ b/dev-python/openstacksdk/Manifest
@@ -1,2 +1,3 @@
 DIST openstacksdk-1.2.0.tar.gz 1160015 BLAKE2B d3ed5b9415715faf6d9cae225e2a8e7c3bd69907599fd2683f53e2070513a1f27aaae2d2f4aa40ada26ff819b5f8238c09e208243197165aa52f19776e53fc7c SHA512 4ce118b8b19b495f333f76cb416d2b4cc2c9ea835979cf67e83f6f7f40df13d29e19ed054a2f3ee469e6c5496da4a7a11193e4815b20195b28ba4c48263b6c1c
 DIST openstacksdk-1.3.0.tar.gz 1158244 BLAKE2B c318be32242ff6a5dce3fb94122c08603f3f132d0e9781a13f6bad9bf8fb516741e62b255e1d0d9b12c2967bbd6cea54cfcc248ba9de6279edfac85399b4a0bd SHA512 ceeb68fea5ce9e5271a86b783986bc3a26f03654cc3e2be0b704484976e273049c0499377d08c59466fa02d45d6ec39fdc4fcc42d8b4ee4b5723bfe3853737b3
+DIST openstacksdk-1.3.1.tar.gz 1158149 BLAKE2B b1fb89e3c8d59dc1188bcfa4eeb55a7de40a61f30ff42f3dceb5be311f0c4e59af24dfa176d07237cf778f7b5e7b01855d97462d137ed51daf56140c01503135 SHA512 0792f974eb5dffe34565241082bd5fe17f75a0b666ce971938f325fe2b6cdff258d86658c608863f26799018e2a5b8dd2016d14d3300e536b5f301e3476cbbd6
diff --git a/dev-python/openstacksdk/openstacksdk-1.3.1.ebuild b/dev-python/openstacksdk/openstacksdk-1.3.1.ebuild
new file mode 100644
index 000000000000..90a810d51d04
--- /dev/null
+++ b/dev-python/openstacksdk/openstacksdk-1.3.1.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A collection of libraries for building applications to work with OpenStack"
+HOMEPAGE="
+	https://opendev.org/openstack/openstacksdk/
+	https://github.com/openstack/openstacksdk/
+	https://pypi.org/project/openstacksdk/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.13[${PYTHON_USEDEP}]
+	>=dev-python/appdirs-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/requestsexceptions-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonpatch-1.20[${PYTHON_USEDEP}]
+	>=dev-python/os-service-types-1.7.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth1-3.18.0[${PYTHON_USEDEP}]
+	>=dev-python/decorator-4.4.1[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/dogpile-cache-0.6.5[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.7.0[${PYTHON_USEDEP}]
+	dev-python/importlib-metadata[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/prometheus-client-0.4.2[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-6.1.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/statsd-3.3.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Internet?
+	sed -e 's:test_create_dynamic_large_object:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# TODO
+	sed -e 's:test_generate_form:_&:' \
+		-e 's:test_create_static_large_object:_&:' \
+		-e 's:test_object_segment_retries:_&:' \
+		-e 's:test_object_segment_retry_failure:_&:' \
+		-e 's:test_slo_manifest_retry:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# unhappy about paths due to test runner
+	sed -e 's:test_method_not_supported:_&:' \
+		-i openstack/tests/unit/test_exceptions.py || die
+	sed -e 's:test_repr:_&:' \
+		-i openstack/tests/unit/test_resource.py || die
+
+	# requires hacking
+	rm openstack/tests/unit/test_hacking.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b openstack/tests/unit
+}
diff --git a/dev-python/python-lsp-server/Manifest b/dev-python/python-lsp-server/Manifest
index d4a57c690cab..db1f8f052b67 100644
--- a/dev-python/python-lsp-server/Manifest
+++ b/dev-python/python-lsp-server/Manifest
@@ -1 +1,2 @@
 DIST python-lsp-server-1.7.3.tar.gz 97336 BLAKE2B 3b9d206451e59741113db116621594d3329651150f6819c2e1f1956f758f26eb3ff9f5c66e02313ce1693daf2925d62320a749a23921d64d0758891658cdb2ae SHA512 b34b8ae4311f4c8af9379f6a5d94400f34e3221f9bc55a4d95f909a23d0098bab4bd27992792901cea67b01202720b3cc76f89138841b352a49191aa86603c02
+DIST python-lsp-server-1.7.4.tar.gz 97864 BLAKE2B 9832298391d72bf2f035f388694a7879d66546ead5a36837220cb3af5d8181eba198c04dd82747cba75f0478d256b001476c24b02bc679fc07cb41c7aedb0e66 SHA512 7aa96de6e51548e2854b55690698fe6c7bda60103c11ad5982df611c65569cec1ab13691727c92ec47d9ac44c34f233f872211a41041ea0969223e10e87d7e08
diff --git a/dev-python/python-lsp-server/python-lsp-server-1.7.4.ebuild b/dev-python/python-lsp-server/python-lsp-server-1.7.4.ebuild
new file mode 100644
index 000000000000..04e2c9c926a3
--- /dev/null
+++ b/dev-python/python-lsp-server/python-lsp-server-1.7.4.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Python Language Server for the Language Server Protocol"
+HOMEPAGE="https://github.com/python-lsp/python-lsp-server"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="all-plugins"
+
+BDEPEND="
+	test? (
+		>=dev-python/autopep8-1.6.0[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		>=dev-python/flake8-5.0.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		>=dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pydocstyle-6.3.0[${PYTHON_USEDEP}]
+		<dev-python/pydocstyle-6.4.0[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+		dev-python/QtPy[gui,testlib,${PYTHON_USEDEP}]
+		>=dev-python/rope-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/yapf-0.33.0[${PYTHON_USEDEP}]
+		>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
+	)
+"
+
+RDEPEND="
+	dev-python/docstring-to-markdown[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.17.2[${PYTHON_USEDEP}]
+	>=dev-python/python-lsp-jsonrpc-1.0.0[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	all-plugins? (
+		>=dev-python/autopep8-1.6.0[${PYTHON_USEDEP}]
+		>=dev-python/flake8-5.0.0[${PYTHON_USEDEP}]
+		>=dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pydocstyle-6.3.0[${PYTHON_USEDEP}]
+		<dev-python/pydocstyle-6.4.0[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/rope-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/yapf-0.33.0[${PYTHON_USEDEP}]
+		>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# broken by presence of pathlib2
+	'test/plugins/test_autoimport.py'
+)
+
+python_prepare_all() {
+	# remove pytest-cov dep
+	sed -i -e '/addopts =/d' pyproject.toml || die
+	# unpin all the deps
+	sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
+	distutils-r1_python_prepare_all
+}
+
+pkg_postinst() {
+	optfeature "Automatically format Python code to conform to the PEP 8 style guide" dev-python/autopep8
+	optfeature "A wrapper around PyFlakes, pep8 & mccabe" dev-python/flake8
+	optfeature "flake8 plugin: McCabe complexity checker" dev-python/mccabe
+	optfeature "Python style guide checker (fka pep8)" dev-python/pycodestyle
+	optfeature "Python docstring style checker" dev-python/pydocstyle
+	optfeature "Passive checker for Python programs" dev-python/pyflakes
+	optfeature "Python code static checker" dev-python/pylint
+	optfeature "Python refactoring library" dev-python/rope
+	optfeature "A formatter for Python files" dev-python/yapf
+}
diff --git a/dev-python/readthedocs-sphinx-ext/Manifest b/dev-python/readthedocs-sphinx-ext/Manifest
index e3c39d586af2..27a3062757c3 100644
--- a/dev-python/readthedocs-sphinx-ext/Manifest
+++ b/dev-python/readthedocs-sphinx-ext/Manifest
@@ -1,2 +1,3 @@
 DIST readthedocs-sphinx-ext-2.2.0.tar.gz 12721 BLAKE2B 3ac02a96a059e6d6b94af4318a5e816f8664e1164edb315d7540d1bfcce3b0edbbe9d567b0dc2931179cb309714175c64a3684b9d568551cc240ccbefc77a10a SHA512 8f7009a0716751de2fe2fed726aa08bb382d15ef6c4fb66e6c29537f985a92ab7cc137f81a4f6200e794cb7f495ebf561356194f57c694509b67e7686bef52c5
 DIST readthedocs-sphinx-ext-2.2.1.tar.gz 12644 BLAKE2B eb7b5f8d91dcf9f413cabe790537ed9179790c48e5778f026f07d442f4b446c6968b86c7e7eef4d548307ebd85ece8ff5a1fb3877ac4e3187ee8c53be86fc7dc SHA512 d2933228678549b7ab53bf7b8720eb23a5fcc05983dea56ab762906fc8a1445b2b94e0c12d647e18e6156fa1460a31ec0e7a7d7e4e8f5c46c5e39a9f35c382b9
+DIST readthedocs-sphinx-ext-2.2.2.tar.gz 12106 BLAKE2B 4b9785c6b36ea66a7910d544b3acde9accc676e18b6c1e37b9285f6e095371bd7baf19b912b604596e92c89ad935c37263b2c977c66265e7697f18d399fd3006 SHA512 333e2068a92287821991e4e96b397e0d2b62f5080b65aff8f31b8828a7e930b038fb5ee176e20622e1a78c966c5d4cf84dfead832f4cbe1e68f2b0a0260009f7
diff --git a/dev-python/readthedocs-sphinx-ext/readthedocs-sphinx-ext-2.2.2.ebuild b/dev-python/readthedocs-sphinx-ext/readthedocs-sphinx-ext-2.2.2.ebuild
new file mode 100644
index 000000000000..c30960101db6
--- /dev/null
+++ b/dev-python/readthedocs-sphinx-ext/readthedocs-sphinx-ext-2.2.2.ebuild
@@ -0,0 +1,30 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Code specific for Read the Docs and Sphinx"
+HOMEPAGE="
+	https://github.com/readthedocs/readthedocs-sphinx-ext/
+	https://pypi.org/project/readthedocs-sphinx-ext/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/jinja-2.9[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/sphinx[${PYTHON_USEDEP}]
+"
+
+# unittest should be sufficient but tests are very verbose, so pytest's
+# output capture is most welcome
+distutils_enable_tests pytest
diff --git a/dev-python/rope/Manifest b/dev-python/rope/Manifest
index 9ad7e44a2945..369ee811fd12 100644
--- a/dev-python/rope/Manifest
+++ b/dev-python/rope/Manifest
@@ -1 +1,2 @@
 DIST rope-1.8.0.tar.gz 297235 BLAKE2B e9849b75b3ec640201b30318863066b969b5ebde98522c3c09f70bcc344bce5f604601bd155ed0ce6fb3eebb392ea3669f77fb2da21c11078e1041ae13464fd8 SHA512 2fa8e56d6d7fd0a15acb16a1fe27db89d9c2dd6f93fabd448509a112a6ef7f3dfdd4d3d544cf1218149c7a7fa1db9908b107b6eae6e89299f32c0d1586ceaf4e
+DIST rope-1.9.0.tar.gz 298227 BLAKE2B c136678bdd9d580d0f0ada93e5c61b963bfe5b9867b39f8c9ba35578f4c8b2ebca1031d00bea4bf2f10ebdf300bc4920827a3325a5c26498efb3e6a4af5b016a SHA512 fd8cc75c70814afc427fbccbe8a1389773737ee664a42a43bb2fb7e7ff667fac4680d233c751ee15b03e41b60ba270b3cf48b1a766420468e4a7c974e4c0158c
diff --git a/dev-python/rope/rope-1.9.0.ebuild b/dev-python/rope/rope-1.9.0.ebuild
new file mode 100644
index 000000000000..4cab361cd93e
--- /dev/null
+++ b/dev-python/rope/rope-1.9.0.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python refactoring library"
+HOMEPAGE="
+	https://pypi.org/project/rope/
+	https://github.com/python-rope/rope/
+"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="doc"
+
+RDEPEND="
+	>=dev-python/pytoolconfig-1.2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# our venv style confuses this comparison
+	ropetest/contrib/autoimport/utilstest.py::test_get_package_source_typing
+	ropetest/contrib/autoimport/utilstest.py::test_get_package_tuple_typing
+	ropetest/contrib/autoimport/utilstest.py::test_get_package_tuple_compiled
+)
diff --git a/dev-python/spyder-kernels/Manifest b/dev-python/spyder-kernels/Manifest
index b21695286c01..d09cc3497140 100644
--- a/dev-python/spyder-kernels/Manifest
+++ b/dev-python/spyder-kernels/Manifest
@@ -1,2 +1,3 @@
 DIST spyder-kernels-2.4.3.tar.gz 97886 BLAKE2B 1783747662745fa0807e50a9bfe8e350c394a3b571bf74b2f884aeb0c5b995c1b8d571f1b382272903ce005a140762327fa08d35247a9ced9e84709dec23a3c6 SHA512 efacde9e9cd511583fa1bc732c7823baee34cac086cacc7d2f69062b4721dc17eb322445a9641e55a716db980f7cb083fda61c279ba69c97b74664dd4b139f7f
+DIST spyder-kernels-2.4.4.tar.gz 98216 BLAKE2B f9f7c007f3c8f4365b84606e7473c169b525aad6d4ddccd6a72fc4d84f48b3fbf0272bd8f8e7f9cc7eb48df555e333f1b8ef0adc8c2f0b8d6df4ff9de35568f8 SHA512 826ced4928d8308e1a31790f0938e24ee8171b7e1f890a322bf652798991db4f3c2c270dd1b9cee44110ac85724043e4f80bc2adb54ad9f09f5414ee8bbd0a4a
 DIST spyder-kernels-3.0.0b1.tar.gz 236330 BLAKE2B 512fb11371b481102fb9b984eaaf665eed5eeeb2c0039a7e445f6e8139bca0a71f24d68b869614f3d65c9d51640d135c4a3dd33a32dd6c8750d5ba3c7b3330ef SHA512 e8e4cb9e7a577ff2ea969c78aafb1585a6afb652d5ee0063cdaada302648d3152ed38ae33376a4e13e4e183bd18233ff8305ecbe3e248422d2a056b08b0e7226
diff --git a/dev-python/spyder-kernels/spyder-kernels-2.4.4.ebuild b/dev-python/spyder-kernels/spyder-kernels-2.4.4.ebuild
new file mode 100644
index 000000000000..f183dd2a9c3e
--- /dev/null
+++ b/dev-python/spyder-kernels/spyder-kernels-2.4.4.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Kernels used by spyder on its ipython console"
+HOMEPAGE="
+	https://github.com/spyder-ide/spyder-kernels/
+	https://pypi.org/project/spyder-kernels/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	<dev-python/ipykernel-7[${PYTHON_USEDEP}]
+	>=dev-python/ipykernel-6.23.2[${PYTHON_USEDEP}]
+	<dev-python/ipython-9[${PYTHON_USEDEP}]
+	>=dev-python/ipython-8.11.0[${PYTHON_USEDEP}]
+	<dev-python/jupyter-client-9[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-7.4.9[${PYTHON_USEDEP}]
+	dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-22.1.0[${PYTHON_USEDEP}]
+	>=dev-python/wurlitzer-1.0.3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/cython[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/xarray[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# we no longer package distributed, and also removed dependency on dask
+	spyder_kernels/console/tests/test_console_kernel.py::test_dask_multiprocessing
+	# RuntimeError: There is no current event loop in thread 'MainThread'.
+	# https://bugs.gentoo.org/834893
+	spyder_kernels/console/tests/test_console_kernel.py::test_cwd_in_sys_path
+	spyder_kernels/console/tests/test_console_kernel.py::test_multiprocessing
+	spyder_kernels/console/tests/test_console_kernel.py::test_multiprocessing_2
+	spyder_kernels/console/tests/test_console_kernel.py::test_runfile
+	spyder_kernels/console/tests/test_console_kernel.py::test_np_threshold
+	spyder_kernels/console/tests/test_console_kernel.py::test_turtle_launch
+	spyder_kernels/console/tests/test_console_kernel.py::test_matplotlib_inline
+)
diff --git a/dev-python/zope-exceptions/Manifest b/dev-python/zope-exceptions/Manifest
index 5a3299be9e7c..3e01f62292c3 100644
--- a/dev-python/zope-exceptions/Manifest
+++ b/dev-python/zope-exceptions/Manifest
@@ -1 +1,2 @@
 DIST zope.exceptions-4.6.tar.gz 30876 BLAKE2B 9cc9a040269aa2f813018670e3692c9897fbea3a346b37e72fc54e72fb33dbaf0f14c192a76a7c40f57674caee4e17e86aec5f1d60e1c0e6a801d859d9629189 SHA512 d28a4434b27f6611040b290dcece26c1880982853092c89d5a8d74093cb9339a62834d7c3949d5ea28c4d3fc01c6f36180df22031cded6e4c963acfff65c2ec4
+DIST zope.exceptions-5.0.tar.gz 30287 BLAKE2B 43fab206ef16b330a4ca460a432be375450fd3637a7964797fcb15a35f6adcd654b6105bb61043391ae6448ce03ea2ddd89dc86b6a90be69e2b0c541ca2b30e7 SHA512 0aba148751420c92a403169f72801fe03745196f918e1993d159a8d89310f2f71af26a15eab20c51b39747c3ddfc61eebc48e228517418fedb45d21b89475ed1
diff --git a/dev-python/zope-exceptions/zope-exceptions-5.0.ebuild b/dev-python/zope-exceptions/zope-exceptions-5.0.ebuild
new file mode 100644
index 000000000000..61d2e2b23081
--- /dev/null
+++ b/dev-python/zope-exceptions/zope-exceptions-5.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="General purpose exceptions for Zope packages"
+HOMEPAGE="
+	https://pypi.org/project/zope.exceptions/
+	https://github.com/zopefoundation/zope.exceptions/
+"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	dev-python/zope-interface[${PYTHON_USEDEP}]
+	!dev-python/namespace-zope
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "/'setuptools'/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	distutils_write_namespace zope
+	eunittest
+}