Adding metadata

8 files changed, 170 insertions, 4 deletions

diff --git a/dev-python/coverage/coverage-6.3.2-r1.ebuild b/dev-python/coverage/coverage-6.3.2-r1.ebuild
new file mode 100644
index 000000000000..9686dc3a9779
--- /dev/null
+++ b/dev-python/coverage/coverage-6.3.2-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Code coverage measurement for Python"
+HOMEPAGE="https://coverage.readthedocs.io/en/latest/ https://pypi.org/project/coverage/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-macos"
+
+BDEPEND="
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		>=dev-python/unittest-mixins-1.4[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/^addopts/s:-q -n auto::' setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+test_tracer() {
+	local -x COVERAGE_TEST_TRACER=${1}
+	einfo "  Testing with the ${COVERAGE_TEST_TRACER} tracer ..."
+	epytest tests
+}
+
+python_test() {
+	"${EPYTHON}" igor.py zip_mods || die
+
+	local -x COVERAGE_TESTING=True
+	# TODO: figure out why they can't be imported inside test env
+	local -x COVERAGE_NO_CONTRACTS=1
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=_hypothesis_pytestplugin,flaky.flaky_pytest_plugin,xdist.plugin
+
+	if [[ ${EPYTHON} != pypy* ]]; then
+		cp "${BUILD_DIR}/install$(python_get_sitedir)"/coverage/*.so \
+			coverage/ || die
+		test_tracer c
+		rm coverage/*.so || die
+	else
+		test_tracer py
+	fi
+}
diff --git a/dev-python/makefun/makefun-1.13.1.ebuild b/dev-python/makefun/makefun-1.13.1.ebuild
index a2e4ba26de91..20fdb45695aa 100644
--- a/dev-python/makefun/makefun-1.13.1.ebuild
+++ b/dev-python/makefun/makefun-1.13.1.ebuild
@@ -14,7 +14,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64"
+KEYWORDS="~amd64 ~riscv"
 
 BDEPEND="dev-python/setuptools_scm[${PYTHON_USEDEP}]"
 
diff --git a/dev-python/pyopencl/Manifest b/dev-python/pyopencl/Manifest
index 8c0b9caec76e..13b577749c8c 100644
--- a/dev-python/pyopencl/Manifest
+++ b/dev-python/pyopencl/Manifest
@@ -1 +1,2 @@
 DIST pyopencl-2021.2.13.tar.gz 452397 BLAKE2B 8764fe1caf14e73b39aa455e7ea9e00b1733df4ef0d21fd1e2b6383db60eae33a1e1569d71dbd56617dc463e31426e3814cfe0201f8c891293fb32f4fad6a96e SHA512 16b527f69d4fa8bb8dd16cea67e7403893c813c625e0eb1f465fa8a94c9e4a878a5d5d589592b017bb548e1ff7ec5c36c79acd3cb55dee57592ca360a524ac7c
+DIST pyopencl-2022.1.tar.gz 452537 BLAKE2B 0d4d178a6bdf14dc3769dcb78c42bc894c0a443a6811fe9b25dedbc4a43debc06d1a1c32cb2a0df06fe16d1b2e78e65ef4f3ca8e9931be39384b3c8c813336de SHA512 e873807e757c19b59dbac2a0522fbb9c6e8af955d62bdcf06d8f3d792db3c9d2ce15372a6eefdca5b3f6756c35a85b5ff8d7dc1b6449bfd12c2b588576dd6f24
diff --git a/dev-python/pyopencl/pyopencl-2022.1.ebuild b/dev-python/pyopencl/pyopencl-2022.1.ebuild
new file mode 100644
index 000000000000..0c558a6407c3
--- /dev/null
+++ b/dev-python/pyopencl/pyopencl-2022.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+DESCRIPTION="Python wrapper for OpenCL"
+HOMEPAGE="https://mathema.tician.de/software/pyopencl/
+	https://pypi.org/project/pyopencl/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples opengl"
+
+DEPEND=">=virtual/opencl-2"
+RDEPEND="${DEPEND}
+	>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/mako-0.3.6[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/pytools-2021.2.7[${PYTHON_USEDEP}]"
+# libglvnd is only needed for the headers
+BDEPEND="dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/pybind11-2.5.0[${PYTHON_USEDEP}]
+	opengl? ( media-libs/libglvnd )"
+
+# The test suite fails if there are no OpenCL platforms available, and
+# even if there is one (which requires the presence of both an OpenCL
+# runtime *and* hardware supported by it - simply emerging any runtime
+# is not enough) the vast majority of tests end up skipped because by
+# default the portage user hasn't got sufficient privileges to talk
+# to the GPU.
+RESTRICT="test"
+
+python_configure_all() {
+	local myconf=()
+	if use opengl; then
+		myconf+=(--cl-enable-gl)
+	fi
+
+	"${EPYTHON}" configure.py \
+		"${myconf[@]}"
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/scrypt/Manifest b/dev-python/scrypt/Manifest
index f8ec8e3a6068..86a9482a3f2b 100644
--- a/dev-python/scrypt/Manifest
+++ b/dev-python/scrypt/Manifest
@@ -1,2 +1,2 @@
-DIST scrypt-0.8.18.tar.gz 56651 BLAKE2B d0e71e0677ab5f159da829eaf8e794fab9fa9290ff3688e525c4f2e9c60fda532d1c302fe4088bd8e88e06e926ef95d06bad145697e8a13e2662eda7027479b7 SHA512 b033203f65dd63c1e915eeff6232c01f806eb01d3ce18e753b6161ae667555095fe775585dd0d4e15ae228f2d4862860093c1a18d5b810b438d032df9fb24d81
 DIST scrypt-0.8.19.tar.gz 54770 BLAKE2B cf4cc0343f661466394a012ecba61b85431ed4c4552d976ebe1e435d9b97a29ad584e5ab1e01d2387c61562cdbb5cdfacfc5da0b3e70ea0570221e85c31139b3 SHA512 26503aa5c06b4c47a25f7a8c1b4c9a81986ffef5816f11851b2db755b13eed11c0fade9e00942b389204089547718de05db540da91196c3a37ce219ff1a601f8
+DIST scrypt-0.8.20.tar.gz 55874 BLAKE2B b31c7dcec735944f6162709ba6ceb90160b3c9c403121a47e62563f8d2fc50f0505f180d7c18fa2c8e9037a097ca3bffea4c54c1f3b6861004f65a189a20b576 SHA512 da8d34755d4b6c98dc57ff7baf17839cf2434a6d7eb9f6fdc69b3e458d41b4fc49f7fd3a5631318b82bc4b2e46dedb806035897bf1be5a4670b4120f6b46efbc
diff --git a/dev-python/scrypt/scrypt-0.8.18.ebuild b/dev-python/scrypt/scrypt-0.8.20.ebuild
index 56b038f2d6e0..f81e03803665 100644
--- a/dev-python/scrypt/scrypt-0.8.18.ebuild
+++ b/dev-python/scrypt/scrypt-0.8.20.ebuild
@@ -1,6 +1,6 @@
-# Copyright 2021 Liguros Authors
+# Copyright 2021-2022 Liguros Authors
 # Distributed under the terms of the GNU General Public License v2
-EAPI=7
+EAPI=8
 
 PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
 
diff --git a/dev-python/trimesh/Manifest b/dev-python/trimesh/Manifest
index 9f638a0d669b..7110b29f56c2 100644
--- a/dev-python/trimesh/Manifest
+++ b/dev-python/trimesh/Manifest
@@ -1 +1,2 @@
 DIST trimesh-3.10.0.tar.gz 10736418 BLAKE2B 9e65e9e5bc3984d1dca5c5d4a0498ff1f6357760a2337091a07953572c057a1807903f1a412246472f71d7fa344532ed13a8082b91de56be6c5b22d473a24e70 SHA512 33db340d8b840d4771f3d09b0529e311cdb3712a4eb43b9090a47b557632b2e97ac61ae2fed0e5ebc3da27574eb03ff96e1af1c52b2758dbcb8ae1e37737b5b7
+DIST trimesh-3.10.1.tar.gz 10738596 BLAKE2B 9dc310b3e2b26fcf85f8c15841e5db1cf0edfb52593b3d89ee7ccb0678df2e9261f79cc9ed6709b5cad2ed633b220daa4f0fcb88da27bd942d1973d89968f147 SHA512 555777569c5bbfda2b93cc52ec21dfb9efecda30f3c0283415249a742b3717df8dcea9ce9cf79e42419d1bdafcad34795dd198f80b5e8a791f7cfb1a9cc2a17a
diff --git a/dev-python/trimesh/trimesh-3.10.1.ebuild b/dev-python/trimesh/trimesh-3.10.1.ebuild
new file mode 100644
index 000000000000..17aa2acd01b9
--- /dev/null
+++ b/dev-python/trimesh/trimesh-3.10.1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for loading and using triangular meshes"
+HOMEPAGE="https://trimsh.org/ https://github.com/mikedh/trimesh"
+# No tests in PyPI tarballs
+SRC_URI="https://github.com/mikedh/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorlog[${PYTHON_USEDEP}]
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/msgpack[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycollada[${PYTHON_USEDEP}]
+	dev-python/pyglet[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/svg-path[${PYTHON_USEDEP}]
+	dev-python/sympy[${PYTHON_USEDEP}]
+	dev-python/xxhash[${PYTHON_USEDEP}]
+	sci-libs/rtree[${PYTHON_USEDEP}]
+	sci-libs/shapely[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+pkg_postinst() {
+	optfeature_header "${PN} functionality can be extended by installing the following packages:"
+	optfeature "making GUI applications with 3D stuff" dev-python/glooey
+	optfeature "2D triangulations of polygons" dev-python/mapbox_earcut
+	optfeature "loading a number of additional mesh formats" dev-python/meshio
+	optfeature "figuring out how much memory we have" dev-python/psutil
+	optfeature "marching cubes and other nice stuff" sci-libs/scikit-image
+}