Adding metadata

29 files changed, 593 insertions, 99 deletions

diff --git a/dev-python/bottle/Manifest b/dev-python/bottle/Manifest
index d02a1b78ee69..b20305e8f36e 100644
--- a/dev-python/bottle/Manifest
+++ b/dev-python/bottle/Manifest
@@ -1,2 +1,3 @@
 DIST bottle-0.12.25.tar.gz 74231 BLAKE2B 2856d94e1525f21e272d70ca3101188ea65417179342d7b3e971c5d1a3be77265e4197e5d29764a5739adbd984883ed121524f29e6a5933b8681e2c34b511a57 SHA512 14b8ed1ffd58f9667d451872ccf73a6f4bf8f7ffb9329f55314f90c770630cfe3f9956f786bcc7fd5f67fde22d14961952969af405912ebe71f019ca6599c975
 DIST bottle-0.13.1.tar.gz 836422 BLAKE2B 8160de68b04cab8b3fe86dfc4b9f354ff2de523eae79277b91889e634629e9b462f9013c9821409ad3b43aa329c02ddce66bde45bc1c650a2826e641236b2fe7 SHA512 504704d20712723436c61712e8aa41e603a0f66f74927b4d4122aaea3a090ab910d5daa12217d48b803a66fc3d96d491c2a0b30df236aff50520adb8c115609f
+DIST bottle-0.13.2.tar.gz 98472 BLAKE2B 44c47d052e1daa99bea23fa0be9bb9977c4747bbee496e6815e7267b473cfa659026b8abed248d89235915c5018c29b455c379fa9ed22df8ba861b909b27cbce SHA512 3923070d3723fa975aaed79a6edc7ec47ce2d3cbc4b3fbddff340e19e3e13215034208c2bd198726b0461008313c4600021bd2766b7f0a0dfae2b12ff988f52d
diff --git a/dev-python/bottle/bottle-0.13.2.ebuild b/dev-python/bottle/bottle-0.13.2.ebuild
new file mode 100644
index 000000000000..871af07f73d9
--- /dev/null
+++ b/dev-python/bottle/bottle-0.13.2.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="A fast and simple micro-framework for small web-applications"
+HOMEPAGE="
+	https://bottlepy.org/
+	https://github.com/bottlepy/bottle/
+	https://pypi.org/project/bottle/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/mako[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+pkg_postinst() {
+	optfeature "Templating support" dev-python/mako
+}
diff --git a/dev-python/bottleneck/Manifest b/dev-python/bottleneck/Manifest
index 8ce948a5e14e..8d5d93089a76 100644
--- a/dev-python/bottleneck/Manifest
+++ b/dev-python/bottleneck/Manifest
@@ -1 +1,2 @@
 DIST bottleneck-1.4.0.tar.gz 103490 BLAKE2B c72b53bd1f4325fa53d7824e335ec50a37da7650c097bdda22548637c1e5a95bfa219dad1361dfb2eecdcf0fa1445a5c6cfb94b7472290fa6317524dc474f46c SHA512 07c1224d63a34e12488dce1f72152fdc493db904130cef46092f7f9c3218a04032e90d64dbf385069072c5d56c7ea09db15897d5c77b9d53db2e3da9414f84cc
+DIST bottleneck-1.4.1rc1.tar.gz 103592 BLAKE2B 1e201ae87274e33245a56a9976d951e0040c9bb0bcca714a1b5dcd5b2e40a782dfa0ee09dbb7743e803fe5bd6c1c074abff24408d68bd3dd00050fb8d6e07ab3 SHA512 5ba05a852833f1eae3b5b5d96125484011faa08cc6556cdbadc668ef3c5efde406ff5432235de2ef65bb6ce3ca9f8aab159e33b2ddbfb8566638dfa9746f9ef0
diff --git a/dev-python/bottleneck/bottleneck-1.4.1_rc1.ebuild b/dev-python/bottleneck/bottleneck-1.4.1_rc1.ebuild
new file mode 100644
index 000000000000..6add1d6233c6
--- /dev/null
+++ b/dev-python/bottleneck/bottleneck-1.4.1_rc1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYPI_PN=${PN^}
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Fast NumPy array functions written in C"
+HOMEPAGE="
+	https://github.com/pydata/bottleneck/
+	https://pypi.org/project/Bottleneck/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
+
+DEPEND="
+	>=dev-python/numpy-1.9.1:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# don't overwrites user's optimization level
+	sed -e '/extra_compile_args=\["-O2"\]/d' -i setup.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# GC assumptions?
+				tests/memory_test.py::test_memory_leak
+			)
+			;;
+	esac
+
+	rm -rf bottleneck || die
+	epytest --pyargs bottleneck
+}
diff --git a/dev-python/django-cors-headers/Manifest b/dev-python/django-cors-headers/Manifest
index febb9963e194..231d9c2d991a 100644
--- a/dev-python/django-cors-headers/Manifest
+++ b/dev-python/django-cors-headers/Manifest
@@ -1 +1,2 @@
 DIST django-cors-headers-4.4.0.gh.tar.gz 31028 BLAKE2B 065ac5a96c3871e8dc0eff48ef54efeb57d60a2a1588b69345f116600fe31ce7b0532ff38ca554eb5a6cff338f10e557c8876486a10db158c24a6097c44d7288 SHA512 7a380512a62420d4b6b47d43fd5d5ced1579db61fc538b4b22665e14a71298a1b1f9ebe93f808245b756d18c494177ef9ecaa01ae8d86f90a2bbf9db9b1997d7
