Adding metadata

2 files changed, 99 insertions, 0 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index bfe21d486e3f..03e851718637 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -6,3 +6,5 @@ DIST tox-4.54.0.tar.gz 279256 BLAKE2B f1a1265879ce21f9f4005268dd5800dd7d84d6c914
 DIST tox-4.54.0.tar.gz.provenance 9424 BLAKE2B b9f9dee2859d4e640edd8e9ca8274a2715c25a11fe4639ec0b210f9565a12a50523c7f3e051f370259a70772b29abd617b28fa177da7bdc69179b8bd8ff35cf7 SHA512 efdf4aabc3d64219f842c06b9b8ae07b1532076269bd4753bf11e93ff59498337e35eb436f5c5a43028ba4027cd63b5d216febdeb6e0ec9208a435305c8a785f
 DIST tox-4.55.0.tar.gz 279415 BLAKE2B 11dda60b9cabd4829237c736bcb9772dd67fb0b3cd3ab5298c8c4ffd7a641430d2ad642a3fd74d8ccae96344b91cf73aeadf1b734b1bd61eb2284c0ba38c70eb SHA512 febc47e4eec439f60dbd26a996469923129aa079abc660f90e6f3da6f37aa1bc335970aea9cde5b7747cbf236acbfd54038aa9b97bba66603ce30c59dde0b39a
 DIST tox-4.55.0.tar.gz.provenance 9518 BLAKE2B 63757d88294e09a97b15c77315e567b10bbade87ce731051e2fa513adedf03d43df2fc135b635dfe378d292a5a6cdd81b4177b1d8bb6b7ee5bf5111856738899 SHA512 532bdf5719ce9ea6b11894af6043890289fc72e87d1c2476fc629c2ec8766f76e2444282ee6bb5f9160c20145571c079138e777629b6d026f3420a38f6602fd5
+DIST tox-4.55.1.tar.gz 280676 BLAKE2B ccbf018634d708ba00710ea1c15fa1328acf402f021559cb0d3e78a050449a0a0fae9e3a072c0efcf13e98031ed4aa3baf0298b35cba8cae2d8336c181edb40a SHA512 5d34cccd8e4813c0e4a4406711f2e9e3bd61228d3668044d82858d7fbd9aca60e28ac4cf9a3b13f01acc181de1822b3b4f8d27acb99d403faafbfc8063fc5dcf
+DIST tox-4.55.1.tar.gz.provenance 9530 BLAKE2B 6a8de7003c54e6c388154619fc5900bd968e72862267615f67157e4b4c1294cd1d70dfcb02189788bb415ef84e07775acf08c38fa66113f850c78b00a28f2b68 SHA512 c8773255b47b7078b80c179dff30b0a51a1ec3e0b2576377c377aec87fefa74383e14e4a9c19a067b9eadd45e8611e6d0c2eddbd60b774ac91fbb62abf803e56
diff --git a/dev-python/tox/tox-4.55.1.ebuild b/dev-python/tox/tox-4.55.1.ebuild
new file mode 100644
index 000000000000..db6e52f11b21
--- /dev/null
+++ b/dev-python/tox/tox-4.55.1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/tox-dev/tox
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~ppc ~ppc64 ~riscv ~s390 ~x86"
+
+RDEPEND="
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/pyproject-api[${PYTHON_USEDEP}]
+	dev-python/python-discovery[${PYTHON_USEDEP}]
+	dev-python/tomli-w[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/argcomplete[${PYTHON_USEDEP}]
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/distlib[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{mock,rerunfailures,timeout,xdist} )
+# xdist seems to mess up state between successive implementation runs
+distutils_enable_tests pytest
+
+src_prepare() {
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_run_installpkg_targz
+		tests/tox_env/python/virtual_env/package/test_package_pyproject.py::test_pyproject_installpkg_pep517_envs
+		# require tombi
+		tests/session/cmd/test_schema.py::test_schema_tombi_lint
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	case ${EPYTHON} in
+		python*)
+			local EPYTEST_PLUGINS=( "${EPYTEST_PLUGINS[@]}" time-machine )
+			;;
+		pypy3*)
+			EPYTEST_DESELECT+=(
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+			)
+			;;
+	esac
+
+	epytest -o addopts=
+}