Adding metadata

11 files changed, 358 insertions, 0 deletions

diff --git a/dev-python/GitPython/GitPython-3.1.15.ebuild b/dev-python/GitPython/GitPython-3.1.15.ebuild
new file mode 100644
index 000000000000..a6bd373ac290
--- /dev/null
+++ b/dev-python/GitPython/GitPython-3.1.15.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+TEST_P=GitPython-${PV}
+GITDB_P=gitdb-4.0.5-r1
+SMMAP_P=smmap-3.0.4
+
+DESCRIPTION="Library used to interact with Git repositories"
+HOMEPAGE="https://github.com/gitpython-developers/GitPython https://pypi.org/project/GitPython/"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz
+	test? (
+		https://dev.gentoo.org/~mgorny/dist/${TEST_P}.gitbundle
+		https://dev.gentoo.org/~mgorny/dist/${GITDB_P}.gitbundle
+		https://dev.gentoo.org/~mgorny/dist/${SMMAP_P}.gitbundle
+	)"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-vcs/git
+	>=dev-python/gitdb-4.0.1[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		>=dev-python/ddt-1.1.1[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests unittest
+
+src_test() {
+	git config --global user.email "travis@ci.com" || die
+	git config --global user.name "Travis Runner" || die
+
+	git clone "${DISTDIR}/${TEST_P}.gitbundle" "${T}"/test || die
+	git clone "${DISTDIR}/${GITDB_P}.gitbundle" \
+		"${T}"/test/git/ext/gitdb || die
+	git clone "${DISTDIR}/${SMMAP_P}.gitbundle" \
+		"${T}"/test/git/ext/gitdb/gitdb/ext/smmap || die
+
+	cd "${T}"/test || die
+	TRAVIS=1 ./init-tests-after-clone.sh || die
+	cat test/fixtures/.gitconfig >> ~/.gitconfig || die
+	rm -r test/performance || die
+	# tests requiring network access
+	sed -i -e 's:test_fetch_error:_&:' test/test_remote.py || die
+	sed -i -e 's:test_leaking_password_in_clone_logs:_&:' test/test_repo.py || die
+	rm test/test_installation.py || die
+
+	distutils-r1_src_test
+}
diff --git a/dev-python/GitPython/Manifest b/dev-python/GitPython/Manifest
index 981dccdfc978..8dd2e5966cb2 100644
--- a/dev-python/GitPython/Manifest
+++ b/dev-python/GitPython/Manifest
@@ -1,4 +1,6 @@
 DIST GitPython-3.1.14.gitbundle 4446003 BLAKE2B db7844045aed7c40a3f341706e017e877bf3dedde61665754c1d4b14b98d0ddc863666ff1dceb313174a908f8fbacbda0586e53e874a1397e6eeb562cf1ddf1f SHA512 ecd570bdb85dfa64f42ce447bf381868d584eb56897954d893ba1f1ee193fa4e45f3847fe842a67276da0cf155a2501ed4c25d34d300a9776b0f068b659ba014
 DIST GitPython-3.1.14.tar.gz 171534 BLAKE2B bcb2b7a497f6eabebe3187ad5104bede01c1a53aa52d15bdc7112198224c566cefc1ecae448dc47f6610e05cf871620a862ca6a3cca17bd8812720e64a9a1d86 SHA512 ee9015d82a53aba18dde8cede276d1d4410c7d9791c5b224c772114801c1e6dc4210c02399dc1248593a4e52d5f5e549cdbf927d6a7c7f9a5a9b0801f5d79675
+DIST GitPython-3.1.15.gitbundle 4811422 BLAKE2B 16399b302f7f3f36b315bcaa1535992a43b02fd888586d135824f8f4dc5ba611875d68e6d3102d71edc93848a91d3b244176d6b735ef30d65fdf64c28d325ef9 SHA512 13064036f20aaa58cf7784a3a61ed9c9e08414e9126332fc629e976889c87a2a70b1c9270774df676dcc08ded0ee3629112c60b88025536a9d13a04491b7b1e2
+DIST GitPython-3.1.15.tar.gz 175132 BLAKE2B 5a0cc8176257a5fec9afbf81351da191fc70ad5678d3ee89d36807cdf01a7f69216916723ac551bcc29fbc07a88a9a0357d12d41b4f43888917bd45dd766328e SHA512 bee1e12625995a0264694796ec6f346a5258ec13c24517939e65eaf9b679d82afb7848c02e6222389609bdf3a0dccbce4af1bd59a5d12f2851da47878a21b210
 DIST gitdb-4.0.5-r1.gitbundle 1499071 BLAKE2B e429014def18d645b7117b27f592ead9c518076eeee2f6cc42c4a231f9a4f61c8275ccb1def5d042d44f34863528570163e9e154bb1536a0917b10f135e2462c SHA512 6fcf345af9f72afa39f4ba931bf474b2596678f1b790e3d4e1e3f7420baafbad04689bcdee9e99407f7c2b1c6f0d36fcf524b408ceb37b95dc4980e9423b1ad7
 DIST smmap-3.0.4.gitbundle 276552 BLAKE2B 2d17b927b2c644d2f1984168ee99fe5a9a58392401ac0b2894a1d5e5f9c292f32311a7a5d7669bd93c642ff791f4801d61ef3236c1dafa1434e99a17fd8751f6 SHA512 6deb282c6ece3b556c59c458b5242ff362b903441db63c005a0ab1ac055b3f974f9b34f30e0a4a41ef9246696e08b191254f72db61a8f24d4eb2f0e48a08937b
diff --git a/dev-python/importlib_metadata/Manifest b/dev-python/importlib_metadata/Manifest
index d1e4024dd488..54902782b600 100644
--- a/dev-python/importlib_metadata/Manifest
+++ b/dev-python/importlib_metadata/Manifest
@@ -2,3 +2,4 @@ DIST importlib_metadata-3.10.1.tar.gz 39980 BLAKE2B 9e7ba25618c9a530d122e43d6d56
 DIST importlib_metadata-3.7.3.tar.gz 37193 BLAKE2B 0de5f4ece99db9ec4f86e9b967c8583d06a5bda939a7bdb137dba3c6a9d7fd034802d9fa0eb5bf209ae5ada89ebd0f3120557d3fa2b300739ebff2ff1bb6edb8 SHA512 1d6ee80edb3e5efb56deb0676ef42ba72fdaf124504023954cb3b1192e5378c3370a35b5e77708f3d9a19c02f0d89a1ba08a919a7aaec5e284f54c2eb3c61fc1
 DIST importlib_metadata-3.8.2.tar.gz 38973 BLAKE2B 40b001870608003a9beaa513e5f7dad0217884719a78a64dd74bad3db275ac30bc226d57f61aa644fcd0425bc69e06ce66555aa92132e89d36ecd5519c7d32d9 SHA512 c4ca5055c759b588b42708a9ca903d4cda91614385cc39016c5126e37e1f3bd0faafe7ec0cf6d58553ac71c1a028f0f74d0ba3d66135e97d75b051ea4f71cbeb
 DIST importlib_metadata-4.0.0.tar.gz 41881 BLAKE2B cd0330e2a5959f651ef6ceee722762c3cbb034a534dab6c24523ca76d25dde4cb2c6bb06cef7e787db9a9cd83ca08a71bfd7b849db57ef4a95e461e6d887b14e SHA512 bbdf7b3f1e714c5a02babe0f9ff5eb366942e21b626d1d61839ee04040d0ed529cd299afd446639795b34665be20e6438d8e9970292b282946a8b6495682f726
+DIST importlib_metadata-4.0.1.tar.gz 42189 BLAKE2B ed0fda0a2218efc75ce4fd614c8d69767042f035d026b28348d7909b7d6a520e6c1a6f1edb8a00f5e0c0e0e9f818d65e97ad590471d2398a5fb21f4efbdad600 SHA512 972e2f4bcd6433f603f0c6e23f4dbf4269993a47a5a8f66740e0143df63568ea8ca4ed6aa84587dcf967c6c4ba93e5d5ead9ac9444db9bc6424bd8c238f8335e
diff --git a/dev-python/importlib_metadata/importlib_metadata-4.0.1.ebuild b/dev-python/importlib_metadata/importlib_metadata-4.0.1.ebuild
new file mode 100644
index 000000000000..79245facc8ba
--- /dev/null
+++ b/dev-python/importlib_metadata/importlib_metadata-4.0.1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# NB: this package extends beyond built-in importlib stuff in py3.8+
+# new entry_point API not yet included in cpython release
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Read metadata from Python packages"
+HOMEPAGE="https://github.com/python/importlib_metadata"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS=""
+
+RDEPEND="
+	$(python_gen_cond_dep 'dev-python/typing-extensions[${PYTHON_USEDEP}]' python3_{6,7})
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pyfakefs[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/importlib_resources[${PYTHON_USEDEP}]
+		' pypy3 python3_{7,8})
+	)
+"
+
+distutils_enable_sphinx docs dev-python/jaraco-packaging dev-python/rst-linker
+distutils_enable_tests unittest
+
+python_prepare_all() {
+	# Skip a test that requires pep517 which is not in the tree
+	sed -e 's:test_find_local:_&:' -i tests/test_integration.py || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/nltk/Manifest b/dev-python/nltk/Manifest
index 917e6461ad39..bd72396ac03a 100644
--- a/dev-python/nltk/Manifest
+++ b/dev-python/nltk/Manifest
@@ -1,2 +1,3 @@
 DIST nltk-3.5.tar.gz 2805844 BLAKE2B d2494d831cf5503ac938b203e405ebae606166dbb907655113d3a5267bd54f03b6d8d5ac9e545fefd0b7855ce0c985064c9e746e402c540e19546e2d11ec151e SHA512 056ae219af607c158f1f2adc6fb9b4f402721778c13bf5ebc178deaf631142ad3e571d8b1fd96145067833cbeac4db25fc07c3fd032188c2d8ee7e5d7bd824f6
 DIST nltk-3.6.1.tar.gz 2820223 BLAKE2B 74ae44376e8f59e4ccfd4bdb5d6f535a8480733a2fdc6a8f1117a551f64d9f6404ca237bd27cd4a4a9d32443d38179c7a1c824e00e808868d45e468ab84eb1bd SHA512 ab0e8abc938fa0bfadc3f02dc583749775a6c06d2d2ee30692ccd9c118277fd79cfed02f858d4347dacbe87f146cb8f9af1203a8d68685f131da5f6b127b86cb
+DIST nltk-3.6.2.tar.gz 2819833 BLAKE2B 9796822c35c524432e9790d0890b4388fbaa85b659e5415037422a22e8edbaf20775196b4416f441d62592b387066de9f7741b988c0d463349fc5c906bfd75b2 SHA512 3fd2cba52377613f35f6574f859482de987f969cfc8d4243a859be365ab1bd8300f9013dcedc6caeff7aa7fc035b331a47b557027209ca9a85b0cc7fbde44d6d
diff --git a/dev-python/nltk/nltk-3.6.2.ebuild b/dev-python/nltk/nltk-3.6.2.ebuild
new file mode 100644
index 000000000000..84fcd25fe7c2
--- /dev/null
+++ b/dev-python/nltk/nltk-3.6.2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="sqlite,tk?,xml(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Natural Language Toolkit"
+HOMEPAGE="https://www.nltk.org/ https://github.com/nltk/nltk/"
+SRC_URI="https://github.com/nltk/nltk/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
+IUSE="tk"
+
+RDEPEND="
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/joblib[${PYTHON_USEDEP}]
+	dev-python/regex[${PYTHON_USEDEP}]
+	dev-python/tqdm[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/joblib[${PYTHON_USEDEP}]
+		>=dev-python/nltk-data-20200312-r1
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pyparsing[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/twython[${PYTHON_USEDEP}]
+		sci-libs/scikit-learn[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	)"
+PDEPEND="dev-python/nltk-data"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# requires unpackaged pycrfsuite
+	sed -i -e '/>>>/s@$@ # doctest: +SKIP@' nltk/tag/crf.py || die
+	# replace fetching from network with duplicate file URL
+	sed -e 's@https://raw.githubusercontent.com/nltk/nltk/develop/nltk/test/toy.cfg@nltk:grammars/sample_grammars/toy.cfg@' \
+		-i nltk/test/data.doctest || die
+	# requires X and hangs in Xvfb
+	sed -e 's:test_plot:_&:' \
+		-i nltk/test/unit/test_cfd_mutation.py || die
+
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	cd nltk/test || die
+	distutils-r1_src_test
+}
diff --git a/dev-python/reportlab/metadata.xml b/dev-python/reportlab/metadata.xml
index 4ca4f82820ba..94cb04f73484 100644
--- a/dev-python/reportlab/metadata.xml
+++ b/dev-python/reportlab/metadata.xml
@@ -5,8 +5,36 @@
   <email>python@gentoo.org</email>
   <name>Python</name>
  </maintainer>
+ <longdescription lang="en">
+    ReportLab is the time-proven, ultra-robust open-source engine for creating
+    complex, data-driven PDF documents and custom vector graphics. It's free,
+    open-source, and written in Python. The package sees 50,000+ downloads per
+    month, is part of standard Linux distributions, is embedded in many
+    products, and was selected to power the print/export feature for Wikipedia.
+
+    The ReportLab Toolkit has evolved over the years in direct response to the
+    real-world reporting needs of large institutions. The library implements
+    three main layers:
+
+        A graphics canvas API that 'draws' PDF pages A charts and widgets
+        library for creating reusable data graphics. A page layout engine -
+        PLATYPUS ("Page Layout and TYPography Using Scripts") - which builds
+        documents from elements such as headlines, paragraphs, fonts, tables
+        and vector graphics.
+
+    The open-source ReportLab Toolkit provides the core of our commercial
+    product, ReportLab PLUS, which generates PDF at higher speed and allows use
+    of our smart XML-based templating language RML. ReportLab PLUS contains
+    significant upgrades over the open-source library that allows for a much
+    faster development cycle. If you are putting substantial time into
+    building a solution please consider the commercial version; it is faster,
+    does more, and the revenues directly support ongoing development. You
+    can trial ReportLab PLUS for free.
+  </longdescription>
  <upstream>
   <remote-id type="pypi">reportlab</remote-id>
+  <bugs-to>mailto:reportlab-users@lists2.reportlab.com</bugs-to>
+  <doc lang="en">https://www.reportlab.com/dev/docs</doc>
  </upstream>
  <origin>gentoo-staging</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/sqlalchemy/Manifest b/dev-python/sqlalchemy/Manifest
index 35cf421c62ba..f5ae39bcf931 100644
--- a/dev-python/sqlalchemy/Manifest
+++ b/dev-python/sqlalchemy/Manifest
@@ -1,5 +1,6 @@
 DIST SQLAlchemy-1.3.23.tar.gz 6313652 BLAKE2B e87f67ee7ee70036b94e1708c1a59f58b1f8abad23aa26c74e2a9a2172bee5a6411b2be95bff0f1c6e39d3a0de0839adc6b43f4cde597a18d4cf930e4c37b11e SHA512 dcd1a0878fd58ee49691bb7e8a2571cb40cc942380a4fe0e66d3abb1723830f178e7b3944c5c2d69bd3aaff04cd2ca171bbabbe34f59f54bcf4b9ee2782f9570
 DIST SQLAlchemy-1.3.24.tar.gz 6353598 BLAKE2B 6eb92b20fa3412a1f1398e18e902e3338320973287afa4a37477ec28d47e7422a19c3a60e6290a6da7b23512c0d818a26400958d02097def778c917f098bb3db SHA512 4f5f0a23e80e1cebe541f8748a7e794e8964d986252803b3289a7cea732ad22557e00221775332e2766b6ff16ad5d9069223f441f8880ca6d0c47011f15fee5b
+DIST SQLAlchemy-1.4.10.tar.gz 7549562 BLAKE2B 042fcb35c84f7aaa7d58d8617089366feb214b7234ec251fa778c656e70a47bfe5881d520e681447b8acffa98a755cbf9e6227b2b96c97e068112615aeb9609d SHA512 aa2b737a4bb418050ab81aca7154aee956cf8d207a9fcc8db8138b08e4bd3d4b88ef9f84eef2c9f72238a788c83c3f69823e96e4befa615a309b63550eef03de
 DIST SQLAlchemy-1.4.2.tar.gz 7464092 BLAKE2B dd4cf617a66ed4eba54e41ebaead189409e09e434bdfe8e6f71e2fd4bd9ea574acef8feb42290a3fe80f602d2de2160b075633449b0b543e44b44f0fc7c867bc SHA512 b436576d6c72d0ec285b926f5741b6bdba14fa959248be1c4bdcc8b87dfc512653e48fb2d356ab85d0e90a374c48de5311f43f4f3ce6cb64876e1316c6169423
 DIST SQLAlchemy-1.4.5.tar.gz 7502502 BLAKE2B d3b07bdf65a31e124d705c22de9ec9d57f5324f61b5ee2e5df13dbcf9e02154983179f87da06bcdc2e19b08375a51a500faa72a67ed7415a51ea266623f70a1b SHA512 1b7e709b0a2c1adaa536c247d411e67abf41b6346fd2592af15d063b7cc52811091890470c2cb553cf8e07e4e1ce31ea46afc82a1266e7e737be4f9bd52bb9f0
 DIST SQLAlchemy-1.4.6.tar.gz 7519545 BLAKE2B ba7c9abc716dc20f5342d1f133d1a1959dff8c804268440215e9181f58cac3d2bae3052c76abf3de2551330af5946cd7f8427acaca9d73ae068444db8cc22c5b SHA512 09914c9cce75f7d973fc55bd79099c8998da343ff727eb1ab5ab3ad23555a7d8386709f9e431c7ad2eadb938dac1d79839073ee554d81bfea4128f77e73dc20a
diff --git a/dev-python/sqlalchemy/sqlalchemy-1.4.10.ebuild b/dev-python/sqlalchemy/sqlalchemy-1.4.10.ebuild
new file mode 100644
index 000000000000..aa99618e929b
--- /dev/null
+++ b/dev-python/sqlalchemy/sqlalchemy-1.4.10.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+PYTHON_REQ_USE="sqlite?"
+
+inherit distutils-r1 multiprocessing optfeature
+
+MY_PN="SQLAlchemy"
+MY_P="${MY_PN}-${PV/_beta/b}"
+
+DESCRIPTION="Python SQL toolkit and Object Relational Mapper"
+HOMEPAGE="https://www.sqlalchemy.org/ https://pypi.org/project/SQLAlchemy/"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="examples +sqlite test"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/importlib_metadata[${PYTHON_USEDEP}]
+	' python3_7 pypy3)
+"
+# Use pytest-xdist to speed up tests
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# remove optional/partial dep on greenlet, greenlet is not very portable
+	sed -i -e '/greenlet/d' setup.cfg || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# Disable tests hardcoding function call counts specific to Python versions.
+	epytest --ignore test/aaa_profiling \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "MySQL support" dev-python/mysqlclient dev-python/pymysql \
+		dev-python/mysql-connector-python
+	optfeature "mssql support" dev-python/pymssql
+	optfeature "postgresql support" dev-python/psycopg:2
+}
diff --git a/dev-python/virtualenv/Manifest b/dev-python/virtualenv/Manifest
index 10c11a908207..3eb2c66ddb40 100644
--- a/dev-python/virtualenv/Manifest
+++ b/dev-python/virtualenv/Manifest
@@ -1,2 +1,3 @@
 DIST virtualenv-16.7.10.tar.gz 5116776 BLAKE2B 42f0a4b4330850b504f8febd991ef6ecdcbb0821efdd94ca324a8cc34a68a760a8a98de97f0cb2384d8e6cbb0ce8f261995c6433886444e29b75ba0ce09ca12c SHA512 f06d7c354ce1910f04dbcbe1a77e60392653bbe4f638bafbe9284454db2c0e5d63cf9159201d0916fc01aaba91d45fb733b63096c38517fcd83fd00ed8b26d28
 DIST virtualenv-20.4.3.tar.gz 10579193 BLAKE2B 02102579eb72b7e4ea8fa182b3c7ef5d8b9d95992b5f73b0f24737522dfae988a91953c49df5aa17541f3f0b1c54557ece7feba173a9cce3bb65964bddbd6edb SHA512 d79479d73fc87f34462e775629306bd20ff5d25eb1829c6719f08c800df6a5db03254b04773766a703d903d577cf74b8409a026196ba98d0f5f94f70604ed576
+DIST virtualenv-20.4.4.tar.gz 10579531 BLAKE2B 9e10c07bd191d745d6904f304787a3913c0c574bb4453549796052f27329cbc2e3700fbc6f40ff02f4e94b8f1c21458c8fbd706b05ae458c033722d3eaf04f2e SHA512 acc528cccfc80aeed2fcd7209cab7ff0f1a7d1dc01a59fdb6a07703c7905904ab68d3f4ff312e108c687d03495e82ed8d26ecc15c2b17b9e771605a46164b4bd
diff --git a/dev-python/virtualenv/virtualenv-20.4.4.ebuild b/dev-python/virtualenv/virtualenv-20.4.4.ebuild
new file mode 100644
index 000000000000..ee2a5ae36ba5
--- /dev/null
+++ b/dev-python/virtualenv/virtualenv-20.4.4.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+DISTUTILS_USE_SETUPTOOLS=manual
+
+inherit distutils-r1
+
+DESCRIPTION="Virtual Python Environment builder"
+HOMEPAGE="
+	https://virtualenv.pypa.io/en/stable/
+	https://pypi.org/project/virtualenv/
+	https://github.com/pypa/virtualenv/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/appdirs-1.4.3[${PYTHON_USEDEP}]
+	>=dev-python/distlib-0.3.1[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-41[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-0.12[${PYTHON_USEDEP}]
+	' python3_{6,7} pypy3)
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_resources-1.0[${PYTHON_USEDEP}]
+	' python3_6 pypy3)"
+# coverage is used somehow magically in virtualenv, maybe it actually
+# tests something useful
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/coverage[${PYTHON_USEDEP}]
+			dev-python/flaky[${PYTHON_USEDEP}]
+			>=dev-python/pip-20.0.2[${PYTHON_USEDEP}]
+			>=dev-python/pytest-freezegun-0.4.1[${PYTHON_USEDEP}]
+			>=dev-python/pytest-mock-2.0.0[${PYTHON_USEDEP}]
+			>=dev-python/pytest-timeout-1.3.4[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+			>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+		' 'python3*')
+	)"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme \
+	dev-python/towncrier
+distutils_enable_tests pytest
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local deselect=(
+		tests/unit/activation/test_xonsh.py
+		tests/unit/seed/embed/test_bootstrap_link_via_app_data.py::test_seed_link_via_app_data
+		tests/unit/create/test_creator.py::test_cross_major
+	)
+	[[ ${EPYTHON} == pypy3 ]] && deselect+=(
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-pypy3-posix-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-pypy3-posix-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-pypy3-posix-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-pypy3-posix-copies-global]'
+		'tests/unit/create/test_creator.py::test_zip_importer_can_import_setuptools'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.9-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.9--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.10-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.10--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.9-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.9--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.10-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.10--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3--bin-]'
+	)
+
+	distutils_install_for_testing
+	epytest ${deselect[@]/#/--deselect }
+}
+
+pkg_postinst() {
+	elog "Please note that while virtualenv package no longer supports"
+	elog "Python 2.7, you can still create py2.7 virtualenvs via:"
+	elog "  $ virtualenv -p 2.7 ..."
+}