Adding metadata

18 files changed, 442 insertions, 3 deletions

diff --git a/dev-python/aesara/Manifest b/dev-python/aesara/Manifest
index 3eebd69eefc3..00e059d45c9c 100644
--- a/dev-python/aesara/Manifest
+++ b/dev-python/aesara/Manifest
@@ -2,3 +2,4 @@ DIST aesara-rel-2.2.2.tar.gz 8174668 BLAKE2B c95347e8b74f6600c3570177f86b7ebd751
 DIST aesara-rel-2.2.3.tar.gz 8179701 BLAKE2B 53ef58d6f0ab33e7efe3d0eaa2b55153a2ab29c958b48f52f814fecf7f5fa65424465470cde0ebb8d2ef1ced6968fd01217d9f7bd61acc8843cde1a9c0a94cbe SHA512 21414230c0be2c31e08fd371ee69c3bb7098b2134a5aec006abeca00a333e025fcbfd10ebdcbf54d243e1bc8c45f301a2c3443531ba5eaf0fe3a1ac5645ae4f5
 DIST aesara-rel-2.2.4.tar.gz 8180599 BLAKE2B 2b5e6ce0b0cbf0405d312f5b7c842057f05378c240c4dd36818c1b9d1b57667494c2472537e039ab16fac702a30a692bba5c8d5fc8801eb0c7e492d7f8e059b3 SHA512 3e0fe0cfa37f3b597ab94778dca60368aedbf9df79b4bb79812a190d77743addd1ddf5f234bf62c2dd744054204f03b84b358d0c58c27c28829b8fbe919bd151
 DIST aesara-rel-2.2.5.tar.gz 8180714 BLAKE2B 8c94d26df9244c95a58dcf0c7f8d733841f25aad63046b12264e8081bbb5a7debad82f48dc9b3119c87d8d4709f9016205aeff025235fce2dc381832c9f5a312 SHA512 9b28163277b358ebb5bc4d77d7fb9f0e47c4aad3eb92de4702148990fb7cd367c67e42d161465129695869a6c23f31251705c6a24ebd36f048259d70c32f9a65
