Adding metadata

20 files changed, 386 insertions, 6 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index b20a428a6ae4..64f56f6df122 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -6,3 +6,4 @@ DIST boto3-1.26.33.gh.tar.gz 581883 BLAKE2B a2ac93a516932b8cfcb039e215608ebdd3f5
 DIST boto3-1.26.34.gh.tar.gz 582767 BLAKE2B 279138d5b6093a16d54bd14bab6e9e4c4901d03a38e968c693dff6c585c30098d6520b3d7f5d98c8db94948bf431ff93531c5f706b9e8bf25501255b46c40203 SHA512 b9cc60eda79e8addba92013e34893cb7c59557d350d065f7406c1fb2b0c4256612a09d049ebc62f2ee447922f9ae99557a84f60379267f576a6665dbdc193d1e
 DIST boto3-1.26.36.gh.tar.gz 584205 BLAKE2B d5aad2ab0b8ee3392c636309454859e30cbe937d0dc2efb4b5a817fc83c555e5592ec8a8ae94a273ab2ab55be5d627b44475d0b5ca77caebc246229e3f78b155 SHA512 818843d82b27ee2e376382f1a74a950cbacf04a588bdc012e8c88d569ad5571d231a2dd399a3e26efc3de96c89f722ceabc3e70eb3cdba930c08277fa6c2c189
 DIST boto3-1.26.37.gh.tar.gz 584822 BLAKE2B 08c08502f3defee6365aa19a55cb5bb6c006ce9685421119d1469f90f35e0aeb49fc11a6c5dd133cdfe1138248c0952338adb7b864010825f6f32f40398c2f4f SHA512 4c73b45cae0ed42f219b77d5b58f26560f3ac660d66eaea0c8452053ed38b4c8cc7ab168062483a52e091f7241623466a473368e0545a9fa07c0ac12d0185e31
+DIST boto3-1.26.38.gh.tar.gz 585100 BLAKE2B 22bbaad5e5ba59c29300ac1331e570b763d7544c9feddff307b2eba3e3da9076c6d64ed189d115ff63fd2deb156f6edd2a767121489c5d02e9ee0b897cb39712 SHA512 f97bd9cffd6d4c4d03841038940edb592962b72a3595e9255fc0af491aee1eb1742e819861c8f207383062f6ec284f8ecc37e9a30c59eb1e7702066b4a7c988f
diff --git a/dev-python/boto3/boto3-1.26.38.ebuild b/dev-python/boto3/boto3-1.26.38.ebuild
new file mode 100644
index 000000000000..aa8071e64d5e
--- /dev/null
+++ b/dev-python/boto3/boto3-1.26.38.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index df4fa38c992c..af20f85dfa19 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -6,3 +6,4 @@ DIST botocore-1.29.33.gh.tar.gz 11053602 BLAKE2B 746a59340b7a01c46b15d36d735c67d
 DIST botocore-1.29.34.gh.tar.gz 11061036 BLAKE2B 03b4b48d1308113be6711e27d15dfca4e361ba6c1464c009cdbb0524ddf2075a749e8433d52fe760a4a3871ce3f646c08db125f81828c1b29d8ee3d2a2176331 SHA512 683a0f0d62559db351036426bf59e3179c259cddb4010e6064cac2f23d43e07d98b6aed8a1cf5b3a8089ae24a95f1b3f2543bbd23bc0a21d7aad90114041619b
 DIST botocore-1.29.36.gh.tar.gz 11075582 BLAKE2B 4db73c753acc1eba93bc5fc3a2486b3ded6ee41e35220f56cefc71e808128cb88582474782b1e77b992186b8bcab3ec34ec5566517b1464ee226480f615ef1f0 SHA512 dfaf655fabe85c54cc58a4266fa11b78c7b0dab771a639d9bf8d2583db1b245ae8d5344b7fc6aff759fce80a3ab7ba7f61a7d912adc1dab3c147077cd4fd79c9
 DIST botocore-1.29.37.gh.tar.gz 11077206 BLAKE2B 59c877edba074d4d5858dbf0a4026c0884cc4fce5bc2c9a7d933cfbff8317825663955205ebc754f8a4713b817b7d775fe208d6946f788a1943989949da58a04 SHA512 e79447fe66a506326c5f6396a32b5f4f6560038c57ab03457c36c838f52c1e48a94cba7624350a738eb937d0f3954984b77fd97ffb4becfa72cc4c61005efd40
