Adding metadata

30 files changed, 516 insertions, 148 deletions

diff --git a/dev-python/aiosignal/aiosignal-1.2.0-r1.ebuild b/dev-python/aiosignal/aiosignal-1.2.0-r1.ebuild
new file mode 100644
index 000000000000..4450c7a53cba
--- /dev/null
+++ b/dev-python/aiosignal/aiosignal-1.2.0-r1.ebuild
@@ -0,0 +1,34 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A list of registered asynchronous callbacks"
+HOMEPAGE="
+	https://pypi.org/project/aiosignal/
+	https://github.com/aio-libs/aiosignal/
+"
+SRC_URI="
+	https://github.com/aio-libs/aiosignal/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/frozenlist-1.1.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/addopts/d' pytest.ini || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/boltons/boltons-21.0.0-r1.ebuild b/dev-python/boltons/boltons-21.0.0-r1.ebuild
new file mode 100644
index 000000000000..193ecda48bc3
--- /dev/null
+++ b/dev-python/boltons/boltons-21.0.0-r1.ebuild
@@ -0,0 +1,33 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Pure-python utilities in the same spirit as the standard library"
+HOMEPAGE="https://boltons.readthedocs.org/"
+SRC_URI="https://github.com/mahmoud/boltons/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme
+
+DOCS=( CHANGELOG.md README.md TODO.rst )
+
+PATCHES=(
+	"${FILESDIR}"/${P}-python3.10.patch
+	"${FILESDIR}"/${P}-python3.11-tests.patch
+)
+
+EPYTEST_DESELECT=(
+	# fails if there's any noise/differences in traceback text caused
+	# by e.g. pytest-qt noise or python3.11 adding ^^^^^^ markers
+	tests/test_tbutils.py::test_exception_info
+)
diff --git a/dev-python/boltons/files/boltons-21.0.0-python3.11-tests.patch b/dev-python/boltons/files/boltons-21.0.0-python3.11-tests.patch
new file mode 100644
index 000000000000..a54b2a4d0cf1
--- /dev/null
+++ b/dev-python/boltons/files/boltons-21.0.0-python3.11-tests.patch
@@ -0,0 +1,7 @@
+object.__getstate__ was added in 3.11 (bpo-26579) and the test is unaware
+--- a/tests/test_dictutils.py
++++ b/tests/test_dictutils.py
+@@ -476,2 +476,3 @@
+                        '__getitem__',
++                       '__getstate__',
+                        '__gt__',
diff --git a/dev-python/frozenlist/frozenlist-1.3.0.ebuild b/dev-python/frozenlist/frozenlist-1.3.0.ebuild
index b5b8ec626f1d..cead66b31b1b 100644
--- a/dev-python/frozenlist/frozenlist-1.3.0.ebuild
+++ b/dev-python/frozenlist/frozenlist-1.3.0.ebuild
@@ -5,15 +5,18 @@ EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
 PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
 inherit distutils-r1
 
 DESCRIPTION="A list-like structure which implements collections.abc.MutableSequence"
 HOMEPAGE="
 	https://pypi.org/project/frozenlist/
-	https://github.com/aio-libs/frozenlist/"
+	https://github.com/aio-libs/frozenlist/
+"
 SRC_URI="
 	https://github.com/aio-libs/frozenlist/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz"
+		-> ${P}.gh.tar.gz
+"
 
 LICENSE="Apache-2.0"
 SLOT="0"
