Adding metadata

17 files changed, 490 insertions, 4 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 6999118add2e..099fa77d7d7b 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -9,3 +9,4 @@ DIST boto3-1.18.5.tar.gz 394930 BLAKE2B a7f58699a4a27c85f00f47eb34d861509446d159
 DIST boto3-1.18.6.tar.gz 394941 BLAKE2B c7ef6f85fea5a12c248afd03cbe5cca2475c32de0d5b90e8390837e4e1980390e07bc99b6dd1e1831c34135503fe5859e0a837e0aff88f7af2bd8ddcad804a1d SHA512 01cdc6e71b8cd04da7e6f2bf9268625824c12b53fc7322343ae635d5fdd6ed30170fb698d7c4a788b4095fbfc186ef72a11fb6f785a1006fe7861d2db6108da9
 DIST boto3-1.18.7.tar.gz 395640 BLAKE2B 6a9fa1dd55644806fe93271805f35fbe0c4cb65d1de08dded2d2f57fcefa96e32c4ebe7b60743c52c0898222bc06d33dbd03d304bbef327b88022450a7943e2c SHA512 20e7fedab7d061ab02f391e9baf36cb554e7f194f38d24d5a75f76715b2acf1b51b6adce5d8cf5a2a0d29df73566db00b8813a219d45a194d9a8eb93d0dab570
 DIST boto3-1.18.8.tar.gz 397295 BLAKE2B 34e4e9dbaf53d7e9917b26f62385a012663147bcebe3a3989f3e306ed1bad8fc90c47ecd0901e127ad024f67d6891e3eb2b2f59e179ca45fe88b5cca6968bbef SHA512 59ea0cb50058fde12f748b394b9ba7053755c642d6124343a6fe00d8c7918f123b508441006c5a9ebc6319d4318f7f95c481cca47d692349c4591958c38d53c7
+DIST boto3-1.18.9.tar.gz 397452 BLAKE2B 1a600eb067baebb59141f1e8cb15442d7fa338430534099df84b8b71f6fd90a56aa5ead0c38ba317018897861f996ce38cf995233778ad57e3be82e82870173b SHA512 12d2b8a1baa9993be322b770a13a8895718bd25c6d4a51bdef39413368c9ba62fdc93e4f517d3556e5d6a26e860b21f1bdd1ee6b0f49c83082973ee716d3017c
diff --git a/dev-python/boto3/boto3-1.18.9.ebuild b/dev-python/boto3/boto3-1.18.9.ebuild
new file mode 100644
index 000000000000..bee358e1c595
--- /dev/null
+++ b/dev-python/boto3/boto3-1.18.9.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# prevent an infinite loop
+	rm tests/functional/docs/test_smoke.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests -v tests/unit/ tests/functional/ ||
+		die "test failed under ${EPYTHON}"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 8924afb62cb7..83bd255e0611 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -9,3 +9,4 @@ DIST botocore-1.21.5.tar.gz 7968981 BLAKE2B cea2c648e5f8d6f99bd1f11f430511abdc41
 DIST botocore-1.21.6.tar.gz 7974218 BLAKE2B f3391b620a21d04712e1254c4e8ffc090956bc1e0a41278be2c0e02a659ada639af2cc4e94bf607492164a8425988c16e8b899726fe645871b1cf6d1f98ef04d SHA512 1a74f2450a1c57a61c704550c0f08fd518b8d4fc463acdd8622ca8bf7fa51293c52c54999e1a1d563815cb0fd35585072753d623739a6738367b0bae94f655b7
 DIST botocore-1.21.7.tar.gz 7977343 BLAKE2B 19c5bf5de40ab131585e30bb85486fcffc3428808811b312b33578174ce31a691f4f4d955462120f05d2aad2cd5e5772789704eee641760fb67099aa3cddc9b5 SHA512 db1bb36faa6857a1cc717e5d591954415bb948178ee2be90ab9c32c11b1fb45c5b5aff87dfacd907c2f11bc7cdd2cd4de2ee9c847fa8cda4e5f0814a828b1019
 DIST botocore-1.21.8.tar.gz 7996323 BLAKE2B a0c21ec64fd97f011d2e986806b0a47f5f5941f13b7a17fe84f4886a98e91629c641b9e39c2040105ebe4102d8a9c84ebaffbb6a0bf9ef8c48be80804863d441 SHA512 178914d04d1abfaed5fc7e5225e3da54706608d8075298e3b1d7ca4ef09fdef11ee4eb4b7e2f5eb60ab1527b2dcd0c46bbd6b987903be8959ea16e775ca9b548