+DIST botocore-1.29.38.gh.tar.gz 11079677 BLAKE2B 3edca40f575278b24c4b65ccaba3432715f8d7908f6e561cc475963f0865ef777a53845a1e8579f023a4943d69f33c8e1071afa6dd214d480dd48bacc8c132e1 SHA512 814863a6653f36f58bb20d4c7e154ba6d731f4046f3183ce696f515b1baa5ce342620bdfdd09eeea3847c6494add5611651487ad4d8f9c773823cf20393cb940
diff --git a/dev-python/botocore/botocore-1.29.38.ebuild b/dev-python/botocore/botocore-1.29.38.ebuild
new file mode 100644
index 000000000000..36f6e1eb862b
--- /dev/null
+++ b/dev-python/botocore/botocore-1.29.38.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+		# fails on unrelated warnings
+		tests/unit/test_client.py::TestAutoGeneratedClient::test_BOTO_DISABLE_COMMONNAME
+		tests/unit/test_client.py::TestClientErrors::test_BOTO_DISABLE_COMMONNAME
+		# TODO
+		tests/functional/test_credentials.py::SSOSessionTest::test_token_chosen_from_provider
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/django-tables2/Manifest b/dev-python/django-tables2/Manifest
index ea01ba5f4fdb..d778af29dc41 100644
--- a/dev-python/django-tables2/Manifest
+++ b/dev-python/django-tables2/Manifest
@@ -1,2 +1,3 @@
 DIST django-tables2-2.3.4.tar.gz 77706 BLAKE2B 54e0903747ab29dab26049868f8cfd412d23fe3f36eaf292bebc90ee1c307f08d04af1eed469423e3699db227110fc0347a8034acb3b3b46971d37b3aebb84a1 SHA512 d10144b79850847d2787e4a97f450eb3709a419a5dcd330667e3746c16f3be7472c6c26dbf7d765356130b79b8c915c46fd3201c83e66806753f1bb95911895f
 DIST django-tables2-2.4.1.gh.tar.gz 429723 BLAKE2B 80361d419279f548c089c4da990a45c6b43576746ec2762928af907415f3ea331a89f7e0ec7b792d27e15ed409b25f3ee26b3794cdb16255835f0d74faee068c SHA512 e2431f86e049b9dee1100d48727ea2003e431a3ad5bf8e8a4b773d53dc4d5e90ec310a7f07ce7532e044903d760aacda37b3512770f6e0db6527842d1cbdd6d9
