Adding metadata

2 files changed, 101 insertions, 0 deletions

diff --git a/dev-python/tables/files/tables-3.11.1-blosc2-3.1.patch b/dev-python/tables/files/tables-3.11.1-blosc2-3.1.patch
new file mode 100644
index 000000000000..820ec3b79df9
--- /dev/null
+++ b/dev-python/tables/files/tables-3.11.1-blosc2-3.1.patch
@@ -0,0 +1,17 @@
+From 25b4701e8a75c33fa2c05d192c061ea6855fa861 Mon Sep 17 00:00:00 2001
+From: Antonio Valentino <antonio.valentino@tiscali.it>
+Date: Sat, 9 May 2026 11:13:47 +0200
+Subject: [PATCH] Fix compatibility with c-blosc2 v3.x
+
+diff --git a/setup.py b/setup.py
+index 5d10d2cc5..80ef98aaa 100755
+--- a/setup.py
++++ b/setup.py
+@@ -1251,6 +1251,7 @@ def compiler_has_flags(compiler, flags):
+         "include_dirs": inc_dirs,
+     }
+     def_macros.extend(abi3_macros)
++    def_macros.append(("BLOSC2_MAX_DIM", 8))
+     extension_kwargs.update(abi3_ext_kwargs)
+ 
+     extensions = [
diff --git a/dev-python/tables/tables-3.11.1-r1.ebuild b/dev-python/tables/tables-3.11.1-r1.ebuild
new file mode 100644
index 000000000000..04d9433be9fc
--- /dev/null
+++ b/dev-python/tables/tables-3.11.1-r1.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 prefix pypi
+
+DESCRIPTION="Hierarchical datasets for Python"
+HOMEPAGE="
+	https://www.pytables.org/
+	https://github.com/PyTables/PyTables/
+	https://pypi.org/project/tables/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~sparc ~x86"
+IUSE="+cpudetection examples test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	app-arch/bzip2:0=
+	app-arch/lz4:0=
+	>=app-arch/zstd-1.0.0:=
+	>=dev-libs/c-blosc-1.11.1:0=
+	>=dev-libs/c-blosc2-2.11.0:=
+	dev-libs/lzo:2=
+	>=dev-python/numpy-1.19.0:=[${PYTHON_USEDEP}]
+	>=sci-libs/hdf5-1.8.4:=
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/numexpr-2.6.2[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	cpudetection? ( dev-python/py-cpuinfo[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	>=dev-python/cython-3.1[${PYTHON_USEDEP}]
+	virtual/pkgconfig
+	cpudetection? ( dev-python/py-cpuinfo[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+	)
+"
+
+python_prepare_all() {
+	local PATCHES=(
+		# https://github.com/PyTables/PyTables/commit/25b4701e8a75c33fa2c05d192c061ea6855fa861
+		"${FILESDIR}/${P}-blosc2-3.1.patch"
+	)
+
+	distutils-r1_python_prepare_all
+
+	rm -r c-blosc/{blosc,internal-complibs} || die
+
+	sed -i -e '/blosc2/d' pyproject.toml || die
+	hprefixify -w '/prefixes =/' setup.py
+
+	# TODO
+	sed -i -e 's:test_write_chunk_filtermask:_&:' \
+		tables/tests/test_direct_chunk.py || die
+
+	export PYTABLES_NO_EMBEDDED_LIBS=1
+	export USE_PKGCONFIG=TRUE
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	"${EPYTHON}" tables/tests/test_all.py -v || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r contrib examples
+		docompress -x /usr/share/doc/${PF}/{contrib,examples}
+	fi
+}