+DIST aesara-rel-2.2.6.tar.gz 8180674 BLAKE2B 6d2c237a748aeee524e4182c47b17a9f7e7325d94410f8c9d7e3dea1d22306dbaa32be1b6f3c471baffad30527451772c08eaaed4494bcceba1759e9f7e9c837 SHA512 360f280fb997b33fbcef08a278816e51b26e8ba4f6d9b0681984394f293d342b498d4633d5efc1b92d64b056b4cd63b918ea7dd46d00aa78519e00919586f842
diff --git a/dev-python/aesara/aesara-2.2.6.ebuild b/dev-python/aesara/aesara-2.2.6.ebuild
new file mode 100644
index 000000000000..3cf1e5f99421
--- /dev/null
+++ b/dev-python/aesara/aesara-2.2.6.ebuild
@@ -0,0 +1,70 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1 multiprocessing optfeature
+
+MY_P=aesara-rel-${PV}
+DESCRIPTION="Library for operating on mathematical expressions with multi-dimensional arrays"
+HOMEPAGE="https://github.com/aesara-devs/aesara"
+SRC_URI="https://github.com/aesara-devs/aesara/archive/rel-${PV}.tar.gz -> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/filelock[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.17.0[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_sphinx doc 'dev-python/sphinx_rtd_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -i -e "s/tests.\*/tests\*/" setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local exclude=(
+		# speed tests are unreliable
+		tests/scan/test_basic.py::test_speed
+		tests/scan/test_basic.py::test_speed_rnn
+		tests/scan/test_basic.py::test_speed_batchrnn
+		tests/link/test_vm.py::test_speed
+		tests/link/test_vm.py::test_speed_lazy
+		tests/tensor/test_gc.py::test_merge_opt_runtime
+
+		# rounding problem?
+		# https://github.com/aesara-devs/aesara/issues/477
+		tests/tensor/test_math_scipy.py::TestGammaUBroadcast::test_good
+		tests/tensor/test_math_scipy.py::TestGammaUInplaceBroadcast::test_good
+	)
+
+	distutils_install_for_testing
+	# we do not package numba
+	epytest ${exclude[@]/#/--deselect } \
+		--ignore tests/link/test_numba.py \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
+
+# https://dev.gentoo.org/~mgorny/python-guide/concept.html#packaging-pkgutil-style-namespaces-in-gentoo
+python_install() {
+	rm "${BUILD_DIR}"/lib/bin/__init__.py || die
+	distutils-r1_python_install
+}
+
+pkg_postinst() {
+	optfeature "GPU code generation/execution on NVIDIA gpus" dev-util/nvidia-cuda-toolkit dev-util/nvidia-cuda-sdk
+	optfeature "GPU/CPU code generation on CUDA and OpenCL devices" dev-libs/libgpuarray dev-python/pycuda
+}
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 3ae3e8fbce96..b110176e6e19 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -5,3 +5,4 @@ DIST boto3-1.19.5.tar.gz 433567 BLAKE2B 52c12a4dd18d6f02326f8002b345cc5df224455f
 DIST boto3-1.19.6.tar.gz 434389 BLAKE2B 3c7e4c91c95b93358b4a31d401e03f8a397802004a6ee2bfc2ef1a31df8b89e8866fa73d3354509ae00537898cc8e04b878cc9d00f82ae4e94266e8185e7abd1 SHA512 6ba4f7a89d973991afe329b4c648c8ecb0bb256d63c7e60ae8bb70e6fd5fc9b1929168dfdd55f2c84039856a32c891013abf61dc2e65f516490c446b0dfaaac2
 DIST boto3-1.19.7.tar.gz 434848 BLAKE2B 102b2d985cbad6c6ff6fc7866f47c172028e4b1a56ef7eac5854b12aedfbca1b94eb426fead04397e119ebaf939f7732202718395775b0555f566ed938c27dc7 SHA512 40cf5341bfd7cc4cae4c542e39e4c5ec1b63ba3bfee5faedb75633e656700dd5e80a137b234b57d22cc1b7d85a2056ced4eb8b7189ab57c8f2c0269e8826811d
 DIST boto3-1.19.8.tar.gz 435192 BLAKE2B 2cec7fe3a114ef349e4afc15f15315d351de93ecae3439946d9936effa257e55a88f6605b33e13ca927a245e99ad60b0c9c356320be6e4f95a99e52c6ff8da11 SHA512 f1038a0103f09c4bb20d4feb30abf3e2be2535d8e9e0e807e4d98f20ac27f27f0260b274c1b6e6b91f00c5d3e4206a92ab1cd80029f2b0720241d98356f688e7
+DIST boto3-1.19.9.tar.gz 435493 BLAKE2B 7f1485c51816ab4c0c52e47f110eebf5b9fd989e695d24daa0bf38fa9fbe09c2dd40758ece655d3e2734e88ad4aa73e606b951ea39b3fe718c6ad1498d7a52d4 SHA512 9cfb454af95d92c68cfd4e12d285ae4c43084d818c3fe75d98929a42eedcf04574e96663b69db6204cab211352dd59254e6c53fb4c3c03bc6ed896d805e6e59e
diff --git a/dev-python/boto3/boto3-1.19.9.ebuild b/dev-python/boto3/boto3-1.19.9.ebuild
new file mode 100644
index 000000000000..30a0b44d3f8c
--- /dev/null
+++ b/dev-python/boto3/boto3-1.19.9.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 6ffdbb992fdb..98b34aba7d2a 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -5,3 +5,4 @@ DIST botocore-1.22.5.tar.gz 8301083 BLAKE2B 91f9d38e7c5bcb0b8f58c04547ad45489f58
 DIST botocore-1.22.6.tar.gz 8302901 BLAKE2B 4627c7bfcbd1750a6517c045b7c7c986c6defb9b35e413fae47e03fe24f3404ff4905c714212ad00193eb4dfa2893a0080da97acb538965a8792278915823a3b SHA512 f39eb6f339011709fa764d3783f225fbd4e4100e51466de9c87d6a3a5430823e81be1b024963ded49785b4fd49febdfa66dd3f91c3b9296508c3d71d794d170d
 DIST botocore-1.22.7.tar.gz 8306878 BLAKE2B fd427ced3eb3c2ce71a28f7334ee312293fc98c7b2d91991ce6c894f71bd39b356aa3a2f0a0495fd91e394be4d284b21dc8272863e9568167112aadccaed21a6 SHA512 39eaa5d4bc64669bc398797c69d63157a6a4539bed1c4cdc492c4fe94c9a32d58ac9ea8c06fafd75a5c36ab9d3a5c99f88990b03bcef6cccf7e0c4247330780b
 DIST botocore-1.22.8.tar.gz 8316687 BLAKE2B 0ea2bfbf794d156e5843687927980d4dc9e4243c00ec6ee3175dd02cf7d99a10e549b06eb377edb52b73ca64e4e97e6c03c96389773f5ac87f648a6ec6a89398 SHA512 d35748c240ad83155c5d97b044569e1d7093469acdac948d4ce396b1f17563ed5e9bbfa91799a87fabd93df3b63724be096d489be909aa1567d59e6bafe99e03
+DIST botocore-1.22.9.tar.gz 8325440 BLAKE2B 9d1612941e37446e030178eec54fd17ee4b9ad4bd43a943a09cc53cf343e5dee7f568702da5f1110ddfc4c814c2aef3997dd72c2e07445ad3287044ffc77a34c SHA512 6be85c95fd9ddd7f7756a337b696433c0d7c3d67fd33e2c3249914fd9db957b16d89b54551bfad58e79292becc054220efb70c45af234b92009e0de72e95a512
diff --git a/dev-python/botocore/botocore-1.22.9.ebuild b/dev-python/botocore/botocore-1.22.9.ebuild
new file mode 100644
index 000000000000..9cd77a5ad4d0
--- /dev/null
+++ b/dev-python/botocore/botocore-1.22.9.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/cherrypy/cherrypy-18.6.1.ebuild b/dev-python/cherrypy/cherrypy-18.6.1.ebuild
index 9f86cfaf56fe..586d80406aec 100644
--- a/dev-python/cherrypy/cherrypy-18.6.1.ebuild
+++ b/dev-python/cherrypy/cherrypy-18.6.1.ebuild
@@ -9,7 +9,7 @@ inherit distutils-r1
 MY_P="CherryPy-${PV}"
 
 DESCRIPTION="CherryPy is a pythonic, object-oriented HTTP framework"
-HOMEPAGE="https://pypi.org/project/CherryPy/"
+HOMEPAGE="https://cherrypy.dev https://pypi.org/project/CherryPy/"
 SRC_URI="mirror://pypi/C/CherryPy/${MY_P}.tar.gz"
 S="${WORKDIR}/${MY_P}"
 
diff --git a/dev-python/google-api-python-client/Manifest b/dev-python/google-api-python-client/Manifest
index 0d066840e575..28b7a60f9bbf 100644
--- a/dev-python/google-api-python-client/Manifest
+++ b/dev-python/google-api-python-client/Manifest
@@ -1,2 +1,3 @@
 DIST google-api-python-client-2.27.0.tar.gz 27434968 BLAKE2B 95575f70ec3a7cb71a252495c8daa74ee06fc5499c4b9febbb4f492db9d043e1a67d78bb7a5cafb64bf50697922b1b5f92cf8e5d023fab762cd4dc585507d139 SHA512 7486cb120ca726a7ba57e8629e6e369c49d1de4459986c1458d087fd1c01be2979ac0d30697d50adbb1ff67c0d262e68bb17c7f43e1148db62d04b7befe3af2f
 DIST google-api-python-client-2.28.0.tar.gz 27582046 BLAKE2B 84803c124bdda7d93a28b9690848ab2a41bcb1327feb26cb13c17b395f6fa57d86cb4ae01095966cf5423a821c49996931dde45f95d5f23fedc05e09f875de3a SHA512 d9cbec2ad600af281df2ad6db34d146a37b8248240357d7bc8a7c651d06029dc9dba2e408aa6b7f364e30ffd2b063926e67b184d90ff66f771974ca84979d8db
+DIST google-api-python-client-2.29.0.tar.gz 27697101 BLAKE2B e8c9ea3e6a0ff89dce9baef9328dd6a424b096cafe00504f28b516c753c5e9a861fe472edd3e980861c244b0642589cddf537f9a0a37ec9e089ea533b8b5d22c SHA512 c842c16496349fff2ba9522fc7144342024fcb056a79c50350c9fdd01a44f843aaaf5c7f8058595029815c0b9d4d7014ea41d28647dae6780a4dc9ee1bcddad2
diff --git a/dev-python/google-api-python-client/google-api-python-client-2.29.0.ebuild b/dev-python/google-api-python-client/google-api-python-client-2.29.0.ebuild
new file mode 100644
index 000000000000..7602d879caea
--- /dev/null
+++ b/dev-python/google-api-python-client/google-api-python-client-2.29.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Google API Client for Python"
+HOMEPAGE="https://github.com/googleapis/google-api-python-client"
+SRC_URI="https://github.com/googleapis/google-api-python-client/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/httplib2-0.15[${PYTHON_USEDEP}]
+	<dev-python/httplib2-1[${PYTHON_USEDEP}]
+	dev-python/google-api-core[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.35.0[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-httplib2-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/uritemplate-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/uritemplate-5[${PYTHON_USEDEP}]
+	"
+# grpcio support is broken if grpcio-status is not installed,
+# and we do not package the latter
+BDEPEND="
+	test? (
+		!!dev-python/grpcio
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/oauth2client[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests --install pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# require Internet access (and credentials)
+		tests/test_discovery.py::DiscoveryErrors::test_credentials_and_credentials_file_mutually_exclusive
+		tests/test_discovery.py::DiscoveryFromDocument::test_api_endpoint_override_from_client_options_mapping_object
+	)
+
+	distutils_install_for_testing
+	epytest tests
+}
diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index a21f167444e5..c520b20769f9 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1 +1,2 @@
 DIST kombu-5.1.0.tar.gz 416353 BLAKE2B 2c26aac0a8eda62475e2a9a859b2548046dfce0699a8dafce3cc6471ee3b82f82882a53903a86f69cf16f948e4d0e66f379479f7f1f46aca2bcbdd031ba87811 SHA512 62ef16e8e3fb592882b8060f29b95e7224ba635132ed688eece0c2d254e7f7fb525c778cac23f15495464c6dbcf84d7a1372fde6f55fcfe66677cf43d3e9d4de
+DIST kombu-5.2.0.tar.gz 419952 BLAKE2B 99065bc89152ce6b8646d74fd77eb162150313b30d911a6d3d58cefc279bf7539742cd259fad456925796e718f732d3a0243a3e3cca99d2cae5e5de575489359 SHA512 c5336e239c69cb584cca9dfca137f0bc27ee24d4a2f260d78d70e18925528cd97763a805eefb7270617aad499f9f9a66ed0eaa9acf418e1ae950727c01a84b6e
diff --git a/dev-python/kombu/kombu-5.2.0.ebuild b/dev-python/kombu/kombu-5.2.0.ebuild
new file mode 100644
index 000000000000..4daffb6f4d41
--- /dev/null
+++ b/dev-python/kombu/kombu-5.2.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1 optfeature
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="https://pypi.org/project/kombu/ https://github.com/celery/kombu"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/py-amqp-5.0.6[${PYTHON_USEDEP}]
+	<dev-python/py-amqp-6.0.0[${PYTHON_USEDEP}]
+	dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		>=dev-python/boto3-1.4.4[${PYTHON_USEDEP}]
+		>=dev-python/case-1.5.2[${PYTHON_USEDEP}]
+		dev-python/kazoo[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+		dev-python/pycurl[${PYTHON_USEDEP}]
+		>=dev-python/pymongo-3.3.0[${PYTHON_USEDEP}]
+		dev-python/Pyro4[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+		>=dev-python/redis-py-3.3.11[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/zstandard[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx_celery
+
+EPYTEST_IGNORE=(
+	# Unpackaged azure-servicebus
+	t/unit/transport/test_azureservicebus.py
+	# Unpackaged librabbitmq
+	t/unit/transport/test_librabbitmq.py
+	# Unpackaged python-consul
+	t/unit/transport/test_consul.py
+	# AttributeError: test_Etcd instance has no attribute 'patch'
+	t/unit/transport/test_etcd.py
+)
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+	optfeature "Etcd backend" dev-python/python-etcd
+	optfeature "MongoDB backend" dev-python/pymongo
+	optfeature "Pyro 4 backend" dev-python/Pyro4
+	optfeature "Redis backend" dev-python/redis-py
+	optfeature "sqlalchemy backend" dev-python/sqlalchemy
+	optfeature "yaml backend" dev-python/pyyaml
+	optfeature "Zookeeper backend" dev-python/kazoo
+	optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+	optfeature "brotli compression" "app-arch/brotli[python]"
+	optfeature "zstd compression" dev-python/zstandard
+}
diff --git a/dev-python/lxml/Manifest b/dev-python/lxml/Manifest
index c59350fa14fc..2beb210c3e8b 100644
--- a/dev-python/lxml/Manifest
+++ b/dev-python/lxml/Manifest
@@ -1 +1,2 @@
 DIST lxml-4.6.3.tar.gz 948931 BLAKE2B 373248827cb6bc0698b632ef60978adb2b8f7c37444fa1804567f08eb669018dc38fadf52422262fd96280e88c59578d244e4c5a1ed55609af55c010b3bf2b09 SHA512 50e42d6269dc45b4c0ab3285c49307f8bee87fcc4b9e0f531e1ee37bcf83c5938b7e361f906a3158fac8df89a79b932dd64a8839455e45f45f3a5f0ba73ff6a5
+DIST lxml-4.6.4.tar.gz 953275 BLAKE2B 7dae0fe0c92c937d823429b32ae952e501e193835892d40746aa35e48586df4e497865f246362ef10430cc9187cd54f98078b7edcc0fd9f421ac9d15994e7b2a SHA512 4e62b7c9ceec47f490136e86e9875aae3f3dccd0ee5e504f8128c62cdb111e00e64ee35678028438b87d32253fdeb8e1184d4017b56e06dfbc93cd0e8736101f
diff --git a/dev-python/lxml/lxml-4.6.4.ebuild b/dev-python/lxml/lxml-4.6.4.ebuild
new file mode 100644
index 000000000000..112c1490d439
--- /dev/null
+++ b/dev-python/lxml/lxml-4.6.4.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1 optfeature toolchain-funcs
+
+DESCRIPTION="A Pythonic binding for the libxml2 and libxslt libraries"
+HOMEPAGE="https://lxml.de/ https://pypi.org/project/lxml/ https://github.com/lxml/lxml"
+SRC_URI="https://github.com/lxml/lxml/archive/${P}.tar.gz"
+S=${WORKDIR}/lxml-${P}
+
+LICENSE="BSD ElementTree GPL-2 PSF-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc examples +threads test"
+RESTRICT="!test? ( test )"
+
+# Note: lib{xml2,xslt} are used as C libraries, not Python modules.
+RDEPEND="
+	>=dev-libs/libxml2-2.9.12-r2
+	>=dev-libs/libxslt-1.1.28"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	dev-python/cython[${PYTHON_USEDEP}]
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/docutils[${PYTHON_USEDEP}]
+			dev-python/pygments[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+		')
+	)
+	test? ( dev-python/cssselect[${PYTHON_USEDEP}] )
+	"
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.6.0-tests-pypy.patch
+)
+
+python_check_deps() {
+	use doc || return 0
+	has_version "dev-python/docutils[${PYTHON_USEDEP}]" &&
+	has_version "dev-python/pygments[${PYTHON_USEDEP}]" &&
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]" &&
+	has_version "dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]"
+}
+
+python_prepare_all() {
+	# avoid replacing PYTHONPATH in tests.
+	sed -i -e '/sys\.path/d' test.py || die
+
+	# don't use some random SDK on Darwin
+	sed -i -e '/_ldflags =/s/=.*isysroot.*darwin.*None/= None/' \
+		setupinfo.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	tc-export PKG_CONFIG
+	distutils-r1_python_compile
+}
+
+python_compile_all() {
+	use doc && emake html
+}
+
+python_test() {
+	cp -r -l src/lxml/tests "${BUILD_DIR}"/lib/lxml/ || die
+	cp -r -l src/lxml/html/tests "${BUILD_DIR}"/lib/lxml/html/ || die
+	ln -s "${S}"/doc "${BUILD_DIR}"/ || die
+
+	"${EPYTHON}" test.py -vv --all-levels -p || die "Test ${test} fails with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use doc; then
+		local DOCS=( README.rst *.txt doc/*.txt )
+		local HTML_DOCS=( doc/html/. )
+	fi
+	if use examples; then
+		dodoc -r samples
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Support for BeautifulSoup as a parser backend" dev-python/beautifulsoup4
+	optfeature "Translates CSS selectors to XPath 1.0 expressions" dev-python/cssselect
+}
diff --git a/dev-python/mypy/mypy-0.910.ebuild b/dev-python/mypy/mypy-0.910-r1.ebuild
index 2a569de9a258..24329f75b01a 100644
--- a/dev-python/mypy/mypy-0.910.ebuild
+++ b/dev-python/mypy/mypy-0.910-r1.ebuild
@@ -15,6 +15,8 @@ SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~riscv ~s390 sparc x86"
 
 # stubgen collides with this package: https://bugs.gentoo.org/585594
+# Note: replace toml with tomli on next version bump
+# https://github.com/python/mypy/pull/10824
 RDEPEND="
 	!dev-util/stubgen
 	>=dev-python/psutil-4[${PYTHON_USEDEP}]
@@ -23,6 +25,7 @@ RDEPEND="
 	>=dev-python/typing-extensions-3.7.4[${PYTHON_USEDEP}]
 	>=dev-python/mypy_extensions-0.4.3[${PYTHON_USEDEP}]
 	<dev-python/mypy_extensions-0.5.0[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
 "
 BDEPEND="
 	test? (
diff --git a/dev-python/prettytable/prettytable-2.3.0.ebuild b/dev-python/prettytable/prettytable-2.3.0.ebuild
index e758ee944f3b..46bbb4ad7c88 100644
--- a/dev-python/prettytable/prettytable-2.3.0.ebuild
+++ b/dev-python/prettytable/prettytable-2.3.0.ebuild
@@ -14,7 +14,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~sparc ~x86"
 
 RDEPEND="
 	dev-python/wcwidth[${PYTHON_USEDEP}]
diff --git a/dev-python/pytest-lazy-fixture/pytest-lazy-fixture-0.6.3.ebuild b/dev-python/pytest-lazy-fixture/pytest-lazy-fixture-0.6.3.ebuild
index 4a04a30a1c00..ce990c95ee53 100644
--- a/dev-python/pytest-lazy-fixture/pytest-lazy-fixture-0.6.3.ebuild
+++ b/dev-python/pytest-lazy-fixture/pytest-lazy-fixture-0.6.3.ebuild
@@ -12,7 +12,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 x86"
+KEYWORDS="amd64 ~sparc x86"
 
 RDEPEND="dev-python/pytest[${PYTHON_USEDEP}]"
 
diff --git a/dev-python/regex/Manifest b/dev-python/regex/Manifest
index c6fc7d37bc09..42305af63806 100644
--- a/dev-python/regex/Manifest
+++ b/dev-python/regex/Manifest
@@ -1,5 +1,6 @@
 DIST regex-2021.10.23.tar.gz 703746 BLAKE2B e26ec50994375f8b128206743209dff1ceb760b67967ff66d2553c1da27840e0df1611bf1a2746fd26246d3ac8b4a3974c98c8b4d4ede4e6d7954875c17b2405 SHA512 6bc67a066a7f33f6567a672132b1b65d89b21152d5ec3546262e542413ce40999ad57fb55eec92b9f4010489968b6eed1dab27efa63e14b771d883a890ddf9ab
 DIST regex-2021.10.8.tar.gz 703541 BLAKE2B da2a35c0f95c208fe2a9951d4c8cf756cd9eecb3ff27c5d729e9b5702256cc12bdde896019abf2aa12d206cbaace0fa693be332ff8d8baa5e6e628866eb64dea SHA512 395fbef61d54fad539bbd1e51c9100cba02bcd3a147e95a32ff8c32cb7fca66df98bade638e24f9a5c6e5d6c7becca033f925c4fa675b4e6689cba8316a8b46d
 DIST regex-2021.11.1.tar.gz 713328 BLAKE2B 165949eed94deb7ad6a12ca8e73f99b2b6aae26032d6545e74a897c25b32101707d67efba4cc936cdcad361a799e5742816178f0157d37e1fe9876c8cd4d60f0 SHA512 98efb00a88548ec63759f82870775d192ad2456d6c7b6362837e66980f029356fc270e991cf40ea049ead4c98d2baf8bb9a19b118ded7fb24a0bd6efcc1f6916
+DIST regex-2021.11.2.tar.gz 712630 BLAKE2B 0a6247d1ca26b0ce644f8036892ed4a5177d69b06eb6055bcd42a08874b24666df7525d19c270b61eca0c14474a0b68fb365e4f0499cdf5ede6510595bc302b8 SHA512 1863158271224595f6a540dcc0f7fd9125b69f9cdcf7b67efc589605b739e7ed7a09fbe30fbd1f26b1d57fca25df8b150b9726412d331a4aa757387c247cb904
 DIST regex-2021.8.28.tar.gz 694689 BLAKE2B 1aeceeb77df3c67e3ac14811000dc0f0cccf2a4994fd349f01f3a4e793f265dc9a73ea685202c6a7af8f507f0db94d6b74b1ae448ce58dd985ca4122c3454cba SHA512 da95f8ce03200f45b6be8730b65d01170847d074202e9b5f311688e22e3d59c32a8ff93768e2ac0105bac02936cbcde49eb114b762e89e6ebf895d8b799b4bf9
 DIST regex-2021.9.30.tar.gz 703504 BLAKE2B d958fa97aabb4c25c424591cfc9b6006c72e72d33029902a00e705c0db6786dcca92b006c4d77f98b0dd183405f63e282f33af75361d20d2b61f65d70da40da6 SHA512 3ce87e01a6e90a2519046595548f9ce38fb177db0d5c2359c57df857a2a9f14be1c6d228b7bd724d5bd66f723e33fd6056180fb45c50931bb0ec5e723df2f16a
diff --git a/dev-python/regex/regex-2021.11.2.ebuild b/dev-python/regex/regex-2021.11.2.ebuild
new file mode 100644
index 000000000000..92ae2cbca7dc
--- /dev/null
+++ b/dev-python/regex/regex-2021.11.2.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Alternative regular expression module to replace re"
+HOMEPAGE="https://bitbucket.org/mrabarnett/mrab-regex"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="doc"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2021.4.4-pypy3-fix-test_empty_array.patch"
+	"${FILESDIR}/${PN}-2021.4.4-pypy3-fix-test_issue_18468.patch"
+)
+
+distutils_enable_tests unittest
+
+python_test() {
+	eunittest -s "${BUILD_DIR}"/lib
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/Features.html )
+	local DOCS=( README.rst docs/*.rst )
+
+	distutils-r1_python_install_all
+}