Adding metadata

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-python/urwid/urwid-4.1.1.ebuild b/dev-python/urwid/urwid-4.1.1.ebuild
new file mode 100644
index 000000000000..aba0d14bbb3d
--- /dev/null
+++ b/dev-python/urwid/urwid-4.1.1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_VERIFY_REPO=https://github.com/urwid/urwid
+PYTHON_COMPAT=( python3_{13..14} )
+PYTHON_REQ_USE="ncurses"
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Curses-based user interface library for Python"
+HOMEPAGE="
+	https://urwid.org/
+	https://pypi.org/project/urwid/
+	https://github.com/urwid/urwid/
+"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="examples"
+
+RDEPEND="
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+	>=dev-python/wcwidth-0.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	sed -i -e 's:--cov --cov-report=term::' pyproject.toml || die
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Trio event loop" "dev-python/trio"
+}