Updating liguros repo

15 files changed, 360 insertions, 9 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 70f41002ee6c..8fa817fbc3ab 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -3,3 +3,4 @@ DIST boto3-1.14.59.tar.gz 334641 BLAKE2B 96cd0750521715f030c2668cf21b7d6e5f53ffb
 DIST boto3-1.14.63.tar.gz 334965 BLAKE2B 370a1d5bcc32ba6fd8f187fa56fbb3afa4aafa0692245efe024efdefb3d0a314b24873f641b3789430d6a64df70e55743a73760b8282ecaeb64116d9c27b82bc SHA512 668ec7a40d7be74268005d342b568e2d0efe0a3aafca7123c27e966fd89334dbdab04bca0a7ab216eae1f26f0506ef4ccacead49b1714a94a84c7a315e71e505
 DIST boto3-1.15.0.tar.gz 335099 BLAKE2B 0cdf8cc0007a90671d4d3c66482d834e24860990bf46634bf542e2e2a025a661d7a45d6be33932581e2697daf5829ca7f47021f863b4219cd3287650bb1ebaa4 SHA512 ed0ddbd4372d591062ef0ce102e6c913842c70921486b09ba1c2901a28d02cf0c41917e246a3654c43382254be32aa5242667199f8a0c2bb9293d7e2cc3827a5
 DIST boto3-1.15.1.tar.gz 335146 BLAKE2B d2d008dcb2059b120f142aaf588264122d1e84b450ab1fbc938627d1c8cc9bb60d1b80e68bc5e538376b56866156ca901abde747a8f973588b64b962284229c4 SHA512 46e1aabaa975b0215c2ece160b5e584468ba19699f87686c2787404d0a13274f763272cec577f830c6c71cb7f9e10b1c317a1348770f49283257d8cba65c5e3a
+DIST boto3-1.15.2.tar.gz 335231 BLAKE2B f1eb144da7afc1cf630cdc1f61880d094186a37d46556ae361da278fd3045a119dcb09c3d08387a019ca88d6502fa8710a5e5733cd9dc9056676ef17853d76e2 SHA512 6866e0d6a50d11495e5f2a33a392b0edbe1ff6625235b26b5d6028f7c2c7089d78febe17b982f65dc2564254800a23409247ac09716b099f09f3751c5b7f47b5
diff --git a/dev-python/boto3/boto3-1.15.2.ebuild b/dev-python/boto3/boto3-1.15.2.ebuild
new file mode 100644
index 000000000000..12584b2fba42
--- /dev/null
+++ b/dev-python/boto3/boto3-1.15.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+DISTUTILS_USE_SETUPTOOLS=bdepend
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# prevent an infinite loop
+	rm tests/functional/docs/test_smoke.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests -v tests/unit/ tests/functional/ || die "test failed under ${EPYTHON}"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 03e9cf7e1a70..28b8282e5412 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -3,3 +3,4 @@ DIST botocore-1.17.59.tar.gz 6829639 BLAKE2B efacd4c875e17f187abd5c4602a82229ed2
 DIST botocore-1.17.63.tar.gz 6841028 BLAKE2B 89b2d5d520e733deaf3c4b68faa103e4227107cebd3803d1cb6e47ec0df9f7a07d72eb24836a45762ead2ce1aa381d5b1dfcc33eb9a80c5f8d021c0dbfb631c3 SHA512 e4cf3fbb4c8a5c05dc8265b67fbba0bf03dcf12d28bcd0e1dd304392614d86f061a5115f8129eefa2fa44efab17a8720b7c39c082c2908bf4e29bbefb57e92fb
 DIST botocore-1.18.0.tar.gz 6838497 BLAKE2B efc0930b8ffafdf8d7f24d4f30cbf12e0dd81aa4ae405beee7663271fe8ffe680df91d40f8629b75635fae87ad29f0186e42f11e4bfebc64cc58979edd74e64b SHA512 43b5992d1ffb8d10f32f532c3085825e3775e3da4d6c25c2e300dfcd6e24967bdd318a7be37889a9d7802eb74bd9085b9642cda099b0064cbd9ffd65a56b7de5
 DIST botocore-1.18.1.tar.gz 6839699 BLAKE2B 188c5a05345fc7c4d4c05b3a8d9b675b5c2141326caa62f9ae8a5a996f6c7ff4e56c581fd010afbc4c57073d7b6efd22debad3e03456f6ad0453c7f823d6409e SHA512 63a9a7ac93a8774d7a1a511da0464d7b5d0841598c7358e97343406b4d76842ca56a0187ff173e0a29d9da9ee22f94fde66f4b8c3e9c8a3fbcabdaddbe95b752
