Adding metadata

16 files changed, 392 insertions, 2 deletions

diff --git a/dev-python/autobahn/Manifest b/dev-python/autobahn/Manifest
index 6346603232ed..53a3bc7b96ff 100644
--- a/dev-python/autobahn/Manifest
+++ b/dev-python/autobahn/Manifest
@@ -1,3 +1,4 @@
 DIST autobahn-21.11.1.tar.gz 365165 BLAKE2B 91a12bf1fa9acd056246d86675c76fbcdb4de8914f4ab5e2c8ec06cf8e822cc1a72f8a7b39b520405cce32e2f32024ebbaa48ba024e1dc71b50da4e6f8913e19 SHA512 5a23272046ef67821e86c6bfe766273b3ba73a75fbc51c7864c2ab83ffb8d4e119022980f8b71c453118bf15b26ede8042aa0114e54caebbfb33555208093ac2
 DIST autobahn-22.1.1.tar.gz 365843 BLAKE2B 835861db493be3f70fbff1971f3ab09346f689b5e100ea29115635b6d283c14f944a6c6fcc234d549cfa895496125ce7d03576ea6536c0536f6e79277a1e5592 SHA512 9198fc71ef0d967e9d0d577684c9c5f6ef36d12392a043f581a0be920fc0bf842369f50406a3a5a33d1c6063d21a57136735d8dc123230b18b6da8c4e80f8eed
 DIST autobahn-22.2.1.tar.gz 375438 BLAKE2B dffc92c0bfb1b34f4929aea72bb60b55ab7ec73a1cdd2148f7b9498bb4a75f6c0d0ff3b653aa5b31b08cbd707121d56f721540d97acc88ea8776836978ecc184 SHA512 dd1543ddf918bd54f3436cdea2be28b1402e651ec8867303a4d9140d395e37bb3e9867c0360f20611acc61c3431533d6b47eba9fac1d8b3363b588a3aa626188
