Adding metadata

23 files changed, 380 insertions, 72 deletions

diff --git a/dev-python/asgiref/asgiref-3.3.4.ebuild b/dev-python/asgiref/asgiref-3.3.4.ebuild
index 7229d1d336b0..feea5298bf37 100644
--- a/dev-python/asgiref/asgiref-3.3.4.ebuild
+++ b/dev-python/asgiref/asgiref-3.3.4.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
 inherit distutils-r1
 
 DESCRIPTION="ASGI utilities (successor to WSGI)"
@@ -20,7 +20,7 @@ KEYWORDS="amd64 arm arm64 ~ppc ~ppc64 ~sparc x86"
 RDEPEND="
 	$(python_gen_cond_dep '
 		dev-python/typing-extensions[${PYTHON_USEDEP}]
-	' python3_7)"
+	' python3_7 pypy3)"
 BDEPEND="
 	test? ( dev-python/pytest-asyncio[${PYTHON_USEDEP}] )"
 
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 587f9859e691..a5f7dabeabca 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -6,3 +6,4 @@ DIST boto3-1.17.67.tar.gz 368242 BLAKE2B 72e612816c45d49c74430d82f4ede59f6b6e7c1
 DIST boto3-1.17.68.tar.gz 368708 BLAKE2B 4ed78bae6e8c9ee6e8f1a5a4009f89b1c5efac1ddfa8189a6ec76f1ba47b8113dd479ed935e1d6f4631fcd1e40659398a5189bab77b15e1efe5acf706871b90f SHA512 c8a4a78da518530b3e47c1f3e37f51a61070f9b626b29ee4b1a990bfb2dfce49332add6674a0ec8b156c50e922736a500f2b265cf9ba286000aca55a272a7257
 DIST boto3-1.17.69.tar.gz 369006 BLAKE2B 6ad2e9ccb71872c5936f63b786b4b7addd5ff6ff9ccc9b8a65361006ae77861175692fd8a7d4075cf170f92aac4c0f3072a598a99191356909cd95122c34d3ba SHA512 7dfe8ceb621a63ac3e2c2d0852d8ba380200cd91f9f548109c8c5f6b0704a5c56acb645cdec6b7974bb30402a5832d001f5cc9e8d30f940560a06f88407c5385
 DIST boto3-1.17.70.tar.gz 369851 BLAKE2B 31416aed68f340842962dca12f77e169f87f2f2a63fa5189c298678d0672f1edf349e0884856624faa971dd2e1c248e320c92dc8189fc63612cce24680971e5c SHA512 fa0bbcdc9027f09007780f75d3a41aef7656c934bc10f710f5787fd7cd7a7124475437e62e7d507e24f773668102a75c4b3b5cfffa5d2834f75fa930894ce227
+DIST boto3-1.17.71.tar.gz 370105 BLAKE2B d0ea164459e7f79f5d9124af1917eb1a6ef9743792cd13daf58f8c70c852e537392ae8e3fb7ddaf5cea75e914ebb44c205f865f1b896827322b0be8500dc4a4f SHA512 b934ee87fbbced5a6c180517eb2b304b0d097dabc7f9831ebd4945d1b69919e3701955d92b4cfa5cd00da42f32fce731b70dfb3f69b5583eba0a032b4ef3505d
diff --git a/dev-python/boto3/boto3-1.17.71.ebuild b/dev-python/boto3/boto3-1.17.71.ebuild
new file mode 100644
index 000000000000..2df16964cdb0
--- /dev/null
+++ b/dev-python/boto3/boto3-1.17.71.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_SETUPTOOLS=bdepend
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# prevent an infinite loop
+	rm tests/functional/docs/test_smoke.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests -v tests/unit/ tests/functional/ || die "test failed under ${EPYTHON}"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 4457861ca1e7..6c3387e4f238 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -6,3 +6,4 @@ DIST botocore-1.20.67.tar.gz 7691087 BLAKE2B b56cb7e80179b7c5c2b4daa27907870c075
 DIST botocore-1.20.68.tar.gz 7692876 BLAKE2B a5de44db992688a7ceff14e2663e21f370811871d87286215d04db9d0ba9649c67c047b6ec290967eddcdc8cc6fd12bbe9c99589fea183ec2b2036dc69f4d7e6 SHA512 f3de8f5cb621174dc0ed1b8c8d4cbbc3cee56f0b0f4363767cfc68a879fc6e837225e82538640736687efa4340d62ff3d1923abc315f914b0a9189f775c65b6b
 DIST botocore-1.20.69.tar.gz 7695769 BLAKE2B 994e5415c278a0c021deb1749c59ee5c654c7212cc2a1961fb2c528b7f5aea0a4d3f70c88a72489410cda935c8498cb3c4b1ec4830b3150ee043eb3429174781 SHA512 dbb0e77484a545489b54a1f71c78d2cf7d95b7f3a4f4ec54a9c07d7af354e9037d6eaa3100cf6a8e89d778bb0ed19f9475d68dceee98666bd69a4b05662c5939
 DIST botocore-1.20.70.tar.gz 7700136 BLAKE2B ab7ea88763dd4637754a5d9eb955e0947efd9c5fa87856276056d6eaac341f57d5edd43ca830dd35c1283c6f41de43be2f9b06e8f328a8900cde41ec5953bf9d SHA512 d992b88df31a77b153fd3110119d1523587e98d56e4b80ac14d0c5351d76b3e4c188295fbbeafcd8efd3f414a1c0af0d78f21555b2d3285d6f8e88eefab282dc
+DIST botocore-1.20.71.tar.gz 7720081 BLAKE2B 4f5d4f237222a034d2102cb637722c7d63ac34549ca582fce8d7b02a93345cc48067b195f339010a0dd47fa04a53ee4dde5f98eb58a1db3b0d4c958066717063 SHA512 7a9154efeeedc90dd9089641798494095cca9f1967e3615131af154e718081e2ce85e37fea1a729e7d7cd42d2fd6a9f79cae9409ff32aa18674a40a0e2fd0fe1
diff --git a/dev-python/botocore/botocore-1.20.71.ebuild b/dev-python/botocore/botocore-1.20.71.ebuild
new file mode 100644
index 000000000000..9d681f87244c
--- /dev/null
+++ b/dev-python/botocore/botocore-1.20.71.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+	# very unstable
+	sed -i -e 's:test_stress_test_token_bucket:_&:' \
+		tests/functional/retries/test_bucket.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# note: suites need to be run separately as one of the unit tests
+	# seems to be leaking mocks and breaking a few functional tests
+	nosetests -v tests/unit ||
+		die "unit tests failed under ${EPYTHON}"
+	nosetests -v tests/functional ||
+		die "functional tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/click/Manifest b/dev-python/click/Manifest
index a1e3db9c7a82..d87af49097bb 100644
--- a/dev-python/click/Manifest
+++ b/dev-python/click/Manifest
@@ -1 +1,2 @@
 DIST click-7.1.2.tar.gz 295757 BLAKE2B aea76d5378cfa49fe58a83132737d609d48b3d3a71ec65c0a8a144c7a0e244b5bdf0196ffe2150889b82edda20c3f1faa3c84a227fc9ef459a5a9646cff86129 SHA512 d0caf2fb0a258774a18a7b8f83bdfa73abeb70196a70b45a6cc35befaeb862d068d2f2cce4e27201ab2e3adcd02e7e2f099d6c37c497a507010eefa10ad16eba
+DIST click-8.0.0.tar.gz 329520 BLAKE2B a3a5e299390c8223794c31fd0278367ed941923f81e73e2b4ac878ef670b156de9de4b8d539e1d0a968b8ff99764086b34ebf50d3afe3afa7060aeafc7ed8831 SHA512 656509d4eb49ce46738d09499a924a6064857d13995c0ec289b9a731c05165582c30fd4a8a09d0531ace77c217a9d4ba3f305ba2843c7879d90c84a78072046d
diff --git a/dev-python/click/click-8.0.0.ebuild b/dev-python/click/click-8.0.0.ebuild
new file mode 100644
index 000000000000..d984ba107cde
--- /dev/null
+++ b/dev-python/click/click-8.0.0.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A Python package for creating beautiful command line interfaces"
+SRC_URI="https://github.com/pallets/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+HOMEPAGE="https://palletsprojects.com/p/click/ https://pypi.org/project/click/"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="examples"
+
+distutils_enable_sphinx docs \
+	'>=dev-python/docutils-0.14' \
+	dev-python/pallets-sphinx-themes
+distutils_enable_tests pytest
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/flask/Manifest b/dev-python/flask/Manifest
index e9ecc229b2f4..58d0f76cca23 100644
--- a/dev-python/flask/Manifest
+++ b/dev-python/flask/Manifest
@@ -1 +1,2 @@
 DIST Flask-1.1.2.tar.gz 637516 BLAKE2B 90dffbb8faa48489d1c71ff2a064d41e97d2103c07532fd5b252dbe0b32e4babb815e31f0ceae201a66cead645b68149d13d4bb39a0df1b27b4002e613920493 SHA512 9feb6a9a8f34fadbea508d465f73c24b1d81b3f66243804dc3904d198c2fd78e2e1bef94df6a4940a7eec6b9b54abea06557a87de8b27b0a9497d18b3e071384
+DIST Flask-2.0.0.tar.gz 624458 BLAKE2B 82f552cbe714ea4fd64b56f88ee747c292659181139eae5fe0e496457d1f33cb5d7b464ed5250b6087c859691d89cb72a885d8640855dd9dfe7ecc6083bb0c36 SHA512 3fc66aa1568f7dce67bb70b0113401b7535dda32e33ac784a42f08fa21e08b055214218fac06dc6fb4b8f975b2a91321a6c97203f6568efc6bfbbb8d4ef9ddc3
diff --git a/dev-python/flask/flask-2.0.0.ebuild b/dev-python/flask/flask-2.0.0.ebuild
new file mode 100644
index 000000000000..91392ecab1a3
--- /dev/null
+++ b/dev-python/flask/flask-2.0.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
+HOMEPAGE="https://github.com/pallets/flask/"
+MY_PN="Flask"
+MY_P="${MY_PN}-${PV}"
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/mitsuhiko/flask.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/asgiref-3.2[${PYTHON_USEDEP}]
+	>=dev-python/click-7.1.2[${PYTHON_USEDEP}]
+	dev-python/blinker[${PYTHON_USEDEP}]
+	>=dev-python/itsdangerous-2.0[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-2.0[${PYTHON_USEDEP}]"
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -p no:httpbin
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/itsdangerous/Manifest b/dev-python/itsdangerous/Manifest
index 7ed710feb2f2..8dcac31d3e5d 100644
--- a/dev-python/itsdangerous/Manifest
+++ b/dev-python/itsdangerous/Manifest
@@ -1 +1,2 @@
 DIST itsdangerous-1.1.0.tar.gz 53219 BLAKE2B 6ad74dacb9728e77d57ac5e364e79e3cc749be206fa03e82a407cdd77b5b72ddb4861bf181772915e684539e6404c6a45f6081c7c8e17a33a2d532b4fc3fed80 SHA512 61bab3fce5f87a3b5fc8fad61e735a63df6aa039416ee3494e1c99a2a1162b4fb72793bc5dc949de0985724c40121810b159513606c4c3976a7666dba3a1b93d
+DIST itsdangerous-2.0.0.tar.gz 59128 BLAKE2B 0d7eda7e38a3c87a87d1e6fb8522bf7b95354168ac0db6fb1c621f7961c4f0b8382e382d03829a4c18949baf533b9b67904569783990f94fbd3384570cfebf87 SHA512 cc838aff218ff9b119b8f4b4d09b83204990880abdd25e4c33e83f98d521601f272c245d8ac4aa6efde8bf4d443318d7400fb1a0ea8debbd9641ab65de9d47ba
diff --git a/dev-python/itsdangerous/itsdangerous-2.0.0.ebuild b/dev-python/itsdangerous/itsdangerous-2.0.0.ebuild
new file mode 100644
index 000000000000..d7113fac7973
--- /dev/null
+++ b/dev-python/itsdangerous/itsdangerous-2.0.0.ebuild
@@ -0,0 +1,21 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Various helpers to pass trusted data to untrusted environments and back"
+HOMEPAGE="https://pythonhosted.org/itsdangerous/ https://pypi.org/project/itsdangerous/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+
+BDEPEND="
+	test? ( dev-python/freezegun[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
diff --git a/dev-python/jinja/Manifest b/dev-python/jinja/Manifest
index 20f7ddca27b7..01547bef62c9 100644
--- a/dev-python/jinja/Manifest
+++ b/dev-python/jinja/Manifest
@@ -1 +1,2 @@
 DIST jinja-2.11.3.tar.gz 258057 BLAKE2B 4735464d044718ce1e6b2663ecb1b238b38fbf0f37ed683257775fe9e853186c089b98494209e511be5aa96bf6df8f6d472be132b6184a7d9213e182099c0433 SHA512 f8e2951edf780d7b44ac74d36579c89b0a5c076b4250faf643ae7e3ff6a431fedaabed640e5efb496cda1a79a4057bf312ae652484c8d4631d521689eb0adbc1
+DIST jinja-3.0.0.tar.gz 271882 BLAKE2B 7013d74802534273c62db275d95f05f203af97f52fdf9f9be9ec89522e2fce2d4cd0dc00611ad1442680da9ec624dd4ca8be375f021bc9572ef736801fb4b0d0 SHA512 54841f5fc07349eb01002156fb148e8e5905574dcb6e0d51bef2f340c8b94f2b50964b94e09d888d8cd6aa834de3a495301bf2b3cdf3282bce1b04129ea6d69e
diff --git a/dev-python/jinja/jinja-3.0.0.ebuild b/dev-python/jinja/jinja-3.0.0.ebuild
new file mode 100644
index 000000000000..a14704798227
--- /dev/null
+++ b/dev-python/jinja/jinja-3.0.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="A full-featured template engine for Python"
+HOMEPAGE="https://jinja.palletsprojects.com/ https://pypi.org/project/Jinja2/"
+# pypi tarball is missing tests
+SRC_URI="https://github.com/pallets/jinja/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/markupsafe-2.0.0_rc2[${PYTHON_USEDEP}]
+	!dev-python/jinja:compat"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-issues \
+	dev-python/pallets-sphinx-themes
+distutils_enable_tests pytest
+
+# XXX: handle Babel better?
+
+src_prepare() {
+	# avoid unnecessary dep on extra sphinxcontrib modules
+	sed -i '/sphinxcontrib.log_cabinet/ d' docs/conf.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_install_all() {
+	if use examples ; then
+		docinto examples
+		dodoc -r examples/.
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	if ! has_version dev-python/Babel; then
+		elog "For i18n support, please emerge dev-python/Babel."
+	fi
+}
diff --git a/dev-python/markupsafe/Manifest b/dev-python/markupsafe/Manifest
index 7eb4cc83eba0..27007ba0c8a2 100644
--- a/dev-python/markupsafe/Manifest
+++ b/dev-python/markupsafe/Manifest
@@ -1 +1,2 @@
 DIST MarkupSafe-1.1.1.tar.gz 19151 BLAKE2B 184ab0bc42f8d254ef4239f700f019c0a380bdf2117dfe1abe2eb4dfa0f037158d181a120d8654a6971e9c8badb078f997e3a8bf231898e0f4bb3e8496d9abd3 SHA512 f3014e6131a3ab866914c5635b5397ef71906bffb1b6f8c5f2ed2acf167429ff7914236d38943e872683a57a9be9669f4c5aace6274f3307ab21ef25373db0b6
+DIST MarkupSafe-2.0.0.tar.gz 18466 BLAKE2B d065eda7f3f2e02abf2d1a9a20c2eb8ed774fa5153cf4c0584de859ac790a7c4dccc2304f7e920a2345877653ffd9be386bfe677e96bcf1cebb5ca6b87ef9d32 SHA512 260121db97178d5903645c9d1fd38c5d7c7a5bcd31a8def1d5a921328ff86ad025bf62d73734434a7920a00024ff8c0898352f7406713af51051e750b5df7cab
diff --git a/dev-python/markupsafe/markupsafe-2.0.0.ebuild b/dev-python/markupsafe/markupsafe-2.0.0.ebuild
new file mode 100644
index 000000000000..7658d42ca0d4
--- /dev/null
+++ b/dev-python/markupsafe/markupsafe-2.0.0.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+MY_PN="MarkupSafe"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Implements a XML/HTML/XHTML Markup safe string for Python"
+HOMEPAGE="https://pypi.org/project/MarkupSafe/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris"
+
+distutils_enable_tests pytest
diff --git a/dev-python/pydantic/Manifest b/dev-python/pydantic/Manifest
index 20bf88990f29..724cfb12a76e 100644
--- a/dev-python/pydantic/Manifest
+++ b/dev-python/pydantic/Manifest
@@ -1 +1,2 @@
 DIST pydantic-1.8.1.tar.gz 300512 BLAKE2B a7840bd895c73c3049184fc2c4a165783fd68a82290c3826be53667e7b7919580493aff9f2aaa25274b0251da14218dd6f7a41c1cb3cb55f0fbb0c90f79b7833 SHA512 dc58ab2e411744e63408c952c92c589acf037e809c60b85e02f277af2c6342c99c4fbfa7a585f14e57256912c0e6471821973bd2f755aac3822eb3a7883fd407
+DIST pydantic-1.8.2.tar.gz 301802 BLAKE2B f02fca273c356dd0ab177de73d21da7749e1a9ea1ead92f4e82b44285b97e8b8431961b2c30d230cbec817698791e4b0cdf8498615b7a0639fa739b09f1b58e8 SHA512 0a28c64b97678b932092e546da877a4a6d104fc7d3b7cb043b3494f0b7c6900cdc1ab8a83bdbd1879956a81da1b28ca27578b1a003bdca3e08f0f107e5690e06
diff --git a/dev-python/pydantic/pydantic-1.8.2.ebuild b/dev-python/pydantic/pydantic-1.8.2.ebuild
new file mode 100644
index 000000000000..b6d23b4c69a0
--- /dev/null
+++ b/dev-python/pydantic/pydantic-1.8.2.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Data parsing and validation using Python type hints"
+HOMEPAGE="https://github.com/samuelcolvin/pydantic"
+# No tests on PyPI: https://github.com/samuelcolvin/pydantic/pull/1976
+SRC_URI="https://github.com/samuelcolvin/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/python-email-validator[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# seriously?
+	sed -i -e '/CFLAGS/d' setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# TODO
+	epytest --deselect tests/test_hypothesis_plugin.py
+}
diff --git a/dev-python/service_identity/service_identity-21.1.0.ebuild b/dev-python/service_identity/service_identity-21.1.0.ebuild
index c768f9249916..5a8df4438a1d 100644
--- a/dev-python/service_identity/service_identity-21.1.0.ebuild
+++ b/dev-python/service_identity/service_identity-21.1.0.ebuild
@@ -24,5 +24,4 @@ RDEPEND="
 	>=dev-python/attrs-19.1.0[${PYTHON_USEDEP}]
 	dev-python/six[${PYTHON_USEDEP}]"
 
-distutils_enable_sphinx docs
 distutils_enable_tests pytest
diff --git a/dev-python/sympy/Manifest b/dev-python/sympy/Manifest
index cecb7a28ce28..eae3e3ac1e7c 100644
--- a/dev-python/sympy/Manifest
+++ b/dev-python/sympy/Manifest
@@ -1,2 +1 @@
-DIST sympy-1.7.1.tar.gz 6974183 BLAKE2B 4bd8c9d60c46b05a7fc6c622667858fe17d25798756dbe967ce19abc8047263fe540f332e39418e877852c0565270377bd01fea7e65aa35ed4e03079bc130805 SHA512 eb9387bb9c632203af650279f896427556725b7496c00d8dfe97b7476beedbbee5714659f7fb44b4fa986c9567cdcaefcc19401d63e1ca0e9a6c7317855440ea
 DIST sympy-1.8.tar.gz 7167842 BLAKE2B 878c6daf0584c9da54f82b9c68c62715792db428ab4ebfb355f0368c52edb254947d1ce1919e651279b767295ecb00a76b8cbbaa1fbe9c97915221c7403c3ded SHA512 61141e1d0a6105e725fb415edbdf981b3aa95debcfe73f9da5ca36afc7a70e91b5c28ed45454054c1b9a8d45e42bfe724e5b20da717746c301fd095da17f4db7
diff --git a/dev-python/sympy/sympy-1.7.1-r1.ebuild b/dev-python/sympy/sympy-1.7.1-r1.ebuild
deleted file mode 100644
index 89d7e207c626..000000000000
--- a/dev-python/sympy/sympy-1.7.1-r1.ebuild
+++ /dev/null
@@ -1,66 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-DISTUTILS_USE_SETUPTOOLS=rdepend
-PYTHON_COMPAT=( python3_{6,7,8,9,10} )
-
-inherit distutils-r1 virtualx
-
-DESCRIPTION="Computer Algebra System in pure Python"
-HOMEPAGE="https://www.sympy.org/"
-SRC_URI="https://github.com/sympy/sympy/archive/${P}.tar.gz"
-S="${WORKDIR}/${PN}-${P}"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
-IUSE="examples imaging ipython latex mathml opengl pdf png pyglet symengine test texmacs theano"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-RESTRICT="!test? ( test )"
-
-BDEPEND="test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
-RDEPEND="dev-python/mpmath[${PYTHON_USEDEP}]
-	dev-python/pexpect[${PYTHON_USEDEP}]
-	imaging? ( dev-python/pillow[${PYTHON_USEDEP}] )
-	ipython? ( dev-python/ipython[${PYTHON_USEDEP}] )
-	latex? (
-		virtual/latex-base
-		dev-texlive/texlive-fontsextra
-		png? ( app-text/dvipng )
-		pdf? ( app-text/ghostscript-gpl )
-	)
-	mathml? ( dev-libs/libxml2:2[${PYTHON_USEDEP}] )
-	opengl? ( dev-python/pyopengl[${PYTHON_USEDEP}] )
-	pyglet? ( dev-python/pyglet[${PYTHON_USEDEP}] )
-	symengine? ( dev-python/symengine[${PYTHON_USEDEP}] )
-	texmacs? ( app-office/texmacs )
-	theano? ( || ( dev-python/theano-pymc[${PYTHON_USEDEP}] dev-python/theano[${PYTHON_USEDEP}] ) )
-"
-
-src_test() {
-	virtx distutils-r1_src_test
-}
-
-python_test() {
-	"${EPYTHON}" setup.py test || die "Tests failed with ${EPYTHON}"
-}
-
-python_install_all() {
-	local DOCS=( AUTHORS README.md )
-
-	if use examples; then
-		dodoc -r examples
-		docompress -x /usr/share/doc/${PF}/examples
-	fi
-
-	distutils-r1_python_install_all
-
-	if use texmacs; then
-		exeinto /usr/libexec/TeXmacs/bin/
-		doexe data/TeXmacs/bin/tm_sympy
-		insinto /usr/share/TeXmacs/plugins/sympy/
-		doins -r data/TeXmacs/progs
-	fi
-}
diff --git a/dev-python/watchdog/watchdog-2.1.1.ebuild b/dev-python/watchdog/watchdog-2.1.1.ebuild
index 5a39e688ce26..e615d585bbc8 100644
--- a/dev-python/watchdog/watchdog-2.1.1.ebuild
+++ b/dev-python/watchdog/watchdog-2.1.1.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
 inherit distutils-r1 optfeature
 
 DESCRIPTION="Python API and shell utilities to monitor file system events"
@@ -30,7 +30,12 @@ src_prepare() {
 }
 
 python_test() {
-	epytest -p no:django
+	local deselect=()
+	[[ ${EPYTHON} == pypy3 ]] && deselect+=(
+		tests/test_inotify_buffer.py::test_move_internal_batch
+	)
+
+	epytest -p no:django ${deselect[@]/#/--deselect }
 }
 
 pkg_postinst() {
diff --git a/dev-python/werkzeug/Manifest b/dev-python/werkzeug/Manifest
index 27e0e72d79b1..05e039bb981e 100644
--- a/dev-python/werkzeug/Manifest
+++ b/dev-python/werkzeug/Manifest
@@ -1 +1,2 @@
 DIST werkzeug-1.0.1.gh.tar.gz 907482 BLAKE2B d2dcdce8b1bcbb177b52b0915f2c0ac17d235dee3c77b23e81e4b35412d1f53a194d3c7c7f2a5c065ade99797effe72cc464cf6980b12c761a8a919338021660 SHA512 ba82120fb3e96e3a1334c6452d5ba1950fc016d2d147d643bbc2168ccec496f1dea799982ae8c578167155082c0bdbda5d56a23f64b4b6865f97e90e22df022e
+DIST werkzeug-2.0.0.gh.tar.gz 894475 BLAKE2B 608de444944fa0bd35c0244a30967446abb8f0d05a8cd49f09707c368b6f9649b299f427fa7bc2e54628cf3eb688c399e420ecd54f12d7eab9cb063c7c740b07 SHA512 8c8e36a58fe53ac4ad3152a34145c726a9145782262b9d47be7bfe9a8e127666b0d0c0c50d305277a153298644732efe37e3785ceaa5b11394adfeb70d86e70d
diff --git a/dev-python/werkzeug/werkzeug-2.0.0.ebuild b/dev-python/werkzeug/werkzeug-2.0.0.ebuild
new file mode 100644
index 000000000000..4c7e3ca861f3
--- /dev/null
+++ b/dev-python/werkzeug/werkzeug-2.0.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of various utilities for WSGI applications"
+HOMEPAGE="
+	https://werkzeug.palletsprojects.com/
+	https://pypi.org/project/Werkzeug/
+	https://github.com/pallets/werkzeug"
+SRC_URI="
+	https://github.com/pallets/werkzeug/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
+
+DEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		!hppa? ( !ia64? (
+			$(python_gen_cond_dep '
+				dev-python/greenlet[${PYTHON_USEDEP}]
+			' 'python*')
+		) )
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/pytest-xprocess[${PYTHON_USEDEP}]
+		dev-python/watchdog[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -p no:httpbin tests
+}