Adding metadata

3 files changed, 125 insertions, 0 deletions

diff --git a/dev-python/sympy/Manifest b/dev-python/sympy/Manifest
new file mode 100644
index 000000000000..2f74aa336c9b
--- /dev/null
+++ b/dev-python/sympy/Manifest
@@ -0,0 +1 @@
+DIST sympy-1.14.0.gh.tar.gz 7911587 BLAKE2B e465a65b381a21fa6d7584728a2560d13872721b48cf8f1032c610fbd7e4fdc6777064cf430dbb56273d5c715029f8daba790f99ef678476d66ba13b1b7f4aa1 SHA512 c0b382634942fa9f282667d6573f63b505412ac2049096d84bc078b3956860c806f19044447e42991ce78de114afee22c1002fb956ea0383cb27800f2a940cd1
diff --git a/dev-python/sympy/metadata.xml b/dev-python/sympy/metadata.xml
new file mode 100644
index 000000000000..2e68f053aa9b
--- /dev/null
+++ b/dev-python/sympy/metadata.xml
@@ -0,0 +1,34 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>grozin@gentoo.org</email>
+    <name>Andrey Grozin</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>sci-mathematics@gentoo.org</email>
+    <name>Gentoo Mathematics Project</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <longdescription>
+  SymPy is a Python library for symbolic mathematics (manipulation). It
+  aims to become a full-featured computer algebra system (CAS) while keeping
+  the code as simple as possible in order to be comprehensible and easily
+  extensible. SymPy is written entirely in Python and does not require
+  any external libraries, except optionally for plotting support.
+  </longdescription>
+  <stabilize-allarches />
+  <use>
+    <flag name="ipython">Add support for <pkg>dev-python/ipython</pkg>
+    </flag>
+    <flag name="imaging">Add support for <pkg>dev-python/pillow</pkg>
+    </flag>
+    <flag name="mathml">Add support for mathml</flag>
+    <flag name="pyglet">Use <pkg>dev-python/pyglet</pkg> for plots and print preview</flag>
+    <flag name="symengine">Add support for a <pkg>dev-python/symengine</pkg> backend</flag>
+  </use>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/sympy/sympy-1.14.0-r2.ebuild b/dev-python/sympy/sympy-1.14.0-r2.ebuild
new file mode 100644
index 000000000000..651328a538be
--- /dev/null
+++ b/dev-python/sympy/sympy-1.14.0-r2.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Computer Algebra System in pure Python"
+HOMEPAGE="
+	https://www.sympy.org/
+	https://github.com/sympy/sympy/
+	https://pypi.org/project/sympy/
+"
+# pypi sdist misses some files, notably top-level conftest.py, as of 1.12.1_rc1
+SRC_URI="
+	https://github.com/sympy/sympy/archive/${PV/_/}.tar.gz
+		-> ${P/_/}.gh.tar.gz
+"
+S=${WORKDIR}/${P/_/}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~loong ~ppc64 ~riscv x86 ~x64-macos"
+IUSE="imaging ipython latex mathml pdf png pyglet symengine"
+
+RDEPEND="
+	>=dev-python/mpmath-1.1.0[${PYTHON_USEDEP}]
+	imaging? ( dev-python/pillow[${PYTHON_USEDEP}] )
+	ipython? (
+		$(python_gen_cond_dep '
+			dev-python/ipython[${PYTHON_USEDEP}]
+		' 3.12 3.13 3.14)
+	)
+	latex? (
+		virtual/latex-base
+		dev-texlive/texlive-fontsextra
+		png? ( app-text/dvipng )
+		pdf? ( app-text/ghostscript-gpl )
+	)
+	mathml? ( dev-python/lxml[${PYTHON_USEDEP}] )
+	pyglet? ( dev-python/pyglet[${PYTHON_USEDEP}] )
+	symengine? ( dev-python/symengine[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# fix the version number
+	sed -i -e "/__version__/s:\".*\":\"${PV}\":" sympy/release.py || die
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# require old version of antlr4, also deprecated
+		# https://github.com/sympy/sympy/issues/27026
+		sympy/parsing/tests/test_autolev.py
+		sympy/parsing/tests/test_latex.py
+
+		# Deprecation warnings turned failures
+		# https://github.com/sympy/sympy/pull/28158
+		sympy/geometry/tests/test_polygon.py::test_do_poly_distance
+		sympy/plotting/tests/test_plot.py::test_plot_and_save_6
+		sympy/integrals/tests/test_integrals.py::test_integrate_poly_definite
+	)
+
+	nonfatal epytest --veryquickcheck ||
+		die -n "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS README.md )
+
+	distutils-r1_python_install_all
+}