Adding metadata

16 files changed, 602 insertions, 12 deletions

diff --git a/dev-python/fonttools/fonttools-4.60.1.ebuild b/dev-python/fonttools/fonttools-4.60.1.ebuild
index ed06825e6628..9874d4cc7223 100644
--- a/dev-python/fonttools/fonttools-4.60.1.ebuild
+++ b/dev-python/fonttools/fonttools-4.60.1.ebuild
@@ -22,7 +22,7 @@ SRC_URI="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
 IUSE="+native-extensions"
 
 BDEPEND="
diff --git a/dev-python/lxml/lxml-6.0.2.ebuild b/dev-python/lxml/lxml-6.0.2.ebuild
index 11474ebba809..3491f87eec99 100644
--- a/dev-python/lxml/lxml-6.0.2.ebuild
+++ b/dev-python/lxml/lxml-6.0.2.ebuild
@@ -23,7 +23,7 @@ S=${WORKDIR}/lxml-${P}
 
 LICENSE="BSD ElementTree GPL-2 PSF-2"
 SLOT="0"
-KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~loong ~m68k ~mips ~ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ~ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
 IUSE="doc examples +threads test"
 RESTRICT="!test? ( test )"
 
diff --git a/dev-python/numexpr/numexpr-2.13.1.ebuild b/dev-python/numexpr/numexpr-2.13.1.ebuild
index 3c1c126cb553..32fcc8d22cde 100644
--- a/dev-python/numexpr/numexpr-2.13.1.ebuild
+++ b/dev-python/numexpr/numexpr-2.13.1.ebuild
@@ -22,7 +22,7 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
 
 DEPEND="
 	>=dev-python/numpy-2.0.0_rc:=[${PYTHON_USEDEP}]
diff --git a/dev-python/propcache/propcache-0.4.0.ebuild b/dev-python/propcache/propcache-0.4.0.ebuild
index 6804e042772e..2de9c9ac9c31 100644
--- a/dev-python/propcache/propcache-0.4.0.ebuild
+++ b/dev-python/propcache/propcache-0.4.0.ebuild
@@ -17,7 +17,7 @@ HOMEPAGE="
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
 IUSE="+native-extensions"
 
 BDEPEND="
diff --git a/dev-python/pynacl/pynacl-1.6.0.ebuild b/dev-python/pynacl/pynacl-1.6.0.ebuild
index 35d992b64f90..196ddc12442a 100644
--- a/dev-python/pynacl/pynacl-1.6.0.ebuild
+++ b/dev-python/pynacl/pynacl-1.6.0.ebuild
@@ -21,7 +21,7 @@ SRC_URI="
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux"
 
 DEPEND="
 	dev-libs/libsodium:=
diff --git a/dev-python/pyproject-fmt/pyproject-fmt-2.7.0.ebuild b/dev-python/pyproject-fmt/pyproject-fmt-2.7.0.ebuild
index 48e15bd8bd44..eeb43897393a 100644
--- a/dev-python/pyproject-fmt/pyproject-fmt-2.7.0.ebuild
+++ b/dev-python/pyproject-fmt/pyproject-fmt-2.7.0.ebuild
@@ -119,7 +119,7 @@ LICENSE+="
 	|| ( Apache-2.0 Boost-1.0 )
 "
 SLOT="0"
-KEYWORDS="amd64 ~arm arm64 ~loong ppc ppc64 ~riscv ~s390 ~sparc x86"
+KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv ~s390 ~sparc x86"
 
 RDEPEND="
 	~dev-python/toml-fmt-common-1.0.1[${PYTHON_USEDEP}]
diff --git a/dev-python/pyqt5-sip/pyqt5-sip-12.17.1.ebuild b/dev-python/pyqt5-sip/pyqt5-sip-12.17.1.ebuild
index 7da4dcfe43a3..c95a9bea11bf 100644
--- a/dev-python/pyqt5-sip/pyqt5-sip-12.17.1.ebuild
+++ b/dev-python/pyqt5-sip/pyqt5-sip-12.17.1.ebuild
@@ -14,4 +14,4 @@ HOMEPAGE="https://pypi.org/project/PyQt5-sip/"
 
 LICENSE="BSD-2"
 SLOT="0/$(ver_cut 1)"
-KEYWORDS="amd64 ~arm arm64 ~loong ~ppc ppc64 ~riscv x86"
+KEYWORDS="amd64 arm arm64 ~loong ~ppc ppc64 ~riscv x86"
diff --git a/dev-python/pyside/Manifest b/dev-python/pyside/Manifest
index d8177b5beb77..1141c5c8688a 100644
--- a/dev-python/pyside/Manifest
+++ b/dev-python/pyside/Manifest
@@ -1 +1,2 @@
+DIST pyside-setup-everywhere-src-6.10.0.tar.xz 17758096 BLAKE2B c627bd68f13e6af1b49f5857fea0d541e8d8fd4ef2577fcd22e80ee93475f19067f1e2fe85a04b786421960ba4eebb9dc9c5cf8f64b89a4a4e65f58cf005196d SHA512 023599df8423a70ff776159ba302e4a72f43f0b3928f088d6cf429a59a229b170d11671527384b17360a03764ef5b70e358a5df985780212ac7edccb8c2609b5
 DIST pyside-setup-everywhere-src-6.9.3.tar.xz 16663380 BLAKE2B 10834a35c3de13657256892111e3f54dceeb4fef61618b61672018bbffa007cfac0b602bd39b3ef7a472ba47f9444c7e7cf6d43cb411de0dd26333faa0814e7a SHA512 457a447146a8e5be94940b06172a21cdc9f1407c9c48e6449d410ae3f122002f5970c3841cba6135fb4d889c58a4ed1b648f03b708f9a5cfb9f1cc93cbb9d561
