Adding metadata

2 files changed, 72 insertions, 0 deletions

diff --git a/dev-python/tavern/Manifest b/dev-python/tavern/Manifest
index 5a4e682e8e09..71b19cb28ae8 100644
--- a/dev-python/tavern/Manifest
+++ b/dev-python/tavern/Manifest
@@ -2,3 +2,4 @@ DIST tavern-3.3.3.gh.tar.gz 723923 BLAKE2B 55566efa69187761d1d838e7e2d517d691e5f
 DIST tavern-3.4.0.gh.tar.gz 726374 BLAKE2B cd7c873847ba86383a8a1f54ad1d36cd837f496b6548e7c5649f901244607ee50b3c836a61d3576070c2eeb1ccfc33ac27e9c068f0e7eae390d38604c6cff067 SHA512 6629958b05c010836a7cae2586f8a7162255dfe31308347e74c81540d9058cefd728a9b954580f27a01137f40b900a90f3ee1f8e524b63e63a36204bbb69609c
 DIST tavern-3.5.0.gh.tar.gz 730426 BLAKE2B f9950cad5a97a1980d53c62237f94cabe150381580fdbd433ff88c7eb1db8144c49b3b2cb0ec955ca0c83a3636041e656bdc37cda88e94d83c7fa981c2571301 SHA512 8126691c746f92e13679bc18ccdd5ec7a69d304a28c4eadb9d9bf50fcc6b907c377e7e76436eaa4fc81416dab1b2952cde981cfea6b3feb53503ed5ed5e1827f
 DIST tavern-3.6.0.gh.tar.gz 732315 BLAKE2B 08b69fadb6389448c38a902200cc097240945a921e67046857430cb046ba6d1d0abc471c97ac0348eb5a0eec2292977c94459260f36b5235ef6315feb08cd0d5 SHA512 2841c89bb178123c03cdd37352ed9146b60c88b0b531cecde4d40752a86a8354dbf95e0542d2878682b0de03129a7c5c60e28e2399c79d8ab79246b42f8ef51f
+DIST tavern-3.6.1.gh.tar.gz 734344 BLAKE2B bb3ed80c9c290e7c050d1a0590804cbf499fc9584567fab6cce0beeba8ba798319c0c4edaf614cb3cd6fe9a02313e1ff4c47042ece755ff8b408e4125f0f4805 SHA512 1178df1ec0079022dd3cd5afe214e27d0455b7e0f2cd315798f8291d671ae85a51d3e480743d19f5a340ede8a4989700f74d96683ddb99ff7c2212298e2bccf5
diff --git a/dev-python/tavern/tavern-3.6.1.ebuild b/dev-python/tavern/tavern-3.6.1.ebuild
new file mode 100644
index 000000000000..72cafa83f74a
--- /dev/null
+++ b/dev-python/tavern/tavern-3.6.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit-core
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="A tool, library, and Pytest plugin for testing RESTful APIs"
+HOMEPAGE="
+	https://github.com/taverntesting/tavern/
+	https://pypi.org/project/tavern/
+"
+SRC_URI="
+	https://github.com/taverntesting/tavern/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/hypothesis-6[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-1[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4[${PYTHON_USEDEP}]
+	dev-python/pydantic[${PYTHON_USEDEP}]
+	>=dev-python/pyjwt-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/pykwalify-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/pytest-8[${PYTHON_USEDEP}]
+	>=dev-python/python-box-6[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-6.0.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.22.0[${PYTHON_USEDEP}]
+	>=dev-python/simpleeval-1.0.3[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/colorlog[${PYTHON_USEDEP}]
+		dev-python/faker[${PYTHON_USEDEP}]
+		dev-python/paho-mqtt[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( "${PN}" )
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# requires grpc
+	tests/unit/test_extensions.py::TestGrpcCodes
+	# broken with paho-mqtt-2
+	tests/unit/test_mqtt.py::TestClient::test_context_connection_success
+	# TODO
+	tests/unit/response/test_mqtt_response.py::TestResponse::test_same_topic
+)
+EPYTEST_IGNORE=(
+	# require grpc*
+	tavern/_plugins/grpc
+	tests/unit/tavern_grpc
+	# require gql
+	tavern/_plugins/graphql
+	tests/unit/plugins/graphql
+)
+
+src_prepare() {
+	# strip unnecessary pins, upstream doesn't update them a lot
+	sed -i -E -e 's:,?<=?[0-9.]+::' pyproject.toml || die
+	distutils-r1_src_prepare
+}