+DIST django-tables2-2.5.0.gh.tar.gz 430376 BLAKE2B 592a488fea869c2b0630c8d3ad72182636206a2b394355a2702c2dbeac43a67f9175a9f7756349c3d7877d2887af0e32816e2a4c9ba5234f04e9828fe38ffe29 SHA512 b0a31860205c5e68a520d1fdbfe16e094701dbcf1cf8c46d62c32b8194c121271832f08ca0fdb4c05cb52c1fde5ef66e323d3f772e2562da4f48188128cfa8a0
diff --git a/dev-python/django-tables2/django-tables2-2.5.0.ebuild b/dev-python/django-tables2/django-tables2-2.5.0.ebuild
new file mode 100644
index 000000000000..59f97f84c14a
--- /dev/null
+++ b/dev-python/django-tables2/django-tables2-2.5.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Table/data-grid framework for Django"
+HOMEPAGE="
+	https://pypi.org/project/django-tables2/
+	https://github.com/jieter/django-tables2/
+"
+SRC_URI="
+	https://github.com/jieter/django-tables2/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+SLOT="0"
+LICENSE="BSD-2"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/django-3.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/django-filter[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/psycopg:2[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+	)
+"
+
+src_prepare() {
+	# these tests require tablib
+	rm tests/test_export.py tests/test_templatetags.py || die
+	# these tests require fudge
+	rm tests/test_config.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	"${EPYTHON}" manage.py test -v 2 tests || die
+}
diff --git a/dev-python/hcloud-python/Manifest b/dev-python/hcloud-python/Manifest
index 150e9e1f1054..1751a6ea6fb4 100644
--- a/dev-python/hcloud-python/Manifest
+++ b/dev-python/hcloud-python/Manifest
@@ -1 +1,2 @@
 DIST hcloud-python-1.18.1.gh.tar.gz 99042 BLAKE2B 159b2fb29021ca7993f75c4731867ed1bc57e2c9a3cf68a45acf43bb45e9a0862717907d1dfce45c960064ad82b71422e76b290db3516ea3744be95797db5e1e SHA512 6d172c214d25ae846b5561e4caa6b70d4f4e765e064ae971d5b216ceb743ab269f735e2c9adb68f1cf99ef429621b6998a34c8c7befa6d527dc3b774c0639bae
+DIST hcloud-python-1.18.2.gh.tar.gz 98998 BLAKE2B b4f8d3335c4589c8e5f453ed60299b222f002de1d8ae5ba95dcc35c6d4c4c4f649e6924037ed935651976fce06aa4ff61b893e3dcbdf745c6c1d9ff678b04dcd SHA512 da71f5590514d45b630662b1bedf7907e5ba33a48617131615377724e1377a2776f979c00e50521c513052b4f540224439e048e2e1215973b76c55a8a20e1a45
diff --git a/dev-python/hcloud-python/hcloud-python-1.18.2.ebuild b/dev-python/hcloud-python/hcloud-python-1.18.2.ebuild
new file mode 100644
index 000000000000..4264dea73e8b
--- /dev/null
+++ b/dev-python/hcloud-python/hcloud-python-1.18.2.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+inherit distutils-r1
+
+DESCRIPTION="Official Hetzner Cloud python library"
+HOMEPAGE="https://github.com/hetznercloud/hcloud-python"
+SRC_URI="
+	https://github.com/hetznercloud/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/python-dateutil-2.7.5[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.20[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# Integration tests need docker:
+	# https://github.com/hetznercloud/hcloud-python/blob/master/.travis.yml#L16
+	tests/integration
+)
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/httpx-socks/httpx-socks-0.7.5.ebuild b/dev-python/httpx-socks/httpx-socks-0.7.5.ebuild
index 0728c44c2a41..16b8f75b8903 100644
--- a/dev-python/httpx-socks/httpx-socks-0.7.5.ebuild
+++ b/dev-python/httpx-socks/httpx-socks-0.7.5.ebuild
@@ -20,7 +20,7 @@ SRC_URI="
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~loong ~ppc ~ppc64 ~x86"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
 
 RDEPEND="
 	<dev-python/httpx-0.24.0[${PYTHON_USEDEP}]
diff --git a/dev-python/hypercorn/hypercorn-0.14.3-r1.ebuild b/dev-python/hypercorn/hypercorn-0.14.3-r1.ebuild
index ab556e112304..d02fc99029de 100644
--- a/dev-python/hypercorn/hypercorn-0.14.3-r1.ebuild
+++ b/dev-python/hypercorn/hypercorn-0.14.3-r1.ebuild
@@ -20,7 +20,7 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~loong ~ppc ~ppc64 ~x86"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
 
 RDEPEND="
 	dev-python/h11[${PYTHON_USEDEP}]
diff --git a/dev-python/pip-run/Manifest b/dev-python/pip-run/Manifest
index 02c801137df2..0604925be348 100644
--- a/dev-python/pip-run/Manifest
+++ b/dev-python/pip-run/Manifest
@@ -1,2 +1,3 @@
 DIST pip-run-9.0.0.gh.tar.gz 23171 BLAKE2B ca1bee27f4d1826029aa2520dbad9807d22ce66326fd917f0b7687284ce3daf9abcd45e593d735633fb86186ea88ffa0b71780f9b56e27458798763db309bd9d SHA512 117b2260fe628dcc5aae47335ab645c2db47ca9b4d5cd0446ef11bb399c0e91df3a32b61aa7a228aca4d7b837228ddb41fe010896f7debf5fbca6111398cce73
 DIST pip-run-9.2.1.gh.tar.gz 24104 BLAKE2B ebb26cd5356a5919d74c6601b36deed0046c0d67d7533f5817b62b7b7ba74240ef44dd2425be7143f8432d3f8a3f611a051f099b6059e64479eadd77e8f39b45 SHA512 f320da7641817df5c9418094fb49792e3368907ddac551ef22d97ab45b5183cb84f40338da106d5a47d238ca68ca376cbfc6d6c3528b9fca1db02bf910bd3d28
