Adding metadata

34 files changed, 714 insertions, 57 deletions

diff --git a/dev-python/Faker/Faker-22.4.0.ebuild b/dev-python/Faker/Faker-22.4.0.ebuild
new file mode 100644
index 000000000000..b726995539a4
--- /dev/null
+++ b/dev-python/Faker/Faker-22.4.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A Python package that generates fake data for you"
+HOMEPAGE="
+	https://github.com/joke2k/faker/
+	https://pypi.org/project/Faker/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/python-dateutil-2.4.2[${PYTHON_USEDEP}]
+	!dev-ruby/faker
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP},tiff]
+		dev-python/validators[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=faker.contrib.pytest.plugin
+	epytest
+}
diff --git a/dev-python/Faker/Manifest b/dev-python/Faker/Manifest
index 650a82f73c3d..666f805e8810 100644
--- a/dev-python/Faker/Manifest
+++ b/dev-python/Faker/Manifest
@@ -1,2 +1,3 @@
 DIST Faker-22.0.0.tar.gz 1702044 BLAKE2B 17bb5fe42f3d754358a1cf21a23a6917571bdeaff5967b94b3dcc62e08b274f9647ab19b9fa252ccf0f6f821da93ad474c2dddce3c07813048cd910b96d6c68a SHA512 b1539ca7b37d14dcbb06a4dbc198dfacaf4f0d7189f8e8a8986b42ac44780fa1b78c5b02d6f7a289c68a190a83e439f76a92587ee582105c4001246a39d046ce
 DIST Faker-22.2.0.tar.gz 1702497 BLAKE2B ed5d215399d168b79661a5db5a0b7c9a8321f5fdba30041eb6640cc9e6700d838aa7291060b022cc76a44ce2dd3c28eabbe30be35e4b0311edf4c09f4c523042 SHA512 c9a97a29885d73cbd9920938574e7615be43243a4d524391a4e51a1dcf8ca3188a9606094e715773fbd81740145813b1920ac35e99e49dc932d95045e14fa546
+DIST Faker-22.4.0.tar.gz 1702616 BLAKE2B 1a50724c0c8faaf4b2e72d3b23f242be19862133c79a1d49b8919512355ec84d565768b1c0868f287708880a13e833bab4dc911a9f4df53d9a225fa3ea75e00c SHA512 a8531b839c46c0403c37d1f5d58b026a2f8bf9ef66c4ce6302673dc7988250d51d069740bf783abf5b610afc2d01e23aa769c7d32ee03927befb13a610adc586
diff --git a/dev-python/argh/Manifest b/dev-python/argh/Manifest
index cd3085f4f510..0509164b7252 100644
--- a/dev-python/argh/Manifest
+++ b/dev-python/argh/Manifest
@@ -1 +1,2 @@
 DIST argh-0.31.0.tar.gz 65743 BLAKE2B c577273bf361b0bede939b7bcadf9c9ce6dd24d473b834ebd8d2bdc41d163e9cb6f2b79252ab810ac5b6f1f2e20b312cf096b23cf6cd4cd53705fb2c30b55f7d SHA512 d4caefede2596452d3256f4c2194517994dffdb2e01643f0b96b8002d269ac0150e938bb29d0469b67bbb72669b2a82b3e66d28cfecad5230f641c60f1c879e5