+DIST autobahn-22.2.2.tar.gz 375443 BLAKE2B a321cfeaa35e7da5aa58ade0da3bc5891baab1d4a915782e9d25038679261c19744d65baa4a981cb01025902dc8f4ffb93d8c0ad59b8db32119c0fb0eeb49d53 SHA512 95b0ee867a866b1cf67a55ffa9386addd3640b12a3e5a2673b4d496aa6d41ec49408e1f528bc21d1e390d5e3343dda0b1625d4ac0d9e9101db151c7c79623263
diff --git a/dev-python/autobahn/autobahn-22.2.2.ebuild b/dev-python/autobahn/autobahn-22.2.2.ebuild
new file mode 100644
index 000000000000..d4b1f35003a1
--- /dev/null
+++ b/dev-python/autobahn/autobahn-22.2.2.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 optfeature
+
+MY_P=${PN}-$(ver_rs 3 -)
+
+DESCRIPTION="WebSocket and WAMP for Twisted and Asyncio"
+HOMEPAGE="https://pypi.org/project/autobahn/
+	https://crossbar.io/autobahn/
+	https://github.com/crossbario/autobahn-python"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="test xbr"
+RESTRICT="!test? ( test )"
+
+# The order of deps is based on their appearance in setup.py
+# All extra deps should be included in test and in optfeature
+RDEPEND="
+	>=dev-python/zope-interface-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/twisted-20.3.0[${PYTHON_USEDEP}]
+	>=dev-python/attrs-20.3.0[${PYTHON_USEDEP}]
+	>=dev-python/txaio-21.2.1[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	>=dev-python/hyperlink-21.0.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/wsaccel-0.6.3[${PYTHON_USEDEP}]
+		>=dev-python/snappy-0.6.0[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-1.0.2[${PYTHON_USEDEP}]
+		>=dev-python/ujson-4.0.2[${PYTHON_USEDEP}]
+		>=dev-python/cbor2-5.2.0[${PYTHON_USEDEP}]
+		>=dev-python/py-ubjson-0.16.1[${PYTHON_USEDEP}]
+		>=dev-python/flatbuffers-1.12[${PYTHON_USEDEP}]
+		>=dev-python/pyopenssl-20.0.1[${PYTHON_USEDEP}]
+		>=dev-python/service_identity-18.1.0[${PYTHON_USEDEP}]
+		>=dev-python/pynacl-1.4.0[${PYTHON_USEDEP}]
+		>=dev-python/pytrie-0.4[${PYTHON_USEDEP}]
+		>=dev-python/pyqrcode-1.2.1[${PYTHON_USEDEP}]
+		>=dev-python/cffi-1.14.5[${PYTHON_USEDEP}]
+		>=dev-python/argon2-cffi-20.1.0[${PYTHON_USEDEP}]
+		>=dev-python/passlib-1.7.4[${PYTHON_USEDEP}]
+
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	if use xbr ; then
+		eerror "***************"
+		eerror "Required xbr dependencies are incomplete in Gentoo."
+		eerror "So this functionality will not yet work"
+		eerror "Please file a bug if this feature is needed"
+		eerror "***************"
+	else
+		# remove xbr components
+		export AUTOBAHN_STRIP_XBR="True"
+	fi
+
+	# avoid useless rust dependency
+	sed -i -e '/cryptography/s:>=3.4.6::' setup.py || die
+
+	# remove twisted plugin cache regen in setup.py
+	# to fix tinderbox sandbox issue
+	sed -e '/import/s:reactor:__importmustfail__:' \
+		-i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	einfo "Testing all, cryptosign using twisted"
+	local -x USE_TWISTED=true
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	"${EPYTHON}" -m twisted.trial autobahn || die "Tests failed with ${EPYTHON}"
+	unset USE_TWISTED
+
+	einfo "RE-testing cryptosign and component_aio using asyncio"
+	local -x USE_ASYNCIO=true
+	epytest autobahn/wamp/test/test_wamp_{cryptosign,component_aio}.py
+	unset USE_ASYNCIO
+
+	rm -f twisted/plugins/dropin.cache || die
+}
+
+pkg_postinst() {
+	optfeature "C-based WebSocket acceleration" "dev-python/wsaccel"
+	optfeature "non-standard WebSocket compression support" "dev-python/snappy"
+	optfeature "accelerated WAMP serialization support" \
+		"dev-python/msgpack dev-python/ujson dev-python/cbor2 dev-python/flatbuffers dev-python/py-ubjson"
+	optfeature "TLS transport encryption" \
+		"dev-python/pyopenssl dev-python/pynacl dev-python/pytrie dev-python/pyqrcode dev-python/service_identity"
+	optfeature "WAMP-SCRAM authentication" \
+		"dev-python/cffi dev-python/argon2-cffi dev-python/passlib"
+	optfeature "native SIMD acceleration" "dev-python/cffi"
+
+	python_foreach_impl twisted-regen-cache
+}
+
+pkg_postrm() {
+	python_foreach_impl twisted-regen-cache
+}
diff --git a/dev-python/google-api-core/google-api-core-2.5.0.ebuild b/dev-python/google-api-core/google-api-core-2.5.0.ebuild
index 919e2ee109c6..ec7b83078af2 100644
--- a/dev-python/google-api-core/google-api-core-2.5.0.ebuild
+++ b/dev-python/google-api-core/google-api-core-2.5.0.ebuild
@@ -59,3 +59,7 @@ python_compile() {
 	distutils-r1_python_compile
 	find "${BUILD_DIR}" -name '*.pth' -delete || die
 }
+
+python_test() {
+	epytest -p no:aiohttp -p no:trio
+}
diff --git a/dev-python/google-api-python-client/google-api-python-client-2.38.0-r1.ebuild b/dev-python/google-api-python-client/google-api-python-client-2.38.0-r1.ebuild
new file mode 100644
index 000000000000..03decd4ab7a6
--- /dev/null
+++ b/dev-python/google-api-python-client/google-api-python-client-2.38.0-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Google API Client for Python"
+HOMEPAGE="https://github.com/googleapis/google-api-python-client"
+SRC_URI="https://github.com/googleapis/google-api-python-client/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/httplib2-0.15[${PYTHON_USEDEP}]
+	<dev-python/httplib2-1[${PYTHON_USEDEP}]
+	dev-python/google-api-core[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.35.0[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-httplib2-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/uritemplate-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/uritemplate-5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/oauth2client[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# require Internet access (and credentials)
+		tests/test_discovery.py::DiscoveryErrors::test_credentials_and_credentials_file_mutually_exclusive
+		tests/test_discovery.py::DiscoveryFromDocument::test_api_endpoint_override_from_client_options_mapping_object
+	)
+
+	epytest tests
+}
diff --git a/dev-python/google-auth-httplib2/google-auth-httplib2-0.1.0-r1.ebuild b/dev-python/google-auth-httplib2/google-auth-httplib2-0.1.0-r1.ebuild
new file mode 100644
index 000000000000..795ccc7f5304
--- /dev/null
+++ b/dev-python/google-auth-httplib2/google-auth-httplib2-0.1.0-r1.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_P="google-auth-library-python-httplib2-${PV}"
+DESCRIPTION="httplib2 Transport for Google Auth"
+HOMEPAGE="https://pypi.org/project/google-auth-httplib2/
+	https://github.com/googleapis/google-auth-library-python-httplib2"
+SRC_URI="
+	https://github.com/googleapis/google-auth-library-python-httplib2/archive/v${PV}.tar.gz
+		-> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/httplib2[${PYTHON_USEDEP}]
+	dev-python/google-auth[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/google-auth-oauthlib/Manifest b/dev-python/google-auth-oauthlib/Manifest
index 08f446786de0..4cf722bb0993 100644
--- a/dev-python/google-auth-oauthlib/Manifest
+++ b/dev-python/google-auth-oauthlib/Manifest
@@ -1 +1,2 @@
 DIST google-auth-library-python-oauthlib-0.4.6.gh.tar.gz 50982 BLAKE2B 93980a69777089125bca9f583cae0b64f9facf699da3ac135561a9cf135122d9e22a6c0be3325d366dd77a2240fb16d5c63633a216cfee07b9fceb2239227c86 SHA512 a20a85c073a6208d72c8f6ceb34544241f599e716b1191bfc52bcc367797efc18d0e2b94d4e433cec692282b00428bcb4d7e73ed48a26e66d6005189d5dddb77
+DIST google-auth-library-python-oauthlib-0.5.0.gh.tar.gz 52118 BLAKE2B 596f9af156030b0dbc0a35c3946ab865370fa326176fc33b04d55aa5d99950718d275f69b399d9afe303ee84f9c5823571eb4c144353f17fe6a64bbca7a35e18 SHA512 7da0d1c5e8c20aee843798c317a2c1edd29caf98abaf8895e354e20279c45395de4a522e21f11dbbe9e67c3bd984ded101b0cde04519b9256d80bdc42501a71a
diff --git a/dev-python/google-auth-oauthlib/google-auth-oauthlib-0.5.0.ebuild b/dev-python/google-auth-oauthlib/google-auth-oauthlib-0.5.0.ebuild
new file mode 100644
index 000000000000..5fc9b420cd17
--- /dev/null
+++ b/dev-python/google-auth-oauthlib/google-auth-oauthlib-0.5.0.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_P=google-auth-library-python-oauthlib-${PV}
+DESCRIPTION="Google Authentication Library"
+HOMEPAGE="
+	https://pypi.org/project/google-auth-oauthlib/
+	https://github.com/googleapis/google-auth-library-python-oauthlib"
+SRC_URI="
+	https://github.com/googleapis/google-auth-library-python-oauthlib/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/click-6.0.0[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-oauthlib-0.7.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? ( dev-python/mock[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/oauth2client/oauth2client-4.1.3-r1.ebuild b/dev-python/oauth2client/oauth2client-4.1.3-r1.ebuild
index d37a14097aac..3792d32b05cb 100644
--- a/dev-python/oauth2client/oauth2client-4.1.3-r1.ebuild
+++ b/dev-python/oauth2client/oauth2client-4.1.3-r1.ebuild
@@ -1,7 +1,8 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
+
 PYTHON_COMPAT=( python3_{7,8,9,10} )
 
 inherit distutils-r1
diff --git a/dev-python/oauth2client/oauth2client-4.1.3-r2.ebuild b/dev-python/oauth2client/oauth2client-4.1.3-r2.ebuild
new file mode 100644
index 000000000000..61a34ae1f428
--- /dev/null
+++ b/dev-python/oauth2client/oauth2client-4.1.3-r2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Library for accessing resources protected by OAuth 2.0"
+HOMEPAGE="https://github.com/googleapis/oauth2client"
+SRC_URI="https://github.com/googleapis/oauth2client/archive/v${PV/_p/-post}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${P/_p/-post}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/httplib2-0.9.1[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.1.7[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-modules-0.0.5[${PYTHON_USEDEP}]
+	>=dev-python/rsa-3.1.4[${PYTHON_USEDEP}]
+	>=dev-python/six-1.6.1[${PYTHON_USEDEP}]
+	dev-python/keyring[${PYTHON_USEDEP}]
+	!<=dev-python/google-api-python-client-1.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests nose
+
+PATCHES=(
+	"${FILESDIR}/oauth2client-4.1.3-py38.patch"
+)
+
+python_test() {
+	nosetests -v \
+		-e appengine \
+		-e django_util \
+		-e test_multiprocess_file_storage \
+		-e test_bad_positional || die "tests fail with ${EPYTHON}"
+	# appengine - requires appengine
+	# django_util - requires django
+	# test_multiprocess_file_storage - requires fasteners
+	# test_bad_positional - expects TypeError, gets ValueError
+}
diff --git a/dev-python/pytest-console-scripts/Manifest b/dev-python/pytest-console-scripts/Manifest
index 2985f085d292..0b5135c63573 100644
--- a/dev-python/pytest-console-scripts/Manifest
+++ b/dev-python/pytest-console-scripts/Manifest
@@ -1,2 +1,3 @@
 DIST pytest-console-scripts-1.2.0.tar.gz 13976 BLAKE2B 1452ecfdc47d3341d8f3f30d49f371ae89d6138d56e4dc3a230f6a3803c6c36f542df40e2785c99c3cfd5080fa03b5b3d4926bb742dc99bd2127d47305fbf788 SHA512 07c9baab85035265ab6a21cc0c754b076dba87f08e1ab51319ef47a0a8af0b44f7d42422014c68cf93ed28b508138a70e14b968707cc831682885b3ca8106aa7
 DIST pytest-console-scripts-1.2.2.tar.gz 14314 BLAKE2B 1e4c210fe9fa6a4e9dbe308cf3d6c1a1829f2155185fe3911ee0a299c0292db6bceeeeb7efd5ace9a166c90ae8376d3cdfec8b0c0b585467f157e175709afe6d SHA512 c749b76c8370734f9ab7fe93284f9ac25a38e4bef61181a3b61b3b0d229532f1876e668e5a6e1449dcb939d9cb53527e021f79fd9132f3a28bdf45d95bdcb40e
+DIST pytest-console-scripts-1.3.tar.gz 14365 BLAKE2B 7a9b83f53ef9911e5f336375389e6c6311e64e7b4880ea2cb1f996221d4dbf119bf6fc487f7bb7bfda4355df8f797981e99ac9db2fff3e4871173a878a4fbd64 SHA512 8b66df3a8ff700817f8ec34aa95385ff82c4df47fd67974e91cf4d2fdae578d4683032b0a8162723adfcd461e5da7f1c5bb99339d62ed9cbdca4fd1be001b0f6
diff --git a/dev-python/pytest-console-scripts/pytest-console-scripts-1.3.ebuild b/dev-python/pytest-console-scripts/pytest-console-scripts-1.3.ebuild
new file mode 100644
index 000000000000..43daf01fe918
--- /dev/null
+++ b/dev-python/pytest-console-scripts/pytest-console-scripts-1.3.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Pytest plugin for testing console scripts"
+HOMEPAGE="https://github.com/kvas-it/pytest-console-scripts"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/pytest-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local script="${BUILD_DIR}/install${EPREFIX}/usr/bin/pytest"
+	cat > "${script}" <<-EOF
+		#!/usr/bin/env python
+		import pytest
+		import sys
+		sys.exit(pytest.console_main())
+	EOF
+	chmod +x "${script}" || die
+	epytest -x
+	rm "${script}" || die
+}
diff --git a/dev-python/restructuredtext-lint/Manifest b/dev-python/restructuredtext-lint/Manifest
index 8598be37d0c0..0c2d40496582 100644
--- a/dev-python/restructuredtext-lint/Manifest
+++ b/dev-python/restructuredtext-lint/Manifest
@@ -1 +1,2 @@
 DIST restructuredtext_lint-1.3.0.tar.gz 19008 BLAKE2B 45d4a0d02691dbd0f46e57cf637c7b61f6cd93daa5f98a6795b119555913d6dcec7035857ae6a3f73b777d02e7662c2775fa288f3ad7b7ecc3d26c961595f203 SHA512 983f38e51943cb7fd6a36181f99cd9c24c40deaf932ea8f69ae6568255a1ca8800aecd753067304ea596cd84bee4fdd5d96e935e06bf602613c57ad24113520d
+DIST restructuredtext_lint-1.4.0.tar.gz 16723 BLAKE2B 2beaa565391fd1a130f8ef998b140e0ebb4695759a61c0526f066e71c3bd42e981115f267c48d30e19eb45c240907ea71d9f49a03d74e9ce1d4b80a2c0b511c9 SHA512 8e16e2a43cb1e52bb3b4ac60da53130bd4a8d0b823fc95b32e62068bed95728084de3b55820cfcaba70eecaaa93bdf3f956b8bb6c55155115b40c7151ef58a2c
diff --git a/dev-python/restructuredtext-lint/metadata.xml b/dev-python/restructuredtext-lint/metadata.xml
index 66e2c572bf4a..328edb77a060 100644
--- a/dev-python/restructuredtext-lint/metadata.xml
+++ b/dev-python/restructuredtext-lint/metadata.xml
@@ -5,8 +5,12 @@
   <email>prometheanfire@gentoo.org</email>
   <name>Matthew Thode</name>
  </maintainer>
+ <maintainer type="project">
+  <email>python@gentoo.org</email>
+  <name>Python</name>
+ </maintainer>
  <upstream>
-  <remote-id type="pypi">restructuredtext_lint</remote-id>
+  <remote-id type="pypi">restructuredtext-lint</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
  <stabilize-allarches/>
diff --git a/dev-python/restructuredtext-lint/restructuredtext-lint-1.4.0.ebuild b/dev-python/restructuredtext-lint/restructuredtext-lint-1.4.0.ebuild
new file mode 100644
index 000000000000..ba8f837c52ee
--- /dev/null
+++ b/dev-python/restructuredtext-lint/restructuredtext-lint-1.4.0.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_P="${P/-/_}"
+DESCRIPTION="Checks PyPI validity of reStructuredText"
+HOMEPAGE="https://pypi.org/project/restructuredtext-lint/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN/-/_}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/docutils-0.11[${PYTHON_USEDEP}]
+	<dev-python/docutils-1.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
diff --git a/dev-python/test_server/Manifest b/dev-python/test_server/Manifest
index 3f5bf660f22c..7264f0c85488 100644
--- a/dev-python/test_server/Manifest
+++ b/dev-python/test_server/Manifest
@@ -2,3 +2,4 @@ DIST test_server-0.0.31.tar.gz 18578 BLAKE2B a08c23a7db43f1c99a0cd270852d9ea841e
 DIST test_server-0.0.32.tar.gz 17548 BLAKE2B a24397fb73243e6f8dc1ec1fc84cb4e411ae5ac4217b3b3b47e6f819fc6315e3515ffb81a31d941e0ba1dc289adc37c8da3df35016067a94e026484f20d14e88 SHA512 4cc70fff2f1d932f6daba9cf610fb9dc9aca9554f19d494a34300d9b3f31a038cc9843f5e07ec9f884402f6b505e99773e66f8d7da1200cde221af5b83fc2f1c
 DIST test_server-0.0.33.tar.gz 16491 BLAKE2B 8c4f9ae1264b72e940b2e9d8db580ad077e37db2759af6992ee76b3146bfc6260b52dfa649423e74288d01b5090171a99ae66a2b96f986c0a998bbaef048fb53 SHA512 bf7b954a80954e0acfe9eb88dc506e141c9421ef38dcd94a95d0c054b38f088c5c855e1466b7d36d72c1737f34d8639dc456123ca848d567b2d087ff6f9bda00
 DIST test_server-0.0.35.gh.tar.gz 16503 BLAKE2B 01c3ec16c6b6d926ce9220f5878edc385ce087641e2419a613388dde1a5b5018c71991b146fa95b1e5e46a39cc4ca657f68cf06af23f1385ed05835dcea9d609 SHA512 bbea0e9965d3c839fb953f60480c271a8f6a8c808d922a9af68c576fb13d3a5d5b1055767f47874e897a5ee2e87f2749a93dab6e1d69acc143ff886158f95cf6
+DIST test_server-0.0.36.gh.tar.gz 16663 BLAKE2B fa3e6a00aef11727271dee9c3e06ac878da4aac6098df6d9de56049f175af143bb858e2bd8d91cd1acfffcdf59e8d3dd1bc0fa840c1431ab162a599d103e37f7 SHA512 699abef74e5589396e45309b140da15be82de49383d5c683b729343f83a2e369a6e2bd4383ae442369dffe777100099abaf4f917cd700ec9926f2bcdfe0b84ce
diff --git a/dev-python/test_server/test_server-0.0.36.ebuild b/dev-python/test_server/test_server-0.0.36.ebuild
new file mode 100644
index 000000000000..9f43be88efc0
--- /dev/null
+++ b/dev-python/test_server/test_server-0.0.36.ebuild
@@ -0,0 +1,25 @@
+# Copyright 2019-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Server to test HTTP clients"
+HOMEPAGE="
+	https://github.com/lorien/test_server/
+	https://pypi.org/project/test-server/
+"
+SRC_URI="
+	https://github.com/lorien/test_server/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+distutils_enable_tests pytest