+DIST botocore-1.21.9.tar.gz 7999524 BLAKE2B 23852915e20610691bc95a24023b2a06002215bfec1a74bdddaf11f0490ef58dccaad70428126c19928e437b1694a0146145257a6aa500ab690e10490a6e857e SHA512 2053d208e9b41139781fb4a8296c169ddea525998480a2dc524a615d9f7119909ad640acbd2d14ce02e2e3218d3faa954b3b92985f34a6fcb46ad6cdba787277
diff --git a/dev-python/botocore/botocore-1.21.9.ebuild b/dev-python/botocore/botocore-1.21.9.ebuild
new file mode 100644
index 000000000000..5684261bd4b3
--- /dev/null
+++ b/dev-python/botocore/botocore-1.21.9.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+	# very unstable
+	sed -i -e 's:test_stress_test_token_bucket:_&:' \
+		tests/functional/retries/test_bucket.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# note: suites need to be run separately as one of the unit tests
+	# seems to be leaking mocks and breaking a few functional tests
+	nosetests -v tests/unit ||
+		die "unit tests failed under ${EPYTHON}"
+	nosetests -v tests/functional ||
+		die "functional tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/importlib_resources/Manifest b/dev-python/importlib_resources/Manifest
index 365a5340202b..88d1250b2c33 100644
--- a/dev-python/importlib_resources/Manifest
+++ b/dev-python/importlib_resources/Manifest
@@ -1,2 +1,3 @@
 DIST importlib_resources-5.1.4.tar.gz 28783 BLAKE2B e88cbe34dfd9b251fc78f2aba173f3eb657462777cb66454fbc1735575c6cac6a868f5e40206fb8925aa8c7f708d72624693cd772f2335231bc5da4f417d622e SHA512 ede757b0ee4a246a3446a165f4c8e56edf326f90464f01d853b6c04042371ff1edc4e41f388c6ea6973302a183cf1c04ee21335342886747c991ba0b38c7aec3
 DIST importlib_resources-5.2.0.tar.gz 29655 BLAKE2B 570e92750351a72c95653302baee56dadc28a328a8e42af9d3346be9a256c2d43322d75622f78d87b5642ed9503c9b7f1df0b0223414847619efb2ebd5e27f5f SHA512 248de71aec8aae93f14b0c48381e7de4425f1eb0c014a4f4a49859db50e8b0a94c2e1c0a664086c74ac7fe19e526b8e3f4fc82d19d3d722df6625dc0dc708c90