+DIST argh-0.31.1.tar.gz 57186 BLAKE2B a6167b6b1c18cb9ab50f476d39783e4f26aa57a25a2d503465c617b1f6adf72eb8a0ec6df3235a73dc443eaa413819b986bd290e3d093099f54abd349fe8b533 SHA512 cd4bb989e96587c1a0bdf9854164b6bc4cb35e529c19d4812741529f9ad880019ed4691fc2b02c49264dd0cc3f8a10400f7272f7ba9a1979cb5268bbbe83f3a7
diff --git a/dev-python/argh/argh-0.31.1.ebuild b/dev-python/argh/argh-0.31.1.ebuild
new file mode 100644
index 000000000000..4e2593c4f66d
--- /dev/null
+++ b/dev-python/argh/argh-0.31.1.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A simple argparse wrapper"
+HOMEPAGE="
+	https://pythonhosted.org/argh/
+	https://github.com/neithere/argh/
+	https://pypi.org/project/argh/
+"
+
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+LICENSE="LGPL-3"
+
+BDEPEND="
+	test? (
+		dev-python/iocapture[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/cmarkgfm/cmarkgfm-2022.10.27.ebuild b/dev-python/cmarkgfm/cmarkgfm-2022.10.27.ebuild
index be385a77b288..10d237d7568b 100644
--- a/dev-python/cmarkgfm/cmarkgfm-2022.10.27.ebuild
+++ b/dev-python/cmarkgfm/cmarkgfm-2022.10.27.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -18,7 +18,7 @@ SLOT="0"
 
 RDEPEND="
 	app-text/cmark-gfm
-	virtual/python-cffi[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/cffi[${PYTHON_USEDEP}]' 'python*')
 "
 DEPEND="${RDEPEND}"
 
diff --git a/dev-python/elastic-transport/Manifest b/dev-python/elastic-transport/Manifest
index 4711d1bdf5c0..ccaf0175eede 100644
--- a/dev-python/elastic-transport/Manifest
+++ b/dev-python/elastic-transport/Manifest
@@ -1 +1,2 @@
 DIST elastic-transport-python-8.11.0.gh.tar.gz 71944 BLAKE2B 9f5199b171f57169e2ca9d77f225a7ad1d67cc28550a41648f37305342f2cddb2c570e0b314057e49d4a5948ceacdbfbe3d928a456ef47fd334abebbf8c6c718 SHA512 b2ab09c63e5824d8cb59ed78728e4670115eee56bb07310e4d8a083b86eace4bc2dfc0dbefc4346906338acf195b193c0f2fc99a0dc1190ac30950fbe6fbcc70
+DIST elastic-transport-python-8.12.0.gh.tar.gz 72207 BLAKE2B 7777484c965eb893cd7d2cba1d39c2b33a005e7f6d6b3c12dd1cd0fb4e5c396abf36686421817ba1272e814ffef299453c885a6dcc3efe5cacd753bcd621384e SHA512 45834ccb4793d7aa7c7d1774ef26381b7ff0cf69221cc628efeb63a7ff8b163a68ff7f0ef4fa3a2b5ffd45e9374441d8b61b8a9b900f9055ddd67425cf0d727a
diff --git a/dev-python/elastic-transport/elastic-transport-8.12.0.ebuild b/dev-python/elastic-transport/elastic-transport-8.12.0.ebuild
new file mode 100644
index 000000000000..c01c4dff839b
--- /dev/null
+++ b/dev-python/elastic-transport/elastic-transport-8.12.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+MY_P=elastic-transport-python-${PV}
+DESCRIPTION="Transport classes and utilities shared among Python Elastic client libraries"
+HOMEPAGE="
+	https://github.com/elastic/elastic-transport-python/
+	https://pypi.org/project/elastic-transport/
+"
+SRC_URI="
+	https://github.com/elastic/elastic-transport-python/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+PROPERTIES="test_network"
+RESTRICT="test"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.26.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-httpserver[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/sphinx \
+	dev-python/furo \
+	dev-python/sphinx-autodoc-typehints
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e 's:, *<[0-9.]*::' setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# fragile to random warnings
+		tests/node/test_http_aiohttp.py::TestAiohttpHttpNode::test_uses_https_if_verify_certs_is_off
+		tests/node/test_urllib3_chain_certs.py::test_assert_fingerprint_in_cert_chain
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p asyncio -o addopts=
+}
diff --git a/dev-python/elasticsearch/Manifest b/dev-python/elasticsearch/Manifest
index 8413751a3008..5d696f94397e 100644
--- a/dev-python/elasticsearch/Manifest
+++ b/dev-python/elasticsearch/Manifest
@@ -1 +1,2 @@
 DIST elasticsearch-py-8.11.1.gh.tar.gz 902628 BLAKE2B 7a1d780ff9f326567b4023f4a87b2a3be430428c00c528d255502d36623b7d1d6e0811f50a03471254eb79fb1e4146ad24402f202c862cafb44ec16fbcdb454f SHA512 e2efbd3e0658180768a35b601e7bef2748390ce12419f82cdfb1656968666fcc6ae71411d4e88eb155b315d8d8197f65c3e25e6f1e18f04e6459662cf80ab12a
+DIST elasticsearch-py-8.12.0.gh.tar.gz 906227 BLAKE2B 95ebae72e94d57590e0c506a3e1655fec7ea61a192d909c6d2993121b91fbd5d3ce5385c0c687bd09ec2621ef1c416242adf969b12e2d3b26943da3fdbd7918d SHA512 5d8714ba110681ad78e0dc6d48bf67185a8b9dc8fd4fd99f6d5f773a52873c33471a5dc99a4635bd92dd21bb9e7dd957012da3f0610ed0eca0d748eb83ee8868
diff --git a/dev-python/elasticsearch/elasticsearch-8.12.0.ebuild b/dev-python/elasticsearch/elasticsearch-8.12.0.ebuild
new file mode 100644
index 000000000000..33515a54831e
--- /dev/null
+++ b/dev-python/elasticsearch/elasticsearch-8.12.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+MY_P="elasticsearch-py-${PV}"
+DESCRIPTION="Official Elasticsearch client library for Python"
+HOMEPAGE="
+	https://ela.st/es-python
+	https://github.com/elastic/elasticsearch-py/
+	https://pypi.org/project/elasticsearch/
+"
+SRC_URI="
+	https://github.com/elastic/elasticsearch-py/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0/$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	<dev-python/aiohttp-4[${PYTHON_USEDEP}]
+	>=dev-python/aiohttp-3[${PYTHON_USEDEP}]
+	<dev-python/elastic-transport-9[${PYTHON_USEDEP}]
+	>=dev-python/elastic-transport-8[${PYTHON_USEDEP}]
+	<dev-python/requests-3[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/mapbox-vector-tile[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-5.4[${PYTHON_USEDEP}]
+		dev-python/unasync[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# REST api tests are a black hole for effort. It downloads the tests
+	# so its an ever moving target. It also requires effort to blacklist
+	# tests for apis which are license restricted.
+	"test_elasticsearch/test_server/test_rest_api_spec.py"
+	# Counting deprecation warnings from python is bound to fail even
+	# if all are fixed in this package. Not worth it.
+	"test_elasticsearch/test_client/test_deprecated_options.py"
+	# Running daemon for tests is finicky and upstream CI fails at it
+	# as well.
+	"test_elasticsearch/test_server/"
+	"test_elasticsearch/test_async/test_server/"
+)
+
+distutils_enable_sphinx docs/sphinx \
+	dev-python/sphinx-autodoc-typehints \
+	dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -o addopts= -p asyncio
+}
diff --git a/dev-python/jupyterlab/Manifest b/dev-python/jupyterlab/Manifest
index ab22353dffe4..d231aa9f056d 100644
--- a/dev-python/jupyterlab/Manifest
+++ b/dev-python/jupyterlab/Manifest
@@ -1 +1,2 @@
 DIST jupyterlab-4.0.10.tar.gz 18347775 BLAKE2B c217b18a5260da8a9ff7df833b7d2a4233255e5a0bbef37eb638bf0fcd99646f5233b70b17b0eb8a27c4fdc042c9dd55c94ffc4d593f890780c6e3f48cdaafd2 SHA512 e5203a17dcf682927cd480363d5952765e8c02c243f2a8fcbef785ffe4b58ea669a196c9040f516a3b4cecd323d54d005a91ce6ce5dfffb32d4e610c14a6f1e5
+DIST jupyterlab-4.0.11.tar.gz 18348142 BLAKE2B 6a2676504a6475d02965ef7b6e393a52c19b3c6af8e58938a189f6bf22693ec754be6c165029f7b9f68b1b80a9f8c20fb67600cb4e9c526da5ae386b3bf728d3 SHA512 b02d18d0e0ecffc9a5d847efe4ce7c7258c741fd6ae0842f25c2c446b16af7cb11ac422dff7807a1a19f4536b514914e098c4fd04a58ceadb8296ce9aca3e2f3
diff --git a/dev-python/jupyterlab/jupyterlab-4.0.11.ebuild b/dev-python/jupyterlab/jupyterlab-4.0.11.ebuild
new file mode 100644
index 000000000000..86c870676a9c
--- /dev/null
+++ b/dev-python/jupyterlab/jupyterlab-4.0.11.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi xdg
+
+DESCRIPTION="JupyterLab computational environment"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyterlab/jupyterlab/
+	https://pypi.org/project/jupyterlab/
+"
+
+LICENSE="BSD MIT GPL-3 Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/async-lru[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0.3[${PYTHON_USEDEP}]
+	dev-python/jupyter-core[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-lsp-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-server-2.4.0[${PYTHON_USEDEP}]
+	<dev-python/jupyter-server-3[${PYTHON_USEDEP}]
+	>=dev-python/jupyterlab-server-2.19[${PYTHON_USEDEP}]
+	<dev-python/jupyterlab-server-3[${PYTHON_USEDEP}]
+	>=dev-python/notebook-shim-0.2[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/tomli[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.2[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	net-libs/nodejs
+"
+
+BDEPEND="
+	dev-python/hatch-jupyter-builder[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+		>=dev-python/pytest-jupyter-0.5.3[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/requests-cache[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# These tests call npm and want internet
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_uninstall_core_extension
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_install_and_uninstall_pinned_folder
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_install_and_uninstall_pinned
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build_custom_minimal_core_config
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build_custom
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build_check
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build
+	jupyterlab/tests/test_build_api.py::TestBuildAPI::test_clear
+	jupyterlab/tests/test_build_api.py::TestBuildAPI::test_build
+)
+
+EPYTEST_IGNORE=(
+	jupyterlab/tests/test_announcements.py
+)
+
+distutils_enable_tests pytest
+# TODO: package sphinx_copybutton
+#distutils_enable_sphinx docs/source dev-python/sphinx-rtd-theme dev-python/myst-parser
+
+python_install_all() {
+	distutils-r1_python_install_all
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
diff --git a/dev-python/mautrix/Manifest b/dev-python/mautrix/Manifest
index 7a2ff6d7b344..1ea104a0ee38 100644
--- a/dev-python/mautrix/Manifest
+++ b/dev-python/mautrix/Manifest
@@ -1,2 +1,2 @@
-DIST mautrix-0.20.3.tar.gz 243007 BLAKE2B eb273fbe0810c7bfbbf8a2c9f88b72012c358122b96d0293323a3ade0135624133e205116e3a0dba14c694e0351938ab7196b880fa36448f74f72c6c026d1a53 SHA512 646693244305fa7cd5079d9a595d91e9d7253035139b841c4247dbbca5211d87d219d027669304765625ac17a1a8389a454045f8b06b47b13ba344c5134080af
+DIST mautrix-0.20.4.gh.tar.gz 244467 BLAKE2B adbab30c4b4e08b2def968bc7b85c4402cf32cfa4f15b17c8ba126a93230e2d84c6a43a3cc8bd0fe409d4fd1f9129a65c89d68ae61aaecd869cbf62480ff2883 SHA512 30a1a82fdb6875cd24dc685c567ad9c73eaa2d6a25e188498bdfec452dc530c0efa4373d3a1d2b217c5238ee9f33fc2d892549ea576c2f487f942a38eb8363d5
 DIST mautrix-0.20.4.tar.gz 243441 BLAKE2B 8aadbe0147585dbd8c8d019fdbdbbcdd14f8ff3717ef9894abf431a1fe34e6fc8bc1a0dfb27235a04ff48aea60f19f6ee1d362b5712bfe7a1f2be51f774fa8bc SHA512 57bc8a975702d8ab1f5cc28a2d8556a4fb346b299dd9c6f8c1c55c177aaabb1a0a198c4becb9eb8fd7887b142b7ffd6ca3031859d1ea417307fa265c7e4877ba
diff --git a/dev-python/mautrix/mautrix-0.20.3.ebuild b/dev-python/mautrix/mautrix-0.20.3.ebuild
deleted file mode 100644
index 4ad539e05f0f..000000000000
--- a/dev-python/mautrix/mautrix-0.20.3.ebuild
+++ /dev/null
@@ -1,39 +0,0 @@
-# Copyright 2022-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{8,9,10,11,12} )
-
-inherit distutils-r1 optfeature pypi
-
-DESCRIPTION="A Python 3 asyncio Matrix framework"
-HOMEPAGE="https://github.com/mautrix/python/"
-
-LICENSE="MPL-2.0"
-SLOT="0"
-KEYWORDS="~amd64"
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	dev-python/aiohttp[${PYTHON_USEDEP}]
-	dev-python/attrs[${PYTHON_USEDEP}]
-	dev-python/python-olm[${PYTHON_USEDEP}]
-	dev-python/pycryptodome[${PYTHON_USEDEP}]
-	dev-python/unpaddedbase64[${PYTHON_USEDEP}]
-	dev-python/yarl[${PYTHON_USEDEP}]
-	test? (
-		dev-python/aiosqlite[${PYTHON_USEDEP}]
-		dev-python/asyncpg[${PYTHON_USEDEP}]
-		<dev-python/sqlalchemy-2[${PYTHON_USEDEP}]
-	)
-"
-DEPEND="${RDEPEND}"
-
-distutils_enable_tests pytest
-
-pkg_postinst() {
-	optfeature "media transcoding" media-video/ffmpeg
-}
diff --git a/dev-python/mautrix/mautrix-0.20.4-r1.ebuild b/dev-python/mautrix/mautrix-0.20.4-r1.ebuild
new file mode 100644
index 000000000000..165e818f76b3
--- /dev/null
+++ b/dev-python/mautrix/mautrix-0.20.4-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+inherit edo databases distutils-r1 optfeature
+
+DESCRIPTION="A Python 3 asyncio Matrix framework"
+HOMEPAGE="
+	https://pypi.org/project/mautrix/
+	https://github.com/mautrix/python
+"
+
+# use github tarball for test data
+SRC_URI="https://github.com/mautrix/python/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/python-${PV}"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="crypt"
+REQUIRED_USE="test? ( crypt )"
+
+RDEPEND="
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/attrs[${PYTHON_USEDEP}]
+	dev-python/yarl[${PYTHON_USEDEP}]
+	crypt? (
+		dev-python/python-olm[${PYTHON_USEDEP}]
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+		dev-python/unpaddedbase64[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	test? (
+		dev-python/aiosqlite[${PYTHON_USEDEP}]
+		dev-python/asyncpg[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+		$(epostgres --get-depend)
+	)
+"
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme
+
+src_test() {
+	local -x PGHOST="$(epostgres --get-sockdir)"
+	local -x PGPORT="65432"
+	local -x PGUSER="postgres"
+	local -x MEOW_TEST_PG_URL="postgresql:///meow"
+
+	epostgres --start ${PGPORT}
+	edo createdb -U postgres meow
+
+	distutils-r1_src_test
+	epostgres --stop
+}
+
+pkg_postinst() {
+	optfeature "MIME type detection support" dev-python/python-magic
+	optfeature "media transcoding support" media-video/ffmpeg
+}
diff --git a/dev-python/notebook/Manifest b/dev-python/notebook/Manifest
index b656c00f49d4..523464a2b743 100644
--- a/dev-python/notebook/Manifest
+++ b/dev-python/notebook/Manifest
@@ -1 +1,2 @@
 DIST notebook-7.0.6.tar.gz 3930144 BLAKE2B 488689b34b61c37f2233d57d6ef75b3bf843e2340846e88593a6b49d88fc52f908126d2e718808451df1f8cc6f9a5624adef47c1ae4984cd2ff5ed535d47cb37 SHA512 9f9ac4fae93af425a442c25c8a601578a76c802cc50018a6ff6ef99fbabfe3fb649094625dbdda2b7c526cb7262d2c463745b006d35cc1834d40712f3820895b
+DIST notebook-7.0.7.tar.gz 3936954 BLAKE2B 9171ae3974bd4eb36c804858224c386292a3772633017a8bf0c0ef408526278234b022087faad7930aa975c66762690e24a5a368bf9290937bdc8dff63757575 SHA512 05725f6bae2d916c9393f483a05696f6eb0e38a1b15a8427cbd61f508a06d78ead8a70c8764a00403c323b25a1278ea3a8daaf1ff5b5eeb0b35f6ed5e64ea638
diff --git a/dev-python/notebook/notebook-7.0.7.ebuild b/dev-python/notebook/notebook-7.0.7.ebuild
new file mode 100644
index 000000000000..0dabc7a0aa6a
--- /dev/null
+++ b/dev-python/notebook/notebook-7.0.7.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi xdg-utils
+
+DESCRIPTION="Jupyter Interactive Notebook"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter/notebook/
+	https://pypi.org/project/notebook/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/jupyter-server-2.4.0[${PYTHON_USEDEP}]
+	<dev-python/jupyter-server-3[${PYTHON_USEDEP}]
+	>=dev-python/jupyterlab-4.0.2[${PYTHON_USEDEP}]
+	<dev-python/jupyterlab-5[${PYTHON_USEDEP}]
+	>=dev-python/notebook-shim-0.2[${PYTHON_USEDEP}]
+	<dev-python/notebook-shim-0.3[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.2.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/hatch-jupyter-builder[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/nbval[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+		dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+		dev-python/pytest-jupyter[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_install_all() {
+	distutils-r1_python_install_all
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
diff --git a/dev-python/oscrypto/oscrypto-1.3.0-r1.ebuild b/dev-python/oscrypto/oscrypto-1.3.0-r1.ebuild
index 257aab1960fa..986154db08d5 100644
--- a/dev-python/oscrypto/oscrypto-1.3.0-r1.ebuild
+++ b/dev-python/oscrypto/oscrypto-1.3.0-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -24,7 +24,7 @@ RDEPEND="
 "
 BDEPEND="
 	test? (
-		virtual/python-cffi[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/cffi[${PYTHON_USEDEP}]' 'python*')
 	)
 "
 
diff --git a/dev-python/psycopg2cffi/psycopg2cffi-2.9.0-r1.ebuild b/dev-python/psycopg2cffi/psycopg2cffi-2.9.0-r1.ebuild
index 36fa1e462053..0fa0c3288ca3 100644
--- a/dev-python/psycopg2cffi/psycopg2cffi-2.9.0-r1.ebuild
+++ b/dev-python/psycopg2cffi/psycopg2cffi-2.9.0-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2019-2023 Gentoo Authors
+# Copyright 2019-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -24,7 +24,7 @@ RDEPEND="
 	dev-python/six[${PYTHON_USEDEP}]
 "
 BDEPEND="
-	virtual/python-cffi[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/cffi[${PYTHON_USEDEP}]' 'python*')
 	test? (
 		$(epostgres --get-depend)
 	)
diff --git a/dev-python/pydantic/Manifest b/dev-python/pydantic/Manifest
index 54450b903b76..5bac6e2a71ef 100644
--- a/dev-python/pydantic/Manifest
+++ b/dev-python/pydantic/Manifest
@@ -1,4 +1,5 @@
 DIST pydantic-1.10.13.gh.tar.gz 766572 BLAKE2B 3d4f4453469f960467ddf3512be8e97f0abf40406d441a1bc8909df1ebc0e7deaa5e84640d8614395e36d619e87f9d47327cd71526dae203046488d114ade49f SHA512 7ae96c08080e9d3bf3b66ee8ee77efc0b89b6630d4f0c37679e27a28a6433b3628fd342991cf38412ff6d1034c4a907841f74759c2e6b4d51d413d76625d5bfd
+DIST pydantic-1.10.14.gh.tar.gz 767164 BLAKE2B 0018f8db7f0d1e1063e9cf58047319f317aee968cd07837a1983c4283ef317a54d45d717829d2b7e4d5ae6257137a125372323322873fe3354c709ed096f320c SHA512 ba90fc57172b395398b87cac44778e842fba2d28c31d8d90ad49bf870c27da71b9eef2a5cf786b0de0a3ee84af187c0759b8b27a42edaa0feb7183a2b99aa52a
 DIST pydantic-2.4.2.tar.gz 654020 BLAKE2B 2f91b6bf89f87230976a2e777541bb7418382fb3534f5e61e1dc74a18e5e939508a2440d6bee9a09030beb5f2b6a60fd62c3bf30ee0ee2c7d3f71575920a47f3 SHA512 f0e0d90ead4ba754974b38f8e3d24bc017696674ca1ed3300104389d149baa41c495218a118f5e7f98bf20d34b3c17439921eaff0ccd7bf76cac96a16e592b4e
 DIST pydantic-2.5.1.tar.gz 651461 BLAKE2B 4c52abec0f1fc52fdaa0bd820bbb649ffdc348c1b1537ca31b73bf4c4477055841c0cd08df5336e0388974ebe20c384349c4233af20149317d79f51ee98208c6 SHA512 5a3ca05a57297cded56a21f37e13a61e7abce3faa34b1d2f4ad1abab0205aa8b7f753b6e0ac630336ea398b9c5ebd4c7cab55df4fa0f9e965e07b5a7e9d49f3c
 DIST pydantic-2.5.2.tar.gz 652158 BLAKE2B d3a7eeb4e1933d4893df69d2600437a4df1a640f4ec6564079669f8703b8d21bba548197277a373e5a653f4aea67de2336ea983906c2e96b514cdab3f8821dc1 SHA512 56753c9739759251004476620ca25d69bebc7743da911f69a09fcbffa6d6e5ec9b9fc22975e845599fcb2aed5cbbf081c3737d6eab55b9e1696818c4da405e6d
diff --git a/dev-python/pydantic/pydantic-1.10.14.ebuild b/dev-python/pydantic/pydantic-1.10.14.ebuild
new file mode 100644
index 000000000000..af1f52e4b616
--- /dev/null
+++ b/dev-python/pydantic/pydantic-1.10.14.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/_beta/b}
+DESCRIPTION="Data parsing and validation using Python type hints"
+HOMEPAGE="
+	https://github.com/pydantic/pydantic/
+	https://pypi.org/project/pydantic/
+"
+SRC_URI="
+	https://github.com/pydantic/pydantic/archive/v${PV/_beta/b}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="native-extensions"
+
+RDEPEND="
+	>=dev-python/typing-extensions-4.1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	native-extensions? (
+		<dev-python/cython-3[${PYTHON_USEDEP}]
+	)
+	test? (
+		>=dev-python/email-validator-1.2.1[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/python-dotenv[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/CFLAGS/d' setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	if [[ ${EPYTHON} == pypy3 ]] || ! use native-extensions; then
+		# do not build extensions on PyPy to workaround
+		# https://github.com/cython/cython/issues/4763
+		local -x SKIP_CYTHON=1
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=pytest_mock
+
+	local EPYTEST_DESELECT=(
+		# flaky test, known upstream
+		tests/test_hypothesis_plugin.py::test_can_construct_models_with_all_fields
+		# mypy linting causes regressions with new mypy versions
+		tests/mypy
+	)
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				tests/test_private_attributes.py::test_private_attribute
+				tests/test_private_attributes.py::test_private_attribute_annotation
+				tests/test_private_attributes.py::test_private_attribute_factory
+				tests/test_private_attributes.py::test_private_attribute_multiple_inheritance
+				tests/test_private_attributes.py::test_underscore_attrs_are_private
+				tests/test_validators.py::test_annotated_validator_builtin
+			)
+			;;
+		python3.12)
+			EPYTEST_DESELECT+=(
+				tests/test_abc.py::test_model_subclassing_abstract_base_classes_without_implementation_raises_exception
+				tests/test_generics.py::test_partial_specification_name
+				tests/test_generics.py::test_parse_generic_json
+				tests/test_types.py::test_secretfield
+			)
+			;;
+	esac
+	rm -rf pydantic || die
+	epytest
+}
diff --git a/dev-python/pydata-sphinx-theme/Manifest b/dev-python/pydata-sphinx-theme/Manifest
index c66677b50204..4a3892249123 100644
--- a/dev-python/pydata-sphinx-theme/Manifest
+++ b/dev-python/pydata-sphinx-theme/Manifest
@@ -1,2 +1,4 @@
 DIST pydata-sphinx-theme-0.15.1.gh.tar.gz 2408417 BLAKE2B ce5f21c2f9f2b94a7fc7d907c44527459e46c735e3c7bf39966b2402acf94948d9f91941962598d61b992f33b8fde2381e8c5649e9593386572ee79712160f4f SHA512 34eccf49c69e55999e6af2797c0c861f49c43c0d014f05b200ee40cfd703abaecd90be9aaf52409556b9d5acff6238ce09040959a7a07f4dc285a6d40ecfc912
+DIST pydata-sphinx-theme-0.15.2.gh.tar.gz 2409617 BLAKE2B ee9405e36241bfac93927e4de2d12f65b95717e459b1f584179f0d7ad2c5161b85b39ef60527de8b2e0eac8a38621452e3a5dcf15733980359b4f03526a906bb SHA512 11653f36def68ddc63994d00e1de63575ce6a24f7b2887c53ea8c3063bdc30fe57baf25e239a70f63a1598625a3707ac405171230c977d7e0ed3f88404c8cd21
 DIST pydata_sphinx_theme-0.15.1-py3-none-any.whl 4521543 BLAKE2B c5e20e42ce2fd32a46b39037fe680c2ec6a420cc76a02dc1c391f633e3a164de28d107834add9b427e5f27afde0a86e8d32287084c10959cf444f5580a3fb231 SHA512 13ebf72548c963fa850aa2da9d73863cc4c771c7db5a5d90a18af3408f2cf3d75d908aa40c16dfe098941ec5128a0117e5c29aab3e3119715207af28e3a6f8d5
+DIST pydata_sphinx_theme-0.15.2-py3-none-any.whl 4523706 BLAKE2B fdb3ca53d26b7da882b9530929bb41729d77af6aef8c5748c41ab9ea4b43cdc858dd3f270432c18accc59e5408a267125f840b4ed2815d0cda7e748afffa90d0 SHA512 60c00161768cb0259462e7af16b8d2324ddc367391d83efcb34dd7999364b2745795cb6807a903f80cfaf21bd8b2b466cbee3fa9cb800be4221955ab888481d0
diff --git a/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.15.2.ebuild b/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.15.2.ebuild
new file mode 100644
index 000000000000..14f577fd28cf
--- /dev/null
+++ b/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.15.2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Bootstrap-based Sphinx theme from the PyData community"
+HOMEPAGE="
+	https://github.com/pydata/pydata-sphinx-theme/
+	https://pypi.org/project/pydata-sphinx-theme/
+"
+SRC_URI="
+	https://github.com/pydata/pydata-sphinx-theme/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	$(pypi_wheel_url)
+"
+
+LICENSE="BSD-with-disclosure"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/accessible-pygments[${PYTHON_USEDEP}]
+	dev-python/Babel[${PYTHON_USEDEP}]
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/sphinx-5[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-regressions[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_compile() {
+	distutils_wheel_install "${BUILD_DIR}/install" \
+		"${DISTDIR}/$(pypi_wheel_name)"
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)/pydata_sphinx_theme" || die
+	epytest "${S}"/tests
+}
diff --git a/dev-python/pyfakefs/Manifest b/dev-python/pyfakefs/Manifest
index f0f010b66f22..3b0126ee9321 100644
--- a/dev-python/pyfakefs/Manifest
+++ b/dev-python/pyfakefs/Manifest
@@ -1 +1,2 @@
 DIST pyfakefs-5.3.2.gh.tar.gz 225929 BLAKE2B 1a84f52e8d85b55d2ebc0dcf9c4b44bd053c0a3a12d6c47c1f8d5aec304e39a83ffb01d4c707929955ca5cd86ae9427332d5bf043cb7f910fe1d17fbcc19e35c SHA512 4cc2c861fa358c06832df6e8a7cfc91e2b9be42f1164378ea6bd0a3a6cc48f36c545b7d61e03591d025ef7bd98fdc812f903973f28a278056961aec22ca88641
+DIST pyfakefs-5.3.4.gh.tar.gz 226538 BLAKE2B b0cac2799c7d9517a1fc89d15cf92222dc5d5438ba4c43bc8796afbf77c2c7a2729bf42e1b57b1fb3777a91aa0fa12e0d6a0a6e0068855fba86bf6e372bac28e SHA512 10c56af0b871b8b8ce483d01234ebba953b038fd030edf4f0fedcb5b23ee897c912d9e9404521ec11f9e8d0d041d4bde4f101a4d99b3b527721c4c291c2a6745
diff --git a/dev-python/pyfakefs/pyfakefs-5.3.4.ebuild b/dev-python/pyfakefs/pyfakefs-5.3.4.ebuild
new file mode 100644
index 000000000000..6cfb5f72f231
--- /dev/null
+++ b/dev-python/pyfakefs/pyfakefs-5.3.4.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A fake file system that mocks the Python file system modules"
+HOMEPAGE="
+	https://github.com/pytest-dev/pyfakefs/
+	https://pypi.org/project/pyfakefs/
+"
+SRC_URI="
+	https://github.com/pytest-dev/pyfakefs/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=()
+	local EPYTEST_IGNORE=(
+		# test for regression with opentimelineio package
+		pyfakefs/pytest_tests/segfault_test.py
+		# test for regression with undefined package
+		pyfakefs/pytest_tests/pytest_fixture_test.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pyfakefs.pytest_plugin
+}
diff --git a/dev-python/pypdf/Manifest b/dev-python/pypdf/Manifest
index 8a36b64c5569..86b402ab63b5 100644
--- a/dev-python/pypdf/Manifest
+++ b/dev-python/pypdf/Manifest
@@ -1,2 +1,3 @@
 DIST pypdf-3.17.4.gh.tar.gz 7976829 BLAKE2B c2b7aef937186aecf525729f336ad6d00a8bf40850be17cb450daba5d0100acc0b0c3f51ef242e3cf7ef710d5c40c9f334db94a372b6d6eb4f2270dc00dde156 SHA512 f687a2032f085dac9b920f881f2df9f96e4da2a8dcdd5f971d3601ab05ae4f9b5528d0155adcb5ef01c6d8ffdc4f3d79077706915851bad7868bf761d28c513a
+DIST pypdf-4.0.0.gh.tar.gz 7992828 BLAKE2B 97ab3783ab91ebc638b625fe39c3008516de82f1ac384a45ef27a06bb0b91a86a5fdc24efbb92644a4355743b24e86f68822858eef2df39a3b6415795276c7c4 SHA512 488adffc330bb372df245d2dfdaee357bcd4303cc33d7ee31fd7abc393ce366c78715ca4a6516795ada6b5517ca32fec5f24cdad15e0d2c109fa90ebd2f9b05c
 DIST pypdf-sample-files-964fb47b0fbfa89864680582640ae4eedf143890.gh.tar.gz 11668924 BLAKE2B 0c7d8e7cfb2f9d06d7633d57b691ba473d33cfcb58d2f1f83661cef9d755340d05db8767771a385d0ba88aa904f84b8bc7eafdb5d4f614b7a21a2d138572316f SHA512 28070b575273b6fee3173e797ed5bac618f8e8aca16d0122dcf3b4b16cedbcad69b84a9bc4be65037695597bcc1fa7898cdf766c37915c49f880a0c6ca057e68
diff --git a/dev-python/pypdf/pypdf-4.0.0.ebuild b/dev-python/pypdf/pypdf-4.0.0.ebuild
new file mode 100644
index 000000000000..4dd13c1f8f30
--- /dev/null
+++ b/dev-python/pypdf/pypdf-4.0.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+SAMPLE_COMMIT=964fb47b0fbfa89864680582640ae4eedf143890
+DESCRIPTION="Python library to work with PDF files"
+HOMEPAGE="
+	https://pypi.org/project/pypdf/
+	https://github.com/py-pdf/pypdf/
+"
+SRC_URI="
+	https://github.com/py-pdf/pypdf/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	test? (
+		https://github.com/py-pdf/sample-files/archive/${SAMPLE_COMMIT}.tar.gz
+			-> ${PN}-sample-files-${SAMPLE_COMMIT}.gh.tar.gz
+	)
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		>=dev-python/pillow-8.0.0[jpeg,jpeg2k,tiff,${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	tests/test_reader.py::test_decode_permissions
+	tests/test_workflows.py::test_text_extraction_layout_mode
+	# rely on -Werror
+	tests/test_utils.py::test_deprecate_no_replacement
+	tests/test_workflows.py::test_orientations
+	tests/test_writer.py::test_remove_image_per_type
+	# TODO: requires fpdf
+	tests/test_page.py::test_compression
+	tests/test_writer.py::test_merging_many_temporary_files
+)
+
+src_unpack() {
+	default
+	if use test; then
+		mv "sample-files-${SAMPLE_COMMIT}"/* "${S}"/sample-files/ || die
+	fi
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -o addopts= -m "not enable_socket"
+}
diff --git a/dev-python/python-olm/python-olm-3.2.15.ebuild b/dev-python/python-olm/python-olm-3.2.15.ebuild
index 9b9bec966cd5..d42c93cbb0fb 100644
--- a/dev-python/python-olm/python-olm-3.2.15.ebuild
+++ b/dev-python/python-olm/python-olm-3.2.15.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2022-2023 Gentoo Authors
+# Copyright 2022-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -19,8 +19,8 @@ KEYWORDS="~amd64"
 DEPEND="dev-libs/olm"
 RDEPEND="
 	${DEPEND}
+	dev-python/cffi[${PYTHON_USEDEP}]
 	dev-python/future[${PYTHON_USEDEP}]
-	virtual/python-cffi[${PYTHON_USEDEP}]
 "
 BDEPEND="
 	test? (
diff --git a/dev-python/python-olm/python-olm-3.2.16.ebuild b/dev-python/python-olm/python-olm-3.2.16.ebuild
index 160c258ea5fc..fa1aefa13aba 100644
--- a/dev-python/python-olm/python-olm-3.2.16.ebuild
+++ b/dev-python/python-olm/python-olm-3.2.16.ebuild
@@ -20,9 +20,7 @@ KEYWORDS="~amd64"
 DEPEND="dev-libs/olm"
 RDEPEND="
 	${DEPEND}
-	$(python_gen_cond_dep '
-		dev-python/cffi[${PYTHON_USEDEP}]
-	' 'python*')
+	dev-python/cffi[${PYTHON_USEDEP}]
 "
 BDEPEND="
 	test? ( dev-python/aspectlib[${PYTHON_USEDEP}] )
diff --git a/dev-python/skia-pathops/skia-pathops-0.7.4.ebuild b/dev-python/skia-pathops/skia-pathops-0.7.4.ebuild
index 44edc2cbf399..2226fff1a225 100644
--- a/dev-python/skia-pathops/skia-pathops-0.7.4.ebuild
+++ b/dev-python/skia-pathops/skia-pathops-0.7.4.ebuild
@@ -26,7 +26,7 @@ BDEPEND="
 	app-alternatives/ninja
 	app-arch/unzip
 	<dev-python/cython-3[${PYTHON_USEDEP}]
-	dev-util/gn
+	dev-build/gn
 "
 
 PATCHES=( "${FILESDIR}"/${PN}-0.7.4-no-net.patch )
diff --git a/dev-python/skia-pathops/skia-pathops-0.8.0.ebuild b/dev-python/skia-pathops/skia-pathops-0.8.0.ebuild
index a007e9d4f900..4983f6e8e45e 100644
--- a/dev-python/skia-pathops/skia-pathops-0.8.0.ebuild
+++ b/dev-python/skia-pathops/skia-pathops-0.8.0.ebuild
@@ -27,7 +27,7 @@ BDEPEND="
 	app-alternatives/ninja
 	app-arch/unzip
 	dev-python/cython[${PYTHON_USEDEP}]
-	dev-util/gn
+	dev-build/gn
 "
 
 PATCHES=( "${FILESDIR}"/${PN}-0.7.4-no-net.patch )
diff --git a/dev-python/sphinx-issues/Manifest b/dev-python/sphinx-issues/Manifest
index 5083982df452..363165e3713b 100644
--- a/dev-python/sphinx-issues/Manifest
+++ b/dev-python/sphinx-issues/Manifest
@@ -1 +1,2 @@
 DIST sphinx-issues-3.0.1.gh.tar.gz 12320 BLAKE2B 770aa19a443bacd489157244f087fdb99740d5eae2f45246ab0fd0596260f249dcf7fb0642acf0a925d1a1def08f6d944a2ec67017334843b636623b05df8327 SHA512 dd64e1611eb58fc455bedb1658473fd71e4deab1371d8a42e6fa7fe3b128a991251add12e463b9a5826fd4eb5aa12e9a117dcf953feeb8df980a7951e43d8baa
+DIST sphinx_issues-4.0.0.tar.gz 13945 BLAKE2B 43994155a5040b63f34f48b2ddf8f39cf36bd97fc464619f1adb55a2c9b433fb5c1c65f8cd5b2f7928afbd5ebbbbad67c69490ae67aaf220c0a5cf8c44876b69 SHA512 77e249c9ccd9dec96e64ba898e8cf2d1922c6190ad67e9d4d823a4d08d3c07bae217a8bf51c193fc5331c289e53ce6f93ae3d685ac9a618d41f565930557dabb
diff --git a/dev-python/sphinx-issues/sphinx-issues-4.0.0.ebuild b/dev-python/sphinx-issues/sphinx-issues-4.0.0.ebuild
new file mode 100644
index 000000000000..bf3f0f9b3765
--- /dev/null
+++ b/dev-python/sphinx-issues/sphinx-issues-4.0.0.ebuild
@@ -0,0 +1,30 @@
+# Copyright 2019-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Sphinx extension for linking to your project's issue tracker"
+HOMEPAGE="
+	https://github.com/sloria/sphinx-issues/
+	https://pypi.org/project/sphinx-issues/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x64-solaris"
+
+RDEPEND="
+	dev-python/sphinx[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# doesn't work in our pep517 install
+	tests/test_sphinx_issues.py::test_sphinx_build_integration
+)
diff --git a/dev-python/templated-dictionary/Manifest b/dev-python/templated-dictionary/Manifest
index 91930005f293..f3a177a951cf 100644
--- a/dev-python/templated-dictionary/Manifest
+++ b/dev-python/templated-dictionary/Manifest
@@ -1 +1 @@
-DIST templated-dictionary-1.2.tar.gz 11036 BLAKE2B 4126de9e846246e818f9ff57ed20a9d077570290dce9ecc96e33354d3149bf77a48da52e409ad9a9dd408a553e1992372235e5e74d52a39f79782e1408695fce SHA512 65d32a12fd38dd372b41d8650031d3ce948578e0bf9852d53b89c479d48628b12197e0049c3d523dabe49b52056ceac56d396412f715c845a6d510b8b8b16f60
+DIST templated-dictionary-1.4.gh.tar.gz 15384 BLAKE2B 50e5cb2762433526c6eed4f3f77050aae4c9d3a99b4340f1f8b0730825761be03e85b456855939089b26c807acd800d122d2dda5a688d73ab342c31d8af1d797 SHA512 d0c01cf53688192d29cea24d98e86d9f3f555c73ddbdf36297c0e0974b75b88257deb1a70a61e7197f90d6c62ce24fa524d4cdba561742401a439e45ae549fc1
diff --git a/dev-python/templated-dictionary/templated-dictionary-1.2.ebuild b/dev-python/templated-dictionary/templated-dictionary-1.4.ebuild
index 261164180784..4d2be7ceca51 100644
--- a/dev-python/templated-dictionary/templated-dictionary-1.2.ebuild
+++ b/dev-python/templated-dictionary/templated-dictionary-1.4.ebuild
@@ -1,19 +1,20 @@
-# Copyright 2023 Gentoo Authors
+# Copyright 2023-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
-PYPI_NO_NORMALIZE=1
 PYTHON_COMPAT=( python3_{8,9,10,11,12} )
 
-inherit distutils-r1 pypi
+inherit distutils-r1
 
 DESCRIPTION="Python dictionary with Jinja2 expansion"
 HOMEPAGE="
 	https://github.com/xsuchy/templated-dictionary/
 	https://pypi.org/project/templated-dictionary/
 "
+SRC_URI="https://github.com/xsuchy/templated-dictionary/archive/refs/tags/python-${P}-1.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${PN}-python-${P}-1"
 
 SLOT="0"
 LICENSE="GPL-2+"