Adding metadata

32 files changed, 596 insertions, 33 deletions

diff --git a/dev-python/anyio/anyio-3.5.0-r1.ebuild b/dev-python/anyio/anyio-3.5.0-r1.ebuild
index d9afa6b0629d..a246283e09e5 100644
--- a/dev-python/anyio/anyio-3.5.0-r1.ebuild
+++ b/dev-python/anyio/anyio-3.5.0-r1.ebuild
@@ -4,7 +4,7 @@
 EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
 
 inherit distutils-r1
 
@@ -30,8 +30,13 @@ BDEPEND="
 		>=dev-python/hypothesis-4.0[${PYTHON_USEDEP}]
 		>=dev-python/pytest-7[${PYTHON_USEDEP}]
 		>=dev-python/pytest-mock-3.6.1[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
 		dev-python/trustme[${PYTHON_USEDEP}]
-		amd64? ( >=dev-python/uvloop-0.15[${PYTHON_USEDEP}] )
+		amd64? (
+			$(python_gen_cond_dep '
+				>=dev-python/uvloop-0.15[${PYTHON_USEDEP}]
+			' 'python*')
+		)
 	)
 "
 
diff --git a/dev-python/aws-sam-translator/Manifest b/dev-python/aws-sam-translator/Manifest
index ce361c087c7c..307c37d14245 100644
--- a/dev-python/aws-sam-translator/Manifest
+++ b/dev-python/aws-sam-translator/Manifest
@@ -2,3 +2,4 @@ DIST aws-sam-translator-1.40.0.tar.gz 988864 BLAKE2B 5a414bde5ceeb016267c64742e8
 DIST aws-sam-translator-1.42.0.tar.gz 1017720 BLAKE2B d0166b09b99c64f5f4a4c1ebfe63b6a35ca6db73efb97f76b8748272b646fe2fcf9de06c2f6b29ce69a3edfce9235ba932913055e70f48d88569e4df25a6be0e SHA512 6b1bfd4bde203e31a9d98a385d6c0705ba651c39846358e750faf8a30c4e4e8b2ee57623af27da670ee8f1f5edca795b1b5528b5237ff9f01f911d4b9385ebcd
 DIST aws-sam-translator-1.43.0.tar.gz 1046840 BLAKE2B 19e405a07c9eb42ee77f26986eb09e6902559fc3fad5f1b7f4df0d09cb529add1c53910afa3fa3d867f048e69fb4c6872004733fc611347d4438013b80605e5c SHA512 9e7a5b4769eafcf1a9d8af7582cd4af3a82843d2c7c474495b9099fcb94f8dd0dd45d02f52ed609de7dc341b77f0f913526410935244836c3201b99c3fb6a292
 DIST aws-sam-translator-1.44.0.tar.gz 1047747 BLAKE2B 54714943b1bb561e32fb0102aa7b3fdb77d9bd864510ff1cc5315591fad70ef112fe7bc080f2c7ba1444fc2dd7ccae212c539b8ec2015a93b1486e9152493fac SHA512 0c165b808b6ead83bfb3d4ee75ff683e733433b505ec035527b3e2ecac4d166acf60ce7c0a16f16181a42adf126bb215f88916e705fc9746b412ba58dbfe1815
+DIST aws-sam-translator-1.45.0.tar.gz 1053946 BLAKE2B b34c7417bd20fbd5907992e860ff7acaf1f6dea699d4385bda96467ff03965f30b068835af377d41dcd0ef210509d0b21a05b7e65394771981f8b499730acd41 SHA512 218eda9498fe0db9bab71cdd09d128403248e80936eb2a0e8afeff31f5f8e959aa9d70997ed565c05739ab40bc93d51d1fd84969ec9d7e48b8f10c062b2f74d1
diff --git a/dev-python/aws-sam-translator/aws-sam-translator-1.45.0.ebuild b/dev-python/aws-sam-translator/aws-sam-translator-1.45.0.ebuild
new file mode 100644
index 000000000000..8d673ecf7a8a
--- /dev/null
+++ b/dev-python/aws-sam-translator/aws-sam-translator-1.45.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A library that transform SAM templates into AWS CloudFormation templates"
+HOMEPAGE="
+	https://github.com/aws/serverless-application-model/
+	https://pypi.org/project/aws-sam-translator/
+"
+SRC_URI="
+	https://github.com/aws/serverless-application-model/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+S="${WORKDIR}/serverless-application-model-${PV}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/boto3-1.17[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-2.6[${PYTHON_USEDEP}]
+	>=dev-python/six-1.11[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	tests/validator/test_validator_api.py::TestValidatorApi::test_errors_13_error_definitionuri
+	tests/unit/test_region_configuration.py::TestRegionConfiguration::test_is_service_supported_positive_4_ec2
+)
+
+python_prepare_all() {
+	# remove pytest-cov dependency
+	sed -r -e 's:--cov(-[[:graph:]]+|)[[:space:]]+[[:graph:]]+::g' \
+		-i pytest.ini || die
+
+	# deps are installed by ebuild, don't try to reinstall them via pip
+	truncate --size=0 requirements/*.txt || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/backcall/backcall-0.2.0-r1.ebuild b/dev-python/backcall/backcall-0.2.0-r1.ebuild
index 579fffd3c49a..93ae19d93025 100644
--- a/dev-python/backcall/backcall-0.2.0-r1.ebuild
+++ b/dev-python/backcall/backcall-0.2.0-r1.ebuild
@@ -4,7 +4,7 @@
 EAPI=8
 
 DISTUTILS_USE_PEP517=flit
-PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
 
 inherit distutils-r1
 
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 56c1f73940ca..c1049e79fc6f 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -10,4 +10,5 @@ DIST boto3-1.21.31.tar.gz 484562 BLAKE2B f647e7eb053ed38a8c670073ba028e5cccbb540
 DIST boto3-1.21.32.tar.gz 485694 BLAKE2B da6fa6f38b234af9e67bfeb8182751f1ac533a2aea72d8d407aea21554501f598c9da71f3c30dd952248c1ab244c849b779a329fc941d05b53325fe46de2aba4 SHA512 d65cffa91ae1a29e69e4bac2fc0af704987e9bca914f3f905e00c383bc92127c6e41beed71e9445e3f484c6dadde2372aca69f550af600abbb42731275c53eda
 DIST boto3-1.21.33.tar.gz 486096 BLAKE2B 9a37ec9e7d9ede3aa8fb2e7b3c90ae799a803f64a4793ccc2431e23fc71b7db0cb8e1268117eecb2c69baaf60b8e6bd8468c7d6b3288a6ac509c3add7337ba60 SHA512 bd35e3225abb7c7803c2b2f187ecd03f3c59d095f3f571e86b24ff193c09cb32069a88725a2b964a143a752c627be7f92b985add90b5f26eaed766d655e532e1
 DIST boto3-1.21.34.tar.gz 486432 BLAKE2B 9872f7ee32f48f399e1e7a404dc9f68c15ecb639308654a596cc31b3614071fc0b6ef5752eff788f5a363cd11a3cd99bcdc32038f7a8b95971abe71d0d891331 SHA512 3ea997289aa5d1a74fd3c1542b413299b9d89b1f3bc9e3f4cdc568f688b82401772def3d57c1c78d1a5bb0736aa39004cd21f291a35906cf02e9be5cc3321495
+DIST boto3-1.21.35.tar.gz 486835 BLAKE2B 167070bf09785bac17083cef3caf144cf11a4266c4476af2f6e19b06c81f2d2bcee42b8c7de1d1c9ac178c025bcac08366b2c7cb072cdb663910d45f7e8369fa SHA512 fe73111a46fb27d9c77abec3a13c5267243b2fcc3f89c01d9036f6ca9f362d029c9cbfbb6c1df11b302a9fb0468453fc1b91ee3dac4853bab6662f1ebfa211b2
 DIST boto3-1.21.8.tar.gz 473069 BLAKE2B f08f76fb9c4e56e6ba5624c885973599505769d7f9eea6e20a06e1a641768b1f7b108fc7293282a55bf4c7d2b62eb34853f46b8c3ada9afb8fc25624daa60c12 SHA512 23ed88dcaefe3224db05959251befaae4f03859bf00daf649db1e838e5fb92e01a6da4bee8083366d804404aac358df19d7e4552d6aaf39f9c4b371ccc7f9088
diff --git a/dev-python/boto3/boto3-1.21.35.ebuild b/dev-python/boto3/boto3-1.21.35.ebuild
new file mode 100644
index 000000000000..80278b309f54
--- /dev/null
+++ b/dev-python/boto3/boto3-1.21.35.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 0b0784bd78cb..00bf8790b510 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -10,4 +10,5 @@ DIST botocore-1.24.31.tar.gz 8884591 BLAKE2B 596c0df9e5331cf81472c93f436caed79eb
 DIST botocore-1.24.32.tar.gz 8884956 BLAKE2B c899ed9b540663fc16e937d98c4c4383b5b0b9c36a976a6b872019bee46edb6db4b9fbe9cf5cebfa5fd1f43d37d21213c90a93802e6d95e4218693269021f5fe SHA512 06142282ff93918052fc6d4832061c65088a5ce8a9fdbfb587be4a1575edf1ed160c58159f25446c7717a841e9ddff00b0a95dd5926a738ffb166b70b42da71f
 DIST botocore-1.24.33.tar.gz 8885297 BLAKE2B 0c45249844be79643ea312a41ccb0fad06459fae0b1d419bfadec93b213ff2e24894dd255ac940d0df3325f7786386249ce7391b90a04467e9b0a2506e1a4661 SHA512 ac9f983495368cef53e2ca13c80cd8ef90d04efc6cedb7a38072cef67705b6c11bfc4d9802b94c805e798e6161960bf74ccf3b3c6c8c7a258d91b0e1e72aa852
 DIST botocore-1.24.34.tar.gz 8886786 BLAKE2B a100f9085d2d02d476b0748cca38eeff4e5fbe1441e930f286807d66e837c5fbd1ff1ee8328f87f27c5239891fa46d3324c038d8f0f76f10769cbac5f0628c38 SHA512 beee01425c19affed5c2c9b0d995d23c4e9454715c8ab8144c407e330b0d79099885d30376bb678fc28268cba53112b21bda8491614d2ebef4976b803e189bcf
+DIST botocore-1.24.35.tar.gz 8891601 BLAKE2B b6a56efa73a3f76f51764c4c649d38f2e596fb262624bc5931904318b68a773790f6e4e358cf42567aad0de4e97099699935e6da4c21be66a782f7005fbc15bf SHA512 3c0a7c935798a6dcdd419080a31050301f795ff67b8262673ee4ca09d8344f222ce4b1b7bfff3459089bbcb59c42041281ed8005c1533c34c24542d9a45c353c
 DIST botocore-1.24.8.tar.gz 8798121 BLAKE2B 4ca37ed7be0af62901bf154f75739cc7e07505a809e551884c72d5b5eed334fff1111fc6db016df522564a1f3d9b6f258e8eca96161a734711340bf880b553b5 SHA512 6ac2139694ab199313a0fb9a2f783b12de7f3915d10cba739f4758356a3b84a917c3c394954b6d82d7a62de907c6fe57a3559e2b9a625bb0479e7bacd31d21cc
diff --git a/dev-python/botocore/botocore-1.24.35.ebuild b/dev-python/botocore/botocore-1.24.35.ebuild
new file mode 100644
index 000000000000..5fe8ae8c2f96
--- /dev/null
+++ b/dev-python/botocore/botocore-1.24.35.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	epytest tests/{functional,unit} \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
diff --git a/dev-python/gpep517/Manifest b/dev-python/gpep517/Manifest
index f99e0b39a4c3..da0085de5540 100644
--- a/dev-python/gpep517/Manifest
+++ b/dev-python/gpep517/Manifest
@@ -1 +1 @@
-DIST gpep517-1.gh.tar.gz 6871 BLAKE2B a298a445cb24dbc708985ebe0be266ed6549525a2b9d250ddb53129502f04a442927ca4c29445f4caf4ada82e106e5498c9586e78dd8a4bd676c7aff747544b6 SHA512 83ccf6124e388aefcdece391d12daf6a337d52b7bb794268effd2abc9bdab6b00d935d01cac774b4a66704578160e44617b16a5b8b9ef821012d419848145e9c
+DIST gpep517-2.gh.tar.gz 6904 BLAKE2B 5d6f8c02805fec0b9c9929a133817be5d06c76ca2dd5ecd6b59d04eca1ca746b2a63a84df29c929ca06a026eef741a2d872abede6f1d0ac3719ff2005cf20043 SHA512 2b1fce7193a5c03175c34251987f42fe82c79a6eef324759fe5728e0f3b66a10f8aa644ece2193c912e9977f21b14a28fe5c9443e3b01ca8cdacf862afe0838c
diff --git a/dev-python/gpep517/gpep517-1.ebuild b/dev-python/gpep517/gpep517-2.ebuild
index 18fce3e5784a..18fce3e5784a 100644
--- a/dev-python/gpep517/gpep517-1.ebuild
+++ b/dev-python/gpep517/gpep517-2.ebuild
diff --git a/dev-python/h11/h11-0.13.0-r1.ebuild b/dev-python/h11/h11-0.13.0-r1.ebuild
new file mode 100644
index 000000000000..2cce1b86e153
--- /dev/null
+++ b/dev-python/h11/h11-0.13.0-r1.ebuild
@@ -0,0 +1,19 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A pure-Python implementation of HTTP/1.1 inspired by hyper-h2"
+HOMEPAGE="https://github.com/python-hyper/h11/ https://pypi.org/project/h11/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+distutils_enable_tests pytest
diff --git a/dev-python/h11/h11-0.13.0.ebuild b/dev-python/h11/h11-0.13.0.ebuild
index 1b8a0224d4ff..044b69a21839 100644
--- a/dev-python/h11/h11-0.13.0.ebuild
+++ b/dev-python/h11/h11-0.13.0.ebuild
@@ -4,7 +4,7 @@
 EAPI=8
 
 DISTUTILS_USEPEP517=setuptools
-PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
 
 inherit distutils-r1
 
diff --git a/dev-python/hatchling/hatchling-0.22.0.ebuild b/dev-python/hatchling/hatchling-0.22.0.ebuild
index 565caded177b..eb9a3ead8529 100644
--- a/dev-python/hatchling/hatchling-0.22.0.ebuild
+++ b/dev-python/hatchling/hatchling-0.22.0.ebuild
@@ -4,7 +4,7 @@
 EAPI=8
 
 DISTUTILS_USE_PEP517=standalone
-PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
 
 inherit distutils-r1
 
@@ -35,10 +35,13 @@ RDEPEND="
 BDEPEND="
 	${RDEPEND}
 	test? (
-		dev-python/atomicwrites[${PYTHON_USEDEP}]
-		dev-python/click[${PYTHON_USEDEP}]
-		dev-python/httpx[${PYTHON_USEDEP}]
-		dev-python/rich[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/atomicwrites[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+			dev-python/httpx[${PYTHON_USEDEP}]
+			dev-python/platformdirs[${PYTHON_USEDEP}]
+			dev-python/rich[${PYTHON_USEDEP}]
+		' 'python*')
 	)
 "
 
@@ -51,6 +54,11 @@ python_compile() {
 }
 
 python_test() {
+	if [[ ${EPYTHON} != python* ]]; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
 	local -x EPYTEST_DESELECT=(
 		# these run pip to install stuff
 		tests/backend/dep/test_core.py::test_dependency_found
diff --git a/dev-python/httpbin/files/httpbin-0.7.0-werkzeug-2.1.patch b/dev-python/httpbin/files/httpbin-0.7.0-werkzeug-2.1.patch
new file mode 100644
index 000000000000..cf7871268d99
--- /dev/null
+++ b/dev-python/httpbin/files/httpbin-0.7.0-werkzeug-2.1.patch
@@ -0,0 +1,32 @@
+From 5cc81ce87a3c447a127e4a1a707faf9f3b1c9b6b Mon Sep 17 00:00:00 2001
+From: Maximino BOGADO <bogamax2@hotmail.fr>
+Date: Wed, 30 Mar 2022 16:26:31 +0200
+Subject: [PATCH] Replace BaseResponse to Response class (new werkzeug version
+ 2.1.0)
+
+---
+ httpbin/core.py | 4 ++--
+ 1 file changed, 2 insertions(+), 2 deletions(-)
+
+diff --git a/httpbin/core.py b/httpbin/core.py
+index 305c9882..2bad408e 100644
+--- a/httpbin/core.py
++++ b/httpbin/core.py
+@@ -29,7 +29,7 @@
+ from six.moves import range as xrange
+ from werkzeug.datastructures import WWWAuthenticate, MultiDict
+ from werkzeug.http import http_date
+-from werkzeug.wrappers import BaseResponse
++from werkzeug.wrappers import Response
+ from werkzeug.http import parse_authorization_header
+ from flasgger import Swagger, NO_SANITIZER
+ 
+@@ -77,7 +77,7 @@ def jsonify(*args, **kwargs):
+ 
+ 
+ # Prevent WSGI from correcting the casing of the Location header
+-BaseResponse.autocorrect_location_header = False
++Response.autocorrect_location_header = False
+ 
+ # Find the correct template folder when running from a different location
+ tmpl_dir = os.path.join(os.path.dirname(os.path.abspath(__file__)), "templates")
diff --git a/dev-python/httpbin/httpbin-0.7.0-r4.ebuild b/dev-python/httpbin/httpbin-0.7.0-r4.ebuild
index a374703a0977..e389cfe8acf6 100644
--- a/dev-python/httpbin/httpbin-0.7.0-r4.ebuild
+++ b/dev-python/httpbin/httpbin-0.7.0-r4.ebuild
@@ -9,8 +9,10 @@ PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
 inherit distutils-r1
 
 DESCRIPTION="HTTP Request and Response Service"
-HOMEPAGE="https://github.com/postmanlabs/httpbin
-	https://pypi.org/project/httpbin/"
+HOMEPAGE="
+	https://github.com/postmanlabs/httpbin/
+	https://pypi.org/project/httpbin/
+"
 SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="MIT"
@@ -24,7 +26,8 @@ RDEPEND="
 	dev-python/itsdangerous[${PYTHON_USEDEP}]
 	dev-python/markupsafe[${PYTHON_USEDEP}]
 	dev-python/six[${PYTHON_USEDEP}]
-	>=dev-python/werkzeug-0.14.1[${PYTHON_USEDEP}]"
+	<dev-python/werkzeug-2.1[${PYTHON_USEDEP}]
+"
 
 PATCHES=(
 	# do not import raven if it's not going to be used
diff --git a/dev-python/httpbin/httpbin-0.7.0-r5.ebuild b/dev-python/httpbin/httpbin-0.7.0-r5.ebuild
new file mode 100644
index 000000000000..6ef2e7cf1a9a
--- /dev/null
+++ b/dev-python/httpbin/httpbin-0.7.0-r5.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="HTTP Request and Response Service"
+HOMEPAGE="
+	https://github.com/postmanlabs/httpbin/
+	https://pypi.org/project/httpbin/
+"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/brotlicffi[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/itsdangerous[${PYTHON_USEDEP}]
+	dev-python/markupsafe[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-2.0[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	# do not import raven if it's not going to be used
+	# (upstream removed it completely in git anyway)
+	"${FILESDIR}"/${P}-optional-raven.patch
+	# fix tests with new versions of werkzeug
+	"${FILESDIR}"/${P}-test-werkzeug.patch
+	# use brotlicffi instead of brotlipy
+	"${FILESDIR}"/${P}-brotlicffi.patch
+	# fix compat with werkzeug 2.1
+	# https://github.com/postmanlabs/httpbin/pull/674
+	"${FILESDIR}"/${P}-werkzeug-2.1.patch
+)
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# a new version of flask or whatever converts relative redirects
+	# to absolute; this package is dead anyway, so just skip
+	# the relevant tests
+	sed -e 's:test_redirect:_&:' \
+		-e 's:test_relative:_&:' \
+		-i test_httpbin.py || die
+
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/httpcore/httpcore-0.14.7-r1.ebuild b/dev-python/httpcore/httpcore-0.14.7-r1.ebuild
index 573649a14a3c..f79f73a5f46d 100644
--- a/dev-python/httpcore/httpcore-0.14.7-r1.ebuild
+++ b/dev-python/httpcore/httpcore-0.14.7-r1.ebuild
@@ -4,7 +4,7 @@
 EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
 
 inherit distutils-r1 optfeature
 
diff --git a/dev-python/parso/parso-0.8.3-r1.ebuild b/dev-python/parso/parso-0.8.3-r1.ebuild
new file mode 100644
index 000000000000..b6b009168c6c
--- /dev/null
+++ b/dev-python/parso/parso-0.8.3-r1.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A python parser that supports error recovery and round-trip parsing"
+HOMEPAGE="
+	https://github.com/davidhalter/parso/
+	https://pypi.org/project/parso/
+"
+SRC_URI="
+	https://github.com/davidhalter/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# py3.10 changed exception messages
+	test/test_python_errors.py::test_python_exception_matches
+)
diff --git a/dev-python/pylint/Manifest b/dev-python/pylint/Manifest
index e2615338cac4..a48829c2ade7 100644
--- a/dev-python/pylint/Manifest
+++ b/dev-python/pylint/Manifest
@@ -4,3 +4,4 @@ DIST pylint-2.13.1.gh.tar.gz 1116054 BLAKE2B 633636f97e284a8a93c598261b90019ea35
 DIST pylint-2.13.2.gh.tar.gz 1116482 BLAKE2B da35c9f39781bbd796e2ec055b41c44211588d7da360fd27f81eef57a3f5c65e27931ca927b41692627c9914f5c28e3262c0f34a45c38b20aa1b83710ab1d1f1 SHA512 15274658cf3067ffa6635a94f2c75d8854b3843be45ea5dc5896bc12583b156428858baeed19eed4bfab35489326d70d0cce1375354d9ec97d00cfd895fc4a47
 DIST pylint-2.13.3.gh.tar.gz 1116747 BLAKE2B 9ab6ff4746f78472de9c248754d102e55e8cb60d3ead8c5079cfe851b2b7c8e16afc9b0be02041cf24e789784200b90751ad0bcf172eb6d4edd88463863d18ac SHA512 0bda6d89219ad6f7f64f1361f95b85a34e3bc70f9f18f71eaa3d69deb47ab6fc056000c13a11c8c5644f0a9789eac2a5c262ddcf96302aeebfa16aa2e3b3086c
 DIST pylint-2.13.4.gh.tar.gz 1117488 BLAKE2B a660c15c41b529d932a21d438c7cf0f3b97683d6b1452f4383193f97dd22ba6e216a7dc8c3677cb1cb0ab5b76ddb936afa2d87df38d41950e2249bd8867bf44d SHA512 2c0c60908f89bf7a2552f65e0b4957ee6223f5429a6c2ec997aaf75572b11e4247e159da744937dbc7752ebd5eab0a0c873d129983de09ea0954f35f47a1f524
+DIST pylint-2.13.5.gh.tar.gz 1118551 BLAKE2B 70ee4254aa140aba16adfe67aeb896d9c455843dfa945d335b5ba48e85c9d2d8f057223bc74bd4c0c0bfa2d343a9f78e783705b885caaee6895fcddf7ce23ccb SHA512 e399239fbea58260b17f226dddb63f1e6a2f12cdd601a4e73913a169d23fe2b6085e776bf8144e2c5a555dfdc1b28a5818a4103969d504b638b6b41ee296d182
diff --git a/dev-python/pylint/pylint-2.13.5.ebuild b/dev-python/pylint/pylint-2.13.5.ebuild
new file mode 100644
index 000000000000..2417e9131774
--- /dev/null
+++ b/dev-python/pylint/pylint-2.13.5.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python code static checker"
+HOMEPAGE="
+	https://pypi.org/project/pylint/
+	https://github.com/PyCQA/pylint/
+"
+SRC_URI="
+	https://github.com/pycqa/pylint/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~m68k ~ppc ~riscv ~x86"
+IUSE="examples"
+
+# Make sure to check https://github.com/PyCQA/pylint/blob/main/setup.cfg#L43 on bumps
+# Adjust dep bounds!
+RDEPEND="
+	<dev-python/astroid-2.12[${PYTHON_USEDEP}]
+	>=dev-python/astroid-2.11.0[${PYTHON_USEDEP}]
+	>=dev-python/dill-0.2[${PYTHON_USEDEP}]
+	>=dev-python/isort-4.2.5[${PYTHON_USEDEP}]
+	<dev-python/isort-6[${PYTHON_USEDEP}]
+	>=dev-python/mccabe-0.6[${PYTHON_USEDEP}]
+	<dev-python/mccabe-0.8[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+"
+BDEPEND="
+	test? (
+		>=dev-python/GitPython-3[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.4.4-sphinx-theme.patch"
+)
+
+distutils_enable_sphinx doc --no-autodoc
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# No need to run the benchmarks
+		tests/benchmark/test_baseline_benchmarks.py
+
+		# TODO
+		'tests/test_functional.py::test_functional[forgotten_debug_statement_py37]'
+		'tests/test_functional.py::test_functional[dataclass_with_field]'
+		tests/checkers/unittest_typecheck.py::TestTypeChecker::test_nomember_on_c_extension_error_msg
+		tests/checkers/unittest_typecheck.py::TestTypeChecker::test_nomember_on_c_extension_info_msg
+	)
+	# Specify the test directory explicitly to avoid import file mismatches
+	epytest tests
+}
+
+python_install_all() {
+	if use examples ; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/pytest-httpbin/pytest-httpbin-1.0.2.ebuild b/dev-python/pytest-httpbin/pytest-httpbin-1.0.2.ebuild
index 36bae1411990..87cfa227ef0d 100644
--- a/dev-python/pytest-httpbin/pytest-httpbin-1.0.2.ebuild
+++ b/dev-python/pytest-httpbin/pytest-httpbin-1.0.2.ebuild
@@ -31,4 +31,8 @@ PATCHES=(
 	"${FILESDIR}"/pytest-httpbin-1.0.0-pypy3-hang.patch
 )
 
+EPYTEST_DESELECT=(
+	tests/test_server.py::test_redirect_location_is_https_for_secure_server
+)
+
 distutils_enable_tests pytest
diff --git a/dev-python/pytest-trio/pytest-trio-0.7.0-r1.ebuild b/dev-python/pytest-trio/pytest-trio-0.7.0-r1.ebuild
new file mode 100644
index 000000000000..34da941fe36f
--- /dev/null
+++ b/dev-python/pytest-trio/pytest-trio-0.7.0-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="This is a pytest plugin to help you test projects that use Trio"
+HOMEPAGE="
+	https://github.com/python-trio/pytest-trio
+	https://pypi.org/project/pytest-trio/
+"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( MIT Apache-2.0 )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/async_generator-1.9[${PYTHON_USEDEP}]
+	dev-python/outcome[${PYTHON_USEDEP}]
+	>=dev-python/pytest-6.0.0[${PYTHON_USEDEP}]
+	>=dev-python/trio-0.15[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/hypothesis-3.64[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+	dev-python/attrs \
+	dev-python/sphinx_rtd_theme \
+	dev-python/sphinxcontrib-trio
+
+python_prepare_all() {
+	# Defining 'pytest_plugins' in a non-top-level conftest is no longer supported:
+	mv pytest_trio/_tests/conftest.py conftest.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# disable autoloading pytest-asyncio in nested pytest calls
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	# since we disabled autoloading, force loading pytest-trio
+	local -x PYTEST_PLUGINS=pytest_trio.plugin
+	epytest
+}
diff --git a/dev-python/pytest-trio/pytest-trio-0.7.0.ebuild b/dev-python/pytest-trio/pytest-trio-0.7.0.ebuild
index 80ec5c388db4..91dd7f4d6da3 100644
--- a/dev-python/pytest-trio/pytest-trio-0.7.0.ebuild
+++ b/dev-python/pytest-trio/pytest-trio-0.7.0.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
 
 inherit distutils-r1
 
diff --git a/dev-python/setuptools/setuptools-62.0.0.ebuild b/dev-python/setuptools/setuptools-62.0.0.ebuild
index 7da37808a1d1..18c498ca52de 100644
--- a/dev-python/setuptools/setuptools-62.0.0.ebuild
+++ b/dev-python/setuptools/setuptools-62.0.0.ebuild
@@ -18,7 +18,7 @@ HOMEPAGE="
 "
 SRC_URI="
 	mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
-	https://dev.gentoo.org/~floppym/python/${CPY_PATCHSET}.tar.xz
+	https://dev.gentoo.org/~mgorny/dist/python/${CPY_PATCHSET}.tar.xz
 "
 
 LICENSE="MIT"
diff --git a/dev-python/slixmpp/Manifest b/dev-python/slixmpp/Manifest
index 93180e7a2c76..f0834f960727 100644
--- a/dev-python/slixmpp/Manifest
+++ b/dev-python/slixmpp/Manifest
@@ -1 +1,2 @@
 DIST slixmpp-1.8.1.tar.gz 532622 BLAKE2B d0c12c240c8a14df0a0765f8bac02eb545951a0b9749ec9569d651caa3457af1a71f1c6b3a10db879fe25648b1c3c456b78e48042a83124b0a8d4d35df60134d SHA512 13b355592d564b7e211e6007fa19099e619480d0a87332b68163115852840ad2f0c70063b4260fc88d4da67e13ea97c88972fc05999c1870256b0de0257409f9
+DIST slixmpp-1.8.2.tar.gz 535672 BLAKE2B 8af0329083d5e8bb630bfbedddbe67a78eadcbcb25ed5c9b9b0ddbfbedf973702110d2b3558f5bcf25257d6a7029b1e6afba87c57a37c1f0d4d36305b246979b SHA512 243223754a7c84b653d0282b38f4df58fb5905865635c210bc78b444e85c3b8b964feda7d42b66e9c414ea7a07ecadfc3206c446cc1d9fa625308e783e3d3be5
diff --git a/dev-python/slixmpp/slixmpp-1.8.2.ebuild b/dev-python/slixmpp/slixmpp-1.8.2.ebuild
new file mode 100644
index 000000000000..6ad1a08be169
--- /dev/null
+++ b/dev-python/slixmpp/slixmpp-1.8.2.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python 3 library for XMPP"
+HOMEPAGE="https://lab.louiz.org/poezio/slixmpp"
+LICENSE="MIT"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://lab.louiz.org/poezio/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	net-dns/libidn
+"
+RDEPEND="
+	dev-python/aiodns[${PYTHON_USEDEP}]
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	dev-python/pyasn1-modules[${PYTHON_USEDEP}]
+	dev-python/pyasn1[${PYTHON_USEDEP}]
+	${DEPEND}
+"
+
+distutils_enable_tests unittest
diff --git a/dev-python/slixmpp/slixmpp-9999.ebuild b/dev-python/slixmpp/slixmpp-9999.ebuild
index 8fe12a5511d9..6ad1a08be169 100644
--- a/dev-python/slixmpp/slixmpp-9999.ebuild
+++ b/dev-python/slixmpp/slixmpp-9999.ebuild
@@ -27,6 +27,7 @@ DEPEND="
 RDEPEND="
 	dev-python/aiodns[${PYTHON_USEDEP}]
 	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
 	dev-python/defusedxml[${PYTHON_USEDEP}]
 	dev-python/pyasn1-modules[${PYTHON_USEDEP}]
 	dev-python/pyasn1[${PYTHON_USEDEP}]
diff --git a/dev-python/socksio/socksio-1.0.0.ebuild b/dev-python/socksio/socksio-1.0.0.ebuild
index f294d474638a..23aa3ffb66a2 100644
--- a/dev-python/socksio/socksio-1.0.0.ebuild
+++ b/dev-python/socksio/socksio-1.0.0.ebuild
@@ -3,8 +3,9 @@
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{7,8,9,10} )
 DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
 inherit distutils-r1
 
 DESCRIPTION="Sans-I/O implementation of SOCKS4, SOCKS4A, and SOCKS5"
diff --git a/dev-python/soupsieve/Manifest b/dev-python/soupsieve/Manifest
index 813b5593a5fe..8978edcc785f 100644
--- a/dev-python/soupsieve/Manifest
+++ b/dev-python/soupsieve/Manifest
@@ -1 +1,2 @@
 DIST soupsieve-2.3.1.tar.gz 104251 BLAKE2B c395b8dc0944457d6c5f217a03c6fc5f3895868a629eb72d86733fb0d9c6b1d1c41a2e035d5118c9c6fcc6a22e9ff79b9de8417131d30bbc6e1ba02c813ced56 SHA512 3f1245b27d67e8b37bce4cb0b21b2b3f4d6b7ae112cc66672e5406c0701b28e605ed12db1e111bfeccea15625b17042e398b075b7f026d3f3e15069f0cafccac
+DIST soupsieve-2.3.2.tar.gz 103869 BLAKE2B 0820f3935aaf0bda436abf10ddb0d64d6b2de99d116fdc84518879ca468688918a0995f4666e04d4892fee4d221b2d6a843f200c4bf05c3bf5755004a3fbb7ec SHA512 a91c453098697d0b6120e80dd2cf56ec0359d9d3d98ef54e348e8f9832b3b70626fcdc7c21bc3abe0fba32a83cc62d05b750f2d2fa79261479bf89c0aa782caa
diff --git a/dev-python/soupsieve/soupsieve-2.3.2.ebuild b/dev-python/soupsieve/soupsieve-2.3.2.ebuild
new file mode 100644
index 000000000000..cec6870c5ab6
--- /dev/null
+++ b/dev-python/soupsieve/soupsieve-2.3.2.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A modern CSS selector implementation for BeautifulSoup"
+HOMEPAGE="
+	https://github.com/facelessuser/soupsieve/
+	https://pypi.org/project/soupsieve/
+"
+SRC_URI="
+	https://github.com/facelessuser/${PN}/archive/${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="
+	test? (
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/trio/metadata.xml b/dev-python/trio/metadata.xml
index 9274ff78ca8c..6a29a3327bd3 100644
--- a/dev-python/trio/metadata.xml
+++ b/dev-python/trio/metadata.xml
@@ -5,6 +5,10 @@
   <email>andrewammerlaan@gentoo.org</email>
   <name>Andrew Ammerlaan</name>
  </maintainer>
+ <maintainer type="project">
+  <email>python@gentoo.org</email>
+  <name>Python</name>
+ </maintainer>
  <longdescription lang="en">
 The Trio project's goal is to produce a production-quality, permissively licensed, async/await-native I/O library for Python. Like all async libraries, its main purpose is to help you write programs that do multiple things at the same time with parallelized I/O. A web spider that wants to fetch lots of pages in parallel, a web server that needs to juggle lots of downloads and websocket connections at the same time, a process supervisor monitoring multiple subprocesses... that sort of thing. Compared to other libraries, Trio attempts to distinguish itself with an obsessive focus on usability and correctness. Concurrency is complicated; we try to make it easy to get things right.
 
diff --git a/dev-python/trio/trio-0.20.0.ebuild b/dev-python/trio/trio-0.20.0.ebuild
index a1cefb76acaa..108d68a59e12 100644
--- a/dev-python/trio/trio-0.20.0.ebuild
+++ b/dev-python/trio/trio-0.20.0.ebuild
@@ -3,16 +3,20 @@
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
 DISTUTILS_USE_PEP517=setuptools
+
 inherit distutils-r1
 
 DESCRIPTION="Python library for async concurrency and I/O"
 HOMEPAGE="
-	https://github.com/python-trio/trio
-	https://pypi.org/project/trio
+	https://github.com/python-trio/trio/
+	https://pypi.org/project/trio/
+"
+SRC_URI="
+	https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz
 "
-SRC_URI="https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="|| ( Apache-2.0 MIT )"
 SLOT="0"
@@ -31,9 +35,6 @@ BDEPEND="
 	test? (
 		>=dev-python/astor-0.8.0[${PYTHON_USEDEP}]
 		>=dev-python/immutables-0.6[${PYTHON_USEDEP}]
-		dev-python/ipython[${PYTHON_USEDEP}]
-		>=dev-python/jedi-0.18.0[${PYTHON_USEDEP}]
-		dev-python/pylint[${PYTHON_USEDEP}]
 	)
 "
 
@@ -42,10 +43,8 @@ EPYTEST_DESELECT=(
 	# https://github.com/python-trio/trio/issues/1753
 	trio/tests/test_unix_pipes.py::test_close_at_bad_time_for_send_all
 
-	# Fail with Python 3.10 on 'IPPROTO_MPTCP'
-	# Everything else passes and this is a simple check for exported symbols
-	# Let's try again with the next release (after 0.19.0).
-	trio/tests/test_exports.py::test_static_tool_sees_all_symbols
+	# incompatible ipython version?
+	trio/_core/tests/test_multierror.py::test_ipython_exc_handler
 )
 
 EPYTEST_IGNORE=(
@@ -56,7 +55,12 @@ EPYTEST_IGNORE=(
 
 distutils_enable_tests pytest
 distutils_enable_sphinx docs/source \
-					dev-python/immutables \
-					dev-python/sphinxcontrib-trio \
-					dev-python/sphinx_rtd_theme \
-					dev-python/towncrier
+	dev-python/immutables \
+	dev-python/sphinxcontrib-trio \
+	dev-python/sphinx_rtd_theme \
+	dev-python/towncrier
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -m "not redistributors_should_skip"
+}