+DIST pip-run-9.4.0.gh.tar.gz 25821 BLAKE2B 8d4d9712f0563d3edf8d963e14221fde89cffc14c3fb26afc2b18bdeca9917cacb27c88a815d398d2b67f10112e888c9f60b497c3c1bf59d0105a4c972aef15d SHA512 c266e6eb30f21ddfd89cc25dee5c56542b3734497d59315751c190e7bd985c6746b95802255ec05da19d5cec8822f4fa169eba4218989013e36a2c118d560f4d
diff --git a/dev-python/pip-run/pip-run-9.4.0.ebuild b/dev-python/pip-run/pip-run-9.4.0.ebuild
new file mode 100644
index 000000000000..6471d7767f32
--- /dev/null
+++ b/dev-python/pip-run/pip-run-9.4.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Install packages and run Python with them"
+HOMEPAGE="
+	https://github.com/jaraco/pip-run/
+	https://pypi.org/project/pip-run/
+"
+SRC_URI="
+	https://github.com/jaraco/pip-run/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/autocommand[${PYTHON_USEDEP}]
+	dev-python/jaraco-context[${PYTHON_USEDEP}]
+	dev-python/jaraco-text[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-8.3[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/path[${PYTHON_USEDEP}]
+	dev-python/pip[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jaraco-path[${PYTHON_USEDEP}]
+		dev-python/pygments[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# Needs network access, and another test dep nbformat
+	tests/test_scripts.py
+)
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
diff --git a/dev-python/python-multipart/python-multipart-0.0.5.ebuild b/dev-python/python-multipart/python-multipart-0.0.5.ebuild
index 56c511608086..6ca9b25b5d70 100644
--- a/dev-python/python-multipart/python-multipart-0.0.5.ebuild
+++ b/dev-python/python-multipart/python-multipart-0.0.5.ebuild
@@ -20,7 +20,7 @@ SRC_URI="
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~loong ~ppc ~ppc64 ~x86"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
 
 BDEPEND="
 	test? (
diff --git a/dev-python/python-socks/python-socks-2.1.1.ebuild b/dev-python/python-socks/python-socks-2.1.1.ebuild
index 5945059c2a81..0e78900ac588 100644
--- a/dev-python/python-socks/python-socks-2.1.1.ebuild
+++ b/dev-python/python-socks/python-socks-2.1.1.ebuild
@@ -20,7 +20,7 @@ SRC_URI="
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~loong ~ppc ~ppc64 ~x86"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
 
 # curio is not packaged
 # asyncio is the only backend we have, so dep on its deps unconditionally
diff --git a/dev-python/python3-saml/Manifest b/dev-python/python3-saml/Manifest
index 04780796bcb9..a0e74dcfa8b0 100644
--- a/dev-python/python3-saml/Manifest
+++ b/dev-python/python3-saml/Manifest
@@ -1 +1,2 @@
 DIST python3-saml-1.14.0.gh.tar.gz 510031 BLAKE2B 10c1102b29b58017a39241dbab7d2fb85231f051e3701ff24197f2e501ae19b1889d4032fe86a60ed5ee708380d44111dc6ab87900c8463a141ea911fe774eeb SHA512 6807a4741164dfdf185a4c63691d5a1f0e91feff387265dc8b54b135d44158c751c2274eb1f47eb71d61c7e233d38ddc83f34d092cb842676830699ad6ee8af4
+DIST python3-saml-1.15.0.gh.tar.gz 511199 BLAKE2B c1dafb5ff9c45a79042915261cdc380a1ca77b56d518999164f48c904e53a486d157e5b522b77df9abea2b3306f8b17a06a7ac3e41ad0c86bea2c08468199e60 SHA512 8ecfd827e3b90f65a04ed46f8efd49680d42ecaa46b46857e0f712c2996207a8aa38834f55ec35e599845f6921bd4d82d76e549494c71cc5ffd918e70b87b6a8
diff --git a/dev-python/python3-saml/python3-saml-1.15.0.ebuild b/dev-python/python3-saml/python3-saml-1.15.0.ebuild
new file mode 100644
index 000000000000..533624e42319
--- /dev/null
+++ b/dev-python/python3-saml/python3-saml-1.15.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="OneLogin's SAML Python Toolkit"
+HOMEPAGE="
+	https://github.com/SAML-Toolkits/python3-saml/
+	https://pypi.org/project/python3-saml/
+"
+SRC_URI="
+	https://github.com/SAML-Toolkits/python3-saml/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+RDEPEND="
+	>=dev-python/isodate-0.6.1[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.9.0[${PYTHON_USEDEP}]
+	>=dev-python/python-xmlsec-1.3.9[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+python_test() {
+	# The tests are horribly fragile to paths.
+	local -x PYTHONPATH=src
+	eunittest -p '*_test.py'
+}
diff --git a/dev-python/qtawesome/Manifest b/dev-python/qtawesome/Manifest
index 85365dad97b0..d72c250c4fd3 100644
--- a/dev-python/qtawesome/Manifest
+++ b/dev-python/qtawesome/Manifest
@@ -1 +1,2 @@
 DIST QtAwesome-1.2.1.tar.gz 2280937 BLAKE2B 4d54e8d9fabd833ca4a430ed9573da4feb6aeaae9090fbdf7874d68214de0c0548be18b2f5d2c643add754c748f6af97eaa821aa3d341ed6dd563b8769c1a5c7 SHA512 dd4ef533c5a7bc5fc7eba549c166653efb2352e12412d5678e30cc8865fe44684ca6e070ca61801910c3eefd5673325cb87555e0fb30007b5fd0b53d04dc1c44
+DIST QtAwesome-1.2.2.tar.gz 2281303 BLAKE2B 8766f06feb4cbcab213d537e2c6b5fcaa952d2e06cfa2c4ecdbcdd1b2e900b715632ac7280a5b65e8085643267d048a519805ad2d9da57ee1be1b4c311951ff7 SHA512 9117798041b9593f3db9c8e379f2fa38e1d6d73a4d6b370f73a4ca0bcd69af78989ab0e9a9e2aa9ec20e2637ed1123237f6e8da2be383c09d51921d52052498f
diff --git a/dev-python/qtawesome/qtawesome-1.2.2.ebuild b/dev-python/qtawesome/qtawesome-1.2.2.ebuild
new file mode 100644
index 000000000000..e322c611445a
--- /dev/null
+++ b/dev-python/qtawesome/qtawesome-1.2.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 virtualx
+
+MY_PN="QtAwesome"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Enables iconic fonts such as Font Awesome in PyQt"
+HOMEPAGE="
+	https://github.com/spyder-ide/qtawesome/
+	https://pypi.org/project/QtAwesome/
+"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	media-fonts/fontawesome
+	dev-python/QtPy[pyqt5(+),gui,${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-qt[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	# Tests fail with pyside2, so depend on QtPy[pyqt5] and explicitly run
+	# the tests with pyqt5
+	PYTEST_QT_API="pyqt5" epytest || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/starlette/starlette-0.23.1.ebuild b/dev-python/starlette/starlette-0.23.1.ebuild
index 07151be16cbd..a66433daf8c2 100644
--- a/dev-python/starlette/starlette-0.23.1.ebuild
+++ b/dev-python/starlette/starlette-0.23.1.ebuild
@@ -21,7 +21,7 @@ SRC_URI="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~loong ~ppc ~ppc64 ~x86"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
 
 RDEPEND="
 	<dev-python/anyio-5[${PYTHON_USEDEP}]
diff --git a/dev-python/tiny-proxy/tiny-proxy-0.1.1.ebuild b/dev-python/tiny-proxy/tiny-proxy-0.1.1.ebuild
index b1867ad29b87..265c7ba3206c 100644
--- a/dev-python/tiny-proxy/tiny-proxy-0.1.1.ebuild
+++ b/dev-python/tiny-proxy/tiny-proxy-0.1.1.ebuild
@@ -20,7 +20,7 @@ SRC_URI="
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~loong ~ppc ~ppc64 ~x86"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
 
 RDEPEND="
 	<dev-python/anyio-4.0.0[${PYTHON_USEDEP}]