@@ -22,7 +25,8 @@ KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ppc ppc64 ~riscv ~s390 sparc
 BDEPEND="
 	$(python_gen_cond_dep '
 		dev-python/cython[${PYTHON_USEDEP}]
-	' 'python*')"
+	' 'python*')
+"
 
 distutils_enable_tests pytest
 
diff --git a/dev-python/glob2/glob2-0.7-r1.ebuild b/dev-python/glob2/glob2-0.7-r1.ebuild
new file mode 100644
index 000000000000..72bfcb738c44
--- /dev/null
+++ b/dev-python/glob2/glob2-0.7-r1.ebuild
@@ -0,0 +1,22 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Extended version of Python's builtin glob module"
+HOMEPAGE="https://pypi.org/project/glob2/"
+SRC_URI="mirror://pypi/${P::1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest test.py
+}
diff --git a/dev-python/immutables/immutables-0.17.ebuild b/dev-python/immutables/immutables-0.17.ebuild
index dea705315c16..759b05430704 100644
--- a/dev-python/immutables/immutables-0.17.ebuild
+++ b/dev-python/immutables/immutables-0.17.ebuild
@@ -9,7 +9,10 @@ PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
 inherit distutils-r1
 
 DESCRIPTION="A high-performance immutable mapping type for Python"
-HOMEPAGE="https://github.com/MagicStack/immutables"
+HOMEPAGE="
+	https://github.com/MagicStack/immutables/
+	https://pypi.org/project/immutables/
+"
 SRC_URI="
 	https://github.com/MagicStack/${PN}/archive/v${PV}.tar.gz
 		-> ${P}.gh.tar.gz
