Adding metadata

4 files changed, 80 insertions, 0 deletions

diff --git a/dev-python/swagger-spec-validator/Manifest b/dev-python/swagger-spec-validator/Manifest
new file mode 100644
index 000000000000..26f930e89233
--- /dev/null
+++ b/dev-python/swagger-spec-validator/Manifest
@@ -0,0 +1 @@
+DIST swagger_spec_validator-3.0.4.gh.tar.gz 48267 BLAKE2B efcc34606b7f352eceb5842bf0f0497d4c0a3c2315d58e785de1faeea258fdebabcc6fac087ae8bc4f26e6da93eba9ddca76831ad3713682cd596214f446ab82 SHA512 d5e74b14e8800b0ca20be9dc5095ea24c26dcb0720d960d6686cd3687e49e359a8d08cc8595ecb1377dbc79f1f28b299485a1e9d0233b51639d5bf3e3c39c6cc
diff --git a/dev-python/swagger-spec-validator/files/swagger-spec-validator-3.0.4-fix-importlib.patch b/dev-python/swagger-spec-validator/files/swagger-spec-validator-3.0.4-fix-importlib.patch
new file mode 100644
index 000000000000..57b46a23729b
--- /dev/null
+++ b/dev-python/swagger-spec-validator/files/swagger-spec-validator-3.0.4-fix-importlib.patch
@@ -0,0 +1,22 @@
+--- a/swagger_spec_validator/common.py
++++ b/swagger_spec_validator/common.py
+@@ -12,7 +12,7 @@ from urllib.parse import urljoin
+ from urllib.request import pathname2url
+ from urllib.request import urlopen
+ 
+-import importlib_resources
++import importlib.resources as importlib_resources
+ import yaml
+ from typing_extensions import ParamSpec
+ 
+--- a/tests/common_test.py
++++ b/tests/common_test.py
+@@ -1,7 +1,7 @@
+ import uuid
+ from unittest import mock
+ 
+-import importlib_resources
++import importlib.resources as importlib_resources
+ 
+ from swagger_spec_validator.common import read_file
+ from swagger_spec_validator.common import read_resource_file
diff --git a/dev-python/swagger-spec-validator/metadata.xml b/dev-python/swagger-spec-validator/metadata.xml
new file mode 100644
index 000000000000..5e95859f915a
--- /dev/null
+++ b/dev-python/swagger-spec-validator/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/swagger-spec-validator/swagger-spec-validator-3.0.4.ebuild b/dev-python/swagger-spec-validator/swagger-spec-validator-3.0.4.ebuild
new file mode 100644
index 000000000000..a6daa6ac84c7
--- /dev/null
+++ b/dev-python/swagger-spec-validator/swagger-spec-validator-3.0.4.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+MY_P=swagger_spec_validator-${PV}
+DESCRIPTION="Validate Swagger specs against Swagger 1.1 or 2.0 specification"
+HOMEPAGE="
+	https://github.com/Yelp/swagger_spec_validator/
+	https://pypi.org/project/swagger-spec-validator/
+"
+SRC_URI="
+	https://github.com/Yelp/swagger_spec_validator/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.0.4-fix-importlib.patch"
+)
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+	dev-python/sphinx-rtd-theme
+
+EPYTEST_DESELECT=(
+	# network (resolver)
+	tests/util/validate_spec_url_test.py::test_raise_SwaggerValidationError_on_urlopen_error
+	tests/validator12/validate_spec_url_test.py::test_raise_SwaggerValidationError_on_urlopen_error
+	tests/validator20/validate_spec_url_test.py::test_raise_SwaggerValidationError_on_urlopen_error
+)