Adding metadata

3 files changed, 73 insertions, 1 deletions

diff --git a/dev-python/tavern/Manifest b/dev-python/tavern/Manifest
index b1cb810113ef..083a764033bd 100644
--- a/dev-python/tavern/Manifest
+++ b/dev-python/tavern/Manifest
@@ -2,3 +2,4 @@ DIST tavern-2.17.0.gh.tar.gz 243762 BLAKE2B aca42310622fe769ff6a6201c4fd4faa613f
 DIST tavern-3.1.0.gh.tar.gz 406137 BLAKE2B eda723c17098ee57ffdf223e9c46aa5d185f20ce4afa5f35b55e96aef0ebebef13552f64d122eb3dc4ec643f1c10827537b7625b6cf3b66fa990640a3bbace0e SHA512 c87169f926d55eda521c23d0035632677b1708a843f427f2e2788af00600084966894252f957b41898229f9582a21c435cf70727ac270ae74a00bdf7289b9236
 DIST tavern-3.2.0.gh.tar.gz 708286 BLAKE2B ed5efcbdf4224aa23de12eb37ccbea50c1452f6a99950ea4bc9b373670485687223d12c728b8cb263f00fb6143c1ef659670b07ac38430375d076b47a28b56f7 SHA512 c08c5d6ab0fb1c2ed57797be4eae71d467e917104c1aab232797b09b8c6b1512bb441652f6df48582b2d0949f4f09857faf5f6654f4d2e35e1d278021b88d145
 DIST tavern-3.3.0.gh.tar.gz 718906 BLAKE2B 3dda28ae86ccd2f68d1339d9d2a6dc12bdca819aafe90e486db4a5bdf6acd242a2bbed7655b15301ea7f6e377019adad3274ffa84816db2eaffe7ee609dd90c5 SHA512 8432b20a275ac5a7d89525549b32e2d266cdc3e2882f8e09d02665f4fa04e3d4b7154982a36386250c580ba6cec942f9cef24efe3c4ef745a1b26cca12f89703
+DIST tavern-3.3.2.gh.tar.gz 723821 BLAKE2B dbb729475ce99319207f6158057eacfd163807e5d15c1412045b3cf9a4cc3e2c6dffb47fa00cf7dc3f6aba5b09b89478001482f07ca8a636dbd607190814f1a8 SHA512 5f46ab779961f74d8a33f443f82cef33e77d4513278251b2353657c5fbec5b9c6d3d25476cc91288b40046263d3d6ebeb2372b224edf243af318332eba7e341a
diff --git a/dev-python/tavern/tavern-3.2.0.ebuild b/dev-python/tavern/tavern-3.2.0.ebuild
index f90b44ee9736..a0875b6e31e8 100644
--- a/dev-python/tavern/tavern-3.2.0.ebuild
+++ b/dev-python/tavern/tavern-3.2.0.ebuild
@@ -20,7 +20,7 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64"
+KEYWORDS="~amd64 ~arm64"
 
 RDEPEND="
 	>=dev-python/jmespath-1[${PYTHON_USEDEP}]
diff --git a/dev-python/tavern/tavern-3.3.2.ebuild b/dev-python/tavern/tavern-3.3.2.ebuild
new file mode 100644
index 000000000000..963638bac7f6
--- /dev/null
+++ b/dev-python/tavern/tavern-3.3.2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="A tool, library, and Pytest plugin for testing RESTful APIs"
+HOMEPAGE="
+	https://github.com/taverntesting/tavern/
+	https://pypi.org/project/tavern/
+"
+SRC_URI="
+	https://github.com/taverntesting/tavern/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/hypothesis-6[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-1[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4[${PYTHON_USEDEP}]
+	dev-python/pydantic[${PYTHON_USEDEP}]
+	>=dev-python/pyjwt-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/pykwalify-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/pytest-8[${PYTHON_USEDEP}]
+	>=dev-python/python-box-6[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-6.0.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.22.0[${PYTHON_USEDEP}]
+	>=dev-python/simpleeval-1.0.3[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/colorlog[${PYTHON_USEDEP}]
+		dev-python/faker[${PYTHON_USEDEP}]
+		dev-python/paho-mqtt[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( "${PN}" )
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# requires grpc
+	tests/unit/test_extensions.py::TestGrpcCodes
+	# broken with paho-mqtt-2
+	tests/unit/test_mqtt.py::TestClient::test_context_connection_success
+	# TODO
+	tests/unit/response/test_mqtt_response.py::TestResponse::test_same_topic
+)
+EPYTEST_IGNORE=(
+	# require grpc*
+	tavern/_plugins/grpc
+	tests/unit/tavern_grpc
+	# require gql
+	tavern/_plugins/graphql
+	tests/unit/plugins/graphql
+)
+
+src_prepare() {
+	# strip unnecessary pins, upstream doesn't update them a lot
+	sed -i -E -e 's:,?<=?[0-9.]+::' pyproject.toml || die
+	distutils-r1_src_prepare
+}