+DIST botocore-1.18.2.tar.gz 6843154 BLAKE2B 77f4cbccd6a686cfbdb2f25fafb9f2210c0e23de72fb40403f905711ec5d073b92cfd003d39406d273feb0bfb90e2ab594f2bb9c1564b5b0879efdf3bcfa47e3 SHA512 f4fec4caf3b4ebca8a593d58827fb4377c2458b7ebccb53ccd830df5423a2021ecebd534d2fe276662f8d8e91078bb5adbf611a52baa29c8ab3526d9c7b975ac
diff --git a/dev-python/botocore/botocore-1.18.2.ebuild b/dev-python/botocore/botocore-1.18.2.ebuild
new file mode 100644
index 000000000000..12940d28a2af
--- /dev/null
+++ b/dev-python/botocore/botocore-1.18.2.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+	# very unstable
+	sed -i -e 's:test_stress_test_token_bucket:_&:' \
+		tests/functional/retries/test_bucket.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# note: suites need to be run separately as one of the unit tests
+	# seems to be leaking mocks and breaking a few functional tests
+	nosetests -v tests/unit ||
+		die "unit tests failed under ${EPYTHON}"
+	nosetests -v tests/functional ||
+		die "functional tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/cfn-python-lint/Manifest b/dev-python/cfn-python-lint/Manifest
index 956c1b331ef1..36ce423cbe8c 100644
--- a/dev-python/cfn-python-lint/Manifest
+++ b/dev-python/cfn-python-lint/Manifest
@@ -1,3 +1,4 @@
 DIST cfn-python-lint-0.30.1.tar.gz 4137425 BLAKE2B dd4f7d449236e567e7ea0fa662cbe983b6125a6cb557ee314de0e6647c5756b0be450deec7778ac69f1cec95b594c8c74a0a2f56ea229b7dc28ffb918983e6b3 SHA512 67b72973dc174e0de4980606b7886459233fca516a0587b91319127c4df0ce2647bbdc3302d68b63916654a76f4c9405c2f27cfd5e0ad737b00724e403815477
 DIST cfn-python-lint-0.35.1.tar.gz 4501826 BLAKE2B 84da0965fc198ce7b8f955a7d43f9a1c87c9688c301594abe6843509a832b4c9c5fadad1f75ac1c5b20ce2179244fd2b9681f5a92a1dbe38738a61c94f95982a SHA512 6d277048bbd7d8950ef7681c4a31cb82ccc231fb29f5083169caef69bfa4464cd87e473f40c775d798ff511a5db1dff9a17b0c08dcc800db0188e1e84990c9e4
 DIST cfn-python-lint-0.36.0.tar.gz 4879599 BLAKE2B a79a12290e20f4db1e45b29df0486d3b69f3c028f35cae8e8ba9ab5da191c1a5f7fed6bc339d24e3212faab7a05a82e859a79135847eb90b0161fe0aa7b8c995 SHA512 286c8e614ee083981105a74f09b4c75454ae6eef48812ac59852374bea5dfc0d111b006bb67c50e42fa2a1eeb54ce6f25b8bf0f06624da236344e9bbadf4ce1c