diff --git a/dev-python/pyside/files/pyside-6.10.0-dont-vendor-ffmpeg.patch b/dev-python/pyside/files/pyside-6.10.0-dont-vendor-ffmpeg.patch
new file mode 100644
index 000000000000..72c09ec5f9ca
--- /dev/null
+++ b/dev-python/pyside/files/pyside-6.10.0-dont-vendor-ffmpeg.patch
@@ -0,0 +1,18 @@
+--- a/build_scripts/platforms/unix.py
++++ b/build_scripts/platforms/unix.py
+@@ -234,14 +234,6 @@ def prepare_packages_posix(pyside_build, _vars, cross_build=False):
+                 "{st_build_dir}/{st_package_name}/jar",
+                 _vars=_vars)
+ 
+-    # Some libraries specific to Linux/Android from 6.8
+-    # eg: the libav* libraries are required for the multimedia module
+-    if config.is_internal_pyside_build() and (sys.platform != "darwin" or is_android):
+-        qt_multimedia_filters = [f"lib{lib}*.so*" for lib in PYSIDE_MULTIMEDIA_LIBS]
+-        copydir("{qt_lib_dir}", destination_qt_dir / "lib",
+-                _filter=qt_multimedia_filters,
+-                recursive=False, _vars=_vars, force_copy_symlinks=True)
+-
+     # Copy Qt libs to package
+     if OPTION["STANDALONE"]:
+         if config.is_internal_pyside_build() or config.is_internal_shiboken_generator_build():
+
diff --git a/dev-python/pyside/pyside-6.10.0.ebuild b/dev-python/pyside/pyside-6.10.0.ebuild
new file mode 100644
index 000000000000..2dce1eb8e112
--- /dev/null
+++ b/dev-python/pyside/pyside-6.10.0.ebuild
@@ -0,0 +1,563 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# NOTE: We combine here several PyPI packages, we do this because
+# pyside can and does break if it is compiled with a different
+# toolchain then was used to build shiboken. This bundling ensures
+# that we always use the same toolchain for all components.
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..14} )
+LLVM_COMPAT=( {16..20} )
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_EXT=1
+
+inherit distutils-r1 llvm-r2 multiprocessing qmake-utils virtualx
+
+MY_PN=${PN}-setup-everywhere-src
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python bindings for the Qt framework"
+HOMEPAGE="https://wiki.qt.io/PySide6"
+
+if [[ ${PV} == *.9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI=(
+		"https://code.qt.io/${PN}/${PN}-setup.git"
+		"https://github.com/qtproject/${PN}-${PN}-setup.git"
+	)
+	EGIT_BRANCH=dev
+	[[ ${PV} == 6.*.9999 ]] && EGIT_BRANCH=${PV%.9999}
+else
+	SRC_URI="https://download.qt.io/official_releases/QtForPython/${PN}6/PySide6-${PV}-src/${MY_P}.tar.xz"
+	S="${WORKDIR}/${MY_P}"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="|| ( GPL-2 GPL-3 LGPL-3 )"
+SLOT="6/${PV}"
+
+# If a flag enables multiple Qt modules, they should be ordered
+# according to their dependencies, e.g. for 3d, 3DCore must be first.
+# Widgets for various modules are handled as a special case later
+declare -A QT_MODULES=(
+	["3d"]="3DCore 3DRender 3DLogic 3DInput 3DAnimation 3DExtras"
+	["bluetooth"]="Bluetooth"
+	["charts"]="Charts"
+	["+concurrent"]="Concurrent"
+	["+core"]="Core"
+	["+dbus"]="DBus"
+	["designer"]="Designer"
+	["+gui"]="Gui"
+	["help"]="Help"
+	["httpserver"]="HttpServer"
+	["location"]="Location"
+	["multimedia"]="Multimedia" # plus widgets
+	["network-auth"]="NetworkAuth"
+	["+network"]="Network"
+	["nfc"]="Nfc"
+	["+opengl"]="OpenGL" # plus widgets
+	["pdfium"]="Pdf" # plus widgets
+	["positioning"]="Positioning"
+	["+printsupport"]="PrintSupport"
+	["qml"]="Qml"
+	["quick3d"]="Quick3D"
+	["quick"]="Quick" # plus widgets
+	["remoteobjects"]="RemoteObjects"
+	["scxml"]="Scxml"
+	["sensors"]="Sensors"
+	["serialbus"]="SerialBus"
+	["serialport"]="SerialPort"
+	["spatialaudio"]="SpatialAudio"
+	["+sql"]="Sql"
+	["svg"]="Svg" # plus widgets
+	["speech"]="TextToSpeech"
+	["+testlib"]="Test"
+	["uitools"]="UiTools"
+	["webchannel"]="WebChannel"
+	["webengine"]="WebEngineCore" # plus widgets and quick
+	["websockets"]="WebSockets"
+	["webview"]="WebView"
+	["+widgets"]="Widgets"
+	["+xml"]="Xml"
+)
+
+# Manually reextract these requirements on version bumps by running the
+# following one-liner from within "${S}":
+#     $ grep 'set.*_deps' PySide6/Qt*/CMakeLists.txt
+declare -A QT_REQUIREMENTS=(
+	["3d"]="gui network opengl"
+	["bluetooth"]="core"
+	["charts"]="core gui widgets"
+	["concurrent"]="core"
+	["dbus"]="core"
+	["designer"]="widgets"
+	["gles2-only"]="gui"
+	["gui"]="core"
+	["help"]="widgets"
+	["httpserver"]="core concurrent network websockets"
+	["location"]="core positioning"
+	["multimedia"]="core gui network"
+	["network-auth"]="network"
+	["network"]="core"
+	["nfc"]="core"
+	["opengl"]="gui"
+	["pdfium"]="core gui network"
+	["positioning"]="core"
+	["printsupport"]="widgets"
+	["qml"]="network"
+	["quick"]="gui network qml opengl"
+	["quick3d"]="gui network qml quick"
+	["remoteobjects"]="core network"
+	["scxml"]="core"
+	["sensors"]="core"
+	["serialbus"]="core network serialport"
+	["serialport"]="core"
+	["spatialaudio"]="core gui network multimedia"
+	["speech"]="core multimedia"
+	["sql"]="widgets"
+	["svg"]="gui"
+	["testlib"]="widgets"
+	["uitools"]="widgets"
+	["webchannel"]="core"
+	["webengine"]="core gui network printsupport quick webchannel"
+	["websockets"]="network"
+	["webview"]="gui quick webengine"
+	["widgets"]="gui"
+	["xml"]="core"
+)
+
+IUSE="${!QT_MODULES[*]} debug doc gles2-only numpy test tools"
+RESTRICT="!test? ( test )"
+
+# majority of QtQml tests require QtQuick support
+REQUIRED_USE="
+	test? (
+		qml? ( quick )
+	)
+"
+for requirement in "${!QT_REQUIREMENTS[@]}"; do
+	REQUIRED_USE+=" ${requirement}? ( ${QT_REQUIREMENTS[${requirement}]} ) "
+done
+
+# Minimal supported version of Qt.
+QT_PV="$(ver_cut 1-3)*:6"
+
+# WebEngine needs sound support, so enable either pulseaudio or alsa
+RDEPEND="
+	dev-libs/libxml2:=
+	dev-libs/libxslt
+	=dev-qt/qtbase-${QT_PV}[concurrent?,dbus?,gles2-only=,network?,opengl?,sql?,widgets?,xml?]
+	$(llvm_gen_dep '
+		llvm-core/clang:${LLVM_SLOT}
+	')
+	3d? ( =dev-qt/qt3d-${QT_PV}[qml?,gles2-only=] )
+	bluetooth? ( =dev-qt/qtconnectivity-${QT_PV}[bluetooth] )
+	charts? ( =dev-qt/qtcharts-${QT_PV} )
+	designer? ( =dev-qt/qttools-${QT_PV}[designer,widgets,gles2-only=] )
+	gui? (
+		=dev-qt/qtbase-${QT_PV}[gui,jpeg(+)]
+		x11-libs/libxkbcommon
+	)
+	help? ( =dev-qt/qttools-${QT_PV}[assistant,gles2-only=] )
+	httpserver? ( =dev-qt/qthttpserver-${QT_PV} )
+	location? ( =dev-qt/qtlocation-${QT_PV} )
+	multimedia? ( =dev-qt/qtmultimedia-${QT_PV}[widgets(+)?] )
+	network? ( =dev-qt/qtbase-${QT_PV}[ssl] )
+	network-auth? ( =dev-qt/qtnetworkauth-${QT_PV} )
+	nfc? ( =dev-qt/qtconnectivity-${QT_PV}[nfc] )
+	numpy? ( >=dev-python/numpy-2.1.3[${PYTHON_USEDEP}] )
+	pdfium? ( =dev-qt/qtwebengine-${QT_PV}[pdfium(-),widgets?] )
+	positioning? ( =dev-qt/qtpositioning-${QT_PV} )
+	printsupport? ( =dev-qt/qtbase-${QT_PV}[gui,widgets] )
+	qml? ( =dev-qt/qtdeclarative-${QT_PV}[opengl?,widgets?] )
+	quick3d? ( =dev-qt/qtquick3d-${QT_PV}[opengl?] )
+	remoteobjects? ( =dev-qt/qtremoteobjects-${QT_PV} )
+	scxml? ( =dev-qt/qtscxml-${QT_PV} )
+	sensors? ( =dev-qt/qtsensors-${QT_PV}[qml?] )
+	speech? ( =dev-qt/qtspeech-${QT_PV} )
+	serialbus? ( =dev-qt/qtserialbus-${QT_PV} )
+	serialport? ( =dev-qt/qtserialport-${QT_PV} )
+	svg? ( =dev-qt/qtsvg-${QT_PV} )
+	testlib? ( =dev-qt/qtbase-${QT_PV}[gui] )
+	tools? (
+		=dev-qt/qtbase-${QT_PV}
+		=dev-qt/qtdeclarative-${QT_PV}[qmlls]
+		=dev-qt/qttools-${QT_PV}[assistant,designer,linguist]
+		dev-python/pkginfo[${PYTHON_USEDEP}]
+	)
+	uitools? ( =dev-qt/qttools-${QT_PV}[gles2-only=,widgets] )
+	webchannel? ( =dev-qt/qtwebchannel-${QT_PV} )
+	webengine? ( || (
+		=dev-qt/qtwebengine-${QT_PV}[alsa,widgets?]
+		=dev-qt/qtwebengine-${QT_PV}[pulseaudio,widgets?]
+		)
+	)
+	websockets? ( =dev-qt/qtwebsockets-${QT_PV} )
+	webview? ( =dev-qt/qtwebview-${QT_PV} )
+	!dev-python/pyside:0
+	!dev-python/shiboken6
+	!dev-python/pyside6-tools
+"
+
+DEPEND="${RDEPEND}
+	$(llvm_gen_dep '
+		llvm-core/clang:${LLVM_SLOT}
+		llvm-core/llvm:${LLVM_SLOT}
+	')
+	dev-util/vulkan-headers
+	test? ( =dev-qt/qtbase-${QT_PV}[gui] )
+" # testlib is toggled by the gui flag on qtbase
+
+BDEPEND="
+	dev-build/cmake
+	dev-python/distro[${PYTHON_USEDEP}]
+	<dev-python/wheel-0.46.0[${PYTHON_USEDEP}]
+	dev-util/patchelf
+	doc? (
+		>=dev-libs/libxml2-2.6.32
+		>=dev-libs/libxslt-1.1.19
+		media-gfx/graphviz
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/myst-parser[${PYTHON_USEDEP}]
+	)
+	numpy? ( dev-python/numpy[${PYTHON_USEDEP}] )
+"
+
+PATCHES=(
+	# Needs porting to newer wheel and setuptools
+	"${FILESDIR}/${PN}-6.8.2-quick-fix-build-wheel.patch"
+	"${FILESDIR}/${PN}-6.10.0-dont-vendor-ffmpeg.patch"
+)
+
+# Build system duplicates system libraries. TODO: fix
+QA_PREBUILT=(
+	"/usr/lib/python*/site-packages/PySide6/*"
+)
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# Shiboken6 assumes Vulkan headers live under either "$VULKAN_SDK/include"
+	# or "$VK_SDK_PATH/include" rather than "${EPREFIX}/usr/include/vulkan".
+	sed -i -e "s~\bdetectVulkan(&headerPaths);~headerPaths.append(HeaderPath{QByteArrayLiteral(\"${EPREFIX}/usr/include/vulkan\"), HeaderType::System});~" \
+			sources/shiboken6/ApiExtractor/clangparser/compilersupport.cpp || die
+
+	# Shiboken6 assumes the "/usr/lib/clang/${CLANG_NEWEST_VERSION}/include/"
+	# subdirectory provides Clang builtin includes (e.g., "stddef.h") for the
+	# currently installed version of Clang, where ${CLANG_NEWEST_VERSION} is
+	# the largest version specifier that exists under the "/usr/lib/clang/"
+	# subdirectory. This assumption is false in edge cases, including when
+	# users downgrade from newer Clang versions but fail to remove those
+	# versions with "emerge --depclean". See also:
+	#     https://github.com/leycec/raiagent/issues/85
+	#
+	# Sadly, the clang-* family of functions exported by the "toolchain-funcs"
+	# eclass are defective, returning nonsensical placeholder strings if the
+	# end user has *NOT* explicitly configured their C++ compiler to be Clang.
+	# PySide6 does *NOT* care whether the end user has done so or not, as
+	# PySide6 unconditionally requires Clang in either case. See also:
+	#     https://bugs.gentoo.org/619490
+	sed -e \
+		's~(findClangBuiltInIncludesDir())~(QStringLiteral("'"${EPREFIX}"'/usr/lib/clang/'"${LLVM_SLOT}"'/include"))~' \
+		-i sources/shiboken6/ApiExtractor/clangparser/compilersupport.cpp || die
+
+	sed -e \
+		's~set(libclang_directory_suffix "lib")~set(libclang_directory_suffix "'"$(get_libdir)"'")~' \
+		-i sources/shiboken6/cmake/ShibokenHelpers.cmake || die
+
+	# blacklist.txt works like XFAIL
+	cat <<- EOF >> build_history/blacklist.txt || die
+	# segfaults with QOpenGLContext::create
+	[pysidetest::qapp_like_a_macro_test]
+		linux
+	# no mypy
+	[pysidetest::mypy_correctness_test]
+		linux
+	# Tries to execute pip install
+	[pyside6-deploy::test_pyside6_deploy]
+		linux
+	[pyside6-android-deploy::test_pyside6_android_deploy]
+		linux
+	# Behavior changed and test not changed to accomodate
+	# https://bugreports.qt.io/projects/PYSIDE/issues/PYSIDE-3135
+	[registry::existence_test]
+		linux
+	# Doesn't appear to play well with virtualx as it tries to use wayland
+	[QtUiTools::loadUiType_test]
+		linux
+	EOF
+
+	if ! use numpy; then
+		cat <<- EOF >> build_history/blacklist.txt || die
+		# Requires numpy support to pass
+		[sample::array_numpy]
+			linux
+		[sample::nontypetemplate]
+			linux
+		[QtGui::qpainter_test]
+			linux
+		[QtCore::qrangemodel_test]
+			linux
+		EOF
+	fi
+}
+
+python_configure_all() {
+	export LLVM_INSTALL_DIR="$(get_llvm_prefix)"
+
+	ENABLED_QT_MODULES=()
+
+	# The order matters, dependencies must come first so process
+	# REQUIRED_USE and recursively enable modules
+	enable_qt_mod() {
+		local flag=${1}
+		local modules=${QT_MODULES[${flag}]}
+		if [[ -z ${modules} ]]; then
+			die "incorrect flag=${flag}, not registered"
+		fi
+		local dependencies=${QT_REQUIREMENTS[${flag//+}]}
+		if [[ -n ${dependencies} ]]; then
+			local depflag
+			for depflag in ${dependencies}; do
+				if use "${depflag}"; then
+					if [[ -z ${QT_MODULES[${depflag}]} ]]; then
+						depflag=+${depflag}
+					fi
+					enable_qt_mod "${depflag}"
+				else
+					die "${depflag} is required but not enabled"
+				fi
+			done
+		fi
+		if [[ "${ENABLED_QT_MODULES[*]}" != *${modules}* ]]; then
+			# modules is whitespace separated. We expand implicitly.
+			ENABLED_QT_MODULES+=( ${modules} )
+		fi
+	}
+	# Enable specified qt modules
+	local flag
+	for flag in "${!QT_MODULES[@]}"; do
+		if use "${flag//+}"; then
+			enable_qt_mod "${flag}"
+		fi
+	done
+
+	# Special cases
+	if use widgets; then
+		use multimedia && ENABLED_QT_MODULES+=( MultimediaWidgets )
+		use opengl && ENABLED_QT_MODULES+=( OpenGLWidgets )
+		use pdfium && ENABLED_QT_MODULES+=( PdfWidgets )
+		use quick && ENABLED_QT_MODULES+=( QuickWidgets )
+		use svg && ENABLED_QT_MODULES+=( SvgWidgets )
+		use webengine && ENABLED_QT_MODULES+=( WebEngineWidgets )
+	fi
+	if use quick; then
+		use webengine && ENABLED_QT_MODULES+=( WebEngineQuick )
+		use testlib && ENABLED_QT_MODULES+=( QuickTest )
+	fi
+
+	# Arguments listed in options.py
+	MAIN_DISTUTILS_ARGS=(
+		--cmake="${ESYSROOT}/usr/bin/cmake"
+		--ignore-git
+		--limited-api=no
+		--module-subset="$(printf '%s,' "${ENABLED_QT_MODULES[@]}")"
+		--no-strip
+		--no-size-optimization
+		--openssl="${ESYSROOT}/usr/bin/openssl"
+		--qt="$(ver_cut 1-3)"
+		--qtpaths="$(qt6_get_bindir)/qtpaths"
+		--verbose-build
+		--parallel="$(makeopts_jobs)"
+		"$(usex debug "--debug" "--relwithdebinfo")"
+		"--$(usex doc "build" "skip")-docs"
+		"--$(usex numpy "enable" "disable")-numpy-support"
+	)
+
+	if use test; then
+		MAIN_DISTUTILS_ARGS+=(
+			"--build-tests"
+			"--use-xvfb"
+		)
+	fi
+
+	if ! use tools; then
+		MAIN_DISTUTILS_ARGS+=(
+			"--no-qt-tools"
+		)
+	fi
+}
+
+python_compile() {
+	DISTUTILS_ARGS=(
+		"${MAIN_DISTUTILS_ARGS[@]}"
+		--build-type=shiboken6
+	)
+	distutils-r1_python_compile
+
+	# The build system uses its own build dir, find the name of this dir.
+	local pyside_build_dir
+	read -r pyside_build_dir < <(
+		find "${BUILD_DIR}/build$((${#DISTUTILS_WHEELS[@]}-1))" \
+			-maxdepth 1 -type d -name 'qfp*-py*-qt*-*' -printf "%f\n"
+	)
+	export pyside_build_id="${pyside_build_dir#"qfp$(usev debug d)-py${EPYTHON#python}-qt$(ver_cut 1-3)-"}"
+
+	DISTUTILS_ARGS=(
+		"${MAIN_DISTUTILS_ARGS[@]}"
+		--reuse-build
+		--shiboken-target-path="${BUILD_DIR}/build$((${#DISTUTILS_WHEELS[@]}-1))/${pyside_build_dir}/install"
+		--build-type=shiboken6-generator
+	)
+	distutils-r1_python_compile
+	# If no pyside modules enabled, build just shiboken
+	if [[ ${#ENABLED_QT_MODULES[@]} -gt 0 ]]; then
+		DISTUTILS_ARGS=(
+			"${MAIN_DISTUTILS_ARGS[@]}"
+			--reuse-build
+			--shiboken-target-path="${BUILD_DIR}/build$((${#DISTUTILS_WHEELS[@]}-1))/${pyside_build_dir}/install"
+			--build-type=pyside6
+		)
+		distutils-r1_python_compile
+	fi
+
+	# Link libraries to the usual location for backwards compatibility
+	pushd "${BUILD_DIR}/install/$(python_get_sitedir)" >/dev/null ||
+		die
+	mkdir -p "${BUILD_DIR}/install/usr/$(get_libdir)" || die
+	local lib
+	for lib in */*.cpython-*.so
+	do
+		local base=${lib##*/}
+		ln -s "${base}" "${lib%/*}/${base%%.*}-${EPYTHON}.so" ||
+			die
+	done
+	for lib in */*.cpython-*.so."$(ver_cut 1-2)"
+	do
+		local base=${lib##*/}
+		ln -s "${base}" "${lib%/*}/${base%%.*}-${EPYTHON}.so.$(ver_cut 1-2)" ||
+			die
+	done
+	for lib in */*.so*; do
+		ln -s "../../$(python_get_sitedir)/${lib}" \
+			"${BUILD_DIR}/install/usr/$(get_libdir)/${lib#*/}" || die
+	done
+	popd >/dev/null || die
+
+	# Symlinks for compatibility with pypi wheels
+	local dir
+	if [[ -d ${BUILD_DIR}/install/$(python_get_sitedir)/PySide6 ]]
+	then
+		pushd "${BUILD_DIR}/install/$(python_get_sitedir)/PySide6" \
+			>/dev/null || die
+		mkdir -p "${BUILD_DIR}/install/usr/share/PySide6" || die
+		for dir in doc glue typesystems; do
+			ln -s "../../../$(python_get_sitedir)/PySide6/${dir}" \
+				"${BUILD_DIR}/install/usr/share/PySide6/${dir}" ||
+					die
+		done
+		popd >/dev/null || die
+	fi
+	mkdir -p "${BUILD_DIR}/install/usr/include"
+	for dir in PySide6 shiboken6_generator; do
+		if [[ -d ${BUILD_DIR}/install/$(python_get_sitedir)/${dir}/include ]]
+		then
+			ln -s "../../$(python_get_sitedir)/${dir}/include" \
+				"${BUILD_DIR}/install/usr/include/${dir//_generator}" ||
+					die
+		fi
+	done
+
+	# Install misc files from inner install dir
+	find "${BUILD_DIR}"/build*/"${pyside_build_dir}"/install -type f \
+		-name libPySidePlugin.so -exec \
+		mkdir -p "${BUILD_DIR}/install/$(qt6_get_plugindir)/designer/" \; \
+		-exec \
+		cp "{}" "${BUILD_DIR}/install/$(qt6_get_plugindir)/designer/" \; \
+			|| die
+
+	for dir in cmake pkgconfig; do
+		find "${BUILD_DIR}"/build*/"${pyside_build_dir}"/install -type d -name "${dir}" \
+			-exec cp -r "{}" "${BUILD_DIR}/install/usr/lib/" \; \
+				|| die
+	done
+
+	# Uniquify the pkgconfigs file for the current Python target,
+	# preserving an unversioned "shiboken6.pc" file arbitrarily
+	# associated with the last Python target.
+	if [[ -f ${BUILD_DIR}/install/usr/lib/pkgconfig/shiboken6.pc ]]
+	then
+		sed -e 's~prefix=.*~prefix=/usr~g' \
+			-e 's~exec_prefix=.*~exec_prefix=${prefix}~g' \
+			-e "s~libdir=.*~libdir=$(python_get_sitedir)/shiboken6~g" \
+			-e "s~includedir=.*~includedir=$(python_get_sitedir)/shiboken6_generator/include~g" \
+			-i "${BUILD_DIR}/install/usr/lib/pkgconfig/shiboken6.pc" || die
+		cp "${BUILD_DIR}/install/usr/lib/pkgconfig/"shiboken6{,-${EPYTHON}}.pc || die
+	fi
+	if [[ -f ${BUILD_DIR}/install/usr/lib/pkgconfig/pyside6.pc ]]
+	then
+		sed -e 's~^Requires: shiboken6$~&-'${EPYTHON}'~' \
+			-e 's~prefix=.*~prefix=/usr~g' \
+			-e 's~exec_prefix=.*~exec_prefix=${prefix}~g' \
+			-e "s~libdir=.*~libdir=$(python_get_sitedir)/PySide6~g" \
+			-e "s~includedir=.*~includedir=$(python_get_sitedir)/PySide6/include~g" \
+			-e "s~typesystemdir=.*~typesystemdir=$(python_get_sitedir)/PySide6/typesystems~g" \
+			-e "s~gluedir=.*~gluedir=$(python_get_sitedir)/PySide6/glue~g" \
+			-e "s~pythonpath=.*~pythonpath=$(python_get_sitedir)~g" \
+			-i "${BUILD_DIR}/install/usr/lib/pkgconfig/pyside6.pc" || die
+		cp "${BUILD_DIR}/install/usr/lib/pkgconfig/"pyside6{,-${EPYTHON}}.pc || die
+	fi
+
+	sed \
+		-e "s~/lib/libshiboken6\.cpython~/$(get_libdir)/libshiboken6\.cpython~g" \
+		-e "s~/lib/libpyside6\.cpython~/$(get_libdir)/libpyside6\.cpython~g" \
+		-e "s~/lib/libpyside6qml\.cpython~/$(get_libdir)/libpyside6qml\.cpython~g" \
+		-e "s~libshiboken6\.cpython.*\.so\.$(ver_cut 1-3)~libshiboken6\${PYTHON_CONFIG_SUFFIX}\.so\.$(ver_cut 1-2)~g" \
+		-e "s~libpyside6\.cpython.*\.so\.$(ver_cut 1-3)~libpyside6\${PYTHON_CONFIG_SUFFIX}\.so\.$(ver_cut 1-2)~g" \
+		-e "s~libpyside6qml\.cpython.*\.so\.$(ver_cut 1-3)~libpyside6qml\${PYTHON_CONFIG_SUFFIX}\.so\.$(ver_cut 1-2)~g" \
+		-e "s~libshiboken6\.cpython.*\.so\.$(ver_cut 1-2)~libshiboken6\${PYTHON_CONFIG_SUFFIX}\.so\.$(ver_cut 1-2)~g" \
+		-e "s~libpyside6\.cpython.*\.so\.$(ver_cut 1-2)~libpyside6\${PYTHON_CONFIG_SUFFIX}\.so\.$(ver_cut 1-2)~g" \
+		-e "s~libpyside6qml\.cpython.*\.so\.$(ver_cut 1-2)~libpyside6qml\${PYTHON_CONFIG_SUFFIX}\.so\.$(ver_cut 1-2)~g" \
+		-i 	"${BUILD_DIR}/install/usr/lib/cmake/"*/*.cmake || die
+	local file
+	for file in "${BUILD_DIR}/install/usr/lib/cmake/"*/*.cpython-*.cmake
+	do
+		local base=${file##*/}
+		ln -s "${base}" "${file%/*}/${base%%.*}-${EPYTHON}.cmake" ||
+			die
+	done
+}
+
+python_test() {
+	# Otherwise it picks the last built directory breaking assumption for multi target builds
+	local pyside_build_dir="qfp$(usev debug d)-py${EPYTHON#python}-qt$(ver_cut 1-3)-${pyside_build_id}"
+
+	local buildno=$(find "${BUILD_DIR}"/build* -name "${pyside_build_dir}" | sort -V | tail -n1)
+	if [[ -z "${buildno}" ]]; then
+		die "could not find any build directories for ${pyside_build_dir}"
+	fi
+
+	buildno="${buildno#"${BUILD_DIR}/build"}"
+	buildno="${buildno%"/${pyside_build_dir}"}"
+
+	local -x PYTHONPATH="${BUILD_DIR}/install$(python_get_sitedir)"
+	local -x QTEST_ENVIRONMENT=ci
+
+	# test shiboken6 build
+	virtx ${EPYTHON} testrunner.py test --buildno "$((buildno - 1))" --projects=shiboken6 ||
+		die "Tests failed with ${EPYTHON}"
+
+	if use core; then
+		# test pyside6 build
+		virtx ${EPYTHON} testrunner.py test --buildno "${buildno}" --projects=pyside6 ||
+			die "Tests failed with ${EPYTHON}"
+	fi
+}
+
+pkg_preinst() {
+	# Avoid symlinks being blocked by directories
+	rm -rf "${EROOT}/usr/include/"{PySide6,shiboken6} || die
+	rm -rf "${EROOT}/usr/share/PySide6" || die
+}
diff --git a/dev-python/pyside/pyside-6.9999.ebuild b/dev-python/pyside/pyside-6.9999.ebuild
index 9266d0f3dfd1..2dce1eb8e112 100644
--- a/dev-python/pyside/pyside-6.9999.ebuild
+++ b/dev-python/pyside/pyside-6.9999.ebuild
@@ -146,7 +146,12 @@ QT_PV="$(ver_cut 1-3)*:6"
 
 # WebEngine needs sound support, so enable either pulseaudio or alsa
 RDEPEND="
+	dev-libs/libxml2:=
+	dev-libs/libxslt
 	=dev-qt/qtbase-${QT_PV}[concurrent?,dbus?,gles2-only=,network?,opengl?,sql?,widgets?,xml?]
+	$(llvm_gen_dep '
+		llvm-core/clang:${LLVM_SLOT}
+	')
 	3d? ( =dev-qt/qt3d-${QT_PV}[qml?,gles2-only=] )
 	bluetooth? ( =dev-qt/qtconnectivity-${QT_PV}[bluetooth] )
 	charts? ( =dev-qt/qtcharts-${QT_PV} )
@@ -223,6 +228,7 @@ BDEPEND="
 PATCHES=(
 	# Needs porting to newer wheel and setuptools
 	"${FILESDIR}/${PN}-6.8.2-quick-fix-build-wheel.patch"
+	"${FILESDIR}/${PN}-6.10.0-dont-vendor-ffmpeg.patch"
 )
 
 # Build system duplicates system libraries. TODO: fix
@@ -292,6 +298,8 @@ python_prepare_all() {
 			linux
 		[QtGui::qpainter_test]
 			linux
+		[QtCore::qrangemodel_test]
+			linux
 		EOF
 	fi
 }
diff --git a/dev-python/ruamel-yaml-clib/ruamel-yaml-clib-0.2.14.ebuild b/dev-python/ruamel-yaml-clib/ruamel-yaml-clib-0.2.14.ebuild
index 41f24925dc97..d53d3a6cf0bb 100644
--- a/dev-python/ruamel-yaml-clib/ruamel-yaml-clib-0.2.14.ebuild
+++ b/dev-python/ruamel-yaml-clib/ruamel-yaml-clib-0.2.14.ebuild
@@ -21,7 +21,7 @@ S=${WORKDIR}/ruamel_yaml_clib
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
 
 BDEPEND="
 	dev-python/cython[${PYTHON_USEDEP}]
diff --git a/dev-python/simplejson/simplejson-3.20.2.ebuild b/dev-python/simplejson/simplejson-3.20.2.ebuild
index 08230ecf960b..edc412d16f29 100644
--- a/dev-python/simplejson/simplejson-3.20.2.ebuild
+++ b/dev-python/simplejson/simplejson-3.20.2.ebuild
@@ -17,7 +17,7 @@ HOMEPAGE="
 
 LICENSE="|| ( MIT AFL-2.1 )"
 SLOT="0"
-KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
 IUSE="+native-extensions"
 
 DOCS=( README.rst CHANGES.txt )
diff --git a/dev-python/sphinxcontrib-mermaid/sphinxcontrib-mermaid-1.0.0.ebuild b/dev-python/sphinxcontrib-mermaid/sphinxcontrib-mermaid-1.0.0.ebuild
index e1204dcba6ec..fcfffb4660fe 100644
--- a/dev-python/sphinxcontrib-mermaid/sphinxcontrib-mermaid-1.0.0.ebuild
+++ b/dev-python/sphinxcontrib-mermaid/sphinxcontrib-mermaid-1.0.0.ebuild
@@ -20,7 +20,7 @@ SRC_URI="
 
 LICENSE="BSD-2"
 SLOT="0"
-KEYWORDS="amd64 ~arm arm64 ~ppc64 ~riscv ~x86"
+KEYWORDS="amd64 arm arm64 ~ppc64 ~riscv ~x86"
 
 RDEPEND="
 	>=dev-python/sphinx-3.0.0[${PYTHON_USEDEP}]
diff --git a/dev-python/twisted/twisted-25.5.0-r1.ebuild b/dev-python/twisted/twisted-25.5.0-r1.ebuild
index fdf2a070cada..8a2226d567eb 100644
--- a/dev-python/twisted/twisted-25.5.0-r1.ebuild
+++ b/dev-python/twisted/twisted-25.5.0-r1.ebuild
@@ -22,7 +22,7 @@ SRC_URI+="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos"
 IUSE="conch http2 serial ssl test websockets"
 RESTRICT="!test? ( test )"
 
diff --git a/dev-python/zope-interface/zope-interface-8.0.1.ebuild b/dev-python/zope-interface/zope-interface-8.0.1.ebuild
index a239821b5441..c0d4cf6af764 100644
--- a/dev-python/zope-interface/zope-interface-8.0.1.ebuild
+++ b/dev-python/zope-interface/zope-interface-8.0.1.ebuild
@@ -18,7 +18,7 @@ HOMEPAGE="
 
 LICENSE="ZPL"
 SLOT="0"
-KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
 IUSE="+native-extensions test"
 RESTRICT="!test? ( test )"