diff --git a/dev-python/jaraco-collections/jaraco-collections-3.5.1-r1.ebuild b/dev-python/jaraco-collections/jaraco-collections-3.5.1-r1.ebuild
new file mode 100644
index 000000000000..8dec29818636
--- /dev/null
+++ b/dev-python/jaraco-collections/jaraco-collections-3.5.1-r1.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Models and classes to supplement the stdlib collections module"
+HOMEPAGE="https://github.com/jaraco/jaraco.collections"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/jaraco-classes[${PYTHON_USEDEP}]
+	dev-python/jaraco-text[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs \
+	'>=dev-python/jaraco-packaging-3.2' \
+	'>=dev-python/rst-linker-1.9'
+distutils_enable_tests pytest
diff --git a/dev-python/jaraco-stream/jaraco-stream-3.0.3-r1.ebuild b/dev-python/jaraco-stream/jaraco-stream-3.0.3-r1.ebuild
new file mode 100644
index 000000000000..227a63805e1e
--- /dev/null
+++ b/dev-python/jaraco-stream/jaraco-stream-3.0.3-r1.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+inherit distutils-r1
+
+MY_P=${P/-/.}
+DESCRIPTION="Routines for handling streaming data"
+HOMEPAGE="https://github.com/jaraco/jaraco.stream"
+SRC_URI="mirror://pypi/${MY_P::1}/${PN/-/.}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+BDEPEND="
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/more-itertools[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	">=dev-python/jaraco-packaging-3.2" \
+	">=dev-python/rst-linker-1.9"
+distutils_enable_tests pytest
diff --git a/dev-python/jc/Manifest b/dev-python/jc/Manifest
index 8b48e44911db..362c23c1871e 100644
--- a/dev-python/jc/Manifest
+++ b/dev-python/jc/Manifest
@@ -1,2 +1,3 @@
 DIST jc-1.18.7.tar.gz 8106032 BLAKE2B 05c069d0c00c1c789d253419dfc1e2caee656a848618b761664e7d46f87705f945955164c4fc213f7e8f19840b529d02ab52bc439384db122f3d464226c2b4b4 SHA512 c5ce538d4565f29a0d5fb1e39eda80a84481ad74c7ea4ce9339ec7881f2888a105af5c77c8adaf0b6174830e2f7cd1bf9628e5b9bb87d9c7b17e567251645ca9
 DIST jc-1.18.8.tar.gz 8103065 BLAKE2B 77713dda97a4228ed4715f123f2b8c1609496767aabcd38b0e80981959af5308b4296b0e1a76afed42f57517d2dadc773b00e8877324f2e1473f9f4457ea7dfd SHA512 2ed8d6946bc2230f4caaf3ef4fcf80ebb64d1fb5e3d42fddbd306bd84b6f4d4e3e84213ae479267293adb4defb443cb94828f55c74c82782eab8b4b192f792c7
+DIST jc-1.19.0.tar.gz 10264610 BLAKE2B 4f05464196e4e60b3e4a423b7c05a0bfd35128caf3f04b9c846c96bf9cb6e594ac0d46c678e1dca7080212c06d2c679acdffcc0b954b6577925ff5ff80d8f044 SHA512 668fc71d6a4b0d7ba9aac591c2328536df4f61dd9267ecdc6c311efde8dbcc3f244d6236fabd593ca1907fc25eb2a7fc53215756989160167d382e7068e2cf79
diff --git a/dev-python/jc/jc-1.19.0.ebuild b/dev-python/jc/jc-1.19.0.ebuild
new file mode 100644
index 000000000000..0f9893e5eaa7
--- /dev/null
+++ b/dev-python/jc/jc-1.19.0.ebuild
@@ -0,0 +1,31 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Converts the output of popular command-line tools and file-types to JSON"
+HOMEPAGE="
+	https://github.com/kellyjonbrazil/jc/
+	https://pypi.org/project/jc/
+"
+SRC_URI="
+	https://github.com/kellyjonbrazil/jc/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64"
+
+RDEPEND="
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
diff --git a/dev-python/jdcal/jdcal-1.4.1-r1.ebuild b/dev-python/jdcal/jdcal-1.4.1-r1.ebuild
new file mode 100644
index 000000000000..1b5fa9243515
--- /dev/null
+++ b/dev-python/jdcal/jdcal-1.4.1-r1.ebuild
@@ -0,0 +1,19 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Julian dates from proleptic Gregorian and Julian calendars"
+HOMEPAGE="https://github.com/phn/jdcal"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+SLOT="0"
+
+distutils_enable_tests pytest
diff --git a/dev-python/k5test/k5test-0.10.1-r1.ebuild b/dev-python/k5test/k5test-0.10.1-r1.ebuild
new file mode 100644
index 000000000000..6d4b068ea267
--- /dev/null
+++ b/dev-python/k5test/k5test-0.10.1-r1.ebuild
@@ -0,0 +1,16 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Library for testing Python applications in Kerberos 5 environments"
+HOMEPAGE="https://pypi.org/project/k5test/ https://github.com/pythongssapi/k5test"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
diff --git a/dev-python/kconfiglib/kconfiglib-14.1.0-r1.ebuild b/dev-python/kconfiglib/kconfiglib-14.1.0-r1.ebuild
new file mode 100644
index 000000000000..d06e133c7717
--- /dev/null
+++ b/dev-python/kconfiglib/kconfiglib-14.1.0-r1.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1
+
+DESCRIPTION="A flexible Python Kconfig implementation"
+HOMEPAGE="https://github.com/ulfalizer/Kconfiglib https://pypi.org/project/kconfiglib/"
+SRC_URI="https://github.com/ulfalizer/Kconfiglib/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S=${WORKDIR}/${P^}
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# hacks to run tests
+	mkdir Kconfiglib || die
+	ln -s ../tests Kconfiglib || die
+	# don't run kernel Kconfig compat tests
+	sed -e 's/run_compatibility_tests()$/#\0/' -i testsuite.py || die
+}
+
+python_test() {
+	"${EPYTHON}" testsuite.py || die "tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/lazy-object-proxy/lazy-object-proxy-1.7.1-r1.ebuild b/dev-python/lazy-object-proxy/lazy-object-proxy-1.7.1-r1.ebuild
new file mode 100644
index 000000000000..84f2b4e78ce1
--- /dev/null
+++ b/dev-python/lazy-object-proxy/lazy-object-proxy-1.7.1-r1.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="A fast and thorough lazy object proxy"
+HOMEPAGE="
+	https://github.com/ionelmc/python-lazy-object-proxy
+	https://pypi.org/project/lazy-object-proxy/
+	https://python-lazy-object-proxy.readthedocs.org/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# No need to benchmark
+	sed \
+		-e '/benchmark/s:test_:_&:g' \
+		-e '/pytest.mark.benchmark/d' \
+		-i tests/test_lazy_object_proxy.py || die
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/multidict/multidict-6.0.2.ebuild b/dev-python/multidict/multidict-6.0.2.ebuild
index 8b988a535603..1efc3053770b 100644
--- a/dev-python/multidict/multidict-6.0.2.ebuild
+++ b/dev-python/multidict/multidict-6.0.2.ebuild
@@ -5,17 +5,26 @@ EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
 PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
 inherit distutils-r1
 
 DESCRIPTION="multidict implementation"
-HOMEPAGE="https://github.com/aio-libs/multidict/"
-SRC_URI="https://github.com/aio-libs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+HOMEPAGE="
+	https://github.com/aio-libs/multidict/
+	https://pypi.org/project/multidict/
+"
+SRC_URI="
+	https://github.com/aio-libs/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
 
 LICENSE="Apache-2.0"
 SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
 
-BDEPEND=">=dev-python/cython-0.28.4[${PYTHON_USEDEP}]"
+BDEPEND="
+	>=dev-python/cython-0.28.4[${PYTHON_USEDEP}]
+"
 
 distutils_enable_sphinx docs --no-autodoc
 distutils_enable_tests pytest
diff --git a/dev-python/outcome/outcome-1.1.0-r1.ebuild b/dev-python/outcome/outcome-1.1.0-r1.ebuild
index b341888f7ba4..6156743589d4 100644
--- a/dev-python/outcome/outcome-1.1.0-r1.ebuild
+++ b/dev-python/outcome/outcome-1.1.0-r1.ebuild
@@ -10,8 +10,8 @@ inherit distutils-r1
 
 DESCRIPTION="Capture the outcome of Python function calls"
 HOMEPAGE="
-	https://github.com/python-trio/outcome
-	https://pypi.org/project/outcome
+	https://github.com/python-trio/outcome/
+	https://pypi.org/project/outcome/
 "
 SRC_URI="
 	https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz
diff --git a/dev-python/pandas/pandas-1.4.2.ebuild b/dev-python/pandas/pandas-1.4.2.ebuild
index fc1e32df8181..6d65df3624e5 100644
--- a/dev-python/pandas/pandas-1.4.2.ebuild
+++ b/dev-python/pandas/pandas-1.4.2.ebuild
@@ -20,7 +20,7 @@ S="${WORKDIR}/${P/_/}"
 
 SLOT="0"
 LICENSE="BSD"
-KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ~ppc ppc64 ~riscv ~s390 ~sparc ~x86"
 IUSE="doc full-support minimal test X"
 RESTRICT="!test? ( test )"
 
diff --git a/dev-python/parse/parse-1.19.0-r1.ebuild b/dev-python/parse/parse-1.19.0-r1.ebuild
new file mode 100644
index 000000000000..bd7d39f8c0c4
--- /dev/null
+++ b/dev-python/parse/parse-1.19.0-r1.ebuild
@@ -0,0 +1,18 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Parse strings using a specification based on the Python format() syntax"
+HOMEPAGE="https://pypi.org/project/parse/"
+SRC_URI="mirror://pypi/${P::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+distutils_enable_tests unittest
diff --git a/dev-python/pynacl/pynacl-1.5.0-r1.ebuild b/dev-python/pynacl/pynacl-1.5.0-r1.ebuild
new file mode 100644
index 000000000000..e033c7c898cf
--- /dev/null
+++ b/dev-python/pynacl/pynacl-1.5.0-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python binding to the Networking and Cryptography (NaCl) library"
+HOMEPAGE="
+	https://github.com/pyca/pynacl/
+	https://pypi.org/project/PyNaCl/
+"
+SRC_URI="
+	https://github.com/pyca/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/cffi-1.4.1[${PYTHON_USEDEP}]
+	dev-libs/libsodium:0/23
+"
+BDEPEND="${RDEPEND}
+	test? (
+		>=dev-python/hypothesis-3.27.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_compile() {
+	# For not using the bundled libsodium
+	local -x SODIUM_INSTALL=system
+	distutils-r1_src_compile
+}
diff --git a/dev-python/pytest-bdd/pytest-bdd-5.0.0-r1.ebuild b/dev-python/pytest-bdd/pytest-bdd-5.0.0-r1.ebuild
new file mode 100644
index 000000000000..cdea3d708a9f
--- /dev/null
+++ b/dev-python/pytest-bdd/pytest-bdd-5.0.0-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="BDD library for the pytest runner"
+HOMEPAGE="https://pypi.org/project/pytest-bdd/"
+SRC_URI="https://github.com/pytest-dev/pytest-bdd/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/glob2[${PYTHON_USEDEP}]
+	dev-python/mako[${PYTHON_USEDEP}]
+	dev-python/parse[${PYTHON_USEDEP}]
+	dev-python/parse_type[${PYTHON_USEDEP}]
+	dev-python/py[${PYTHON_USEDEP}]"
+BDEPEND="dev-python/packaging[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+DOCS=( AUTHORS.rst CHANGES.rst README.rst )
+
+src_test() {
+	# terminal_reporter test needs exact wrapping
+	local -x COLUMNS=80
+
+	# hooks output parsing may be affected by other pytest-*, e.g. tornasync
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=pytest_bdd.plugin
+
+	distutils-r1_src_test
+}
diff --git a/dev-python/python-engineio/Manifest b/dev-python/python-engineio/Manifest
index 4e535310cfac..fbbfbdce8a6f 100644
--- a/dev-python/python-engineio/Manifest
+++ b/dev-python/python-engineio/Manifest
@@ -1,4 +1 @@
-DIST python-engineio-4.2.1.gh.tar.gz 297657 BLAKE2B 0a634cec9f71a3b8659e5b07cc326fb3d7801c8a834248d6f2ea5a48bcd058f8d0b86c2e43c110ea18ef641e3ace273a2ebd20f350aec9360d38ffe0f32f2778 SHA512 f0ea7cb0a34f49d2e3de58dc1038f41cda099fba0033af7020b9ccacd34fbf44fd1613ef14d4d05013dd99a2d35330769e6c3d2f532556fd39262229e40714f6
-DIST python-engineio-4.3.0.gh.tar.gz 299122 BLAKE2B 929b16650aaf4a429e9a1353a994cc87022644bef48c59aac9c448ec32533a7a7360413143159809042915f69c4f0ae0c2a13e5fe2d61b729c09890508107948 SHA512 c34688f1dcaf4a1a02dea03d2746b0b0e089387d4ac55024e783ee2dbafb59ac43437138747b63b0710425601b27e1a10c56df7c57c1ed16ab2f812a773c8ec4
-DIST python-engineio-4.3.1.gh.tar.gz 299321 BLAKE2B a5234a12ad4434e0793154569f4c3f7d3c416d6334acf6af6de03336861797a42d6930350944a4ed6cca089daaad731b209878b08c61b29a97793afbcea473ac SHA512 6e00134191ff39e3e2f3f8cd933562be8ee9db1512f6b7d3cc2d52283ee2ea329d942edcde0bbfdfed71348d96c62067c423d666ad32a789eab760b583fc75af
 DIST python-engineio-4.3.2.gh.tar.gz 299722 BLAKE2B 87dece98d72b7b0384e3b9d57062a3eaa7aeb80ac3f2f685d50b8816e122398ffd54da1f4b99a90a1f535e2d0f0d282167a682de022373e6108f7e91f8689aa1 SHA512 59933a0093167042a3873ba1561d2859359a5ad160f6b7b5c19478b1f73d1bd068779942c8bfc44dd5a8d9f155359571298b960bcd217aab341bdfec35bc5b28
diff --git a/dev-python/python-engineio/python-engineio-4.2.1.ebuild b/dev-python/python-engineio/python-engineio-4.2.1.ebuild
deleted file mode 100644
index 4fd1b84adacf..000000000000
--- a/dev-python/python-engineio/python-engineio-4.2.1.ebuild
+++ /dev/null
@@ -1,32 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
-
-inherit distutils-r1
-
-DESCRIPTION="Python implementation of the Engine.IO realtime server"
-HOMEPAGE="
-	https://python-engineio.readthedocs.io/
-	https://github.com/miguelgrinberg/python-engineio/
-	https://pypi.org/project/python-engineio/"
-SRC_URI="
-	https://github.com/miguelgrinberg/python-engineio/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="
-	dev-python/aiohttp[${PYTHON_USEDEP}]
-	dev-python/requests[${PYTHON_USEDEP}]
-	dev-python/websocket-client[${PYTHON_USEDEP}]"
-BDEPEND="
-	test? (
-		dev-python/eventlet[${PYTHON_USEDEP}]
-		www-servers/tornado[${PYTHON_USEDEP}]
-	)"
-
-distutils_enable_tests pytest
diff --git a/dev-python/python-engineio/python-engineio-4.3.0.ebuild b/dev-python/python-engineio/python-engineio-4.3.0.ebuild
deleted file mode 100644
index 4fd1b84adacf..000000000000
--- a/dev-python/python-engineio/python-engineio-4.3.0.ebuild
+++ /dev/null
@@ -1,32 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
-
-inherit distutils-r1
-
-DESCRIPTION="Python implementation of the Engine.IO realtime server"
-HOMEPAGE="
-	https://python-engineio.readthedocs.io/
-	https://github.com/miguelgrinberg/python-engineio/
-	https://pypi.org/project/python-engineio/"
-SRC_URI="
-	https://github.com/miguelgrinberg/python-engineio/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="
-	dev-python/aiohttp[${PYTHON_USEDEP}]
-	dev-python/requests[${PYTHON_USEDEP}]
-	dev-python/websocket-client[${PYTHON_USEDEP}]"
-BDEPEND="
-	test? (
-		dev-python/eventlet[${PYTHON_USEDEP}]
-		www-servers/tornado[${PYTHON_USEDEP}]
-	)"
-
-distutils_enable_tests pytest
diff --git a/dev-python/python-engineio/python-engineio-4.3.1.ebuild b/dev-python/python-engineio/python-engineio-4.3.1.ebuild
deleted file mode 100644
index 44a9aa191e68..000000000000
--- a/dev-python/python-engineio/python-engineio-4.3.1.ebuild
+++ /dev/null
@@ -1,32 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
-
-inherit distutils-r1
-
-DESCRIPTION="Python implementation of the Engine.IO realtime server"
-HOMEPAGE="
-	https://python-engineio.readthedocs.io/
-	https://github.com/miguelgrinberg/python-engineio/
-	https://pypi.org/project/python-engineio/"
-SRC_URI="
-	https://github.com/miguelgrinberg/python-engineio/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="
-	dev-python/aiohttp[${PYTHON_USEDEP}]
-	dev-python/requests[${PYTHON_USEDEP}]
-	dev-python/websocket-client[${PYTHON_USEDEP}]"
-BDEPEND="
-	test? (
-		dev-python/eventlet[${PYTHON_USEDEP}]
-		www-servers/tornado[${PYTHON_USEDEP}]
-	)"
-
-distutils_enable_tests pytest
diff --git a/dev-python/python-engineio/python-engineio-4.3.2.ebuild b/dev-python/python-engineio/python-engineio-4.3.2.ebuild
deleted file mode 100644
index 5585c55bfa9e..000000000000
--- a/dev-python/python-engineio/python-engineio-4.3.2.ebuild
+++ /dev/null
@@ -1,38 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
-inherit distutils-r1
-
-DESCRIPTION="Python implementation of the Engine.IO realtime server"
-HOMEPAGE="
-	https://python-engineio.readthedocs.io/
-	https://github.com/miguelgrinberg/python-engineio/
-	https://pypi.org/project/python-engineio/"
-SRC_URI="
-	https://github.com/miguelgrinberg/python-engineio/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="
-	dev-python/aiohttp[${PYTHON_USEDEP}]
-	dev-python/requests[${PYTHON_USEDEP}]
-	dev-python/websocket-client[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		dev-python/eventlet[${PYTHON_USEDEP}]
-		www-servers/tornado[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-distutils_enable_sphinx docs \
-	dev-python/alabaster
diff --git a/dev-python/python-pam/python-pam-2.0.2-r1.ebuild b/dev-python/python-pam/python-pam-2.0.2-r1.ebuild
index 38791866f073..d198e4a67502 100644
--- a/dev-python/python-pam/python-pam-2.0.2-r1.ebuild
+++ b/dev-python/python-pam/python-pam-2.0.2-r1.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://github.com/FirefighterBlu3/python-pam/archive/refs/tags/v${PV}.
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 ~riscv x86"
+KEYWORDS="amd64 ~arm64 ~riscv x86"
 
 RDEPEND="dev-python/six[${PYTHON_USEDEP}]
 	dev-python/toml[${PYTHON_USEDEP}]"
diff --git a/dev-python/sniffio/sniffio-1.2.0-r1.ebuild b/dev-python/sniffio/sniffio-1.2.0-r1.ebuild
new file mode 100644
index 000000000000..f0ae948d24dc
--- /dev/null
+++ b/dev-python/sniffio/sniffio-1.2.0-r1.ebuild
@@ -0,0 +1,30 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Sniff out which async library your code is running under"
+HOMEPAGE="
+	https://github.com/python-trio/sniffio/
+	https://pypi.org/project/sniffio/
+"
+SRC_URI="
+	https://github.com/python-trio/sniffio/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# curio is not packaged
+	sniffio/_tests/test_sniffio.py::test_curio
+)
diff --git a/dev-python/tempora/Manifest b/dev-python/tempora/Manifest
index c36c4a617da4..65472af2543f 100644
--- a/dev-python/tempora/Manifest
+++ b/dev-python/tempora/Manifest
@@ -1 +1,2 @@
 DIST tempora-5.0.0.tar.gz 18532 BLAKE2B f3d59b7d7d2974564b0c7cf25d5bf8716610aa09dd134e37289648e71c4dd6989bfecfafd258da01875de0560cef31fcb8ee0ec85e16d642ff56d10915da6132 SHA512 e95fff8c460329c8369f8f819a95341ec4e1641d2ecc88251c9681ac5e9678eded0f320aa1bff98a980fc552cb214ea3f40c249ea25b54d8fbe34849fffff7b6
+DIST tempora-5.0.1.tar.gz 18456 BLAKE2B b21d60dc8fa5ff9701bbdf66cc9f657c9e4bc779a4a564ea788b201034f818a688c53bcd94f315ef4650b62cce1866fad4a196e2ab724e89670bbc36e9ea15ac SHA512 941b1a231bfae6cf2321325ada785806578643dc9ae215116393623f780de7a409f918c215aae353013bd89c6866ab870ac61470af09f281af0953ce6e20ea3b
diff --git a/dev-python/tempora/tempora-5.0.1.ebuild b/dev-python/tempora/tempora-5.0.1.ebuild
new file mode 100644
index 000000000000..764a461f39a0
--- /dev/null
+++ b/dev-python/tempora/tempora-5.0.1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Objects and routines pertaining to date and time"
+HOMEPAGE="https://github.com/jaraco/tempora"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/jaraco-functools-1.20[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pytest-freezegun[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	">=dev-python/jaraco-packaging-3.2" \
+	">=dev-python/rst-linker-1.9"
diff --git a/dev-python/yarl/yarl-1.7.2-r2.ebuild b/dev-python/yarl/yarl-1.7.2-r2.ebuild
new file mode 100644
index 000000000000..d5872037bf2c
--- /dev/null
+++ b/dev-python/yarl/yarl-1.7.2-r2.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Yet another URL library"
+HOMEPAGE="
+	https://github.com/aio-libs/yarl/
+	https://pypi.org/project/yarl/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/multidict-4.0[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/alabaster
+
+python_test() {
+	cd tests || die
+	epytest --override-ini=addopts=
+}