+DIST cfn-python-lint-0.36.1.tar.gz 4963743 BLAKE2B 31efc227bf2b5aafff0365d0ca949e4007684dd896e6e8a75afb692a260e05f6b134b9cc822855c99edec7398a1cdd767a71557ef7178ff9054c4e737a5a5ec5 SHA512 4682b7a010875df2322856e9a01aa547fcce171c5bb7531ee35d92bcf0cfc523f78b4180fcc6a6c4a1460d5b517e834ce0e0026fa6c2f6afb9ebf3b3c46434bd
diff --git a/dev-python/cfn-python-lint/cfn-python-lint-0.36.1.ebuild b/dev-python/cfn-python-lint/cfn-python-lint-0.36.1.ebuild
new file mode 100644
index 000000000000..17c526935121
--- /dev/null
+++ b/dev-python/cfn-python-lint/cfn-python-lint-0.36.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="CloudFormation Linter"
+HOMEPAGE="https://pypi.org/project/cfn-lint/ https://github.com/aws-cloudformation/cfn-python-lint"
+SRC_URI="https://github.com/aws-cloudformation/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/aws-sam-translator-1.25.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/importlib_resources[${PYTHON_USEDEP}]
+	' python3_6)
+	dev-python/jsonpatch[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]
+	dev-python/junit-xml[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.15.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.11[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/cfn-python-lint-0.30.1-tests.patch"
+)
+
+src_prepare() {
+	# unpin the deps
+	sed -e 's:~=[0-9.]*::' -i setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	distutils_install_for_testing
+	"${EPYTHON}" -m unittest discover -v ||
+		die "tests fail with ${EPYTHON}"
+}
diff --git a/dev-python/isort/isort-4.3.21_p2-r1.ebuild b/dev-python/isort/isort-4.3.21_p2-r1.ebuild
index 2b04e34cb702..566e1de2e279 100644
--- a/dev-python/isort/isort-4.3.21_p2-r1.ebuild
+++ b/dev-python/isort/isort-4.3.21_p2-r1.ebuild
@@ -20,10 +20,6 @@ KEYWORDS="~alpha amd64 arm arm64 ~ia64 ppc ppc64 sparc x86"
 
 RDEPEND="
 	dev-python/pipfile[${PYTHON_USEDEP}]
-	$(python_gen_cond_dep '
-		dev-python/backports-functools-lru-cache[${PYTHON_USEDEP}]
-		dev-python/futures[${PYTHON_USEDEP}]
-	' -2)
 "
 BDEPEND="${RDEPEND}"
 
@@ -32,3 +28,8 @@ PATCHES=(
 )
 
 distutils_enable_tests pytest
+
+python_test() {
+	distutils_install_for_testing
+	pytest -vv || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/nbconvert/Manifest b/dev-python/nbconvert/Manifest
index 5d1c166a0180..9f19f03c2d56 100644
--- a/dev-python/nbconvert/Manifest
+++ b/dev-python/nbconvert/Manifest
@@ -1,3 +1,4 @@
 DIST nbconvert-5.6.1.tar.gz 703233 BLAKE2B e75d558aee6c66fe8e7455ecf22dbbcd2a0698380ffec80eff15aea6c70bc853daa9ab2fd1d114453bd5dfe7e75617afb9f5c1075704bfadbb59fef34bca88a9 SHA512 0c68adcb9f28ead9ec058fc2e02a9a1e6f65818709c99f7a006a59a7562b5f5ee74afe5287e41568c35542898dc1b43c4543d2386cc05a721b3f99d5cc789435
 DIST nbconvert-6.0.3.tar.gz 848214 BLAKE2B 4265486536cfe0cf220b8080374726cc68be4f15033c8248806579b1ea1f759caa667ae11738acce1ecc812c65b954be1c21db0abe69db7bfdf67533ea052c3c SHA512 55e6fc1f136f8bc3b4b662011172ac3f61354ee1afa6904b5df34a382ae96f46e13f097f6067ca5e42d3fd0049f81a8a27d7b7faf605fa948e22d6067bc971ef
 DIST nbconvert-6.0.4.tar.gz 841651 BLAKE2B 080f60103709bd6ddb8258750a51e7bf8891adb1eb2921619cfbb0e774a585f3d3722758d8895f67a76e2705a15a0b35ffcb7c59842ec986a13315e5b10f4eca SHA512 46c2d250e25ad0e2fee0be0fefacc198687acd7ffcb4205bb8cf0ed263e90878cf659f352d551911b0025cb150302ea9ffd67b9453ec23fc5821908f7b56dd75
+DIST nbconvert-6.0.5.tar.gz 841650 BLAKE2B 7f8bb3849374284c90bd7b17c27a313c69694e42d4fd7b5913d3b210a15f17b89ffca8436ce31fa5bfc2b586feb536522106522f3d1741ad0fb6c2995a2e562e SHA512 79164546164eada6998bd6898833dfbada0a1476af8796bea40794f6caf121d0b9560f0f50e3d477357e977222a3b75f3de85ccfa03c4aec93be75801cf6f97c
diff --git a/dev-python/nbconvert/nbconvert-6.0.5.ebuild b/dev-python/nbconvert/nbconvert-6.0.5.ebuild
new file mode 100644
index 000000000000..cfce79b23cdc
--- /dev/null
+++ b/dev-python/nbconvert/nbconvert-6.0.5.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Converting Jupyter Notebooks"
+HOMEPAGE="https://nbconvert.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/bleach[${PYTHON_USEDEP}]
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	>=dev-python/entrypoints-0.2.2[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	dev-python/jupyterlab_pygments[${PYTHON_USEDEP}]
+	>=dev-python/mistune-0.7.4[${PYTHON_USEDEP}]
+	dev-python/nbclient[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	>=dev-python/pandocfilters-1.4.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.2.1[${PYTHON_USEDEP}]
+	dev-python/testpath[${PYTHON_USEDEP}]
+	www-servers/tornado[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pebble[${PYTHON_USEDEP}]
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		>=dev-python/jupyter_client-4.2[${PYTHON_USEDEP}]
+		media-gfx/inkscape
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	mkdir -p "${HOME}/.local" || die
+	cp -r share "${HOME}/.local/" || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	local deselect=(
+		# Missing pyppeteer for now
+		# TODO: Doesn't skip?
+		--deselect exporters/tests/test_webpdf.py
+		# Needs pyppeteer too
+		--deselect 'tests/test_nbconvertapp.py::TestNbConvertApp::test_webpdf_with_chromium'
+	)
+
+	distutils_install_for_testing bdist_egg
+	cd "${TEST_DIR}"/lib || die
+	pytest -vv "${deselect[@]}" --pyargs nbconvert || die "Tests failed with ${EPYTHON}"
+}
+
+pkg_postinst() {
+	if ! has_version app-text/pandoc ; then
+		einfo "Pandoc is required for converting to formats other than Python,"
+		einfo "HTML, and Markdown. If you need this functionality, install"
+		einfo "app-text/pandoc."
+	fi
+}
diff --git a/dev-python/pyh2o/Manifest b/dev-python/pyh2o/Manifest
new file mode 100644
index 000000000000..8f5b4245b529
--- /dev/null
+++ b/dev-python/pyh2o/Manifest
@@ -0,0 +1 @@
+DIST pyh2o-1.tar.gz 7327 BLAKE2B 9d6b308d17dd799e2c83a191c346a3d78fc0a097de2a2fd5cb6277a1525992aa18f6c6b61b2c2503ae4a9e7ddd3575e092aef77a0e84223a5a2c702c0a808f1d SHA512 529fa4d8e9c477346fcbd23d7172d41de96789797f0e1ad0557f4c0bdaea8a519a8e8735845d0080cf171182874ce0819e76357ca7c7db1d62a9544f907095db
diff --git a/dev-python/pyh2o/pyh2o-9999.ebuild b/dev-python/pyh2o/pyh2o-1.ebuild
index cb6ef354e3bf..e6d1189f1439 100644
--- a/dev-python/pyh2o/pyh2o-9999.ebuild
+++ b/dev-python/pyh2o/pyh2o-1.ebuild
@@ -2,19 +2,22 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
 PYTHON_COMPAT=( python3_{5,6,7,8,9} )
 
-inherit distutils-r1 git-r3
+inherit distutils-r1
 
 DESCRIPTION="Python API for sci-libs/libh2o"
 HOMEPAGE="https://github.com/mgorny/pyh2o/"
-SRC_URI=""
-EGIT_REPO_URI="https://github.com/mgorny/pyh2o.git"
+SRC_URI="
+	https://github.com/mgorny/pyh2o/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS=""
-IUSE=""
+KEYWORDS="~amd64 ~x86"
 
 RDEPEND=">=sci-libs/libh2o-0.2.1:="
 DEPEND="${RDEPEND}"
+
+distutils_enable_tests pytest
diff --git a/dev-python/sentry-sdk/Manifest b/dev-python/sentry-sdk/Manifest
index c49f15bd3882..1cef97c52695 100644
--- a/dev-python/sentry-sdk/Manifest
+++ b/dev-python/sentry-sdk/Manifest
@@ -1,2 +1,3 @@
 DIST sentry-sdk-0.16.3.tar.gz 170145 BLAKE2B bf619313fb3f49800f5384f0dfec3aa34ef4bb030c5e038a485a8861a733a537ee7c834c8c200a2244335c3c61e7d564005b81d4e5c5f603d2864b2a943a5384 SHA512 e8589f7bd433d4aff068099e860c0cf012fc88dc63806873573a338bb91848d73e0a2af76dad0a5e023a1b25b0be85507346b77dec5c5a265942005219541699
 DIST sentry-sdk-0.17.6.tar.gz 183157 BLAKE2B ea0f6af54c31abc785274fc75238a02b8c9f7a978881a01203e0928e100c18df2257ec4a3cef608141b6846c616566388134a4ec31364f26d0bc2b0fadbb0dac SHA512 1af433b5c2311612ad650ea196ddfedb444e9ccb424df72422759f8647fe6cc22bb81a15933f2716cf40313ce3b2e262c077168aa831758d057a1f2e5e1499ff
+DIST sentry-sdk-0.17.7.tar.gz 184034 BLAKE2B de71b2e270594abe2e16d7e2fb9db3028e3c2abd4539269562e8786e6d937352153da21d6366d5e0384e3de1dbd6fbabe3d5060a6f0f9953bd260fbd865c893d SHA512 2360321ec0231ba76c968ff4e6dc78d42a48106aa6aade73a1c1194f9406fbafea3b533994da42027b3479302756ed3ec6e44ce551cb01ce60397939beaeb6d4
diff --git a/dev-python/sentry-sdk/sentry-sdk-0.17.7.ebuild b/dev-python/sentry-sdk/sentry-sdk-0.17.7.ebuild
new file mode 100644
index 000000000000..f2de12dd65e8
--- /dev/null
+++ b/dev-python/sentry-sdk/sentry-sdk-0.17.7.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python client for Sentry"
+HOMEPAGE="https://getsentry.com https://pypi.org/project/sentry-sdk/"
+SRC_URI="https://github.com/getsentry/sentry-python/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/sentry-python-${PV}"
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+
+RDEPEND="
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/asttokens[${PYTHON_USEDEP}]
+		<dev-python/dnspython-2[${PYTHON_USEDEP}]
+		dev-python/executing[${PYTHON_USEDEP}]
+		dev-python/eventlet[${PYTHON_USEDEP}]
+		dev-python/fakeredis[${PYTHON_USEDEP}]
+		dev-python/flask-login[${PYTHON_USEDEP}]
+		dev-python/gevent[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pyrsistent[${PYTHON_USEDEP}]
+		dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+		dev-python/pytest-forked[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/werkzeug[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/aiocontextvars[${PYTHON_USEDEP}]
+			dev-python/contextvars[${PYTHON_USEDEP}]
+		' python3_6)
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local deselect=(
+		# tests require Internet access
+		--deselect tests/integrations/stdlib/test_httplib.py
+		--deselect tests/integrations/requests/test_requests.py
+		# wtf is it supposed to do?!
+		--deselect tests/integrations/gcp/test_gcp.py
+		# fails on py3.6, hangs on py3.7+
+		--deselect
+		'tests/test_transport.py::test_transport_works[eventlet'
+		# TODO
+		--deselect
+		'tests/test_basics.py::test_auto_enabling_integrations_catches_import_error'
+		--deselect
+		tests/test_client.py::test_databag_depth_stripping
+		--deselect
+		tests/test_client.py::test_databag_string_stripping
+		--deselect
+		tests/test_client.py::test_databag_breadth_stripping
+		# test_filename: apparently unhappy about pytest being called pytest
+		--deselect 'tests/utils/test_general.py::test_filename'
+		# test_circular_references: apparently fragile
+		--deselect
+		'tests/integrations/threading/test_threading.py::test_circular_references'
+	)
+	[[ ${EPYTHON} == python3.6 ]] && deselect+=(
+		# broken with contextvars on py3.6
+		--deselect
+		'tests/utils/test_contextvars.py::test_leaks[greenlet]'
+		--deselect
+		'tests/test_transport.py::test_transport_works[greenlet'
+	)
+
+	# Prevent tests/integrations/modules/test_modules.py:test_basic failure
+	# Needs to detect sentry-sdk in the installed modules
+	distutils_install_for_testing
+
+	pytest -vv "${deselect[@]}" || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/xlsxwriter/Manifest b/dev-python/xlsxwriter/Manifest
index 913435b492e0..6af8a34ae30c 100644
--- a/dev-python/xlsxwriter/Manifest
+++ b/dev-python/xlsxwriter/Manifest
@@ -1,2 +1,3 @@
 DIST xlsxwriter-1.3.3-tests.tar.gz 32108929 BLAKE2B faabdf2d2662c61217925679b1b22b294db5279da11b959b12d181711a4c9033e34a52d4888e3dfe1d804889eaa2ee8ff03cf1f298b4930268594e2856ddfb85 SHA512 d5bfcb624b66bb2098fcab1623f8e221c1254fd7b094bb71622969618061b434d9a17d9199e32110ef56336e2a96a93c94f1ed1ceca5877ef41fb52c3b2a37b6
 DIST xlsxwriter-1.3.4-tests.tar.gz 32300247 BLAKE2B ef388172c09f258f0c70a45545fae068359ed182693cf5bf04f2d4f6b528a08e5f963766a5b553c70c94b6e7f7e7a45b3d0dd6e6754dec320bf4748a309c2402 SHA512 12bacc4e604f02f2045e1e5e5f402dcb96a04e1fbd8d934d19eefc01d011832586a517e235c99793a4114d64940785ab02586d40b3bf089b455b681268ee4ef6
+DIST xlsxwriter-1.3.5-tests.tar.gz 32306484 BLAKE2B 161eed08d54ffb1728dfef394abd7614d2ec9e275b93079434bd3bd125e5707b15a6ca164a835ddec31894caa83d68dbd8d3cc5f38d24e4e30b2d86bd7f3e240 SHA512 349c7635f6d770ecd3429012c3e3a91f78381427fa166ef29da7cd7fd86e89da82dd51ddd69dca7b9ae4fb4f05ea4213c47c161755ed9a55a83b6b971edf8202
diff --git a/dev-python/xlsxwriter/xlsxwriter-1.3.5.ebuild b/dev-python/xlsxwriter/xlsxwriter-1.3.5.ebuild
new file mode 100644
index 000000000000..d7ebaf8d508a
--- /dev/null
+++ b/dev-python/xlsxwriter/xlsxwriter-1.3.5.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
+
+inherit distutils-r1
+
+MY_PN="XlsxWriter"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python module for creating Excel XLSX files"
+HOMEPAGE="https://github.com/jmcnamara/XlsxWriter"
+SRC_URI="https://github.com/jmcnamara/XlsxWriter/archive/RELEASE_${PV}.tar.gz -> ${P}-tests.tar.gz"
+S="${WORKDIR}/${MY_PN}-RELEASE_${PV}"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+distutils_enable_tests pytest