+DIST importlib_resources-5.2.1.tar.gz 29622 BLAKE2B 3ac095355534c1ea35e65d685e36ea715555dbda686e1312851b0ea5ce079053429812da5ba57b00bf02981786037de2c5e91a4bc0eedf03c8463f184180c10b SHA512 e0534c6e0e1cfe8621710e58f43b0ec3e5a6fd9e1eafa58ffa09f9120e05a416b69b45639f3028f7d4d02831429bc5de3cbfa97e141474d268d6c32a5f14c1bd
diff --git a/dev-python/importlib_resources/importlib_resources-5.2.1.ebuild b/dev-python/importlib_resources/importlib_resources-5.2.1.ebuild
new file mode 100644
index 000000000000..3122ce294d47
--- /dev/null
+++ b/dev-python/importlib_resources/importlib_resources-5.2.1.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# This is a backport of Python 3.9's importlib.resources
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Read resources from Python packages"
+HOMEPAGE="https://github.com/python/importlib_resources"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/zipp-3.1.0[${PYTHON_USEDEP}]
+	' pypy3)
+"
+BDEPEND="
+	dev-python/toml[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-3.4.1[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+distutils_enable_sphinx docs dev-python/rst-linker dev-python/jaraco-packaging
diff --git a/dev-python/pylint/Manifest b/dev-python/pylint/Manifest
index 3d1653ded47d..3ab1c52bfe64 100644
--- a/dev-python/pylint/Manifest
+++ b/dev-python/pylint/Manifest
@@ -4,3 +4,4 @@ DIST pylint-2.9.1.gh.tar.gz 769124 BLAKE2B feabb520c22722df73471e87e05f22f0fb937
 DIST pylint-2.9.3.gh.tar.gz 770364 BLAKE2B 3892286ffbd79b417c6decba44bce97f45192299ac8e2ec0e24770b2dd6cf1c28bac790626a478d47a6124ec0470ea9fc0d4230c5a1e807532852844445bb95a SHA512 45c037b970b66254b54a4810a5609dc098b5493d409826333e6a75f9ff0fc02921162711d88c45fd2f437e6521f639c33b25b714830a977c501612ee497501bb
 DIST pylint-2.9.4.gh.tar.gz 777252 BLAKE2B 84bc535b3c471be5d01a02ee67494d993cc257f0938e1bb0e35b1d64415d256c4f0dabd45cdc3319716c67e5e71ea935b63633f56b97013bd8616296343709d5 SHA512 9b5db20cf2d858e662c309b11cf28bf247b7c5f90de4f747733a0288ff4acced02e0e6b83145e7d940772eb9debf297b9ee6976e0f3ffbd73aaacaa3f4cb51e6
 DIST pylint-2.9.5.gh.tar.gz 778090 BLAKE2B cbcf5427665f56cc37afd08fb537fcc3f17697ca7cdbd7da97bad4093f344c9b961a156f5d141e070fa84c7e07293175a70585a8c996c9cffb7cef80717752af SHA512 84695bae88704391752f4b0944e39f5b44933fee8d88a8839729845b93bbe59876da08ab98645217c4ff2a98fd793a92063123b25a595fb332ce0a3943bcf7e7
+DIST pylint-2.9.6.gh.tar.gz 779390 BLAKE2B b1d8794e1e7ccdde87919eb943f83287c0a7b85b67f3722cbbe68887f2c61ab30b354548e25b70c661234647e35f79beb6aaad5f6be6bfde8c2475cf03676922 SHA512 a23ff089853398df2e4232767ca87c21e4ab4fc6805de80db796c78c56e0da1ade9b0586f5c14a98524bf607e0d240c354cf63287eec7dfdce263188eb19ddce
diff --git a/dev-python/pylint/pylint-2.9.6.ebuild b/dev-python/pylint/pylint-2.9.6.ebuild
new file mode 100644
index 000000000000..3007ff106485
--- /dev/null
+++ b/dev-python/pylint/pylint-2.9.6.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python code static checker"
+HOMEPAGE="https://www.logilab.org/project/pylint
+	https://pypi.org/project/pylint/
+	https://github.com/pycqa/pylint/"
+SRC_URI="
+	https://github.com/pycqa/pylint/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="examples"
+
+RDEPEND="
+	<dev-python/astroid-2.7[${PYTHON_USEDEP}]
+	>=dev-python/astroid-2.6.5[${PYTHON_USEDEP}]
+	>=dev-python/isort-4.2.5[${PYTHON_USEDEP}]
+	<dev-python/isort-6[${PYTHON_USEDEP}]
+	>=dev-python/mccabe-0.6[${PYTHON_USEDEP}]
+	<dev-python/mccabe-0.7[${PYTHON_USEDEP}]
+	>=dev-python/toml-0.7.1[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.4.4-sphinx-theme.patch"
+)
+
+distutils_enable_sphinx doc --no-autodoc
+distutils_enable_tests pytest
+
+python_test() {
+	local skipped_tests=(
+		# No need to run the benchmarks
+		tests/benchmark/test_baseline_benchmarks.py
+	)
+	# Specify the test directory explicitly to avoid import file mismatches
+	epytest tests ${skipped_tests[@]/#/--deselect }
+}
+
+python_install_all() {
+	if use examples ; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/pyotherside/pyotherside-1.5.9.ebuild b/dev-python/pyotherside/pyotherside-1.5.9.ebuild
index 8d7426cd3b0d..a7bf1043868d 100644
--- a/dev-python/pyotherside/pyotherside-1.5.9.ebuild
+++ b/dev-python/pyotherside/pyotherside-1.5.9.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 PYTHON_COMPAT=( python3_{6,7,8,9,10} )
 
diff --git a/dev-python/python-dotenv/python-dotenv-0.18.0-r1.ebuild b/dev-python/python-dotenv/python-dotenv-0.18.0-r1.ebuild
index 473373c28073..165707d97a6b 100644
--- a/dev-python/python-dotenv/python-dotenv-0.18.0-r1.ebuild
+++ b/dev-python/python-dotenv/python-dotenv-0.18.0-r1.ebuild
@@ -12,7 +12,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+KEYWORDS="amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc x86"
 
 DEPEND="
 	test? (
diff --git a/dev-python/sh/sh-1.14.2.ebuild b/dev-python/sh/sh-1.14.2.ebuild
index 3e074861e4db..38a72a217723 100644
--- a/dev-python/sh/sh-1.14.2.ebuild
+++ b/dev-python/sh/sh-1.14.2.ebuild
@@ -13,7 +13,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 ~arm arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+KEYWORDS="amd64 ~arm arm64 ~ppc ~ppc64 ~sparc x86 ~amd64-linux ~x86-linux"
 
 PATCHES=(
 	"${FILESDIR}/sh-1.12.14-skip-unreliable-test.patch"
diff --git a/dev-python/twisted/Manifest b/dev-python/twisted/Manifest
index 2c0ee46f9bf9..0ed1eeac5fba 100644
--- a/dev-python/twisted/Manifest
+++ b/dev-python/twisted/Manifest
@@ -1,4 +1,5 @@
 DIST Twisted-19.10.0.tar.bz2 3118485 BLAKE2B a0d532b67177aa017e463bf823d7842d4f6ff694f78cd7600865718ffe861023a53ea6a922f7de232133edba26f5255074d7ef277ce8f3bdf02d556ccf4abf41 SHA512 de8d7fd0b2081cebeff68b060c8469377011648bc563a94a993d3530fb007ed42c3a54925c9a10c465ee7a3065cc9108ace12d10d358223fab13494becb9ac4b
 DIST Twisted-20.3.0.tar.bz2 3127793 BLAKE2B 2e85fc3ec26d89e563c9e79a5d2adea81ff1745d18f0f92b8d45ae3729fbddf09998664257880372c7a4caeb5977c5cad7c863596b8c27ad7890275cead9f763 SHA512 1b850e5fc21a3630ead4c2cc3622c16e78bb3be38ab11d021779b7ce3d3c30acc4e19d79c7791a5fce6c5c6e09c2baa349901dffe952de67dd98eec419846365
 DIST twisted-21.2.0.tar.gz 3882978 BLAKE2B ba37572b0f9eadf2962a2730e4c2c0ed65f582b11b3350034660a2c53c5cd0892b19867d19e0201d4808c09fca621dbe540d153dc6c7d5827d45d2423d19d28b SHA512 fa743dcf22f3c17dfd17f39b7df0cc31fb8ce3e989478ada9a026424ec2de35e6a403ef35acdef5905eed008d42e3c2fee6b7ccdda433e6c250f1feaa83ea8a4
+DIST twisted-21.7.0.tar.gz 3895345 BLAKE2B 510165ad2933f07005e508df5a8bdf2863a7988c0f18fcc089e948d190c65aab32fc876d3120e311e91d6989f1ea2d8b3b5f5db4a9dfc63c38da56213f718728 SHA512 a946769a6bc6c72af26e7763b9e0675788f134b4d005ea89d935da1b1d5f60d92c84fdb2615e442e7da2b98291ee8a63d5236ec7ba72ef04ad3f847b092feecb
 DIST twisted-regen-cache.gz 911 BLAKE2B ffd3fcda6c67ffe6fd3ef581c8d507548396b66ed0708e9a5c790095e579c0d5f0f71596acf05712989da2ddef2b8d437eca973bc4d80ef8a9fa852915f38305 SHA512 95a9b931c73017d16d1b5e6b41345dddffe62b6af1a8e93b5e40d06d3d15be17b0dd0181c767ffeeb791534d463764ef9e066fa6c2ee2ac4b53c86d1da8fce03
diff --git a/dev-python/twisted/files/twisted-21.7.0-force-gtk3.patch b/dev-python/twisted/files/twisted-21.7.0-force-gtk3.patch
new file mode 100644
index 000000000000..a2e40559ec59
--- /dev/null
+++ b/dev-python/twisted/files/twisted-21.7.0-force-gtk3.patch
@@ -0,0 +1,67 @@
+From eec6b60116e12e015387fe1fa3a729553d3848bf Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
+Date: Sat, 22 May 2021 01:11:48 +0200
+Subject: [PATCH] Force using GTK+3 in twisted.internet.gireactor
+
+Modify twisted.internet.gireactor to explicitly request GTK+ version 3.
+Otherwise it uses the newest version installed which could be GTK+4
+that gireactor is currently incompatible with.
+---
+ src/twisted/internet/gireactor.py           | 3 +++
+ src/twisted/internet/test/test_gireactor.py | 3 +++
+ src/twisted/newsfragments/10200.bugfix      | 1 +
+ 3 files changed, 7 insertions(+)
+ create mode 100644 src/twisted/newsfragments/10200.bugfix
+
+diff --git a/src/twisted/internet/gireactor.py b/src/twisted/internet/gireactor.py
+index 92596db1d..a577825a8 100644
+--- a/src/twisted/internet/gireactor.py
++++ b/src/twisted/internet/gireactor.py
+@@ -24,6 +24,7 @@ On Python 3, pygobject v3.4 or later is required.
+ from twisted.internet.error import ReactorAlreadyRunning
+ from twisted.internet import _glibbase
+ from twisted.python import runtime
++import gi  # type: ignore[import]
+ import gi.pygtkcompat  # type: ignore[import]
+ from gi.repository import GLib  # type: ignore[import]
+ 
+@@ -68,6 +69,7 @@ class GIReactor(_glibbase.GlibReactorBase):
+     def __init__(self, useGtk=False):
+         _gtk = None
+         if useGtk is True:
++            gi.require_version("Gtk", "3.0")
+             from gi.repository import Gtk as _gtk
+ 
+         _glibbase.GlibReactorBase.__init__(self, GLib, _gtk, useGtk=useGtk)
+@@ -112,6 +114,7 @@ class PortableGIReactor(_glibbase.PortableGlibReactorBase):
+     def __init__(self, useGtk=False):
+         _gtk = None
+         if useGtk is True:
++            gi.require_version("Gtk", "3.0")
+             from gi.repository import Gtk as _gtk
+ 
+         _glibbase.PortableGlibReactorBase.__init__(self, GLib, _gtk, useGtk=useGtk)
+diff --git a/src/twisted/internet/test/test_gireactor.py b/src/twisted/internet/test/test_gireactor.py
+index d15a92622..af5092a36 100644
+--- a/src/twisted/internet/test/test_gireactor.py
++++ b/src/twisted/internet/test/test_gireactor.py
+@@ -25,6 +25,9 @@ else:
+         gtk3reactor = None
+     else:
+         gtk3reactor = _gtk3reactor
++        import gi  # type: ignore[import]
++
++        gi.require_version("Gtk", "3.0")
+         from gi.repository import Gtk
+ 
+ from twisted.internet.error import ReactorAlreadyRunning
+diff --git a/src/twisted/newsfragments/10200.bugfix b/src/twisted/newsfragments/10200.bugfix
+new file mode 100644
+index 000000000..7afb343be
+--- /dev/null
++++ b/src/twisted/newsfragments/10200.bugfix
+@@ -0,0 +1 @@
++twisted.internet.gireactor was fixed to force GTK+3 in order to fix use of incompatible GTK+4 API when installed
+-- 
+2.32.0
+
diff --git a/dev-python/twisted/twisted-21.7.0.ebuild b/dev-python/twisted/twisted-21.7.0.ebuild
new file mode 100644
index 000000000000..73c1334f2243
--- /dev/null
+++ b/dev-python/twisted/twisted-21.7.0.ebuild
@@ -0,0 +1,172 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="An asynchronous networking framework written in Python"
+HOMEPAGE="https://www.twistedmatrix.com/trac/"
+SRC_URI="
+	https://github.com/twisted/twisted/archive/${P}.tar.gz
+	https://dev.gentoo.org/~mgorny/dist/twisted-regen-cache.gz"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="conch crypt http2 serial test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/automat-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
+	>=dev-python/hyperlink-17.1.1[${PYTHON_USEDEP}]
+	>=dev-python/incremental-21.3.0[${PYTHON_USEDEP}]
+	>=dev-python/pyhamcrest-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-3.6.5[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-4.4.2[${PYTHON_USEDEP}]
+	conch? (
+		>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+		dev-python/bcrypt[${PYTHON_USEDEP}]
+		>=dev-python/cryptography-1.5.0[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+	)
+	crypt? (
+		>=dev-python/pyopenssl-16.0.0[${PYTHON_USEDEP}]
+		dev-python/service_identity[${PYTHON_USEDEP}]
+		>=dev-python/idna-0.6[${PYTHON_USEDEP}]
+	)
+	serial? ( >=dev-python/pyserial-3.0[${PYTHON_USEDEP}] )
+	http2? (
+		>=dev-python/hyper-h2-3.0.0[${PYTHON_USEDEP}]
+		<dev-python/hyper-h2-4.0.0[${PYTHON_USEDEP}]
+		>=dev-python/priority-1.1.0[${PYTHON_USEDEP}]
+		<dev-python/priority-2.0[${PYTHON_USEDEP}]
+	)
+	!dev-python/twisted-core
+	!dev-python/twisted-conch
+	!dev-python/twisted-lore
+	!dev-python/twisted-mail
+	!dev-python/twisted-names
+	!dev-python/twisted-news
+	!dev-python/twisted-pair
+	!dev-python/twisted-runner
+	!dev-python/twisted-words
+	!dev-python/twisted-web
+"
+BDEPEND="
+	>=dev-python/incremental-21.3.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+		dev-python/bcrypt[${PYTHON_USEDEP}]
+		>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
+		>=dev-python/cryptography-0.9.1[${PYTHON_USEDEP}]
+		dev-python/cython-test-exception-raiser[${PYTHON_USEDEP}]
+		dev-python/gmpy[${PYTHON_USEDEP}]
+		dev-python/idna[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
+		dev-python/pyserial[${PYTHON_USEDEP}]
+		dev-python/service_identity[${PYTHON_USEDEP}]
+		net-misc/openssh
+	)
+"
+
+PATCHES=(
+	# https://twistedmatrix.com/trac/ticket/10200
+	"${FILESDIR}/${P}-force-gtk3.patch"
+)
+
+python_prepare_all() {
+	# upstream test for making releases; not very useful and requires
+	# sphinx (including on py2)
+	rm src/twisted/python/test/test_release.py || die
+
+	# puts system in EMFILE state, then the exception handler may fail
+	# trying to open more files due to some gi magic
+	sed -e '/SKIP_EMFILE/s:False:True:' \
+		-i src/twisted/internet/test/test_tcp.py || die
+
+	# multicast tests fail within network-sandbox
+	sed -e 's:test_joinLeave:_&:' \
+		-e 's:test_loopback:_&:' \
+		-e 's:test_multiListen:_&:' \
+		-e 's:test_multicast:_&:' \
+		-i src/twisted/test/test_udp.py || die
+
+	# accesses /dev/net/tun
+	sed -e '/class RealDeviceTestsMixin/a\
+    skip = "Requires extra permissions"' \
+		-i src/twisted/pair/test/test_tuntap.py || die
+
+	# These tests rely on warnings which seems work unreliably between python versions
+	sed -e 's:test_currentEUID:_&:' \
+		-e 's:test_currentUID:_&:' -i src/twisted/python/test/test_util.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	# TODO: upstream seems to override our build paths
+	distutils_install_for_testing
+
+	"${EPYTHON}" -m twisted.trial twisted ||
+		die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	cd "${D}$(python_get_sitedir)" || die
+
+	# own the dropin.cache so we don't leave orphans
+	touch twisted/plugins/dropin.cache || die
+
+	python_doscript "${WORKDIR}"/twisted-regen-cache
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newconfd "${FILESDIR}/twistd.conf" twistd
+	newinitd "${FILESDIR}/twistd.init" twistd
+}
+
+python_postinst() {
+	twisted-regen-cache || die
+}
+
+pkg_postinst() {
+	python_foreach_impl python_postinst
+
+	einfo "Install complete"
+	if use test ; then
+		einfo ""
+		einfo "Some tests have been disabled during testing due to"
+		einfo "known incompatibilities with the emerge sandboxes and/or"
+		einfo "not runnable as the root user."
+		einfo "For a complete test suite run on the code."
+		einfo "Run the tests as a normal user for each python it is installed to."
+		einfo "  ie:  $ python3.6 /usr/bin/trial twisted"
+	fi
+}
+
+python_postrm() {
+	rm -f "${ROOT}$(python_get_sitedir)/twisted/plugins/dropin.cache" || die
+}
+
+pkg_postrm() {
+	# if we're removing the last version, remove the cache file
+	if [[ ! ${REPLACING_VERSIONS} ]]; then
+		python_foreach_impl python_postrm
+	fi
+}
diff --git a/dev-python/uvicorn/uvicorn-0.14.0-r1.ebuild b/dev-python/uvicorn/uvicorn-0.14.0-r1.ebuild
index 86439af43d20..9d3ca01d3dca 100644
--- a/dev-python/uvicorn/uvicorn-0.14.0-r1.ebuild
+++ b/dev-python/uvicorn/uvicorn-0.14.0-r1.ebuild
@@ -12,7 +12,7 @@ SRC_URI="https://github.com/encode/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+KEYWORDS="amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc x86"
 
 RDEPEND="
 	>=dev-python/asgiref-3.3.4[${PYTHON_USEDEP}]
diff --git a/dev-python/zeroconf/Manifest b/dev-python/zeroconf/Manifest
index 2cbd9afd6e35..eb2cf6a288e0 100644
--- a/dev-python/zeroconf/Manifest
+++ b/dev-python/zeroconf/Manifest
@@ -2,3 +2,4 @@ DIST python-zeroconf-0.30.0.gh.tar.gz 64301 BLAKE2B ea0d5e36f3f012f217cbd4eeff0a
 DIST python-zeroconf-0.32.0.gh.tar.gz 115276 BLAKE2B 7084c02f989ebc6db6686b82ce3212158595b87e00567e4857e84790a30a2fa6f688288769d1eb118da485a6755da1ef404765070d26905d10ab45b1d95ca849 SHA512 6a612b39be85e673cffc560ea5bcc16facc5a16a370ff6edb1d4f7ff978a01d6ba249a9b313caca3b3ed0c6463a4914a98063eb89f28268cec1c9a2faa4db611
 DIST python-zeroconf-0.32.1.gh.tar.gz 116507 BLAKE2B 03de415620745b75cd43be74b724faf909aad9628175f18cf4b2c04245d02adbca984eaa861e807729f36caa3feecab913f2e4aafcdd9aac1af02de6eeefbb3d SHA512 cefcd1abdc3ca2b5ed796aee09e6826c0d0f54343bdefbf45c425d6e033542dc061c84fb4438ba53774d87c6516801c6e2196c1e6cfdd9dbf9187f5d8d4b1b11
 DIST python-zeroconf-0.33.0.gh.tar.gz 118002 BLAKE2B e5bdf8011777f46207c7f0aafbf4bfc34e704b59e01fcecd93e2ca05154f836bbe206688242eb37578a0e3b6d462de86944bdc81b96b0f3613eed21e9d0b6be0 SHA512 214fc1b25e1b900b6745f808144c0a1d94102dbc30f1e6ae49dfbfe2e75e9611e33d1341d192641be363662a0259aa340f52fe20fcf2bd5cf1611e823754186d
+DIST python-zeroconf-0.33.2.gh.tar.gz 118266 BLAKE2B e239443c778d24895a830ac8d4f23be5eeac701b92ddf945efc955a731cbce62bea10243f57a0929ad21c4444d32c37b0a9e23b53e734362b9c6b9ce85e2eb59 SHA512 9631dc348baf028794934d826a1fd2e874cf9039e6fb1c93a1b9a8e2a95ae436ab2fc1a955e2d89656c37a56b71075b578857f6de041a7e61ff55c7a62a2a7a3
diff --git a/dev-python/zeroconf/zeroconf-0.33.2.ebuild b/dev-python/zeroconf/zeroconf-0.33.2.ebuild
new file mode 100644
index 000000000000..c406eead3ace
--- /dev/null
+++ b/dev-python/zeroconf/zeroconf-0.33.2.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+MY_P=python-zeroconf-${PV}
+DESCRIPTION="Pure Python Multicast DNS Service Discovery Library (Bonjour/Avahi compatible)"
+HOMEPAGE="
+	https://github.com/jstasiak/python-zeroconf/
+	https://pypi.org/project/zeroconf/"
+SRC_URI="
+	https://github.com/jstasiak/python-zeroconf/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND=">=dev-python/ifaddr-0.1.7[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local excludes=(
+		# network
+		tests/test_core.py::Framework::test_close_multiple_times
+		tests/test_core.py::Framework::test_launch_and_close
+		tests/test_core.py::Framework::test_launch_and_close_context_manager
+		tests/test_core.py::Framework::test_launch_and_close_v4_v6
+		tests/test_core.py::Framework::test_launch_and_close_v6_only
+		tests/services/test_types.py::ServiceTypesQuery::test_integration_with_listener_ipv6
+	)
+
+	epytest ${excludes[@]/#/--deselect }
+}