+DIST django-cors-headers-4.5.0.gh.tar.gz 31156 BLAKE2B 5f3c16c6524bdb5832579d9313863e8df334cfca4fbb2831c9cd813759e5f6b491c3967117bd04775dc42d01ef290f0fe5c36d708ee13b4c3076d4513988e91d SHA512 084a6809bfb8b15fe23b65c1cca52453c94a7f659174bb06c36dbc6ec925638bc4f8e2303d7b3e6ef1e0953815b5caf642a5ae988f8a65b18b278f28d59cd4d0
diff --git a/dev-python/django-cors-headers/django-cors-headers-4.5.0.ebuild b/dev-python/django-cors-headers/django-cors-headers-4.5.0.ebuild
new file mode 100644
index 000000000000..1d7e525698dc
--- /dev/null
+++ b/dev-python/django-cors-headers/django-cors-headers-4.5.0.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Django App that adds CORS (Cross-Origin Resource Sharing) headers to responses"
+HOMEPAGE="
+	https://github.com/adamchainz/django-cors-headers/
+	https://pypi.org/project/django-cors-headers/
+"
+SRC_URI="
+	https://github.com/adamchainz/django-cors-headers/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/asgiref-3.6[${PYTHON_USEDEP}]
+	>=dev-python/django-3.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-django[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index cc2981428fa1..4181b2fa3f82 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -5,3 +5,4 @@ DIST hypothesis-6.112.4.gh.tar.gz 9477498 BLAKE2B ef27f97b419e0bb454ef63c03ecf87
 DIST hypothesis-6.113.0.gh.tar.gz 9479824 BLAKE2B e5a87d042d409757451db19bf8b7433e78140cbc6bc9ab6dab4a02cdf2b311734fa37c03aa3b3d51a652b823a3fa554205d4f0188c2e5f2e439609132b4e17d9 SHA512 c8e4711b3496811fd67a20545aa4abfa5b38289befbffa3eab7d9daf155b899124e62a2771b772b009a373308a32967e8804c99a70507ee7996ab3adf92d41e0
 DIST hypothesis-6.114.0.gh.tar.gz 9477661 BLAKE2B 26cc5cb5a4082b689f024963745f44cb0fbec169b6596145dafcabd7750887d3ecda15e22ef05ebebb0ea756629a51d86f7586f7eb0e2bcedd11380a86881c3f SHA512 e779047546b4f55a7085ee7b3bd05ea292d97cdfb5fe1b85a083a4d29120d3b8fdc50cb8651eee4ed391f6b1634c928b7e38f7956e595b856e9b53115d8a85af
 DIST hypothesis-6.114.1.gh.tar.gz 9477292 BLAKE2B 3dadb706f7d283febdc30c9e897fa5b648382edd9bba0ed0824abc2f2c1f6562f0ac77003df496d1def1e56092412c14674b5e768f9583607463f92b78770ad5 SHA512 14526a836c71cdec68a3fbd54391d4f6fe6911305fea9b349c77c59a3f352b7105531a44df05e26cd372d457ed07f7c8199967f444ede14b7d66151afe815727
+DIST hypothesis-6.115.0.gh.tar.gz 9478048 BLAKE2B 8c5ecea0b3515c06f692395e18f27dbc7c273d5b68aa15bacbd8a6965954647e7e8606ec5cd15aa7f42a7d651b21cef93b80bacb42844129d1ce8e57c55ff76f SHA512 1bb73466d35ba8254f0413e883994e734e514af2cfd73ce8ab352b451837a4f297125778939d99404b675a78e603272f76f695326ae52d904c75bea5aa910321
diff --git a/dev-python/hypothesis/hypothesis-6.115.0.ebuild b/dev-python/hypothesis/hypothesis-6.115.0.ebuild
new file mode 100644
index 000000000000..902ce1505c8b
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.115.0.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( pypy3 python3_{10..13} )
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/pytest-8[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/requests-toolbelt-0.10.1
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,_hypothesis_pytestplugin
+	local -x HYPOTHESIS_NO_PLUGINS=1
+
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# failing due to warnings from numpy/cython
+				hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+			)
+			;;
+	esac
+
+	epytest -o filterwarnings= tests/cover tests/pytest tests/quality
+}
+
+src_install() {
+	local HAD_CLI=
+
+	distutils-r1_src_install
+
+	if [[ ! ${HAD_CLI} ]]; then
+		rm -r "${ED}/usr/bin" || die
+	fi
+}
+
+python_install() {
+	distutils-r1_python_install
+	if use cli && has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		HAD_CLI=1
+	else
+		rm -r "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/kiwisolver/kiwisolver-1.4.7.ebuild b/dev-python/kiwisolver/kiwisolver-1.4.7.ebuild
index 89e0b60fd7ee..4d8b6c822426 100644
--- a/dev-python/kiwisolver/kiwisolver-1.4.7.ebuild
+++ b/dev-python/kiwisolver/kiwisolver-1.4.7.ebuild
@@ -22,7 +22,7 @@ S=${WORKDIR}/${MY_P}
 
 LICENSE="Clear-BSD"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ppc ppc64 ~riscv ~s390 sparc x86 ~arm64-macos ~x64-macos"
 
 COMMON_DEPEND="
 	>=dev-python/cppy-1.2.0[${PYTHON_USEDEP}]
diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index a11d7c268c91..37a64204a00a 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1 +1,3 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
+EBUILD langdetect-1.0.9.ebuild 494 BLAKE2B 9b3521c5721afa49a58e0c35267f7d82bb56bd7e1d6d3152be0d36cd220180a526cb20b90b1113fbf0fff4a512137570f0b3bcf864498b7b7cc00403cb61ca27 SHA512 16d311400bf84a5f04e15f3da4b68b2810e4b005009f4d03dc8a487176dfc294403c976c412c83dcfa8084a49ef7b7d5389b43fb2ba446ce107ce4595e3558c6
+MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch b/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
deleted file mode 100644
index 637368d2f237..000000000000
--- a/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
+++ /dev/null
@@ -1,13 +0,0 @@
-Fix "Package 'langdetect.profiles' is absent from the `packages` configuration."
-
---- a/setup.py
-+++ b/setup.py
-@@ -18,7 +18,7 @@ setup(
-     author_email='michal.danilak@gmail.com',
-     url='https://github.com/Mimino666/langdetect',
-     keywords='language detection library',
--    packages=['langdetect', 'langdetect.utils', 'langdetect.tests'],
-+    packages=['langdetect', 'langdetect.utils', 'langdetect.tests', 'langdetect.profiles'],
-     include_package_data=True,
-     install_requires=['six'],
-     license='MIT',
diff --git a/dev-python/langdetect/langdetect-1.0.9.ebuild b/dev-python/langdetect/langdetect-1.0.9.ebuild
index eb2586280d80..56733bbffc48 100644
--- a/dev-python/langdetect/langdetect-1.0.9.ebuild
+++ b/dev-python/langdetect/langdetect-1.0.9.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2022-2024 Gentoo Authors
+# Copyright 2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -19,6 +19,4 @@ KEYWORDS="~amd64"
 
 RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
 
-PATCHES=( "${FILESDIR}/${P}-explicit-config.patch" )
-
 distutils_enable_tests unittest
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index c0f74ac187e2..020e07f2a3dd 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -2,9 +2,11 @@
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
  <maintainer type="person">
-  <email>pastalian46@gmail.com</email>
-  <name>Takuya Wakazono</name>
+  <email>marcin.deranek@slonko.net</email>
+  <name>Marcin Deranek</name>
  </maintainer>
- 
- <origin>gentoo-guru-overlay</origin>
+ <upstream>
+  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
+ </upstream>
+ <origin>slonko-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/mkdocstrings-python/Manifest b/dev-python/mkdocstrings-python/Manifest
index 96bdeb0424c4..8819ea8601c7 100644
--- a/dev-python/mkdocstrings-python/Manifest
+++ b/dev-python/mkdocstrings-python/Manifest
@@ -1,3 +1,4 @@
 DIST mkdocstrings_python-1.10.8.tar.gz 161724 BLAKE2B 1720bd166c8b924f3d024ffbdaa46383a68ddbb4db1aff6d588049272f8e34046ac7ae62a6d9739dca029794e42afa0415179c978874b6012ace4842978184de SHA512 da179fc31af4bc6dba62b050c26736b313859dac6b8c29c877126081d6bb228255be626af09a61ae2a5b449dd0a1a19d41b1313dc9d1fd10e001e16a423c485c
 DIST mkdocstrings_python-1.10.9.tar.gz 162070 BLAKE2B a939f662ae33eba397260589f634ea6a2acaeecb1acd0711eefc65cbce09e5fbfc03aab19c6daa960d853a4387f09699a6fd32bf73f39d6d8c95732cb6d3cad9 SHA512 4f6729506208409ed9936e663dc1514457dbb0977408949d2f4121440e33084b7f152c21138f99332b18825425432f85cf2300e9b14dd6d9e36a9f50e52abd7a
 DIST mkdocstrings_python-1.11.1.tar.gz 166890 BLAKE2B 47241f180421e3b535a58801363907d85eb9550593b849f7210a4584e5b1fafbf261feec2a3d9f5f88b0d25d5f6ae8a824c561718a2729a9cd2ada72a31f9fa8 SHA512 224210247e277b626916cebba816e2cf78ce1af8338c5bae783aa3550352e121dfe8a27ccb61258ee3723c46c6e36e74bd129ed5ae2297ff7bb451c27f9faef7
+DIST mkdocstrings_python-1.12.0.tar.gz 167909 BLAKE2B b9bc04bd9e82a17c97773eb054ea7e1fdb8548073b334a13020149c10e656cd390ae7036c2a6809203fc673f471d06891c47d1859ea10fe0580dcbae9b38d79a SHA512 0cf21f6d57a3ff9be8e194eb0915fa8ba72aaee1d7499be68e749f2f23821c5009876c981a4d2c879345a005f22fa587a52a1ed6c9f72b1594b1c3ca71aad8e6
diff --git a/dev-python/mkdocstrings-python/mkdocstrings-python-1.12.0.ebuild b/dev-python/mkdocstrings-python/mkdocstrings-python-1.12.0.ebuild
new file mode 100644
index 000000000000..e0cab3a4c2aa
--- /dev/null
+++ b/dev-python/mkdocstrings-python/mkdocstrings-python-1.12.0.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python handler for dev-python/mkdocstrings"
+HOMEPAGE="
+	https://mkdocstrings.github.io/python/
+	https://github.com/mkdocstrings/python/
+	https://pypi.org/project/mkdocstrings-python/
+"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv"
+
+RDEPEND="
+	>=dev-python/griffe-0.49[${PYTHON_USEDEP}]
+	>=dev-python/mkdocstrings-0.26.0[${PYTHON_USEDEP}]
+	>=dev-python/mkdocs-autorefs-1.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mkdocs-material[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export PDM_BUILD_SCM_VERSION=${PV}
diff --git a/dev-python/mkdocstrings/Manifest b/dev-python/mkdocstrings/Manifest
index 2a87a85487d3..bc4eb0f72216 100644
--- a/dev-python/mkdocstrings/Manifest
+++ b/dev-python/mkdocstrings/Manifest
@@ -1,2 +1,3 @@
 DIST mkdocstrings-0.26.0.tar.gz 92218 BLAKE2B 6eee2a080b568ccb90d8ac122da9bb9c1d35088e4f3d43f98da287e581f549f25b6da9dd7f0fbe9dffcaeea8acc1143cd77b4e2fb5d208d592242954724f98e3 SHA512 b1e63fae1e22f0fd1977e7274b94bf3f50ab673d6e3c77d291095bf3503fff8afde08d29917fdbddd00ac716ac048248362dbc526446924592b57f2ea339caf8
 DIST mkdocstrings-0.26.1.tar.gz 92677 BLAKE2B 010464f8af2b741fb74cae7140c8552ee05e84a275952701bc29f8f4d057fd4f82a6129da070cb1ae41f0a1e407b8cce6dda4a924650bb83f41c9bf5caf208e4 SHA512 75c1b794dc816523b1c0202304146a986e87403f65e1ed728ed585eb6d78f9ae5fe1ab97798fa8d9ad24f41ec590ad3bb31dec2d420f6312da126b55540301da
+DIST mkdocstrings-0.26.2.tar.gz 92512 BLAKE2B e2ca2ba4d5a8916cdb77efb0db6c0fdc5f8969b27f4b0b5b199873a62c85150b5a0dde45797b48d297e08f9e082c9c5329084feb15379ae0a16821ac11aa3fed SHA512 7ea34df4204ae82faa19ddaf81a073152c57d9ef7f55f8935c1eb1b244ebc6ed749d853c72fd28e69ee5e1aa12ae7a2e4b6fff4f9965856a837d15dd0e2cc11e
diff --git a/dev-python/mkdocstrings/mkdocstrings-0.26.2.ebuild b/dev-python/mkdocstrings/mkdocstrings-0.26.2.ebuild
new file mode 100644
index 000000000000..f70eedb0d291
--- /dev/null
+++ b/dev-python/mkdocstrings/mkdocstrings-0.26.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Automatic documentation from sources, for MkDocs"
+HOMEPAGE="
+	https://mkdocstrings.github.io/
+	https://github.com/mkdocstrings/mkdocstrings/
+	https://pypi.org/project/mkdocstrings/
+"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv"
+
+RDEPEND="
+	>=dev-python/click-7.0[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.11.1[${PYTHON_USEDEP}]
+	>=dev-python/markdown-3.6[${PYTHON_USEDEP}]
+	>=dev-python/markupsafe-1.1[${PYTHON_USEDEP}]
+	>=dev-python/mkdocs-1.5[${PYTHON_USEDEP}]
+	>=dev-python/mkdocs-autorefs-1.2[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.2[${PYTHON_USEDEP}]
+	>=dev-python/pymdown-extensions-6.3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/markdown-exec[${PYTHON_USEDEP}]
+		dev-python/mkdocs-material[${PYTHON_USEDEP}]
+		dev-python/mkdocstrings-python[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+"
+
+# mkdocstrings documentation generation requires several currently
+# unpackaged mkdocs extensions and plug-ins, and this test
+# makes use of mkdocs configuration
+EPYTEST_DESELECT=(
+	tests/test_plugin.py::test_disabling_plugin
+	# WTF, it tries to unlink installed files from installed package?!
+	tests/test_handlers.py::test_extended_templates
+	# Needs unpackaged mkdocs-callouts, mkdocs-literate-nav, and possibly more
+	tests/test_inventory.py::test_sphinx_load_mkdocstrings_inventory_file
+	# Internet
+	tests/test_inventory.py::test_load_inventory
+)
+
+distutils_enable_tests pytest
+
+export PDM_BUILD_SCM_VERSION=${PV}
diff --git a/dev-python/pillow/pillow-10.4.0.ebuild b/dev-python/pillow/pillow-10.4.0.ebuild
index 5daf68cb51db..9c818c768bed 100644
--- a/dev-python/pillow/pillow-10.4.0.ebuild
+++ b/dev-python/pillow/pillow-10.4.0.ebuild
@@ -28,7 +28,7 @@ S="${WORKDIR}/${MY_P}"
 
 LICENSE="HPND"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ~ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~loong ~m68k ~mips ~ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
 IUSE="examples imagequant +jpeg jpeg2k lcms test tiff tk truetype webp xcb zlib"
 REQUIRED_USE="test? ( jpeg jpeg2k lcms tiff truetype )"
 RESTRICT="!test? ( test )"
diff --git a/dev-python/python-tests/Manifest b/dev-python/python-tests/Manifest
index 1c80235a7e47..918e9a9dd305 100644
--- a/dev-python/python-tests/Manifest
+++ b/dev-python/python-tests/Manifest
@@ -8,12 +8,9 @@ DIST Python-3.12.7.tar.xz 20444032 BLAKE2B eed8744261cab3b401963ec5187a8b814adb9
 DIST Python-3.12.7.tar.xz.asc 963 BLAKE2B 8c7db3d1971d93a10c611a2e6dd3679d0b331b48df87b5fe410b089061e48753d98af67084d4f051a31ae803fce3aa3c7af7cba9c692640f50068bd1e46f40e6 SHA512 4d0a7a0da2c81888e93d8ff89ca2ed4bb85a7b0bd00f0d54a14e2c201affac2677ef3984d2b5aea253e624f6465548d9032eefdd9033c1eb3864d82cfd8d3df0
 DIST Python-3.13.0.tar.xz 22532980 BLAKE2B 4a4e397199402de8c9fe8e4d63443ed972cbe8a4f541743908d699c7987127d159d600fd14145b6a946e8671426279d230c9155fdc5863c1e49a945eedcbf21b SHA512 44a143c9b96b55b01885ec020c3364265bda55289615cd7d5071915b0d0178a6f35e7551a89090001fcb7f3172d38177a56bf8b8532b15c9dbc50295c9210152
 DIST Python-3.13.0.tar.xz.asc 963 BLAKE2B d05f02692a9fea42b73dbfe5dc42bd6533555e5ecb848510d2b94bb7f0e55d4a0f89bcd20b073ed2c7f7a68be35b12cb6dbff6bc16fc9a4592ded2c339ada7fd SHA512 1b8bb0fe4eb93e31ec1770e90b94d44b5864c0391aad5dcba3a30d8e505d9b17107385414353c0060007f8a536254f49b8e919f36ddf6421a6e4330f817f1a3e
-DIST Python-3.13.0rc3.tar.xz 22527884 BLAKE2B 9c6423e9871b30af70ece10598e798da443b40b3e40cae86ec59d396184df005627a5edeedf34d31c7953f972850e41d1cc708edd8e39c1327d319b0f6973049 SHA512 152e5b6d64048c1779612e66d5999c424ca7c61c8a0f4973f7b3019629d6a7923b422aec0bee30e7bc2d589a807d87e15a19b8fb4446bcf082eb663885a49b36
-DIST Python-3.13.0rc3.tar.xz.asc 963 BLAKE2B e03d902eee320939cb77094e1b64e0101d0172ebdcc502255da1c0fc84476f43fafe900321c78cd78248a751b3a3921572ba4f305ed77ed78f175184b21f667f SHA512 c8f80b12f5e3021a11fc3ef5ce84572db9de7165ce89a03206cb0727b54f90ca2e444a16df064e6423e15b7bf2364db088b0c9315967dd340e735eabf7b892ce
 DIST python-gentoo-patches-3.10.15_p1.tar.xz 24048 BLAKE2B 191c28ad9bc781d6f3077870e8d40ff98a47a64009ecfbbd10fe2b3c5330692181837fd3e9b336fd01f936a39160fc12761b2ef9bc00843248ab978cda2e2767 SHA512 4461e351c991694415e2812e558d6c3d3f79295358623dc955bc0839691a170d95a3efd31c0bf9f0d6191e4184d7b55fdb485b948d591782fef5b060d7660cce
 DIST python-gentoo-patches-3.11.10_p1.tar.xz 10592 BLAKE2B 1cc02d22b55cb76beba133c37e6db3b9ba12b11cd8776acb064f14431842405cbc9efb5a06319cff1c73d9178ddbbe2e340829d4628c88a9589aa2fc1d308f80 SHA512 7ddb08e4d8a9173a26fa18de687a4c85c3d460e2bc595da6f4b15cfe3be264ccdc7d61d5fed1e7a82f256d21caf3ea7de87f774fde61a9d37bed15f86f546adb
 DIST python-gentoo-patches-3.12.6_p2.tar.xz 8144 BLAKE2B 2f36ce972e0b3e2884c9df629e3aeb1af05e4c77dffb866ff28e08a0a7df3c7cf36a9de250d148d909c07fd5bad483c95b3267818657c04e7d0d6fe512e21f9a SHA512 caa86c6cf693f9293b3aa8944452d117b78c1c3f8d6a6aa658cb5c2d2ffb0cecc6cf14b293872bd2101766ee7167ba88183904b2814090f8cbc64c1fa3b771be
 DIST python-gentoo-patches-3.12.6_p4.tar.xz 8764 BLAKE2B a75b9bc3768f1e07272f43d1a8f0fb6858eee7c786bc3141cd152382c287ee984b92ff1301e5894db7c24af994ee52ac7374a3edf692aa4255c1413b73209020 SHA512 237c9e8b50173a757204621d7019f68f230ea3e520ea1f078528acfb509fe7f44c0919a8ac0245e79b1a51c3e3545dd9ded51047451048ca782e35b1c4365363
 DIST python-gentoo-patches-3.12.7_p1.tar.xz 10228 BLAKE2B 71cc6034201198d9483414fa362d68b550bfcbf75ca6f44dd8ab9d90b201098a05cbf4799b1db9359f4dc464acfcee9b0ce59045db27e8e9ce916b5aab010448 SHA512 22f9256c28b96723ad86878cbe44da155e280a8df08c6bcc568dc5296aca1a6fcc41ab823ee9e6d34ce5954bbedb76aea7dba2d9189e0558c536e8b2b9a3c8ce
 DIST python-gentoo-patches-3.13.0.tar.xz 8316 BLAKE2B 8fb8ba8f41f310140ad7066b614952023112d5043e5d82058364125611785144c1843e87eecb7669bcbab51c40d0694069526219f7419a7009517ce0821b74ba SHA512 0eb31ebfa3411020aa70b3b66fd7eec98b4b7a686b0e8f1f7ed76a8186a7c1ee85ccd9565a86a1d7ec13b975855eeb7303036af05e2dfdce3d64e4ad99299df4
-DIST python-gentoo-patches-3.13.0rc3.tar.xz 8004 BLAKE2B e1ec0d1b0d84fd5875111ed9916879bb78fcf764f6d6c12f570083df9215e0585ff4137636756bf3674f991f3bccdd859ec21d37c4b6a8dd738da03ecdedaa75 SHA512 1495f5f68d6ae10ad676b075cf4540dcdc38b254a9f4309d76097bdda427e06b65df173c99cd9c4f74646a4a29f10faa38a5a0342b1a40c1ebb6f92cf5a6f3b4
diff --git a/dev-python/python-tests/python-tests-3.13.0_rc3.ebuild b/dev-python/python-tests/python-tests-3.13.0_rc3.ebuild
deleted file mode 100644
index cfe398eecb56..000000000000
--- a/dev-python/python-tests/python-tests-3.13.0_rc3.ebuild
+++ /dev/null
@@ -1,69 +0,0 @@
-# Copyright 2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{9,10,11,12,13} )
-
-inherit python-r1 verify-sig
-
-MY_PV=${PV/_}
-MY_P="Python-${MY_PV%_p*}"
-PYVER=$(ver_cut 1-2)
-PATCHSET="python-gentoo-patches-${MY_PV}"
-
-DESCRIPTION="Test modules from dev-lang/python"
-HOMEPAGE="
-	https://www.python.org/
-	https://github.com/python/cpython/
-"
-SRC_URI="
-	https://www.python.org/ftp/python/${PV%%_*}/${MY_P}.tar.xz
-	https://dev.gentoo.org/~mgorny/dist/python/${PATCHSET}.tar.xz
-	verify-sig? (
-		https://www.python.org/ftp/python/${PV%%_*}/${MY_P}.tar.xz.asc
-	)
-"
-S="${WORKDIR}/${MY_P}/Lib"
-
-LICENSE="PSF-2"
-SLOT="${PYVER}"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-RDEPEND="
-	${PYTHON_DEPS}
-	~dev-lang/python-${PV}:${PYVER}
-	!<dev-lang/python-3.13.0_rc1_p3-r1:${PYVER}
-"
-BDEPEND="
-	${RDEPEND}
-	verify-sig? ( >=sec-keys/openpgp-keys-python-20221025 )
-"
-
-VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/python.org.asc
-
-src_unpack() {
-	if use verify-sig; then
-		verify-sig_verify_detached "${DISTDIR}"/${MY_P}.tar.xz{,.asc}
-	fi
-	default
-}
-
-src_prepare() {
-	local PATCHES=(
-		"${WORKDIR}/${PATCHSET}"
-	)
-
-	cd .. || die
-	default
-}
-
-src_install() {
-	python_setup
-	# keep in sync with TESTSUBDIRS in Makefile.pre.in
-	python_moduleinto "/usr/lib/python${PYVER}"
-	python_domodule test
-	python_moduleinto "/usr/lib/python${PYVER}/idlelib"
-	python_domodule idlelib/idle_test
-}
diff --git a/dev-python/sounddevice/Manifest b/dev-python/sounddevice/Manifest
index 36283ff55932..ac9a849289d9 100644
--- a/dev-python/sounddevice/Manifest
+++ b/dev-python/sounddevice/Manifest
@@ -1,2 +1,2 @@
-DIST sounddevice-0.4.7.tar.gz 53389 BLAKE2B 37b1bf020645d1f55f0ee0757be3f48bd02ea59154d7f25e84d3f357ba2eedd76d1744637ee9d366e850615a71532ad27d68c643ab922e9e947d5bac6cedf94a SHA512 5d04af8d337c81bbe8dbc52c94478976e52949a3d6c0954e62007b2b2781cd475463ea41bb7bfde63417b8c460452ea7d5ebe64d3aec9faad641d1d3a14e297d
 DIST sounddevice-0.5.0.tar.gz 53661 BLAKE2B 71c9c77446f93cc62262c16213f0225be235637d233777fa03ab4a3b926effb3992efd47dca5b09e98e2f6f543ae5b9b05c31537386cc17ac4a3845af01f914d SHA512 a06966244f0ff54def3ad53839c553523a1e342609af84b8f8d4c0f3ed787f225035f80cf614e521d3642a0bf3e68f7e2924837a7b24d1dcc7d13d4ddac6a4a3
+DIST sounddevice-0.5.1.tar.gz 54145 BLAKE2B 78c3215c977ab336f70ad8947ef681a34e81dc2132ba5bb62f51d10312b7e0fe4365789c319c710d0e5989423000d48e3315d140038d85a45d01187c16549d28 SHA512 2e53ca607f6e9ef5911bd14ce2f8cc33b8d9b746815c98a51d831ce5c23da09dbac043e080c027ef1c50fd75e1727975e777c3a4262625a845769f8b5a3d9507
diff --git a/dev-python/sounddevice/sounddevice-0.4.7.ebuild b/dev-python/sounddevice/sounddevice-0.5.1.ebuild
index ff4025a76695..ff4025a76695 100644
--- a/dev-python/sounddevice/sounddevice-0.4.7.ebuild
+++ b/dev-python/sounddevice/sounddevice-0.5.1.ebuild
diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index 751127cf152b..7e8e6e5d2ff3 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -2,3 +2,4 @@ DIST sphinx-7.4.7.gh.tar.gz 8135111 BLAKE2B b5a511355b16edfbcf32f9a20855466251c5
 DIST sphinx-8.0.2.gh.tar.gz 8264835 BLAKE2B ed6e321a1e58341609d88993c418ec1a0a580683ed28895077322fdba839d5c158007d65d5349d4d53c5e3b49ae823142cc6eb0203812580ebbb5b95247bf157 SHA512 5e9f38af91d7a80b6a80a80ab26adbebc1c3303996182a58eed9120ed896c5bfde022616e116e8cb8195fe03741e93fd97dcacccf492912ab147c5bfcb79213d
 DIST sphinx-8.1.0.gh.tar.gz 8245765 BLAKE2B a1caee3905b233f5401a7660d876befcfe85d5d630d1ce67c7386eb56aebe855684e88ed95899a9c0ad359c6ae02024784dd0388cf46ae6e41e927608514f6b8 SHA512 265d69167c8c8e3eb9ef174a22641b15eff7585026f1cfcaf00ba9966ad8a60ec0bc6128158fcb2b098f63c6444b1392de6413ac5884e7eafe6544c3a9c99443
 DIST sphinx-8.1.1.gh.tar.gz 8246435 BLAKE2B bc1e45b2528ae5e8376965cc923a4103c2ac410022d2991c162f75ab922c361ae696f1317728e4b4e23e7a121c486cf59b44c394211c9cfb249ffed3a4824ba5 SHA512 74cb44d3714a4000f92fe302cdd820be49580554fa3585de85d5d636b413e0eacbbc81cb26286304564bab0fe3eccfb16ab1d37bbe0251c5eab902179e8130d2
+DIST sphinx-8.1.2.gh.tar.gz 8245135 BLAKE2B 9edf8421120f9535ac71b2006f6130181fee8effb7d384d393524982db23aa3eb9f17eadeedcdac7b1b9546a33212068191d104ff6f45c554e7bac47978d5d8c SHA512 53592150846cfab4589a2c1b8189db26a4ea3441b256e57661e2529e0f6b5fafa701a7cac8401df724755d08d81ff2f283e8fdaa25671014c49ff083ca51854e
diff --git a/dev-python/sphinx/sphinx-8.1.2.ebuild b/dev-python/sphinx/sphinx-8.1.2.ebuild
new file mode 100644
index 000000000000..868bc4119e9f
--- /dev/null
+++ b/dev-python/sphinx/sphinx-8.1.2.ebuild
@@ -0,0 +1,144 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="
+	https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinx/
+	https://pypi.org/project/Sphinx/
+"
+SRC_URI="
+	https://github.com/sphinx-doc/sphinx/archive/v${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc latex"
+
+RDEPEND="
+	>=dev-python/alabaster-0.7.14[${PYTHON_USEDEP}]
+	>=dev-python/Babel-2.13[${PYTHON_USEDEP}]
+	<dev-python/docutils-0.22[${PYTHON_USEDEP}]
+	>=dev-python/docutils-0.20[${PYTHON_USEDEP}]
+	>=dev-python/imagesize-1.3[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-23.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.14[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.30.0[${PYTHON_USEDEP}]
+	>=dev-python/snowballstemmer-2.2[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-applehelp-1.0.7[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-devhelp-1.0.6[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-htmlhelp-2.0.6[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-jsmath-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-qthelp-1.0.6[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-serializinghtml-1.1.9[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2[${PYTHON_USEDEP}]
+	' 3.10)
+	latex? (
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)
+"
+BDEPEND="
+	doc? (
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)
+	test? (
+		app-text/dvipng
+		>=dev-python/cython-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/defusedxml-0.7.1[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		>=dev-python/setuptools-67.0[${PYTHON_USEDEP}]
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		virtual/imagemagick-tools[jpeg,png,svg]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/sphinx-3.2.1-doc-link.patch"
+	#"${FILESDIR}/sphinx-4.3.2-doc-link.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# disable internet access
+	sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+		doc/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# we can't use distutils_enable_sphinx because it would
+	# introduce a dep on itself
+	use doc && build_sphinx doc
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+	local EPYTEST_DESELECT=(
+		# less interesting failures
+		tests/test_builders/test_build_latex.py::test_build_latex_doc
+		tests/test_extensions/test_ext_math.py::test_imgmath_png
+		tests/test_extensions/test_ext_math.py::test_imgmath_numfig_html
+	)
+	case ${EPYTHON} in
+		python3.13x)
+			EPYTEST_DESELECT+=(
+				tests/test_extensions/test_ext_autodoc.py::test_autodoc_special_members
+				tests/test_extensions/test_ext_autodoc_configs.py::test_autodoc_type_aliases
+				tests/test_extensions/test_ext_autodoc_configs.py::test_autodoc_typehints_format_fully_qualified
+				tests/test_extensions/test_ext_autodoc_configs.py::test_autodoc_typehints_none
+				tests/test_extensions/test_ext_autodoc_configs.py::test_autodoc_typehints_signature
+			)
+			;;
+		pypy3)
+			EPYTEST_DESELECT+=(
+				tests/test_extensions/test_ext_autodoc.py::test_autodoc_exception
+				tests/test_extensions/test_ext_autodoc.py::test_autodoc_ignore_module_all
+				tests/test_extensions/test_ext_autodoc.py::test_autodoc_inherited_members_None
+				tests/test_extensions/test_ext_autodoc.py::test_autodoc_subclass_of_builtin_class
+				tests/test_extensions/test_ext_autodoc.py::test_automethod_for_builtin
+				tests/test_extensions/test_ext_autodoc.py::test_cython
+				tests/test_extensions/test_ext_autodoc.py::test_format_signature
+				tests/test_extensions/test_ext_autodoc.py::test_partialfunction
+				tests/test_extensions/test_ext_autodoc_autoclass.py::test_autodoc_process_bases
+				tests/test_extensions/test_ext_autodoc_autoclass.py::test_show_inheritance_for_decendants_of_generic_type
+				tests/test_extensions/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
+				tests/test_extensions/test_ext_autodoc_autofunction.py::test_builtin_function
+				tests/test_extensions/test_ext_autodoc_autofunction.py::test_methoddescriptor
+				tests/test_extensions/test_ext_autodoc_automodule.py::test_automodule_inherited_members
+				tests/test_extensions/test_ext_autodoc_preserve_defaults.py::test_preserve_defaults_special_constructs
+				tests/test_extensions/test_ext_autosummary.py::test_autosummary_generate_content_for_module
+				tests/test_extensions/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
+				tests/test_util/test_util_inspect.py::test_isattributedescriptor
+				tests/test_util/test_util_inspect.py::test_signature
+				tests/test_util/test_util_typing.py::test_is_invalid_builtin_class
+			)
+			;;
+	esac
+
+	# note: pytest-xdist causes random test failures
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p rerunfailures --reruns=5
+}
diff --git a/dev-python/sphinxext-opengraph/sphinxext-opengraph-0.9.1.ebuild b/dev-python/sphinxext-opengraph/sphinxext-opengraph-0.9.1.ebuild
index 6f94992f5090..fa906f429058 100644
--- a/dev-python/sphinxext-opengraph/sphinxext-opengraph-0.9.1.ebuild
+++ b/dev-python/sphinxext-opengraph/sphinxext-opengraph-0.9.1.ebuild
@@ -21,12 +21,15 @@ LICENSE="GPL-3"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
 
+RDEPEND="
+	dev-python/myst-parser[${PYTHON_USEDEP}]
+	dev-python/furo[${PYTHON_USEDEP}]
+	dev-python/sphinx-design[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+"
 BDEPEND="
 	doc? (
-		dev-python/myst-parser[${PYTHON_USEDEP}]
-		dev-python/furo[${PYTHON_USEDEP}]
-		dev-python/sphinx-design[${PYTHON_USEDEP}]
-		dev-python/matplotlib[${PYTHON_USEDEP}]
+		${RDEPEND}
 	)
 "
 
diff --git a/dev-python/trove-classifiers/Manifest b/dev-python/trove-classifiers/Manifest
index 469cc1048f9e..f4013ac05cf6 100644
--- a/dev-python/trove-classifiers/Manifest
+++ b/dev-python/trove-classifiers/Manifest
@@ -1 +1,2 @@
+DIST trove_classifiers-2024.10.12.tar.gz 16100 BLAKE2B 56c8b409874370ec3861b61c2e5ef3f19469781196b71d3e674f9d95fd1e8df32445158f12ba54679dc21cb64194d98b7bd6ce2d3f1fbad20b11a29db64bfcf4 SHA512 fb848b4f46979887ae0ca426ec18bcc72689bdf46d4cd19353b2650acd98a9e74179f9df43a5fac27a2ef37078a8312267f3e1b08241f6ed73b6dc6c0bb08c61
 DIST trove_classifiers-2024.9.12.tar.gz 16058 BLAKE2B 6cac2247910e95bf1f0b9a37b0f0e59062652526a45c4097c743a5f0665a5d8b5042bb7eb02741f2bf9b7d669a1be238940ab2b498281ef3ce6f3fa4c0c2961c SHA512 4fc6efc514638dfb2aee4fbd06f258bb9d5d9d54269e6d33f3739a63d61d6d3caa9a7124f9e5ad601714253c27b97bc9a60f3a9369f2f358ed19fbdfcefcbb10
diff --git a/dev-python/trove-classifiers/trove-classifiers-2024.10.12.ebuild b/dev-python/trove-classifiers/trove-classifiers-2024.10.12.ebuild
new file mode 100644
index 000000000000..d3efb3b1e483
--- /dev/null
+++ b/dev-python/trove-classifiers/trove-classifiers-2024.10.12.ebuild
@@ -0,0 +1,42 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Canonical source for classifiers on PyPI (pypi.org)"
+HOMEPAGE="
+	https://github.com/pypa/trove-classifiers/
+	https://pypi.org/project/trove-classifiers/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+
+distutils_enable_tests pytest
+
+src_configure() {
+	grep -q 'build-backend = "setuptools' pyproject.toml ||
+		die "Upstream changed build-backend, recheck"
+	# write a custom pyproject.toml to ease hatchling bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "trove-classifiers"
+		version = "${PV}"
+		description = "Canonical source for classifiers on PyPI (pypi.org)."
+	EOF
+}
+
+python_test() {
+	epytest
+	"${EPYTHON}" -m tests.lib || die
+}
diff --git a/dev-python/yarl/Manifest b/dev-python/yarl/Manifest
index 8abe715a7ba3..e604e3ba484c 100644
--- a/dev-python/yarl/Manifest
+++ b/dev-python/yarl/Manifest
@@ -3,4 +3,5 @@ DIST yarl-1.12.1.tar.gz 163223 BLAKE2B 9d295c9e018ef15f3b089327006ea7dda7689b6ad
 DIST yarl-1.13.1.tar.gz 165912 BLAKE2B dfe4f9ac09c66d05b6d072cd6676d1753f97224d556dbd22601e544569d5e852b073c1a89e4ba471177c530ec580fb74700b9e6e21730c548e434ef75933b6bf SHA512 8fccb36dbb019d02fc50f006a3a59decd413abfc6387fd7c1220444f4f79412be1d5119c32fd668b3d553fbaf4de64b9135345e8300c7fa025d892c847955f88
 DIST yarl-1.14.0.tar.gz 166127 BLAKE2B 7974896144ef23309aead8935f18fe717e39b982bc75eb3c828eaf9a1d01b413c2bbb270344160a396927fc32571928c67eae46146920cc6908e2e3f74e90cd8 SHA512 8cc9d1aaa6fcccdfce5ea0a0ac3f89b81c5719568b76e66637e9a7baa0637770523f86495f70e28f94f166579e77d72afd708cef1306dafcd8093c7fb2a1d3f0
 DIST yarl-1.15.0.tar.gz 167065 BLAKE2B 2daae4ee528501cc00e4e967bce32b15585a827463b76ef8c27db3808dc3bfeac93de8eec0e2a9af28d3622d70a40ce66845c69744ad49dda7205e93d047f614 SHA512 25a2b2434204e29f4fc4ef438efda0747aedc3e703a8164f9aa5fee809d8d01895f3b0a9aa4de1d3deaa719d940b2b5e681360e47d8e3704200bffdf5e7151a8
+DIST yarl-1.15.1.tar.gz 168422 BLAKE2B 2368b4c340d5aa63b49d75befdf7d6e5b9a9a4509406b0beadbca7e20610b29d7f737b29a1b75dc5b1682fd60d3d22177dbcf756aa217cd926e3b82502ca11a0 SHA512 90a60b037c6fac6139016a9846d230cd0ed67875c31eadb61ad0ee1e239caf95a59cfed6312ce83215bb7ae9eca366d1162cbf7f5e61b236cee75bac0c08670c
 DIST yarl-1.9.4.tar.gz 141869 BLAKE2B 367eac4674bf1190122f10bb1dc1c4f3d5e4263e1d95ff2b871067d55a894dc19a6bb5a6c673d1bed28b3c5f77c704799568edfe639d50f0ae10313eb847352d SHA512 e4f7917f1625b40125abae9a13d61795f97e8cf489735e15cf58476e97c3bcf840b1452482f1f7a737fbb2bdd1dc7bbcfa882d0a7f76a27dfb3aea72b7a66c82
diff --git a/dev-python/yarl/yarl-1.15.1.ebuild b/dev-python/yarl/yarl-1.15.1.ebuild
new file mode 100644
index 000000000000..638ce0f69079
--- /dev/null
+++ b/dev-python/yarl/yarl-1.15.1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Yet another URL library"
+HOMEPAGE="
+	https://github.com/aio-libs/yarl/
+	https://pypi.org/project/yarl/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+native-extensions"
+
+RDEPEND="
+	>=dev-python/idna-2.0[${PYTHON_USEDEP}]
+	>=dev-python/multidict-4.0[${PYTHON_USEDEP}]
+	>=dev-python/propcache-0.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	native-extensions? (
+		dev-python/cython[${PYTHON_USEDEP}]
+	)
+	dev-python/expandvars[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	local -x YARL_NO_EXTENSIONS=0
+	if ! use native-extensions || [[ ${EPYTHON} != python* ]]; then
+		YARL_NO_EXTENSIONS=1
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# benchmarks
+		tests/test_quoting_benchmarks.py
+		tests/test_url_benchmarks.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local opts=()
+	# note different boolean logic than for backend (sigh)
+	local -x YARL_NO_EXTENSIONS=
+	if ! use native-extensions || [[ ${EPYTHON} != python* ]]; then
+		YARL_NO_EXTENSIONS=1
+	fi
+
+	rm -rf yarl || die
+	epytest -o addopts= "${opts[@]}"
+}