Adding metadata

3 files changed, 87 insertions, 0 deletions

diff --git a/dev-python/twine/Manifest b/dev-python/twine/Manifest
new file mode 100644
index 000000000000..a0c0e7daea53
--- /dev/null
+++ b/dev-python/twine/Manifest
@@ -0,0 +1 @@
+DIST twine-6.2.0.gh.tar.gz 167087 BLAKE2B 51c95da17fee1336bc94b0847035c0a6e115915696b8a127fb21f8e75c4a8090af221cacd6196279a9352c607a8b643500a6260963f2bc9e6f570b318626d4f6 SHA512 3637b9b6644678a9573ba93d5f2b90b5660f8df126f7a6fde1519fc45f93f1fa0646b16b35087c4b1187b2be1845ce2c3c6f40f96716e2c44d1a6cd471e3b64b
diff --git a/dev-python/twine/metadata.xml b/dev-python/twine/metadata.xml
new file mode 100644
index 000000000000..5e95859f915a
--- /dev/null
+++ b/dev-python/twine/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/twine/twine-6.2.0.ebuild b/dev-python/twine/twine-6.2.0.ebuild
new file mode 100644
index 000000000000..e3a55560a890
--- /dev/null
+++ b/dev-python/twine/twine-6.2.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of utilities for publishing packages on PyPI"
+HOMEPAGE="
+	https://twine.readthedocs.io/
+	https://github.com/pypa/twine/
+	https://pypi.org/project/twine/
+"
+SRC_URI="
+	https://github.com/pypa/twine/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv ~s390 ~sparc x86"
+
+RDEPEND="
+	>=dev-python/colorama-0.4.3[${PYTHON_USEDEP}]
+	dev-python/id[${PYTHON_USEDEP}]
+	>=dev-python/keyring-21.2.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-24.0[${PYTHON_USEDEP}]
+	>=dev-python/readme-renderer-35.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.20.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-0.8.0[${PYTHON_USEDEP}]
+	>=dev-python/rfc3986-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/rich-12.0.0[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.26.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/jaraco-envs[${PYTHON_USEDEP}]
+		dev-python/jaraco-functools[${PYTHON_USEDEP}]
+		dev-python/munch[${PYTHON_USEDEP}]
+		dev-python/portend[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		dev-python/pypiserver[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# pytest-socket dep relevant only to test_integration, and upstream
+	# disables it anyway
+	sed -i -e '/--disable-socket/d' pytest.ini || die
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# Internet
+		tests/test_integration.py
+	)
+	local EPYTEST_DESELECT=(
+		# Avoid needing heavy virtualx
+		tests/test_auth.py::test_warns_for_empty_password
+	)
+
+	local -x COLUMNS=80
+	epytest
+}