Adding metadata

2 files changed, 89 insertions, 0 deletions

diff --git a/dev-python/trimesh/Manifest b/dev-python/trimesh/Manifest
index 7efc8ba3dfb9..f2ddc66f70dd 100644
--- a/dev-python/trimesh/Manifest
+++ b/dev-python/trimesh/Manifest
@@ -1 +1,2 @@
 DIST trimesh-4.12.2.gh.tar.gz 13717637 BLAKE2B a0f04335d7f7335b2044bda841b06a5dcfcb1f26c569f84c57049c4f2f444595e4ab27021c0c6d3013f100248897a3df75a53cee806975fa6d5ec7914f77315c SHA512 4f8cfee0435c16b932740f4900f1ef75046c06bb64a20fe49c2a858aba7392009d6dcdeab80a08392e185e2f2890198078213e984563bfebd059b339852fb18d
+DIST trimesh-5.0.0.gh.tar.gz 13747514 BLAKE2B a7728a5d846018e37ec1e7b2cf3f8896096a962b5c8c7134d2a56d263b688ac7bbaef6eeefa4d6a9c0d8a57e2670c616f29029a8fc814e447e9aa4474bc34afe SHA512 8201f6fe444a141b4b7990c40644e8cff095abc6373b37c6116a5805dc886fcce365b1c7438ccfef0b800a09f7c50bffea838c8baece3c6ffdef56c01550429b
diff --git a/dev-python/trimesh/trimesh-5.0.0.ebuild b/dev-python/trimesh/trimesh-5.0.0.ebuild
new file mode 100644
index 000000000000..6715afbbe9e4
--- /dev/null
+++ b/dev-python/trimesh/trimesh-5.0.0.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for loading and using triangular meshes"
+HOMEPAGE="
+	https://trimesh.org/
+	https://github.com/mikedh/trimesh/
+	https://pypi.org/project/trimesh/
+"
+SRC_URI="
+	https://github.com/mikedh/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/charset-normalizer[${PYTHON_USEDEP}]
+	dev-python/colorlog[${PYTHON_USEDEP}]
+	dev-python/httpx[${PYTHON_USEDEP}]
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.21[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycollada[${PYTHON_USEDEP}]
+	dev-python/pyglet[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	>=dev-python/shapely-1.8.2[${PYTHON_USEDEP}]
+	dev-python/svg-path[${PYTHON_USEDEP}]
+	dev-python/sympy[${PYTHON_USEDEP}]
+	dev-python/xxhash[${PYTHON_USEDEP}]
+	dev-python/rtree[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mapbox-earcut[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+: ${EPYTEST_TIMEOUT:=300}
+EPYTEST_RERUNS=3
+EPYTEST_XDIST=1
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# requires manifold3d
+	tests/test_boolean.py::test_multiple_difference
+	tests/test_ray.py::test_contains_cavity
+	# timing nonsense
+	tests/test_bounds.py::BoundsTest::test_obb_mesh_large
+)
+EPYTEST_IGNORE=(
+	# require pyinstrument
+	tests/test_sweep.py
+)
+
+python_test() {
+	# We run tests in parallel, so avoid having n^2 threads in lapack
+	# tests.
+	local -x BLIS_NUM_THREADS=1
+	local -x MKL_NUM_THREADS=1
+	local -x OMP_NUM_THREADS=1
+	local -x OPENBLAS_NUM_THREADS=1
+
+	epytest
+}
+
+pkg_postinst() {
+	optfeature_header "${PN} functionality can be extended by installing the following packages:"
+	optfeature "2D triangulations of polygons" dev-python/mapbox-earcut
+	optfeature "loading a number of additional mesh formats" dev-python/meshio
+	optfeature "figuring out how much memory we have" dev-python/psutil
+	optfeature "marching cubes and other nice stuff" dev-python/scikit-image
+}